passenger 4.0.59 → 4.0.60

data/packaging/debian/debian_specs/nginx/modules/nginx-lua/src/ngx_http_lua_variable.h

@@ -0,0 +1,20 @@
+
+/*
+ * Copyright (C) Xiaozhe Wang (chaoslawful)
+ * Copyright (C) Yichun Zhang (agentzh)
+ */
+
+
+#ifndef _NGX_HTTP_LUA_VARIABLE_H_INCLUDED_
+#define _NGX_HTTP_LUA_VARIABLE_H_INCLUDED_
+
+
+#include "ngx_http_lua_common.h"
+
+
+void ngx_http_lua_inject_variable_api(lua_State *L);
+
+
+#endif /* _NGX_HTTP_LUA_VARIABLE_H_INCLUDED_ */
+
+/* vi:set ft=c ts=4 sw=4 et fdm=marker: */

data/packaging/debian/debian_specs/nginx/modules/nginx-lua/src/ngx_http_lua_worker.c

@@ -0,0 +1,64 @@
+
+/*
+ * Copyright (C) Yichun Zhang (agentzh)
+ */
+
+
+#ifndef DDEBUG
+#define DDEBUG 0
+#endif
+#include "ddebug.h"
+
+
+#include "ngx_http_lua_worker.h"
+
+
+static int ngx_http_lua_ngx_worker_exiting(lua_State *L);
+static int ngx_http_lua_ngx_worker_pid(lua_State *L);
+
+
+void
+ngx_http_lua_inject_worker_api(lua_State *L)
+{
+    lua_createtable(L, 0 /* narr */, 2 /* nrec */);    /* ngx.worker. */
+
+    lua_pushcfunction(L, ngx_http_lua_ngx_worker_exiting);
+    lua_setfield(L, -2, "exiting");
+
+    lua_pushcfunction(L, ngx_http_lua_ngx_worker_pid);
+    lua_setfield(L, -2, "pid");
+
+    lua_setfield(L, -2, "worker");
+}
+
+
+static int
+ngx_http_lua_ngx_worker_exiting(lua_State *L)
+{
+    lua_pushboolean(L, ngx_exiting);
+    return 1;
+}
+
+
+static int
+ngx_http_lua_ngx_worker_pid(lua_State *L)
+{
+    lua_pushinteger(L, (lua_Integer) ngx_pid);
+    return 1;
+}
+
+
+#ifndef NGX_LUA_NO_FFI_API
+int
+ngx_http_lua_ffi_worker_pid(void)
+{
+    return (int) ngx_pid;
+}
+
+
+int
+ngx_http_lua_ffi_worker_exiting(void)
+{
+    return (int) ngx_exiting;
+}
+#endif

data/packaging/debian/debian_specs/nginx/modules/nginx-lua/src/ngx_http_lua_worker.h

@@ -0,0 +1,17 @@
+
+/*
+ * Copyright (C) Yichun Zhang (agentzh)
+ */
+
+
+#ifndef _NGX_HTTP_LUA_WORKER_H_INCLUDED_
+#define _NGX_HTTP_LUA_WORKER_H_INCLUDED_
+
+
+#include "ngx_http_lua_common.h"
+
+
+void ngx_http_lua_inject_worker_api(lua_State *L);
+
+
+#endif /* _NGX_HTTP_LUA_WORKER_H_INCLUDED_ */

data/packaging/debian/debian_specs/nginx/modules/nginx-lua/tapset/ngx_lua.stp

@@ -0,0 +1,5 @@
+function ngx_http_lua_ctx_context(r)
+{
+
+}
+

data/packaging/debian/debian_specs/nginx/modules/nginx-lua/util/build.sh

@@ -0,0 +1,39 @@
+#!/bin/bash
+
+# this file is mostly meant to be used by the author himself.
+
+version=${1:-0.8.54}
+opts=$2
+
+root=$(cd ${0%/*}/.. && echo $PWD)
+mkdir -p $root/{build,work}
+
+cd $root
+git submodule update --init
+
+cd $root/build
+if [ ! -s nginx-$version.tar.gz ]; then
+    wget "http://sysoev.ru/nginx/nginx-$version.tar.gz" -O nginx-$version.tar.gz
+fi
+tar -xzvf nginx-$version.tar.gz
+
+cd nginx-$version/
+if [[ "$BUILD_CLEAN" -eq 1 || ! -f Makefile || "$root/config" -nt Makefile || "$root/util/build.sh" -nt Makefile ]]; then
+	./configure --prefix=$root/work \
+				--add-module=$root \
+				--add-module=$root/deps/ngx_devel_kit \
+				$opts \
+                                --with-debug
+fi
+
+if [ -f $root/work/sbin/nginx ]; then
+    rm -f $root/work/sbin/nginx
+fi
+
+if [ -f $root/work/logs/nginx.pid ]; then
+    kill `cat $root/work/logs/nginx.pid`
+fi
+
+make -j2
+make install
+

data/packaging/debian/debian_specs/nginx/modules/nginx-lua/util/build2.sh

@@ -0,0 +1,55 @@
+#!/usr/bin/env bash
+
+# this file is mostly meant to be used by the author himself.
+
+root=`pwd`
+version=${1:-1.4.1}
+home=~
+force=$2
+
+# the ngx-build script is from https://github.com/agentzh/nginx-devel-utils
+
+            #--add-module=$home/work/nginx_upload_module-2.2.0 \
+
+            #--without-pcre \
+            #--without-http_rewrite_module \
+            #--without-http_autoindex_module \
+            #--with-cc=gcc46 \
+            #--with-cc=clang \
+            #--without-http_referer_module \
+
+time ngx-build $force $version \
+            --with-ipv6 \
+            --with-cc-opt="-I$PCRE_INC" \
+            --with-http_realip_module \
+        --with-http_ssl_module \
+            --add-module=$root/../ndk-nginx-module \
+            --add-module=$root/../set-misc-nginx-module \
+            --with-ld-opt="-L$PCRE_LIB -Wl,-rpath,$PCRE_LIB:$LIBDRIZZLE_LIB:/usr/local/lib" \
+            --with-http_spdy_module \
+            --without-mail_pop3_module \
+            --without-mail_imap_module \
+            --without-mail_smtp_module \
+            --without-http_upstream_ip_hash_module \
+            --without-http_empty_gif_module \
+            --without-http_memcached_module \
+            --without-http_auth_basic_module \
+            --without-http_userid_module \
+                --add-module=$home/work/nginx/ngx_http_auth_request_module-0.2 \
+                --add-module=$root/../echo-nginx-module \
+                --add-module=$root/../memc-nginx-module \
+                --add-module=$root/../srcache-nginx-module \
+                --add-module=$root \
+                --add-module=$root/../lua-upstream-nginx-module \
+              --add-module=$root/../headers-more-nginx-module \
+                --add-module=$root/../drizzle-nginx-module \
+                --add-module=$root/../rds-json-nginx-module \
+                --add-module=$root/../coolkit-nginx-module \
+                --add-module=$root/../redis2-nginx-module \
+                --with-http_gunzip_module \
+          --with-select_module \
+          --with-poll_module \
+          --with-rtsig_module \
+                $opts \
+                --with-debug
+

data/packaging/debian/debian_specs/nginx/modules/nginx-lua/util/fix-comments

@@ -0,0 +1,27 @@
+#!/usr/bin/env perl
+
+use strict;
+use warnings;
+
+for my $infile (@ARGV) {
+    warn "Processing $infile...\n";
+    open my $in, $infile or
+        die "Cannot open $infile for reading: $!\n";
+    my $s;
+    my $changed = 0;
+    while (<$in>) {
+        $changed += s{//(.*)}{/* $1 */};
+        $s .= $_;
+    }
+    close $in;
+
+    if ($changed) {
+        my $outfile = $infile;
+        open my $out, ">$outfile" or
+            die "Cannot open $outfile for writing: $!\n";
+        print $out $s;
+        close $out;
+        warn "Wrote $outfile\n";
+    }
+}
+

data/packaging/debian/debian_specs/nginx/modules/nginx-lua/util/gdbinit

@@ -0,0 +1,415 @@
+# This gdb script provides several useful routines for debugging ngx_lua or
+# standalone Lua/LuaJIT.
+#
+# You need gdb >= v7.3 to make this script working correctly.
+#
+# Installation: place it at $HOME/.gdbinit
+#
+# -- chaoslawful <at> gmail <dot> com
+
+#### Lua type defines ####
+
+set $__LUA_TNONE = -1
+set $__LUA_TNIL = 0
+set $__LUA_TBOOLEAN = 1
+set $__LUA_TLIGHTUSERDATA = 2
+set $__LUA_TNUMBER = 3
+set $__LUA_TSTRING = 4
+set $__LUA_TTABLE = 5
+set $__LUA_TFUNCTION = 6
+set $__LUA_TUSERDATA = 7
+set $__LUA_TTHREAD = 8
+
+#### Lua constants ####
+
+set $__LUA_GLOBALSINDEX = -10002
+set $__LUA_ENVIRONINDEX = -10001
+set $__LUA_REGISTRYINDEX = -10000
+
+#### Auxiliary methods ####
+
+define __lua_debug_instance
+	if !$__lua_debug_instance
+		set $__lua_debug_instance = (lua_Debug*)malloc(sizeof(lua_Debug))
+	end
+end
+
+define __free_lua_debug_instance
+	if $__lua_debug_instance
+		set $rc = free($__lua_debug_instance)
+		set $__lua_debug_instance = 0
+	end
+end
+
+set $__BUCKET_SIZE = 16
+define __set_instance
+	if !$__set_instance
+		set $__set_instance = (void*(*(*))[2])malloc($__BUCKET_SIZE*sizeof(void*(*)[2]))
+		set $rc = memset($__set_instance, 0, $__BUCKET_SIZE*sizeof(void*(*)[2]))
+	end
+end
+
+define __free_set_instance
+	if $__set_instance
+		__set_clean
+		set $rc = free($__set_instance)
+		set $__set_instance = 0
+	end
+end
+
+define __set_add
+	set $p = (void*)$arg0
+	set $__bkt_idx = (int)$p%$__BUCKET_SIZE
+
+	__set_instance
+	set $__elem = (void*(*)[2])$__set_instance[$__bkt_idx]
+	set $__found = 0
+	while $__elem
+		if (*$__elem)[0] == $p
+			set $__found = 1
+			loop_break
+		end
+		set $__elem = (void*(*)[2])(*$__elem)[1]
+	end
+	if $__found
+		set $existed_in_set = 1
+	else
+		set $existed_in_set = 0
+
+		set $rc = (void*(*)[2])calloc(1, sizeof(void*)*2)
+		set (*$rc)[0] = $p
+		set (*$rc)[1] = $__set_instance[$__bkt_idx]
+		set $__set_instance[$__bkt_idx] = $rc
+	end
+end
+
+define __set_is_exist
+	set $p = (void*)$arg0
+	set $__bkt_idx = (int)$p%$__BUCKET_SIZE
+
+	__set_instance
+	set $__elem = (void*(*)[2])$__set_instance[$__bkt_idx]
+	set $__found = 0
+	while $__elem
+		if (*$__elem)[0] == $p
+			set $__found = 1
+			loop_break
+		end
+		set $__elem = (void*(*)[2])(*$__elem)[1]
+	end
+	if $__found
+		set $existed_in_set = 1
+	else
+		set $existed_in_set = 0
+	end
+end
+
+define __set_clean
+	__set_instance
+
+	set $__bkt_idx = 0
+	while $__bkt_idx < $__BUCKET_SIZE
+		set $__elem = (void*(*)[2])$__set_instance[$__bkt_idx]
+		while $__elem
+			set $__next = (void*(*)[2])(*$__elem)[1]
+			set $rc = free($__elem)
+			set $__elem = $__next
+		end
+		set $__set_instance[$__bkt_idx] = 0
+		set $__bkt_idx = $__bkt_idx+1
+	end
+end
+
+define hook-quit
+	__free_lua_debug_instance
+	__free_set_instance
+end
+
+define hook-detach
+	__free_lua_debug_instance
+	__free_set_instance
+end
+
+define hook-disconnect
+	__free_lua_debug_instance
+	__free_set_instance
+end
+
+define _lua_pop
+	set $l = (lua_State*)$arg0
+	set $_n = (int)$arg1
+	set $_rc = lua_settop($l, -$_n-1)
+end
+
+define _lua_dump_locals
+	set $l = (lua_State*)$arg0
+	set $dbg = (lua_Debug*)$arg1
+	set $idx = 1
+
+	set $rc = lua_getlocal($l, $dbg, $idx)
+	if $rc
+		printf "\t----[[ Locals ]]----\n"
+		while $rc
+			printf "\t%d:\t'%s' = ", $idx, $rc
+			__lua_dump_stack $l -1
+			printf "\n"
+
+			_lua_pop $l 1
+			set $idx = $idx + 1
+			set $rc = lua_getlocal($l, $dbg, $idx)
+		end
+	else
+		printf "\tNo locals!\n"
+	end
+	printf "\n"
+end
+
+define _lua_dump_upvalues
+	set $l = (lua_State*)$arg0
+	set $dbg = (lua_Debug*)$arg1
+	set $idx = 1
+
+	set $rc = lua_getinfo($l, "f", $dbg)
+	if $rc
+		set $rc = lua_getupvalue($l, -1, $idx)
+		if $rc
+			printf "\t----[[ Upvalues ]]----\n"
+			while $rc
+				printf "\t%d:\t'%s' = ", $idx, $rc
+				__lua_dump_stack $l -1
+				printf "\n"
+
+				_lua_pop $l 1
+				set $idx = $idx + 1
+				set $rc = lua_getupvalue($l, -1, $idx)
+			end
+		else
+			printf "\tNo upvalues!\n"
+		end
+		_lua_pop $l 1
+	else
+		printf "\tFailed to get function closure!\n"
+	end
+	printf "\n"
+end
+
+define __lua_dump_stack
+	__set_clean
+	__lua_dump_stack_aux $arg0 $arg1 0
+end
+
+define __lua_dump_stack_aux
+	set $l = (lua_State*)$arg0
+	set $nidx_$arg2 = (int)$arg1
+	set $cidx_$arg2 = (int)$arg2+1
+
+	# relative stack index to absolute index
+	if $nidx_$arg2 < 0 && $nidx_$arg2 > $__LUA_REGISTRYINDEX
+		set $nidx_$arg2 = $nidx_$arg2 + (int)lua_gettop($l) + 1
+	end
+
+	set $vt_$arg2 = (int)lua_type($l, $nidx_$arg2)
+
+	if $vt_$arg2 == $__LUA_TNONE
+		echo <invalid index>
+	end
+	if $vt_$arg2 == $__LUA_TNIL
+		echo (nil)
+	end
+	if $vt_$arg2 == $__LUA_TBOOLEAN
+		printf "(bool) %d", lua_toboolean($l, $nidx_$arg2)
+	end
+	if $vt_$arg2 == $__LUA_TLIGHTUSERDATA
+		printf "(ludata) %p", lua_touserdata($l, $nidx_$arg2)
+	end
+	if $vt_$arg2 == $__LUA_TNUMBER
+		printf "%g", lua_tonumber($l, $nidx_$arg2)
+	end
+	if $vt_$arg2 == $__LUA_TSTRING
+		set $tmplen = (size_t*)malloc(sizeof(size_t))
+		set $tmp = lua_pushvalue($l, $nidx_$arg2)
+		set $tmp = lua_tolstring($l, -1, $tmplen)
+#printf "(string:%d) ", *$tmplen
+		eval "output/r *(const char (*)[%d])$tmp", *$tmplen
+		_lua_pop $l 1
+		set $tmp = free($tmplen)
+	end
+	if $vt_$arg2 == $__LUA_TTABLE
+		set $rc = lua_topointer($l, $nidx_$arg2)
+#printf "(table) %p { ", $rc
+		printf "{ "
+		__set_add $rc
+		if $existed_in_set
+			printf "... "
+		else
+			set $rc = lua_pushnil($l)
+			set $rc = lua_next($l, $nidx_$arg2)
+			while $rc != 0
+				printf "["
+				__lua_dump_stack_aux $l -2 $cidx_$arg2
+				printf "]"
+				printf " = "
+				__lua_dump_stack_aux $l -1 $cidx_$arg2
+				printf ", "
+				_lua_pop $l 1
+				set $rc = lua_next($l, $nidx_$arg2)
+			end
+		end
+		printf "}"
+	end
+	if $vt_$arg2 == $__LUA_TFUNCTION
+		printf "(func) %p", lua_topointer($l, $nidx_$arg2)
+	end
+	if $vt_$arg2 == $__LUA_TUSERDATA
+		printf "(udata) %p", lua_topointer($l, $nidx_$arg2)
+	end
+	if $vt_$arg2 == $__LUA_TTHREAD
+		printf "(thread) %p", lua_topointer($l, $nidx_$arg2)
+	else
+		if $vt_$arg2 > $__LUA_TTHREAD || $vt_$arg2 < 0
+			echo <unknown type>
+		end
+	end
+end
+
+#### Command methods ####
+
+define lbt 
+	if $argc < 1
+		echo Please specify Lua state and/or dump flag!\n
+	else
+		set $l = (lua_State*)$arg0
+		if $argc > 1
+			set $dump_local = ($arg1&1)==1
+			set $dump_upvalue = ($arg1&2)==2
+		else
+			set $dump_local = 0
+			set $dump_upvalue = 0
+		end
+
+		__lua_debug_instance
+		set $dbg = $__lua_debug_instance
+
+		set $level = 0
+		set $rc = lua_getstack($l, $level, $dbg)
+		while $rc > 0
+			set $rc = lua_getinfo($l, "Sln", $dbg)
+			set $name = $dbg->name
+			if !$name
+				set $name = "???"
+			end
+
+			printf "#%d\t%s\t[%s]\tat %s:%d\n", $level, $name, $dbg->what, $dbg->source, $dbg->currentline
+
+			if $dump_local
+				_lua_dump_locals $l $dbg
+			end
+			if $dump_upvalue
+				_lua_dump_upvalues $l $dbg
+			end
+
+			set $level = $level+1
+			set $rc = lua_getstack($l, $level, $dbg)
+		end
+	end
+end
+
+document lbt
+lbt <lua state> [<dump>]: Dump the backtrace of the specified Lua state. <dump> is a mask value, whose bit 1/2 controls the dump of locals/upvalues at each stack frame correspondingly. So set <dump> to 1 dumps only locals; set to 2 dumps only upvalues; and set to 3 dumps both locals and upvalues.
+end
+
+define ll
+	if $argc != 2
+		echo Please specify Lua state and stack frame number (0-based)!\n
+	else
+		set $l = (lua_State*)$arg0
+		set $level = (int)$arg1
+
+		__lua_debug_instance
+		set $dbg = $__lua_debug_instance
+
+		set $rc = lua_getstack($l, $level, $dbg)
+		if $rc > 0
+			_lua_dump_locals $l $dbg
+		else
+			echo Failed to get Lua stack frame!\n
+		end
+	end
+end
+
+document ll
+ll <lua state> <frameno>: Dump all local vars in the specified Lua stack frame (0-based).
+end
+
+define lu
+	if $argc != 2
+		echo Please specify Lua state and stack frame number (0-based)!\n
+	else
+		set $l = (lua_State*)$arg0
+		set $level = (int)$arg1
+
+		__lua_debug_instance
+		set $dbg = $__lua_debug_instance
+
+		set $rc = lua_getstack($l, $level, $dbg)
+		if $rc > 0
+			_lua_dump_upvalues $l $dbg
+		else
+			echo Failed to get Lua stack frame!\n
+		end
+	end
+end
+
+document lu
+lu <lua state> <frameno>: Dump all upvalues in the specified Lua stack frame (0-based).
+end
+
+define lg
+	if $argc != 1
+		echo Please specify Lua state!\n
+	else
+		set $l = (lua_State*)$arg0
+		__lua_dump_stack $l $__LUA_GLOBALSINDEX
+		printf "\n"
+	end
+end
+
+document lg
+lg <lua state>: Dump all entries in Lua global table.
+end
+
+define lr
+	if $argc != 1
+		echo Please specify Lua state!\n
+	else
+		set $l = (lua_State*)$arg0
+		__lua_dump_stack $l $__LUA_REGISTRYINDEX
+		printf "\n"
+	end
+end
+
+document lr
+lr <lua state>: Dump all entries in Lua registry table.
+end
+
+define ls
+	if $argc != 1
+		echo Please specify Lua state!\n
+	else
+		set $l = (lua_State*)$arg0
+		set $idx = lua_gettop($l)
+		while $idx >= 1
+			printf "#%d ", $idx
+			__lua_dump_stack $l $idx
+			printf "\n"
+			set $idx = $idx - 1
+		end
+	end
+end
+
+document ls
+ls <lua state>: Dump all entries in call stack.
+end
+
+# vi:ft=gdb ts=4 sw=4
+