octopress 3.0.0.alpha1

data/.themes/classic/assets/javascripts/lib/octopress.js

@@ -0,0 +1,83 @@
+var octopress = (function(){
+  return {
+    addMobileNav: function () {
+      var mainNav = $('ul.main-navigation, ul[role=main-navigation]').before('<fieldset class="mobile-nav">')
+      var mobileNav = $('fieldset.mobile-nav').append('<select>');
+      mobileNav.find('select').append('<option value="">Navigate&hellip;</option>');
+      var addOption = function(i, option) {
+        mobileNav.find('select').append('<option value="' + this.href + '">&raquo; ' + $(this).text() + '</option>');
+      }
+      mainNav.find('a').each(addOption);
+      $('ul.subscription a').each(addOption);
+      mobileNav.find('select').bind('change', function(event) {
+        if (event.target.value) { window.location.href = event.target.value; }
+      });
+    }
+
+    , addSidebarToggler: function () {
+      if(!$('body').hasClass('sidebar-footer')) {
+        $('#content').append('<span class="toggle-sidebar"></span>');
+        $('.toggle-sidebar').bind('click', function(e) {
+          e.preventDefault();
+          if ($('body').hasClass('collapse-sidebar')) {
+            $('body').removeClass('collapse-sidebar');
+          } else {
+            $('body').addClass('collapse-sidebar');
+          }
+        });
+      }
+      var sections = $('.sidebar section');
+      if (sections.length > 1) {
+        sections.each(function(index){
+          if ((sections.length >= 3) && index % 3 === 0) {
+            $(this).addClass("first");
+          }
+          var count = ((index +1) % 2) ? "odd" : "even";
+          $(this).addClass(count);
+        });
+      }
+      if (sections.length >= 3){ $('aside.sidebar').addClass('thirds'); }
+    }
+
+    , testFeature: function (features) {
+      getTestClasses = function (tests) {
+        classes = '';
+        if (typeof(tests.join) == 'function') {
+          for (var i=0; i < features.length; i++)
+            classes += getClass(features[i]) + ' ';
+        } else {
+          classes = getClass(tests);
+        }
+        return classes;
+      }
+
+      getClass = function (test) {
+        return ((Modernizr.testAllProps(test) ? test : "no-"+test).toLowerCase())
+      }
+
+      $('html').addClass(getTestClasses(features));
+    }
+
+    , wrapFlashVideos: function () {
+      $('object').each(function(i, object) {
+        if( $(object).find('param[name=movie]').length ){
+          o = $(object)
+          ratio = (o.height()/o.width()*100)+'%';
+          o.wrap('<div class="flash-video"><div style="padding-bottom: '+ratio+'">')
+        }
+      });
+      $('iframe[src*=vimeo],iframe[src*=youtube]').each(function(i, video) {
+        v = $(video)
+        ratio = (v.height()/v.width()*100)+'%';
+        $(video).wrap('<div class="flash-video"><div style="padding-bottom: '+ratio+'">')
+      });
+    }
+  }
+})();
+
+$(document).ready(function() {
+  octopress.wrapFlashVideos();
+  octopress.testFeature(['maskImage', 'transform']);
+  octopress.addMobileNav();
+  octopress.addSidebarToggler();
+});

data/.themes/classic/assets/javascripts/modules/adn-timeline.coffee

@@ -0,0 +1,68 @@
+# App.net fetcher for Octopress (c) Brandon Mathis // MIT License
+helpers = require('helpers')
+
+Adn =
+  timeline: []
+  cookie: 'adn-feed'
+  classname: 'adn-feed'
+
+  template: ->
+    helpers.statusFeed @timeline, @classname
+
+  errorTemplate: ->
+    helpers.errorTemplate "Failed to load posts.", @classname
+
+  parseHtml: (post)->
+    text = helpers.trimDisplayUrls post.html
+    text = text.replace "@#{mention.name}", "<a href='https://alpha.app.net/#{mention.name}'>@#{mention.name}</a>" for mention in post.entities.mentions
+    text = text.replace "##{hashtag.name}", "<a href='https://alpha.app.net/hashtags/#{hashtag.name}'>##{hashtag.name}</a>" for hashtag in post.entities.hashtags
+    text
+
+  getPost: (post) ->
+    type = if post.repost_of then 'repost' else 'post'
+    post = if type is 'repost' then post.repost_of else post
+    {
+      type: type
+      url: post.canonical_url
+      date: post.created_at
+      author: { user: post.user.username, name: post.user.name, url: post.user.canonical_url } if type is 'repost'
+      text: @parseHtml post
+    }
+
+  format: (posts, user, options) ->
+    postList = []
+    for post in posts
+      postList.push @getPost(post) unless post.repost_of and !options.reposts
+    postList
+
+  init: (user, options, callback) ->
+    posts = $.cookie @cookie
+    if posts
+      @timeline = JSON.parse(posts)
+      if @timeline.length isnt options.count
+        $.removeCookie @cookie
+        @timeline = []
+        init user, options, callback
+      else
+        callback @template()
+    else
+      url =  "https://alpha-api.app.net/stream/0/users/@#{user}/posts?"
+      url += "&max_id=#{options.max_id}" if options.max_id
+      url += "&include_directed_posts=0" unless options.replies
+      url += "&callback=?"
+
+      $.ajax
+        url:      url
+        dataType: 'jsonp'
+        error:    (err)  => callback @errorTemplate
+        success:  (response) =>
+          @timeline = @timeline.concat response.data
+          if @timeline.length < options.count
+            options.max_id = response.meta.max_id
+            init user, options, callback
+          else
+            @timeline = @format @timeline.slice(0, options.count), user, options
+            $.cookie @cookie, JSON.stringify @timeline, { path: '/' }
+            callback @template()
+
+module.exports = Adn

data/.themes/classic/assets/javascripts/modules/delicious-feed.coffee

@@ -0,0 +1,38 @@
+# Delicious fetcher for Octopress (c) Brandon Mathis // MIT License
+helpers = require('helpers')
+
+Delicious =
+  cookie: 'delicious-feed'
+  classname: 'delicious-feed'
+
+  template: (data) ->
+    helpers.linkFeed data, @classname
+
+  errorTemplate: ->
+    helpers.errorTemplate "Failed to load bookmarks.", @classname
+
+  format: (feed) ->
+    for item in feed
+      {
+        url:   item.u
+        date:  item.dt
+        title: item.d
+        text:  item.n
+        meta: "Tagged: " + ("<a title='view items #{item.a} tagged #{tag}' href='http://delicious.com/#{item.a}/#{tag}'>#{tag}</a>" for tag in item.t).join ' '
+      }
+
+  init: (user, options, callback) ->
+    feed = $.cookie @cookie
+    if feed
+      callback @template JSON.parse(feed)
+    else
+      $.ajax
+        url:      "http://feeds.delicious.com/v2/json/#{user}?&count=#{options.count}&callback=?"
+        dataType: 'jsonp'
+        error:    (err)  => callback @errorTemplate
+        success:  (data) =>
+          data = @format data
+          $.cookie @cookie, JSON.stringify data, { path: '/' }
+          callback @template data
+
+module.exports = Delicious

data/.themes/classic/assets/javascripts/modules/github-repos.coffee

@@ -0,0 +1,60 @@
+# Github fetcher for Octopress (c) Brandon Mathis // MIT License
+helpers = require('helpers')
+
+GitHub =
+  cookie: 'github-feed'
+  classname: 'github-feed'
+
+  template: (data)->
+    helpers.linkFeed data, @classname
+
+  errorTemplate: ->
+    helpers.errorTemplate "Failed to load repo list.", @classname
+
+  addRepo: (repo)->
+    title: repo.name
+    url:   repo.url
+    text:  repo.description
+    meta:  repo.meta
+
+  format: (repos, options) ->
+    repoList = []
+
+    if options.repos
+      filter = []
+      filter.push i.trim().toLowerCase() for i in options.repos.split ','
+
+    for repo in repos
+      unless repoList.length is options.count
+        if options.forks or options.watchers
+          repo.meta  = ''
+          if options.watchers
+            repo.meta += "Watchers: #{repo.watchers}"
+          if options.forks
+            repo.meta += ' ,' if repo.meta.length > 0
+            repo.meta += "Forks: #{repo.forks}"
+
+        if filter and filter.indexOf repo.name.toLowerCase() > -1
+          # repo order should match list
+          repoList[filter.indexOf repo.name] = @addRepo repo, options
+        else if !filter
+          repoList.push @addRepo repo, options unless options.skipForks and repo.fork
+
+    repoList
+
+  init: (user, options, callback) ->
+    if options.count or options.repos
+      feed = $.cookie @cookie
+      if feed
+        callback @template JSON.parse(feed)
+      else
+        $.ajax
+          url:      "https://api.github.com/users/#{user}/repos?callback=?"
+          dataType: 'jsonp'
+          error:    (err)  => callback @errorTemplate
+          success:  (data) =>
+            data =  @format(data.data, options)
+            $.cookie @cookie, JSON.stringify data, { path: '/' }
+            callback @template data
+
+module.exports = GitHub

data/.themes/classic/assets/javascripts/modules/github.coffee

@@ -0,0 +1,60 @@
+# Github fetcher for Octopress (c) Brandon Mathis // MIT License
+helpers = require('helpers')
+
+GitHub =
+  cookie: 'github-feed'
+  classname: 'github-feed'
+
+  template: (data)->
+    helpers.linkFeed data, @classname
+
+  errorTemplate: ->
+    helpers.errorTemplate "Failed to load repo list.", @classname
+
+  addRepo: (repo)->
+    title: repo.name
+    url:   repo.url
+    text:  repo.description
+    meta:  repo.meta
+
+  format: (repos, options) ->
+    repoList = []
+
+    if options.repos
+      filter = []
+      filter.push i.trim().toLowerCase() for i in options.repos.split ','
+
+    for repo in repos
+      unless repoList.length is options.count and options.count > 1
+        if options.forks or options.watchers
+          repo.meta  = ''
+          if options.watchers
+            repo.meta += "Watchers: #{repo.watchers}"
+          if options.forks
+            repo.meta += ' ,' if repo.meta.length > 0
+            repo.meta += "Forks: #{repo.forks}"
+
+        if filter and filter.indexOf repo.name.toLowerCase() > -1
+          # repo order should match list
+          repoList[filter.indexOf repo.name] = @addRepo repo, options
+        else if !filter
+          repoList.push @addRepo repo, options unless options.skipForks and repo.fork
+
+    repoList
+
+  init: (user, options, callback) ->
+    if options.count or options.repos
+      feed = $.cookie @cookie
+      if feed
+        callback @template JSON.parse(feed)
+      else
+        $.ajax
+          url:      "https://api.github.com/users/#{user}/repos?callback=?"
+          dataType: 'jsonp'
+          error:    (err)  => callback @errorTemplate
+          success:  (data) =>
+            data =  @format(data.data, options)
+            $.cookie @cookie, JSON.stringify data, { path: '/' }
+            callback @template data
+
+module.exports = GitHub

data/.themes/classic/assets/javascripts/modules/helpers.coffee

@@ -0,0 +1,96 @@
+# Helper methods for Octopress (c) 2013 Brandon Mathis // MIT License
+
+Helpers =
+  # Template helpers
+
+  linkFeed: (feed, classname)->
+    "<ul class='#{classname}'>" + (for item in feed
+      text  = "<li class='feed-item'>"
+      text += "<p class='title'><a href='#{item.url}'>#{item.title.replace '<','&lt;'}</a></p>"
+      text += "<p class='text'>#{item.text.replace '<','&lt;'}</p>"
+      text += "<p class='meta'>#{item.meta}</p>" if item.meta
+      text += "</li>"
+    ).join('') + "</ul>"
+
+  statusFeed: (feed, classname = '')->
+    "<ul class='#{classname}'>" + (for post in feed
+      text  = "<li class='status-item'>"
+      text += "<p><a href='#{post.url}'>#{@timeago post.date}</a>#{post.text}</p>"
+      text += "</li>"
+    ).join('') + "</ul>"
+
+  errorTemplate: (message, service = '') ->
+    "<p class='#{service} feed-error'>#{message}</p>"
+
+  htmlEscape: (str) ->
+    return String(str)
+      .replace(/&/g, '&amp;')
+      .replace(/"/g, '&quot;')
+      .replace(/'/g, '&#39;')
+      .replace(/</g, '&lt;')
+      .replace(/>/g, '&gt;')
+
+  # Url helpers
+
+  trimUrl: (url)->
+    parts = []
+    for part in url.split '/'
+      parts.push part if parts.concat(part).join('/').length < 35
+    parts = parts.join('/')
+    if parts.length < url.length then parts + '&hellip;' else parts
+
+  linkify: (text, marker, url) ->
+    text.replace new RegExp("(^|\\W|>)(#{marker})([^\\s<]+)", 'g'), "$1<a href='#{url}$3'>$2$3</a>"
+
+  trimDisplayUrls: (text)->
+    text.replace />https?:\/\/([^\s<]+)/gi, (match, p1)=>
+      ">#{@trimUrl(p1)}"
+
+  # ----------#
+  # Utilities #
+  # ----------#
+
+  # Sort an array of objects on a given key
+
+  sortByKey: (list, key, order='asc') ->
+    list = list.sort (a,b)->
+      if a[key] > b[key] then 1 else if b[key] > a[key] then -1 else 0
+    if order is 'desc' then list.reverse() else list
+
+
+  # Timeago based on JavaScript Pretty Date Copyright (c) 2011 John Resig
+
+  timeago: (time)->
+    say =
+      just_now:    "now"
+      minute_ago:  "1m"
+      minutes_ago: "m"
+      hour_ago:    "1h"
+      hours_ago:   "h"
+      yesterday:   "1d"
+      days_ago:    "d"
+      last_week:   "1w"
+      weeks_ago:   "w"
+
+    time  = time.replace(/-/g,"/").replace(/[TZ]/g," ")
+    secs  = ((new Date().getTime() - new Date(time).getTime()) / 1000)
+    mins  = Math.floor secs / 60
+    hours = Math.floor secs / 3600
+    days  = Math.floor secs / 86400
+    weeks = Math.floor days / 7
+
+    return '#' if isNaN(secs) or days < 0
+
+    if days is 0
+      if      secs < 60   then say.just_now
+      else if secs < 120  then say.minute_ago
+      else if secs < 3600 then mins + say.minutes_ago
+      else if secs < 7200 then say.hour_ago
+      else                     hours + say.hours_ago
+    else
+      if days is 1        then say.yesterday
+      else if days < 7    then days + say.days_ago
+      else if days is 7   then say.last_week
+      else                     weeks + say.weeks_ago
+
+module.exports = Helpers

data/.themes/classic/assets/javascripts/modules/pinboard-feed.coffee

@@ -0,0 +1,42 @@
+# Pinboard fetcher for Octopress (c) Brandon Mathis // MIT License
+helpers = require('helpers')
+
+Pinboard =
+  cookie: 'pinboard-feed'
+  classname: 'pinboard-feed'
+
+  template: (data) ->
+    helpers.linkFeed data, @classname
+
+  errorTemplate: ->
+    helpers.errorTemplate "Failed to load pins.", @classname
+
+  format: (feed) ->
+    for item in feed
+      {
+        url:   item.u
+        date:  item.dt
+        title: item.d
+        text:  item.n
+        meta: "Tagged: " + ("<a title='view items #{item.a} tagged #{tag}' href='http://pinboard.in/u:#{item.a}/t:#{tag}'>#{tag}</a>" for tag in item.t).join ' '
+      }
+
+  init: (user, options, callback) ->
+    feed = $.cookie @cookie
+    if feed
+      callback @template JSON.parse(feed)
+    else
+      url  = "http://feeds.pinboard.in/json/v1/u:#{user}"
+      url += "&count=#{options.count}"
+
+      $.ajax
+        url:      url
+        dataType: 'jsonp'
+        jsonp:    'cb'
+        error:    (err)  => callback @errorTemplate
+        success:  (data) =>
+          data = @format data
+          $.cookie @cookie, JSON.stringify data, { path: '/' }
+          callback @template data
+
+module.exports = Pinboard