nodectl 0.2.4

data/assets/javascript/controllers/application_controller.coffee

@@ -0,0 +1,73 @@
+UI.ApplicationController = Ember.ArrayController.extend
+  running_actions: (->
+    @store.find('action')
+  ).property()
+
+  version: (->
+    window.settings.version
+  ).property()
+
+  environments: (->
+    UI.get('settings').environments
+  ).property()
+
+  environmentClass: (->
+    UI.get('currentEnvironment').toString()
+  ).property('UI.currentEnvironment')
+
+  current_action: null
+
+  massRunOpened: false
+
+  current_action_hook: (->
+    # TODO: move it away
+    @escape_handler ||= (e) =>
+      if e.keyCode == 27
+        @send('closeAction')
+
+    if @get('current_action')
+      $("body").css('overflow', 'hidden')
+      $(document).on('keyup', @escape_handler)
+    else
+      $("body").css('overflow', 'auto')
+      $(document).off('keyup', @escape_handler)
+  ).observes('current_action')
+
+  actions:
+    install_service: (service) ->
+      service.run_slot('install')
+
+    uninstall_service: (service) ->
+      service.run_slot('uninstall')
+
+    updateAll: ->
+      @get('model').forEach (service) =>
+        if service.get('version_set_supported')
+          service.set_latest_version()
+
+    openAction: (action) ->
+      @set('current_action', action)
+
+    closeAction: ->
+      @set('current_action', null)
+
+    runAll: ->
+      @get('store').find('service').then (list) =>
+        list.forEach (service) =>
+          if !service.get('isRunning') && service.get('start_supported')
+            instance = @get('store').createRecord 'instance', service: service
+            instance.save().then =>
+              service.reload()
+
+    stopAll: ->
+      @get('store').find('instance').then (list) =>
+        list.forEach (instance) =>
+          if instance.get('status') == 'running'
+            instance.set('status', 'stopping')
+            instance.save()
+
+    toggleMassRunOpened: ->
+      @set('massRunOpened', !@get('massRunOpened'))
+
+    setEnvironment: (environment) ->
+      UI.set('currentEnvironment', environment)

data/assets/javascript/controllers/service_controller.coffee

@@ -0,0 +1,62 @@
+UI.ServiceController = Ember.ObjectController.extend
+
+  testme: null
+  inst_options: {}
+
+  currentEnvironmentObserver: (->
+    console.log 'set to ', UI.get('currentEnvironment').toString()
+    @set('inst_options.env', UI.get('currentEnvironment').toString())
+  ).observes('UI.currentEnvironment')
+
+  init: ->
+    @set('inst_options.env', UI.get('currentEnvironment').toString())
+
+  versions_opened: false
+
+  actions:
+    run_slot: (slot_name) ->
+      service = @get('model')
+      service.run_slot(slot_name.toString(), @get('inst_options'))
+
+    run_action: (action_name) ->
+      action = @store.createRecord 'action',
+        name:    action_name.toString()
+        service: @get('model')
+        options: @get('inst_options')
+
+      action.save().then =>
+        @controllerFor('application').send('openAction', action)
+        @get('model').reload()
+
+    startInstance: ->
+      instance = @store.createRecord 'instance',
+        service: @get('model')
+        options: @get('inst_options')
+      
+      instance.save().then =>
+        @get('model').reload()
+
+    stopInstance: (instance) ->
+      instance.set('status', 'stopping')
+      instance.save()
+
+    restartInstance: (instance) ->
+      instance.set('status', 'restarting')
+      instance.save()
+
+    killInstance: (instance) ->
+      instance.set('status', 'stopping')
+      instance.set('force_stop', true)
+      instance.save()
+
+    versions_toggle: ->
+      @set('versions_opened', !@get('versions_opened'))
+
+    setVersion: (version_id) ->
+      @get('model').set_version(version_id)
+
+    setLatestVersion: ->
+      @get('model').set_latest_version()
+
+    installService: (service) ->
+      @get('model').run_slot('install')

data/assets/javascript/event_handler.coffee

@@ -0,0 +1,51 @@
+class @EventHandler
+  constructor: (store) ->
+    @store = store
+    @ws    = new WebSocket("#{window.settings.ws}/events")
+
+    @ws.onmessage = (message) =>
+      event = JSON.parse(message.data)
+
+      switch event.resource
+        when "instance"
+          @instance_event(event)
+        when "action"
+          @action_event(event)
+        else
+          console.error "unknown event resource: '#{event.resource}'"
+
+  instance_event: (event) ->
+    switch event.event_name
+      when "started"
+        @store.find('instance', event.id).then (instance) ->
+          instance.get('service').reload()
+
+      when "stopped"
+        @store.find('instance', event.id).then (instance) ->
+          if event.payload.reason == "crashed"
+            service_id  = instance.get('service.id')
+            instance_id = instance.get('id')
+            window.notifier.error("#{service_id} instance #{instance_id} was crashed")
+
+          instance.get('service').reload()
+      else
+        console.error "unknown instance event: '#{event.event_name}'"
+
+  action_event: (event) ->
+    switch event.event_name
+      when "started"
+        @store.find('action')
+
+      when "stopped"
+        @store.find('action').then =>
+          @store.find('action', event.id).then (action) ->
+            service_id  = action.get('service.id')
+            action_name = action.get('name')
+
+            if action.get('isSucceed')
+              window.notifier.alert("#{service_id} action #{action_name} succeed")
+            else
+              window.notifier.error("#{service_id} action #{action_name} failed")
+
+      else
+        console.error "unknown action event: '#{event.event_name}'"

data/assets/javascript/models/action.coffee

@@ -0,0 +1,28 @@
+@UI.Action = DS.Model.extend
+  ws:          DS.attr('string')
+  name:        DS.attr('string')
+  service:     DS.belongsTo('service')
+  options:     DS.attr()
+  started_at:  DS.attr("string")
+  exit_status: DS.attr("number")
+
+  started_at_formatted: (->
+    moment(@get('started_at')).format("MM-DD-YYYY HH:MM:SS")
+  ).property('started_at')
+
+  result: (->
+    if @get('exit_status') is null
+      null
+    else if @get('exit_status') is 0
+      "succeed"
+    else
+      "failed"
+  ).property('exit_status')
+
+  isSucceed: (->
+    @get('exit_status') is 0
+  ).property('exit_status')
+
+  isFailed: (->
+    @get('exit_status') isnt null && @get('exit_status') isnt 0
+  ).property('exit_status')

data/assets/javascript/models/instance.coffee

@@ -0,0 +1,7 @@
+@UI.Instance = DS.Model.extend
+  status:  DS.attr('string')
+  service: DS.belongsTo('service')
+  options: DS.attr()
+
+  # Fake attrs for API actions
+  force_stop: DS.attr('boolean')

data/assets/javascript/models/service.coffee

@@ -0,0 +1,75 @@
+@UI.Service = DS.Model.extend
+  status:            DS.attr('string')
+  instances:         DS.hasMany('instance', async: true)
+  recipe_name:       DS.attr('string')
+  supported_slots:   DS.attr('array')
+  supported_actions: DS.attr('array')
+  logs:              DS.attr()
+  params:            DS.attr()
+
+  version_id:        DS.attr('string')
+  version_timestamp: DS.attr('string')
+  version_message:   DS.attr('string')
+
+  slot:        DS.attr('string')
+  slot_params: DS.attr()
+
+  start_supported: (->
+    @get('supported_slots').indexOf('start') >= 0 and @get('status') == 'installed'
+  ).property('status')
+
+  stop_supported: (->
+    @get('supported_slots').indexOf('start') >= 0
+  ).property('status')
+
+  install_supported: (->
+    @get('supported_slots').indexOf('install') >= 0 and @get('status') == 'available'
+  ).property('status')
+
+  uninstall_supported: (->
+    @get('supported_slots').indexOf('uninstall') >= 0 and @get('status') == 'installed'
+  ).property('status')
+
+  version_set_supported: (->
+    @get('supported_slots').indexOf('version_set') >= 0
+  )
+
+  params_iterable: (->
+    for key, value of @get('params')
+      $.extend({}, value, {name: key})
+  ).property()
+
+  run_slot: (slot_name, slot_params = {}, callback = null) ->
+    unless @get('supported_slots').indexOf(slot_name) >= 0
+      throw new Error("slot '#{slot_name}' is not supported for service '#{@get('id')}'")
+
+    @set('slot', slot_name)
+    @set('slot_params', slot_params)
+    @save().then =>
+      if slot_name == "install"
+        @get('store').find('service')
+
+      callback() if callback
+
+  set_version: (version_id) ->
+    @set('version_id', version_id)
+    @save().then =>
+      @reload()
+
+
+  set_latest_version: ->
+    @get('versions').then =>
+      @set_version(@get('versions.firstObject.id'))
+
+  versions: ( ->
+    @store.find('version', service_id: @get('id'))
+  ).property()
+
+  isInstalled: (->
+    @get('status') == 'installed'
+  ).property('status')
+
+  isRunning: (->
+    # FIXME: it does not work
+    @get('instances.length') > 0
+  ).property('instances.length')

data/assets/javascript/models/version.coffee

@@ -0,0 +1,3 @@
+@UI.Version = DS.Model.extend
+  timestamp: DS.attr('string')
+  message:   DS.attr('string')

data/assets/javascript/notifier.coffee

@@ -0,0 +1,64 @@
+class @Notifier
+  constructor: ->
+    $ =>
+      wrapper = $("#sound")
+
+      wrapper.append("<audio src='/sounds/error.mp3' preload='auto' id='sound_error'/>")
+      wrapper.append("<audio src='/sounds/alert.mp3' preload='auto' id='sound_alert'/>")
+
+      @sound =
+        error: $('#sound_error')[0];
+        alert: $('#sound_alert')[0];
+
+    @popupEnabled = true
+    @soundEnabled = false
+
+  notify: (text, type = 'alert') ->
+    @_showPopup(text, type)
+    @_playSound(type)
+
+  error: (text) ->
+    @notify(text, 'error')
+
+  alert: (text) ->
+    @notify(text, 'alert')
+
+  popupEnable: ->
+    @popupEnabled = true
+
+  popupDisable: ->
+    @popupEnabled = false
+
+  isPopupEnabled: ->
+    @popupEnabled
+
+  soundEnable: ->
+    @soundEnabled = true
+
+  soundDisable: ->
+    @soundEnabled = false
+
+  isSoundEnabled: ->
+    @soundEnabled
+
+  _showPopup: (text, type) ->
+    if @popupEnabled
+      if Notification && Notification.permission == 'granted'
+        new Notification('Nodectl', body: text)
+      else
+        $.notify_osd.create(text: text)
+
+  _playSound: (type) ->
+    if @soundEnabled && @sound && @sound[type]
+      if @current_sound
+        @current_sound.pause()
+        @current_sound.currentTime = 0
+
+      @current_sound = @sound[type]
+      @sound[type].play()
+
+$.notify_osd.setup
+  visible_max: 10
+  dismissable: true
+
+window.notifier = new Notifier()

data/assets/javascript/router.coffee

@@ -0,0 +1,3 @@
+UI.Router.map ->
+  @resource 'service',  path: '/:service_id', ->
+    @resource 'log', path: '/:log_name'

data/assets/javascript/routes/application.coffee

@@ -0,0 +1,6 @@
+@UI.ApplicationRoute = Em.Route.extend
+  model: ->
+    @store.find('service')
+
+  afterModel: ->
+    new EventHandler(@store)

data/assets/javascript/routes/log.coffee

@@ -0,0 +1,4 @@
+UI.LogRoute = Ember.Route.extend
+  model: (params) ->
+    @modelFor('service').get('logs').find (log) ->
+      log.name == params.log_name

data/assets/javascript/routes/service.coffee

@@ -0,0 +1,3 @@
+UI.ServiceRoute = Ember.Route.extend
+  model: (params) ->
+    @store.find('service', params.service_id)

data/assets/javascript/store.coffee

@@ -0,0 +1,32 @@
+UI.ApplicationSerializer = DS.ActiveModelSerializer.extend {}
+
+UI.ServiceSerializer = DS.ActiveModelSerializer.extend
+  serialize: (record, options) ->
+    json = @_super.apply(@, arguments)
+
+    action = record.get('action')
+
+    if action
+      json.action = action
+      json.action_params = record.get('action_params')
+      record.set('action', undefined)
+      record.set('action_params', undefined)
+
+    json
+
+
+UI.ArrayTransform = DS.Transform.extend
+  serialize: (jsonData)->
+    if Em.typeOf(jsonData) is 'array'
+      jsonData
+    else
+      []
+
+  deserialize: (externalData)->
+    switch Em.typeOf(externalData)
+      when 'array'
+        externalData
+      when 'string'
+        externalData.split(',').map((item)-> jQuery.trim(item))
+      else
+        []

data/assets/javascript/templates/application.hbs

@@ -0,0 +1,82 @@
+<div {{bind-attr class=":main-wrapper environmentClass"}}>
+  <nav class="navbar navbar-inverse navbar-fixed-top" role="navigation">
+    <div class="container-fluid">
+
+      <div class="navbar-header">
+        <button type="button" class="navbar-toggle" data-toggle="collapse" data-target="#navbar">
+          <span class="sr-only">Toggle navigation</span>
+          <span class="icon-bar"></span>
+          <span class="icon-bar"></span>
+          <span class="icon-bar"></span>
+        </button>
+        <a class="navbar-brand" href="#">Nodectl {{version}}</a>
+      </div>
+
+      <div class="collapse navbar-collapse" id="navbar">
+        <ul class="nav navbar-nav navbar-right">
+          {{view UI.NotifierControlView }}
+          {{view UI.ActionsListView tagName='li'}}
+          {{view UI.EnvironmentsListView tagName='li'}}
+        </ul>
+      </div>
+
+    </div>
+  </nav>
+
+  {{#if current_action}}
+    <div class="modal-window">
+      <span class="glyphicon glyphicon-remove modal-window-close" {{action 'closeAction'}}></span>
+      {{view UI.ActionView action=current_action}}
+    </div>
+  {{/if}}
+
+  <div class="container-fluid">
+    <div class="row">
+      <div class="col-xs-12 col-sm-4 col-md-4 col-lg-3 sidebar">
+        <div class="sidebar-services-list list-group">
+          {{#if massRunOpened}}
+            {{view UI.MassRunView services=this}}
+          {{else}}
+            <div class="list-group-item list-group-item-service list-group-item-service-controlls">
+              <div class="btn-group">
+                <button class="btn btn-primary btn-xs" {{action 'toggleMassRunOpened'}}>Run...</button>
+                <button class="btn btn-danger btn-xs" {{action 'stopAll'}}>Stop all</button>
+              </div>
+
+              {{view UI.InstallButtonView class="pull-right"}}
+            </div>
+
+            {{#each}}
+              {{#if isInstalled}}
+                {{#link-to 'service' this class="list-group-item list-group-item-service" classNameBindings="isRunning"}}
+                  <div class="service-run-indicator">&nbsp</div>
+
+                  <div class="sidebar-services-id">
+                    {{id}}
+                  </div>
+
+                  {{#if start_supported}}
+                    <span class="badge">{{instances.length}}</span>
+                  {{/if}}
+                {{/link-to}}
+              {{else}}
+                <div class="list-group-item list-group-item-service list-group-item-uninstalled">
+                  {{id}}
+                  {{#if install_supported}}
+                    {{view UI.InstallButtonView service=this class="pull-right"}}
+                  {{/if}}
+                </div>
+              {{/if}}
+            {{/each}}
+          {{/if}}
+        </div>
+      </div>
+
+      <div class="clearfix visible-xs"></div>
+
+      <div class="col-xs-12 col-sm-8 col-md-8 col-lg-9">
+        {{outlet}}
+      </div>
+    </div>
+  </div>
+</div>