nali 0.0.2

data/Gemfile

@@ -0,0 +1,4 @@
+source 'https://rubygems.org'
+
+# Specify your gem's dependencies in nali.gemspec
+gemspec

data/LICENSE.txt

@@ -0,0 +1,22 @@
+Copyright (c) 2014 4urbanoff
+
+MIT License
+
+Permission is hereby granted, free of charge, to any person obtaining
+a copy of this software and associated documentation files (the
+"Software"), to deal in the Software without restriction, including
+without limitation the rights to use, copy, modify, merge, publish,
+distribute, sublicense, and/or sell copies of the Software, and to
+permit persons to whom the Software is furnished to do so, subject to
+the following conditions:
+
+The above copyright notice and this permission notice shall be
+included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

data/README.md

@@ -0,0 +1,29 @@
+# Nali
+
+TODO: Write a gem description
+
+## Installation
+
+Add this line to your application's Gemfile:
+
+    gem 'nali'
+
+And then execute:
+
+    $ bundle
+
+Or install it yourself as:
+
+    $ gem install nali
+
+## Usage
+
+TODO: Write usage instructions here
+
+## Contributing
+
+1. Fork it
+2. Create your feature branch (`git checkout -b my-new-feature`)
+3. Commit your changes (`git commit -am 'Add some feature'`)
+4. Push to the branch (`git push origin my-new-feature`)
+5. Create new Pull Request

data/Rakefile

@@ -0,0 +1 @@
+require "bundler/gem_tasks"

data/lib/assets/javascripts/nali/application.js.coffee

@@ -0,0 +1,27 @@
+Nali.extend Application:
+  
+  domEngine:     jBone.noConflict()
+  wsServer:      'ws://' + window.location.host
+  defaultUrl:    ''
+  notFoundUrl:   ''
+  htmlContainer: 'body'
+  title:         'Application'
+  
+  run: ( options ) ->
+    @::starting()
+    @[ key ] = value for key, value of options
+    document.addEventListener 'DOMContentLoaded', =>
+      document.removeEventListener 'DOMContentLoaded', arguments.callee, false 
+      @::_           = @domEngine
+      @htmlContainer = @_ @htmlContainer
+      @setTitle @title
+      @trigger 'start'
+    , false 
+    
+  setTitle: ( @title ) ->
+    unless @titleBox
+      @_( '<title>' ).appendTo 'head' unless @_( 'head title' ).lenght
+      @titleBox = @_ 'head title'
+    @titleBox.text @title
+    @trigger 'update.title'
+    @

data/lib/assets/javascripts/nali/collection.js.coffee

@@ -0,0 +1,147 @@
+Nali.extend Collection:
+
+  toShowViews:  []
+  visibleViews: []
+  length:       0
+  
+  cloning: ->
+    @subscribeTo @Model, "create.#{ @model.sysname.lowercase() }", @onModelCreated
+    @adaptations = []
+    @ordering    = {}
+    @adaptCollection()
+    @
+
+  onModelCreated: ( model ) ->
+    @add model if model.isCorrect @filters
+    @
+  
+  onModelUpdated: ( model ) ->
+    @remove model unless model.isCorrect @filters
+    @
+  
+  onModelDestroyed: ( model ) ->
+    @remove model
+    @
+    
+  adaptCollection: ->
+    for name, method of @model when /^_\w+$/.test( name ) and typeof method is 'function'
+      do ( name, method ) =>
+        @[ name = name[ 1.. ] ] = ( args... ) =>
+          @adaptation ( model ) -> model[ name ] args...
+          @
+    @
+  
+  adaptModel: ( model ) ->
+    adaptation.call @, model for adaptation in @adaptations
+    @
+
+  adaptation: ( callback ) ->
+    callback.call @, model for model in @
+    @adaptations.push callback
+    @
+    
+  add: ( model ) ->
+    Array::push.call @, model
+    @adaptModel  model
+    @subscribeTo model, 'destroy', @onModelDestroyed
+    @subscribeTo model, 'update',  @onModelUpdated
+    @reorder()
+    @trigger 'update'
+    @trigger 'update.length'
+    @
+    
+  indexOf: ( model ) ->
+    Array::indexOf.call @, model
+  
+  remove: ( model ) ->
+    Array::splice.call @, @indexOf( model ), 1  
+    @unsubscribeTo model
+    @reorder()
+    @trigger 'update'
+    @trigger 'update.length'
+    @
+    
+  removeAll: ->
+    delete @[ index ] for model, index in @
+    @length = 0
+    @
+    
+  sort: ( sorter ) ->
+    Array::sort.call @, sorter
+    @
+    
+  order: ( @ordering ) ->
+    @reorder()
+    @
+  
+  reorder: ->
+    if @ordering.by?
+      clearTimeout @ordering.timer if @ordering.timer?
+      @ordering.timer = setTimeout =>
+        @sort ( one, two ) =>
+          one = one[ @ordering.by ]
+          two = two[ @ordering.by ]
+          if @ordering.as is 'number'
+            one = parseFloat one
+            two = parseFloat two
+          if @ordering.as is 'string'
+            one = one + ''
+            two = two + ''
+          ( if one > two then 1 else if one < two then -1 else 0 ) * ( if @ordering.desc then -1 else 1 )
+        @orderViews()
+        delete @ordering.timer
+      , 5
+    @
+    
+  orderViews: ->
+    if @inside
+      children = Array::slice.call @inside.children
+      children.sort ( one, two ) => @indexOf( one.view.model ) - @indexOf( two.view.model )
+      @inside.appendChild child for child in children
+    @
+ 
+  show: ( viewName, insertTo, isRelation = false ) ->
+    @adaptation ( model ) -> 
+      view = model.view viewName
+      if isRelation
+        view.subscribeTo @, 'reset', view.hide
+      else unless @visible
+        @visible = true
+        @prepareViewToShow view
+        @hideVisibleViews()
+      else
+        @::visibleViews.push view
+      view.show insertTo
+      @inside ?= view.element[0].parentNode
+    @
+      
+  prepareViewToShow: ( view ) ->
+    unless view in @::toShowViews
+      @::toShowViews.push view
+      @prepareViewToShow layout if ( layout = view.layout() )?.childOf? 'View'
+    @
+    
+  hideVisibleViews: ->
+    view.hide() for view in @::visibleViews when not( view in @::toShowViews )
+    @::visibleViews = @::toShowViews
+    @::toShowViews  = []
+    @
+    
+  first: ->
+    @[0]
+    
+  last: ->
+    @[ @length - 1 ]
+    
+  reset: ->
+    @inside             = null
+    @adaptations.length = 0
+    @trigger 'reset'
+    @
+  
+  destroy: ->
+    @trigger 'destroy'
+    @destroyObservation()
+    @removeAll()
+    @reset()
+    @

data/lib/assets/javascripts/nali/connection.js.coffee

@@ -0,0 +1,58 @@
+Nali.extend Connection:
+
+  initialize: ->
+    @subscribeTo @Application, 'start', @open
+    @::query = ( args... ) => @query args... 
+    @
+    
+  open: ->
+    @dispatcher = new WebSocket @Application.wsServer
+    @dispatcher.onopen    = ( event ) => @onOpen    event
+    @dispatcher.onclose   = ( event ) => @onClose   event
+    @dispatcher.onmessage = ( event ) => @onMessage JSON.parse event.data
+
+  journal: []
+    
+  onOpen: ( event ) ->
+    @trigger 'open'
+    
+  onMessage: ( message ) ->
+    @[ message.action ] message
+    
+  onClose: ( event ) ->
+    @trigger 'close'
+  
+  send: ( msg ) ->
+    @dispatcher.send JSON.stringify msg
+    @
+  
+  sync: ( message ) ->
+    @Model.sync message.params 
+    @
+    
+  notice: ( { model, notice, params } ) ->
+    if model?
+      [ model, id ] = model.split '.'
+      @Model.notice model: model, id: id, notice: notice, params: params
+    else @Notice[ notice ] params 
+    @          
+  
+  success: ( message ) ->
+    @journal[ message.journal_id ].success message.params
+    delete @journal[ message.journal_id ] 
+    @
+    
+  failure: ( message ) ->
+    @journal[ message.journal_id ].failure message.params
+    delete @journal[ message.journal_id ] 
+    @
+    
+  query: ( to, params, success, failure ) ->
+    [ controller, action ] = to.split '.'
+    @journal.push callbacks = success: success, failure: failure
+    @send 
+      controller: controller
+      action:     action
+      params:     params 
+      journal_id: @journal.indexOf callbacks
+    @

data/lib/assets/javascripts/nali/controller.js.coffee

@@ -0,0 +1,45 @@
+Nali.extend Controller:
+
+  extension: ->
+    if @sysname isnt 'Controller'
+      @prepareActions() 
+      @modelSysname = @sysname.replace /s$/, '' 
+    @
+
+  prepareActions: ->
+    @routedActions = {}
+    if @actions?
+      for action of @actions when action isnt 'default'
+        [ name, filters... ] = action.split '/'
+        params = []
+        for filter in filters[ 0.. ] when /^:/.test filter
+          filters.splice filters.indexOf( filter ), 1
+          params.push filter[ 1.. ]
+        @routedActions[ name ] = name: action, filters: filters, params: params
+    @
+  
+  runAction: ( name, filters, params ) ->
+    collection = @Model.extensions[ @modelSysname ].where filters 
+    result = @actions[ @routedActions[ name ].name ].call @, collection, params
+    if result instanceof Object and result.render is false
+      collection.destroy()
+    else
+      collection.show name
+      @changeUrl name, filters
+    @
+      
+  redirect: ( args... ) ->
+    @::redirect args...
+    render: false
+    
+  query: ( args... ) ->
+    @::query args...
+    render: false
+      
+  changeUrl: ( action, filters ) ->
+    params   = ( value for own key, value of filters )
+    url      = @sysname.lowercase().replace /s$/, ''
+    url     += if action is @actions.default then '' else '/' + action
+    url     += '/' + params.join '/' if params.length     
+    @Router.setUrl url
+    @

data/lib/assets/javascripts/nali/cookie.js.coffee

@@ -0,0 +1,21 @@
+Nali.extend Cookie:
+  
+  set: ( name, value, options = {} ) ->
+    set = "#{ name }=#{ escape( value ) }"
+    if options.live? and typeof options.live is 'number'
+      date = new Date
+      date.setDate date.getDate() + options.live 
+      date.setMinutes date.getMinutes() - date.getTimezoneOffset() 
+      set += "; expires=#{ date.toUTCString() }"
+    set += '; domain=' + escape options.domain if options.domain? 
+    set += '; path='   + if options.path? then escape options.path else '/'
+    set += '; secure'    if options.secure?
+    document.cookie = set
+    value
+
+  get: ( name ) ->
+    get = document.cookie.match "(^|;) ?#{ name }=([^;]*)(;|$)"
+    if get then unescape( get[2] ) else null
+
+  remove: ( name ) ->
+    @set name, '', live: -1

data/lib/assets/javascripts/nali/extensions.js.coffee

@@ -0,0 +1,16 @@
+String::uppercase = ->
+  "#{ @toUpperCase() }"
+
+String::lowercase = ->
+  "#{ @toLowerCase() }"
+
+String::capitalize = ->
+  @charAt(0).uppercase() + @slice(1)
+
+String::camelcase = ->
+  @replace /(_[^_]+)/g, ( match ) -> match[ 1.. ].capitalize()
+  
+String::underscore = ->
+  str = @replace /([A-Z])/g, ( match ) -> '_' + match.lowercase()
+  if str[ 0...1 ] is '_' then str[ 1.. ] else str  
+    

data/lib/assets/javascripts/nali/index.js.coffee

@@ -0,0 +1,10 @@
+#= require ./jbone.min
+#= require ./extensions
+#= require ./nali
+#= require ./application
+#= require ./connection
+#= require ./router
+#= require ./view
+#= require ./model
+#= require ./collection
+#= require_tree .

data/lib/assets/javascripts/nali/jbone.min.js

@@ -0,0 +1,10 @@
+/*!
+ * jBone v1.0.18 - 2014-07-08 - Library for DOM manipulation
+ *
+ * https://github.com/kupriyanenko/jbone
+ *
+ * Copyright 2014 Alexey Kupriyanenko
+ * Released under the MIT license.
+ */
+
+!function(a){function b(b){var c=b.length,d=typeof b;return o(d)||b===a?!1:1===b.nodeType&&c?!0:p(d)||0===c||"number"==typeof c&&c>0&&c-1 in b}function c(a,b){var c,d;this.originalEvent=a,d=function(a,b){this[a]="preventDefault"===a?function(){return this.defaultPrevented=!0,b[a]()}:o(b[a])?function(){return b[a]()}:b[a]};for(c in a)(a[c]||"function"==typeof a[c])&&d.call(this,c,a);q.extend(this,b)}var d,e=a.$,f=a.jBone,g=/^<(\w+)\s*\/?>$/,h=/^(?:[^#<]*(<[\w\W]+>)[^>]*$|#([\w\-]*)$)/,i=[].slice,j=[].splice,k=Object.keys,l=document,m=function(a){return"string"==typeof a},n=function(a){return a instanceof Object},o=function(a){var b={};return a&&"[object Function]"===b.toString.call(a)},p=function(a){return Array.isArray(a)},q=function(a,b){return new d.init(a,b)};q.noConflict=function(){return a.$=e,a.jBone=f,q},d=q.fn=q.prototype={init:function(a,b){var c,d,e,f;if(!a)return this;if(m(a)){if(d=g.exec(a))return this[0]=l.createElement(d[1]),this.length=1,n(b)&&this.attr(b),this;if((d=h.exec(a))&&d[1]){for(f=l.createDocumentFragment(),e=l.createElement("div"),e.innerHTML=a;e.lastChild;)f.appendChild(e.firstChild);return c=i.call(f.childNodes),q.merge(this,c)}if(q.isElement(b))return q(b).find(a);try{return c=l.querySelectorAll(a),q.merge(this,c)}catch(j){return this}}return a.nodeType?(this[0]=a,this.length=1,this):o(a)?a():a instanceof q?a:q.makeArray(a,this)},pop:[].pop,push:[].push,reverse:[].reverse,shift:[].shift,sort:[].sort,splice:[].splice,slice:[].slice,indexOf:[].indexOf,forEach:[].forEach,unshift:[].unshift,concat:[].concat,join:[].join,every:[].every,some:[].some,filter:[].filter,map:[].map,reduce:[].reduce,reduceRight:[].reduceRight,length:0},d.constructor=q,d.init.prototype=d,q.setId=function(b){var c=b.jid;b===a?c="window":void 0===b.jid&&(b.jid=c=++q._cache.jid),q._cache.events[c]||(q._cache.events[c]={})},q.getData=function(b){b=b instanceof q?b[0]:b;var c=b===a?"window":b.jid;return{jid:c,events:q._cache.events[c]}},q.isElement=function(a){return a&&a instanceof q||a instanceof HTMLElement||m(a)},q._cache={events:{},jid:0},q.merge=function(a,b){for(var c=b.length,d=a.length,e=0;c>e;)a[d++]=b[e++];return a.length=d,a},q.contains=function(a,b){var c;return a.reverse().some(function(a){return a.contains(b)?c=a:void 0}),c},q.extend=function(a){var b,c,d,e;return j.call(arguments,1).forEach(function(f){if(f)for(b=k(f),c=b.length,d=0,e=a;c>d;d++)e[b[d]]=f[b[d]]}),a},q.makeArray=function(a,c){var d=c||[];return null!==a&&(b(a)?q.merge(d,m(a)?[a]:a):d.push(a)),d},q.Event=function(a,b){var c,d;return a.type&&!b&&(b=a,a=a.type),c=a.split(".").splice(1).join("."),d=a.split(".")[0],a=l.createEvent("Event"),a.initEvent(d,!0,!0),q.extend(a,{namespace:c,isDefaultPrevented:function(){return a.defaultPrevented}},b)},d.on=function(a){var b,d,e,f,g,h,i,j,k=arguments,l=this.length,m=0;for(2===k.length?b=k[1]:(d=k[1],b=k[2]),j=function(j){q.setId(j),g=q.getData(j).events,a.split(" ").forEach(function(a){h=a.split(".")[0],e=a.split(".").splice(1).join("."),g[h]=g[h]||[],f=function(a){a.namespace&&a.namespace!==e||(i=null,d?(~q(j).find(d).indexOf(a.target)||(i=q.contains(q(j).find(d),a.target)))&&(i=i||a.target,a=new c(a,{currentTarget:i}),b.call(i,a)):b.call(j,a))},g[h].push({namespace:e,fn:f,originfn:b}),j.addEventListener&&j.addEventListener(h,f,!1)})};l>m;m++)j(this[m]);return this},d.one=function(a){var b,c,d,e=arguments,f=0,g=this.length;for(2===e.length?b=e[1]:(c=e[1],b=e[2]),d=function(d){a.split(" ").forEach(function(a){var e=function(c){q(d).off(a,e),b.call(d,c)};c?q(d).on(a,c,e):q(d).on(a,e)})};g>f;f++)d(this[f]);return this},d.trigger=function(a){var b,c=[],d=0,e=this.length;if(!a)return this;for(m(a)?c=a.split(" ").map(function(a){return q.Event(a)}):(a=a instanceof Event?a:q.Event(a),c=[a]),b=function(a){c.forEach(function(b){b.type&&a.dispatchEvent&&a.dispatchEvent(b)})};e>d;d++)b(this[d]);return this},d.off=function(a,b){var c,d,e,f,g=0,h=this.length,i=function(a,c,d,e,f){var g;(b&&f.originfn===b||!b)&&(g=f.fn),a[c][d].fn===g&&(e.removeEventListener(c,g),q._cache.events[q.getData(e).jid][c].splice(d,1))};for(e=function(b){var e,g,h;return(c=q.getData(b).events)?!a&&c?k(c).forEach(function(a){for(g=c[a],e=g.length;e--;)i(c,a,e,b,g[e])}):void a.split(" ").forEach(function(a){if(f=a.split(".")[0],d=a.split(".").splice(1).join("."),c[f])for(g=c[f],e=g.length;e--;)h=g[e],(!d||d&&h.namespace===d)&&i(c,f,e,b,h);else d&&k(c).forEach(function(a){for(g=c[a],e=g.length;e--;)h=g[e],h.namespace.split(".")[0]===d.split(".")[0]&&i(c,a,e,b,h)})}):void 0};h>g;g++)e(this[g]);return this},d.find=function(a){for(var b=[],c=0,d=this.length,e=function(c){o(c.querySelectorAll)&&[].forEach.call(c.querySelectorAll(a),function(a){b.push(a)})};d>c;c++)e(this[c]);return q(b)},d.get=function(a){return this[a]},d.eq=function(a){return q(this[a])},d.parent=function(){for(var a,b=[],c=0,d=this.length;d>c;c++)!~b.indexOf(a=this[c].parentElement)&&a&&b.push(a);return q(b)},d.toArray=function(){return i.call(this)},d.is=function(){var a=arguments;return this.some(function(b){return b.tagName.toLowerCase()===a[0]})},d.has=function(){var a=arguments;return this.some(function(b){return b.querySelectorAll(a[0]).length})},d.attr=function(a,b){var c,d=arguments,e=0,f=this.length;if(m(a)&&1===d.length)return this[0]&&this[0].getAttribute(a);for(2===d.length?c=function(c){c.setAttribute(a,b)}:n(a)&&(c=function(b){k(a).forEach(function(c){b.setAttribute(c,a[c])})});f>e;e++)c(this[e]);return this},d.val=function(a){var b=0,c=this.length;if(0===arguments.length)return this[0]&&this[0].value;for(;c>b;b++)this[b].value=a;return this},d.css=function(b,c){var d,e=arguments,f=0,g=this.length;if(m(b)&&1===e.length)return this[0]&&a.getComputedStyle(this[0])[b];for(2===e.length?d=function(a){a.style[b]=c}:n(b)&&(d=function(a){k(b).forEach(function(c){a.style[c]=b[c]})});g>f;f++)d(this[f]);return this},d.data=function(a,b){var c,d=arguments,e={},f=0,g=this.length,h=function(a,b,c){n(c)?(a.jdata=a.jdata||{},a.jdata[b]=c):a.dataset[b]=c},i=function(a){return"true"===a?!0:"false"===a?!1:a};if(0===d.length)return this[0].jdata&&(e=this[0].jdata),k(this[0].dataset).forEach(function(a){e[a]=i(this[0].dataset[a])},this),e;if(1===d.length&&m(a))return this[0]&&i(this[0].dataset[a]||this[0].jdata&&this[0].jdata[a]);for(1===d.length&&n(a)?c=function(b){k(a).forEach(function(c){h(b,c,a[c])})}:2===d.length&&(c=function(c){h(c,a,b)});g>f;f++)c(this[f]);return this},d.removeData=function(a){for(var b,c,d=0,e=this.length;e>d;d++)if(b=this[d].jdata,c=this[d].dataset,a)b&&b[a]&&delete b[a],delete c[a];else{for(a in b)delete b[a];for(a in c)delete c[a]}return this},d.html=function(a){var b,c=arguments;return 1===c.length&&void 0!==a?this.empty().append(a):0===c.length&&(b=this[0])?b.innerHTML:this},d.append=function(a){var b,c=0,d=this.length;for(m(a)&&h.exec(a)?a=q(a):n(a)||(a=document.createTextNode(a)),a=a instanceof q?a:q(a),b=function(b,c){a.forEach(function(a){b.appendChild(c?a.cloneNode():a)})};d>c;c++)b(this[c],c);return this},d.appendTo=function(a){return q(a).append(this),this},d.empty=function(){for(var a,b=0,c=this.length;c>b;b++)for(a=this[b];a.lastChild;)a.removeChild(a.lastChild);return this},d.remove=function(){var a,b=0,c=this.length;for(this.off();c>b;b++)a=this[b],delete a.jdata,a.parentNode&&a.parentNode.removeChild(a);return this},"object"==typeof module&&module&&"object"==typeof module.exports?module.exports=q:"function"==typeof define&&define.amd?(define(function(){return q}),a.jBone=a.$=q):"object"==typeof a&&"object"==typeof a.document&&(a.jBone=a.$=q)}(window);

data/lib/assets/javascripts/nali/model.js.coffee

@@ -0,0 +1,237 @@
+Nali.extend Model:
+  
+  extension: ->
+    if @sysname isnt 'Model'
+      @table       = @tables[ @sysname ] ?= []
+      @table.index = {}
+      @adapt()
+    @
+  
+  tables:      {}
+  hasOne:      []
+  hasMany:     []
+  attributes:  {}
+  updated:     0
+  noticesWait: []
+    
+  adapt: ->
+    for name, method of @ when /^_\w+/.test name
+      do ( name, method ) =>
+        if typeof method is 'function'
+          @[ name[ 1.. ] ] = ( args... ) -> @[ name ] args...
+    @
+    
+  notice: ( params ) ->
+    @noticesWait.push params
+    @runNotices()
+    @
+    
+  runNotices: ->
+    for item, index in @noticesWait[ 0.. ]
+      if model = @extensions[ item.model ].find item.id
+        model[ item.notice ] item.params
+        @noticesWait.splice @noticesWait.indexOf( item ), 1
+    @
+  
+  force: ( attributes = {} ) ->
+    ( attributes = @copy attributes ).id ?= null
+    for name, value of @attributes when not ( name of attributes )
+      if value instanceof Object
+        attributes[ name ] = if value.default? then value.default else null
+      else attributes[ name ] = value or null
+    attributes[ name ] = @normalizeValue value for name, value of attributes
+    @clone( attributes: attributes ).accessing()
+  
+  accessing: ->
+    @access @attributes
+    @setRelations()
+    @
+  
+  save: ( success, failure ) ->
+    if @isValid()?
+      @query "#{ @sysname.lowercase() }s.save", @attributes, #=> success? @
+        ( { attributes, created, updated } ) =>
+          @update( attributes, updated, created ).write()
+          success? @
+    else failure? @
+    @
+  
+  sync: ( { sysname, attributes, created, updated, destroyed } ) ->
+    if model = @extensions[ sysname ].find attributes.id 
+      if destroyed then model.remove()
+      else model.update attributes, updated, created
+    else
+      model = @extensions[ sysname ].build attributes
+      model.updated = updated
+      model.created = created
+      model.write()
+    @
+    
+  select: ( filters, success, failure ) ->
+    @query @sysname.lowercase() + 's.select', filters, success, failure if Object.keys( filters ).length
+    
+  destroy: ( success, failure ) ->
+    @query @sysname.lowercase() + 's.destroy', @attributes, success, failure
+             
+  write: ->
+    unless @ in @table
+      @table.push @ 
+      @table.index[ @id ] = @
+      @onCreate?()
+      @Model.trigger "create.#{ @sysname.lowercase() }", @
+      @Model.runNotices()
+    @
+    
+  remove: ->
+    if @ in @table
+      delete @table.index[ @id ]
+      @table.splice @table.indexOf( @ ), 1 
+      @trigger 'destroy', @
+      @onDestroy?()
+      @unsubscribeAll()
+    @  
+
+  build: ( attributes ) ->
+    @force attributes
+       
+  create: ( attributes, success, failure ) ->
+    @build( attributes ).save success, failure
+    
+  update: ( attributes, updated = 0, created = 0 ) ->
+    if not updated or updated > @updated
+      @created = created if created
+      changed = []
+      changed.push name for name, value of attributes when @update_attribute name, value
+      if changed.length
+        @updated = updated if updated
+        @onUpdate? changed
+        @trigger 'update', @, changed
+    @
+    
+  update_attribute: ( name, value ) ->
+    value = @normalizeValue value
+    if @attributes[ name ] isnt value and @isValidAttributeValue( name, value )?
+      @attributes[ name ] = value
+      @[ 'onUpdate' + name.capitalize() ]?()
+      @trigger "update.#{ name }", @
+      true
+    else false
+      
+  find: ( id ) ->
+    @table.index[ id ]
+        
+  where: ( filters ) ->
+    collection = @Collection.clone model: @, filters: filters
+    collection.add model for model in @table when model.isCorrect filters
+    if @forced and not collection.length
+      attributes = {}
+      attributes[ key ] = value for key, value of filters when typeof value in [ 'number', 'string' ]
+      collection.add @build attributes
+    @select filters
+    collection  
+    
+  normalizeValue: ( value ) ->
+    if typeof value is 'string'
+      value = "#{ value }".trim()
+      if value is ( ( correct = parseInt( value ) ) + '' ) then correct else value
+    else value
+
+  isCorrect: ( filters = {} ) ->
+    return false unless Object.keys( filters ).length
+    return false for name, filter of filters when not @isCorrectAttribute @attributes[ name ], filter
+    return true
+    
+  isCorrectAttribute: ( attribute, filter ) ->                  
+    return false unless attribute
+    if filter instanceof RegExp
+      filter.test attribute
+    else if typeof filter is 'string'
+      attribute.toString() is filter
+    else if typeof filter is 'number'
+      parseInt( attribute ) is filter
+    else if filter instanceof Array
+      attribute.toString() in filter or parseInt( attribute ) in filter
+    else false 
+    
+  setRelations: ->
+    @belongsToRelation  attribute for attribute of @attributes when /_id$/.test attribute
+    @hasOneRelation     attribute for attribute in [].concat @hasOne
+    @hasManyRelation    attribute for attribute in [].concat @hasMany
+    @  
+    
+  belongsToRelation: ( attribute ) ->
+    name  = attribute.replace '_id', ''
+    model = @Model.extensions[ name.capitalize() ]
+    @getter name, => model.find @[ attribute ]
+    @ 
+  
+  hasOneRelation: ( name ) ->
+    @getter name, => 
+      delete @[ name ]
+      ( filters = {} )[ "#{ @sysname.lowercase() }_id" ] = @id
+      relation = @Model.extensions[ name.capitalize() ].where filters
+      @getter name, => relation.first()
+      relation.first()
+    @
+  
+  hasManyRelation: ( name ) ->
+    @getter name, => 
+      delete @[ name ]
+      ( filters = {} )[ "#{ @sysname.lowercase() }_id" ] = @id
+      @[ name ] = @Model.extensions[ name[ ...-1 ].capitalize() ].where filters
+    @     
+  
+  view: ( name ) ->
+    name = @sysname + name.camelcase().capitalize() unless @View.extensions[ name ]?
+    unless ( view = ( @views ?= {} )[ name ] )?
+      if ( view = @View.extensions[ name ] )? 
+        view = ( ( @views ?= {} )[ name ] = view.clone( model: @ ) )
+      else console.error "View %s of model %O does not exist", name, @
+    view
+          
+  show: ( name, insertTo ) ->
+    if ( view = @view( name ) )? then view.show insertTo else null 
+      
+  hide: ( name ) ->
+    if ( view = @view( name ) )? then view.hide() else null    
+      
+  # валидации
+  
+  validations:          
+    # набор валидационных проверок
+    presence:  ( value, filter ) -> if filter then value? else not value?
+    match:     ( value, filter ) -> not value? or filter.test value
+    inclusion: ( value, filter ) -> not value? or value in filter
+    exclusion: ( value, filter ) -> not value? or value not in filter
+    length:    ( value, filter ) ->
+      if not value? then return true else value += ''
+      return false if filter.in?  and value.length not in filter.in
+      return false if filter.min? and value.length < filter.min
+      return false if filter.max? and value.length > filter.max
+      return false if filter.is?  and value.length isnt filter.is
+      true
+    format:    ( value, filter ) -> 
+      return true if not value?
+      return true if filter is 'boolean' and /^true|false$/.test value
+      return true if filter is 'number'  and /^[0-9]+$/.test value
+      return true if filter is 'letters' and /^[A-zА-я]+$/.test value
+      return true if filter is 'email'   and /^\w+([\.-]?\w+)*@\w+([\.-]?\w+)*(\.\w{2,4})+$/.test value
+      false
+  
+  isValid: ->
+    # проверяет валидна ли модель, вызывается перед сохранением модели на сервер если модель валидна, 
+    # то вызов model.isValid()? вернет true, иначе false
+    return null for name, value of @attributes when not @isValidAttributeValue( name, value )? 
+    true
+    
+  isValidAttributeValue: ( name, value ) ->
+    # проверяет валидно ли значение для определенного атрибута модели, вызывается при проверке 
+    # валидности модели, а также в методе update() перед изменением значения атрибута, если значение
+    # валидно то вызов model.isValidAttributeValue( name, value )? вернет true, иначе false
+    for validation, tester of @validations when ( filter = @::attributes[ name ]?[ validation ] )?
+      unless tester.call @, value, filter
+        console.warn 'Attribute %s of model %O has not validate %s', name, @, validation
+        for type in [ 'info', 'warning', 'error' ] when ( message = @::attributes[ name ][ type ] )?
+          @Notice[ type ] message: message
+        return null 
+    true