mt-libcouchbase 1.4.0

data/ext/libcouchbase/cmake/Modules/ConfigureDtrace.cmake

@@ -0,0 +1,52 @@
+FIND_PROGRAM(DTRACE dtrace)
+IF(DTRACE)
+    SET(LCB_DTRACE_HEADER "${LCB_GENSRCDIR}/probes.h")
+    SET(LCB_DTRACE_SRC "${PROJECT_SOURCE_DIR}/src/probes.d")
+
+    # Generate probes.h
+    EXECUTE_PROCESS(COMMAND ${DTRACE} -C -h -s ${LCB_DTRACE_SRC} -o ${LCB_DTRACE_HEADER}
+        RESULT_VARIABLE _rv)
+    IF(NOT ${_rv} EQUAL 0)
+        MESSAGE(WARNING "Could not execute DTrace. DTrace support will be disabled!")
+        RETURN()
+    ENDIF()
+
+    # Fix probes.h on FreeBSD
+    IF(CMAKE_SYSTEM_NAME STREQUAL "FreeBSD")
+        FIND_PROGRAM(SED sed)
+        EXECUTE_PROCESS(COMMAND ${SED} -i.tmp "s/, *char \\*/, const char \\*/g" ${LCB_DTRACE_HEADER}
+            RESULT_VARIABLE _rv)
+        IF(NOT ${_rv} EQUAL 0)
+            MESSAGE(WARNING "Could not execute sed to update dtrace-generated header. DTrace support will be disabled!")
+            RETURN()
+        ENDIF()
+    ENDIF()
+
+    ADD_DEFINITIONS(-DHAVE_DTRACE)
+    IF(NOT APPLE)
+        SET(LCB_DTRACE_OBJECT "${LCB_GENSRCDIR}/probes.o")
+        IF(CMAKE_SYSTEM_NAME STREQUAL "Linux")
+            SET(LCB_DTRACE_OPTIONS "-k")
+        ENDIF()
+        # Generate probes.o
+        IF(CMAKE_SYSTEM_NAME STREQUAL "SunOS" OR CMAKE_SYSTEM_NAME STREQUAL "FreeBSD")
+            SET(LCB_DTRACE_INSTRO ON)
+            UNSET(LCB_DTRACE_OBJECT)
+        ELSE()
+            ADD_CUSTOM_COMMAND(OUTPUT ${LCB_DTRACE_OBJECT}
+                DEPENDS ${LCB_DTRACE_SRC}
+                COMMAND ${DTRACE} -C -G ${LCB_DTRACE_OPTIONS} -s ${LCB_DTRACE_SRC} -o ${LCB_DTRACE_OBJECT})
+        ENDIF()
+    ENDIF()
+
+    FIND_PROGRAM(STAP stap)
+    IF(STAP)
+      SET(LCB_TAPSET_ROOT /usr/share/systemtap/tapset)
+      CONFIGURE_FILE(
+        ${PROJECT_SOURCE_DIR}/cmake/libcouchbase.stp.in
+        ${LCB_GENSRCDIR}/libcouchbase.so.${LCB_SONAME_FULL}.stp)
+      INSTALL(
+        FILES ${LCB_GENSRCDIR}/libcouchbase.so.${LCB_SONAME_FULL}.stp
+        DESTINATION ${LCB_TAPSET_ROOT})
+    ENDIF()
+ENDIF()

data/ext/libcouchbase/cmake/Modules/CopyPDB.cmake

@@ -0,0 +1,42 @@
+IF(POLICY CMP0026)
+    CMAKE_POLICY(SET CMP0026 OLD)
+ENDIF()
+MACRO(TRANSFORM_TARGET tname output_pdb output_exp)
+    # Base extension name
+    GET_FILENAME_COMPONENT(_base "${tname}" NAME_WE)
+    GET_FILENAME_COMPONENT(_type "${tname}" EXT)
+
+    # Path, e.g. 'Debug'
+    GET_FILENAME_COMPONENT(_bindir "${tname}" PATH)
+    GET_FILENAME_COMPONENT(_config "${_bindir}" NAME)
+
+    # e.g. the build directory itself
+    IF(CMAKE_BUILD_TYPE)
+        GET_FILENAME_COMPONENT(_basedir "${_bindir}/../" ABSOLUTE)
+        SET(_config "")
+    ELSE()
+        GET_FILENAME_COMPONENT(_basedir "${_bindir}/../../" ABSOLUTE)
+    ENDIF()
+
+    SET(${output_pdb} "${_basedir}/bin/${_config}/${_base}.pdb")
+    IF( ".dll" STREQUAL "${_type}")
+        SET(${output_exp} "${_basedir}/lib/${_config}/${_base}.exp")
+    ENDIF()
+ENDMACRO()
+
+MACRO(INSTALL_PDBS target)
+    IF(MSVC)
+        GET_TARGET_PROPERTY(_BIN_DEBUG ${target} LOCATION_DEBUG)
+        GET_TARGET_PROPERTY(_BIN_RDB ${target} LOCATION_RelWithDebInfo)
+        TRANSFORM_TARGET(${_BIN_DEBUG} _DEBUG_PDB _DEBUG_EXP)
+        TRANSFORM_TARGET(${_BIN_RDB} _RDB_PDB _RDB_EXP)
+        INSTALL(FILES ${_DEBUG_PDB} DESTINATION bin CONFIGURATIONS DEBUG)
+        INSTALL(FILES ${_RDB_PDB} DESTINATION bin CONFIGURATIONS RelWithDebInfo)
+        IF(_DEBUG_EXP)
+            INSTALL(FILES ${_DEBUG_EXP} DESTINATION lib CONFIGURATIONS DEBUG)
+        ENDIF()
+        IF(_RDB_EXP)
+            INSTALL(FILES ${_RDB_EXP} DESTINATION lib CONFIGURATIONS RelWithDebInfo)
+        ENDIF()
+    ENDIF(MSVC)
+ENDMACRO()

data/ext/libcouchbase/cmake/Modules/DistScript.cmake

@@ -0,0 +1,17 @@
+EXECUTE_PROCESS(
+    COMMAND ${CMAKE_COMMAND} --build . --config Debug)
+
+EXECUTE_PROCESS(
+    COMMAND ${CMAKE_COMMAND} --build . --config RelWithDebInfo)
+
+EXECUTE_PROCESS(
+    COMMAND ${CMAKE_COMMAND}
+        -DCMAKE_INSTALL_CONFIG_NAME=Debug
+        -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
+        -P cmake_install.cmake)
+
+EXECUTE_PROCESS(
+    COMMAND ${CMAKE_COMMAND}
+        -DCMAKE_INSTALL_CONFIG_NAME=RelWithDebInfo
+        -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
+        -P cmake_install.cmake)

data/ext/libcouchbase/cmake/Modules/DownloadLcbDep.cmake

@@ -0,0 +1,18 @@
+# DownloadLcbDeb(url location)
+MACRO(DOWNLOAD_LCB_DEP url dest)
+    FIND_PROGRAM(WGET wget)
+    FIND_PROGRAM(CURL curl)
+    IF(CURL)
+        EXECUTE_PROCESS(COMMAND "${CURL}" "${url}" -L -o "${dest}" RESULT_VARIABLE DLRC)
+    ELSEIF(WGET)
+        EXECUTE_PROCESS(COMMAND "${WGET}" "${url}" -O "${dest}" RESULT_VARIABLE DLRC)
+    ENDIF()
+    IF(NOT DLRC EQUAL 0)
+      MESSAGE(WARNING "Using buggy built-in CMake downloader")
+      FILE(DOWNLOAD ${url} ${dest} INACTIVITY_TIMEOUT 30 SHOW_PROGRESS STATUS RET)
+      LIST(GET RET 0 DLRC)
+    ENDIF()
+    IF(NOT DLRC EQUAL 0)
+        MESSAGE(FATAL_ERROR "Failed to download ${url}")
+    ENDIF()
+ENDMACRO()

data/ext/libcouchbase/cmake/Modules/FindCouchbaseHdrHistogram.cmake

@@ -0,0 +1,15 @@
+FIND_PATH(HDR_HISTOGRAM_INCLUDES hdr_histogram.h
+    HINTS ENV HDR_HISTOGRAM_DIR
+    PATH_SUFFIXES include/hdr
+    PATHS
+	/usr/local)
+FIND_LIBRARY(HDR_HISTOGRAM_LIBRARIES NAMES hdr_histogram
+    HINTS ENV HDR_HISTOGRAM_DIR
+    PATH_SUFFIXES lib
+    PATHS
+	/usr/local)
+IF(HDR_HISTOGRAM_LIBRARIES AND HDR_HISTOGRAM_INCLUDES)
+    SET(HDR_HISTOGRAM_FOUND TRUE)
+ELSE()
+    SET(HDR_HISTOGRAM_FOUND FALSE)
+ENDIF()

data/ext/libcouchbase/cmake/Modules/FindCouchbaseLibev.cmake

@@ -0,0 +1,73 @@
+# Locate libev library
+# This module defines
+#  HAVE_LIBEV, if false, do not try to link with libev
+#  LIBEV_LIBRARIES, Library path and libs
+#  LIBEV_INCLUDE_DIR, where to find the libev headers
+
+FIND_PATH(LIBEV_INCLUDE_DIR ev.h
+    PATHS ${LIBEV_ROOT}
+    PATH_SUFFIXES include libev
+    NO_DEFAULT_PATH)
+
+FIND_LIBRARY(LIBEV_LIBRARIES
+    NAMES ev libev
+    PATHS ${LIBEV_ROOT}
+    PATH_SUFFIXES lib libev
+    NO_DEFAULT_PATH)
+
+FIND_PATH(LIBEV_INCLUDE_DIR ev.h
+    HINTS
+        ENV LIBEV_DIR
+    PATH_SUFFIXES include include/libev
+    PATHS
+        ${DEPS_INCLUDE_DIR}
+        ~/Library/Frameworks
+        /Library/Frameworks
+        /opt/local
+        /opt/csw
+        /opt/libev
+        /opt)
+
+FIND_LIBRARY(LIBEV_LIBRARIES
+    NAMES ev libev
+    HINTS
+        ENV LIBEV_DIR
+    PATH_SUFFIXES lib libev
+    PATHS
+        ${DEPS_LIB_DIR}
+        ~/Library/Frameworks
+        /Library/Frameworks
+        /opt/local
+        /opt/csw
+        /opt/libev
+        /opt)
+
+IF (LIBEV_LIBRARIES AND LIBEV_INCLUDE_DIR)
+    SET(HAVE_LIBEV true)
+    MESSAGE(STATUS "Found libev in ${LIBEV_INCLUDE_DIR} : ${LIBEV_LIBRARIES}")
+ELSE (LIBEV_LIBRARIES)
+    SET(HAVE_LIBEV false)
+ENDIF (LIBEV_LIBRARIES AND LIBEV_INCLUDE_DIR)
+
+INCLUDE(CMakePushCheckState)
+INCLUDE(CheckFunctionExists)
+IF(HAVE_LIBEV)
+    CMAKE_PUSH_CHECK_STATE()
+    SET(CMAKE_REQUIRED_FLAGS "-I${LIBEV_INCLUDE_DIR}")
+    SET(CMAKE_REQUIRED_LIBRARIES ${LIBEV_LIBRARIES})
+    SET(CMAKE_REQUIRED_INCLUDES "ev.h")
+    CHECK_FUNCTION_EXISTS(ev_loop HAVE_LIBEV3)
+    IF(NOT HAVE_LIBEV3)
+        CHECK_FUNCTION_EXISTS(ev_run HAVE_LIBEV4)
+    ENDIF()
+    CMAKE_POP_CHECK_STATE()
+    IF(HAVE_LIBEV3)
+        MESSAGE(STATUS "libev3 found")
+    ELSEIF(HAVE_LIBEV4)
+        MESSAGE(STATUS "libev4 found")
+    ELSE()
+        MESSAGE(STATUS "libev not found")
+    ENDIF()
+ENDIF()
+
+MARK_AS_ADVANCED(HAVE_LIBEV LIBEV_INCLUDE_DIR LIBEV_LIBRARIES)

data/ext/libcouchbase/cmake/Modules/FindCouchbaseLibevent.cmake

@@ -0,0 +1,54 @@
+# Locate libevent library
+# This module defines
+#  HAVE_LIBEVENT, if false, do not try to link with libevent
+#  LIBEVENT_LIBRARIES, Library path and libs
+#  LIBEVENT_INCLUDE_DIR, where to find the ICU headers
+#  HAVE_LIBEVENT
+#  HAVE_LIBEVENT2
+
+FIND_PATH(LIBEVENT_INCLUDE_DIR evutil.h
+          HINTS
+               ${LIBEVENT_ROOT}
+               ENV LIBEVENT_DIR
+          PATH_SUFFIXES include
+          PATHS
+               ${DEPS_INCLUDE_DIR}
+               ~/Library/Frameworks
+               /Library/Frameworks
+               /opt/local
+               /opt/csw
+               /opt/libevent
+               /opt)
+
+FIND_LIBRARY(LIBEVENT_LIBRARIES
+             NAMES event_core libevent_core
+             HINTS
+                 ${LIBEVENT_ROOT}
+                 ENV LIBEVENT_DIR
+             PATHS
+                 ${DEPS_LIB_DIR}
+                 ~/Library/Frameworks
+                 /Library/Frameworks
+                 /opt/local
+                 /opt/csw
+                 /opt/libevent
+                 /opt)
+
+INCLUDE(CMakePushCheckState)
+INCLUDE(CheckFunctionExists)
+
+IF (LIBEVENT_LIBRARIES AND LIBEVENT_INCLUDE_DIR)
+  SET(HAVE_LIBEVENT true)
+  MESSAGE(STATUS "Found libevent in ${LIBEVENT_INCLUDE_DIR} : ${LIBEVENT_LIBRARIES}")
+  CMAKE_PUSH_CHECK_STATE()
+  SET(CMAKE_REQUIRED_FLAGS "-I${LIBEVENT_INCLUDE_DIR}")
+  SET(CMAKE_REQUIRED_INCLUDES "event2/event.h")
+  SET(CMAKE_REQUIRED_LIBRARIES ${LIBEVENT_LIBRARIES})
+  CHECK_FUNCTION_EXISTS(event_new HAVE_LIBEVENT2)
+  CMAKE_POP_CHECK_STATE()
+
+ELSE (LIBEVENT_LIBRARIES)
+  SET(HAVE_LIBEVENT false)
+ENDIF (LIBEVENT_LIBRARIES AND LIBEVENT_INCLUDE_DIR)
+
+MARK_AS_ADVANCED(HAVE_LIBEVENT LIBEVENT_INCLUDE_DIR LIBEVENT_LIBRARIES)

data/ext/libcouchbase/cmake/Modules/FindCouchbaseLibuv.cmake

@@ -0,0 +1,57 @@
+# Locate libuvent library
+# This module defines
+#  HAVE_LIBUV, if false, do not try to link with libuvent
+#  LIBUV_LIBRARIES, Library path and libs
+#  LIBUV_INCLUDE_DIR, where to find the ICU headers
+
+FIND_PATH(LIBUV_INCLUDE_DIR uv.h
+          HINTS
+               ${LIBUV_ROOT}
+          PATH_SUFFIXES include
+          PATHS
+               ~/Library/Frameworks
+               /Library/Frameworks
+               /opt/local
+               /opt/csw
+               /opt/libuv
+               /opt)
+MESSAGE(STATUS "Found UV include dir: ${LIBUV_INCLUDE_DIR}")
+
+IF(WIN32)
+    FIND_LIBRARY(LIBUV_LIBRARIES_DEBUG
+        NAMES uv libuv
+        HINTS ${LIBUV_ROOT}
+        PATH_SUFFIXES Debug Debug/lib)
+
+    FIND_LIBRARY(LIBUV_LIBRARIES_OPTIMIZED
+        NAMES uv libuv
+        HINTS ${LIBUV_ROOT}
+        PATH_SUFFIXES Release Release/lib)
+
+    SET(LIBUV_LIBRARIES
+        OPTIMIZED ${LIBUV_LIBRARIES_OPTIMIZED}
+        DEBUG ${LIBUV_LIBRARIES_DEBUG})
+
+ELSE()
+    FIND_LIBRARY(LIBUV_LIBRARIES
+        NAMES uv
+        HINTS ${LIBUV_ROOT}
+        PATH_SUFFIXES lib
+        PATHS
+            ~/Library/Frameworks
+            /Library/Frameworks
+            /opt/local
+            /opt/csw
+            /opt/libuv
+            /opt)
+ENDIF(WIN32)
+
+
+IF (LIBUV_LIBRARIES)
+  SET(HAVE_LIBUV true)
+  MESSAGE(STATUS "Found libuv in ${LIBUV_INCLUDE_DIR} : ${LIBUV_LIBRARIES}")
+ELSE (LIBUV_LIBRARIES)
+  SET(HAVE_LIBUV false)
+ENDIF (LIBUV_LIBRARIES)
+
+MARK_AS_ADVANCED(HAVE_LIBUV LIBUV_INCLUDE_DIR LIBUV_LIBRARIES LIBUV_ROOT)

data/ext/libcouchbase/cmake/Modules/FindProfiler.cmake

@@ -0,0 +1,16 @@
+FIND_LIBRARY(LIBPROFILER
+             NAMES profiler
+             HINTS
+                 ENV LIBPROFILER_DIR
+             PATHS
+                 ${DEPS_LIB_DIR}
+                 ~/Library/Frameworks
+                 /Library/Frameworks
+                 /opt/local
+                 /opt)
+
+IF(LIBPROFILER)
+  MESSAGE(STATUS "Found libprofiler: ${LIBPROFILER}")
+ELSE()
+  MESSAGE(FATAL_ERROR "Unable to find gperftools libprofiler, Try disabling LCB_USE_PROFILER option of CMake.")
+ENDIF()

data/ext/libcouchbase/cmake/Modules/GenerateConfigDotH.cmake

@@ -0,0 +1,49 @@
+# Writes the 'config.h' header..
+INCLUDE(CheckFunctionExists)
+INCLUDE(CheckIncludeFiles)
+INCLUDE(CheckSymbolExists)
+
+IF(UNIX)
+    CHECK_FUNCTION_EXISTS(gethrtime HAVE_GETHRTIME)
+    CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
+    CHECK_FUNCTION_EXISTS(clock_gettime HAVE_CLOCK_GETTIME)
+    CHECK_FUNCTION_EXISTS(setitimer HAVE_SETITIMER)
+    CHECK_SYMBOL_EXISTS(htonll arpa/inet.h HAVE_HTONLL)
+    CHECK_SYMBOL_EXISTS(res_search "netinet/in.h;resolv.h" HAVE_RES_SEARCH)
+    CHECK_INCLUDE_FILES(dlfcn.h HAVE_DLFCN_H)
+    CHECK_INCLUDE_FILES(netdb.h HAVE_NETDB_H)
+    CHECK_INCLUDE_FILES(stdint.h HAVE_STDINT_H)
+    CHECK_INCLUDE_FILES(stddef.h HAVE_STDDEF_H)
+    CHECK_INCLUDE_FILES(strings.h HAVE_STRINGS_H)
+    CHECK_INCLUDE_FILES(sys/socket.h HAVE_SYS_SOCKET_H)
+    CHECK_INCLUDE_FILES(sys/stat.h HAVE_SYS_STAT_H)
+    CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
+    CHECK_INCLUDE_FILES(unistd.h HAVE_UNISTD_H)
+    CHECK_INCLUDE_FILES(sys/uio.h HAVE_SYS_UIO_H)
+    CHECK_INCLUDE_FILES(fcntl.h HAVE_FCNTL_H)
+    CHECK_INCLUDE_FILES(sys/time.h HAVE_SYS_TIME_H)
+    CHECK_INCLUDE_FILES(arpa/inet.h HAVE_ARPA_INET_H)
+    CHECK_INCLUDE_FILES(inttypes.h HAVE_INTTYPES_H)
+    CHECK_INCLUDE_FILES(arpa/nameser.h HAVE_ARPA_NAMESER_H)
+ENDIF()
+
+SET(CMAKE_TEST_SHARED_OBJECT "libm.so")
+IF (WIN32)
+  SET(CMAKE_TEST_SHARED_OBJECT "kernel32.dll.")
+  CHECK_FUNCTION_EXISTS(_ftime64_s HAVE__FTIME64_S)
+ELSEIF (APPLE)
+  SET(CMAKE_TEST_SHARED_OBJECT "libm.dylib")
+ELSEIF (CMAKE_SYSTEM_NAME STREQUAL "Linux")
+  EXECUTE_PROCESS(COMMAND ${CMAKE_LINKER} -lm -t
+    OUTPUT_VARIABLE LIBM_SO_TRACE
+    ERROR_QUIET
+    OUTPUT_STRIP_TRAILING_WHITESPACE)
+  STRING(REGEX MATCH [-_a-z0-9/]+libm.so[.0-9]* LIBM_SO_PATH ${LIBM_SO_TRACE})
+  IF (EXISTS "${LIBM_SO_PATH}")
+    GET_FILENAME_COMPONENT(CMAKE_TEST_SHARED_OBJECT ${LIBM_SO_PATH} NAME)
+  ENDIF()
+ENDIF()
+
+CONFIGURE_FILE(
+    ${PROJECT_SOURCE_DIR}/cmake/config-cmake.h.in
+    ${LCB_GENSRCDIR}/config.h)

data/ext/libcouchbase/cmake/Modules/GetLibcouchbaseFlags.cmake

@@ -0,0 +1,142 @@
+# Common flags for libcouchbase modules. This defines the specific flags
+# required for various compilation modes
+# Exports:
+#   LCB_CORE_CFLAGS:
+#       C flags to be used by our "Core" modules. This contains
+#       many warnings.
+#   LCB_CORE_CXXFLAGS:
+#       Like LCB_CORE_CFLAGS, but for C++
+#
+#   LCB_BASIC_CFLAGS
+#       Basic C flags without extra warnings
+#   LCB_BASIC_CXXFLAGS
+#       Basic C++ flags without extra warnings.
+#
+# Note that global flags will still be modified for debug settings and the
+# like.
+
+MACRO(list2args VAR)
+    STRING(REPLACE ";" " " _tmp "${${VAR}}")
+    SET("${VAR}" "${_tmp}")
+ENDMACRO(list2args)
+
+LIST(APPEND LCB_GNUC_CPP_WARNINGS
+    -Wall -pedantic -Wshadow -fdiagnostics-show-option -Wformat
+    -Wno-strict-aliasing -Wextra -Winit-self -Wno-missing-field-initializers
+    -Wno-variadic-macros)
+
+IF(CMAKE_C_COMPILER_ID STREQUAL "Clang")
+    LIST(APPEND LCB_GNUC_CPP_WARNINGS -Wno-cast-align -Wno-dollar-in-identifier-extension)
+ENDIF()
+
+IF(LCB_USE_ASAN)
+    SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fno-omit-frame-pointer -fsanitize=address")
+    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-omit-frame-pointer -fsanitize=address")
+    SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -undefined dynamic_lookup -fsanitize=address")
+    SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=address")
+ENDIF()
+
+IF(LCB_USE_COVERAGE)
+    SET(_covflags "-fprofile-arcs -ftest-coverage")
+    IF(CMAKE_COMPILER_IS_GNUCC)
+        SET(_covflags "--coverage ${_covflags}")
+    ENDIF()
+
+    LIST(APPEND LCB_GNUC_CPP_WARNINGS ${_covflags})
+    SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${_covflags}")
+    SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${_covflags}")
+ENDIF()
+
+list2args(LCB_GNUC_CPP_WARNINGS)
+
+LIST(APPEND LCB_GNUC_C_WARNINGS
+    ${LCB_GNUC_CPP_WARNINGS}
+    -std=gnu99
+    -Wundef -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls
+    -Wmissing-declarations)
+list2args(LCB_GNUC_C_WARNINGS)
+
+LIST(APPEND LCB_GNUC_CXX_WARNINGS
+    ${LCB_GNUC_CPP_WARNINGS}
+    -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy
+    -Wno-long-long -Wredundant-decls)
+
+INCLUDE(CheckCXXCompilerFlag)
+CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
+IF(COMPILER_SUPPORTS_CXX11)
+    LIST(APPEND LCB_GNUC_CXX_WARNINGS -std=c++11)
+ENDIF()
+
+list2args(LCB_GNUC_CXX_WARNINGS)
+
+#MSVC-specific flags for C/C++
+LIST(APPEND LCB_CL_CPPFLAGS /nologo /W3 /MP /EHsc)
+LIST(APPEND LCB_CL_CPPFLAGS /wd4800 /wd4244 /wd4267)
+list2args(LCB_CL_CPPFLAGS)
+
+# Common flags for DEBUG
+LIST(APPEND LCB_CL_CPPFLAGS_DEBUG /RTC1)
+list2args( LCB_CL_CPPFLAGS_DEBUG)
+
+# Common flags for RELEASE
+LIST(APPEND LCB_CL_CPPFLAGS_REL /O2)
+list2args(LCB_CL_CPPFLAGS_REL)
+
+MACRO(SET_ALL_FLAGS extra_flags)
+    FOREACH(variant C CXX)
+        FOREACH(config RELEASE DEBUG RELWITHDEBINFO)
+            SET(varname "CMAKE_${variant}_FLAGS_${config}")
+            SET(existing ${${varname}})
+            SET(${varname} "${existing} ${extra_flags}")
+        ENDFOREACH()
+        SET(CMAKE_${variant}_FLAGS "${CMAKE_${variant}_FLAGS} ${extra_flags}")
+    ENDFOREACH()
+ENDMACRO()
+
+IF(MSVC)
+    ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS)
+    # Don't warn about "deprecated POSIX names"
+    ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_DEPRECATE)
+
+    # Need this for VS 2012 for googletest and C++
+    IF(MSVC_VERSION EQUAL 1700 OR MSVC_VERSION GREATER 1700)
+        ADD_DEFINITIONS(-D_VARIADIC_MAX=10)
+    ENDIF()
+    SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /TC ${LCB_CL_CPPFLAGS}")
+    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${LCB_CL_CPPFLAGS}")
+    SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${LCB_CL_CPPFLAGS_DEBUG}")
+    SET(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${LCB_CL_CPPFLAGS_DEBUG}")
+    SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${LCB_CL_CPPFLAGS_REL}")
+    SET(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${LCB_CL_CPPFLAGS_REL}")
+
+    # put debug info into release build and revert /OPT defaults after
+    # /DEBUG so that it won't degrade performance and size
+    # http://msdn.microsoft.com/en-us/library/xe4t6fc1(v=vs.80).aspx
+    # Since CMake for some odd reason strips 'incremental' and 'INCREMENTAL', we'll
+    # use weird casing here
+    SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /OPT:REF /OPT:ICF /IncReMenTal:no")
+    SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /OPT:REF /OPT:ICF /InCreMenTal:no")
+    SET(LCB_CORE_CXXFLAGS "")
+    SET(LCB_CORE_CFLAGS "")
+    SET(LCB_BASIC_CFLAGS "")
+    SET(LCB_BASIC_CXXFLAGS "")
+
+ELSE()
+    # GCC
+    SET_ALL_FLAGS("-fno-strict-aliasing")
+    IF(WIN32)
+        SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -gstabs")
+        SET(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -gstabs")
+        SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc -static-libstdc++")
+        SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc -static-libstdc++")
+    ELSE()
+        SET_ALL_FLAGS("-pthread")
+    ENDIF()
+    SET(LCB_CORE_CFLAGS "${LCB_GNUC_C_WARNINGS} -DHAVE_VISIBILITY -fvisibility=hidden")
+    SET(LCB_CORE_CXXFLAGS "${LCB_GNUC_CXX_WARNINGS} -DHAVE_VISIBILITY -fvisibility=hidden")
+ENDIF()
+
+IF(LCB_UNIVERSAL_BINARY AND (${CMAKE_SYSTEM_NAME} MATCHES "Darwin"))
+    SET(CMAKE_C_FLAGS
+        "${CMAKE_C_FLAGS} -force_cpusubtype_ALL -arch i386 -arch x86_64")
+ENDIF()

data/ext/libcouchbase/cmake/Modules/GetPlatformCCInfo.cmake

@@ -0,0 +1,45 @@
+# Gets string/platform information about the specific compiler
+# Defines:
+#  LCB_CC_STRING for the C compiler string (i.e. "msvc", "mingw")
+#  LCB_ARCH_STRING for the target architecture, e.g. "x86"
+
+# Figure out how we're building!
+IF(MSVC)
+    IF(CMAKE_CL_64)
+        SET(LCB_ARCH_STRING "amd64")
+    ELSE()
+        SET(LCB_ARCH_STRING "x86")
+    ENDIF(CMAKE_CL_64)
+
+    IF(MSVC80)
+        SET(LCB_CC_STRING "vs8")
+    ELSEIF(MSVC90)
+        SET(LCB_CC_STRING "vc9")
+    ELSEIF(MSVC_VERSION EQUAL 1600)
+        SET(LCB_CC_STRING "vc10")
+    ELSEIF(MSVC_VERSION EQUAL 1700)
+        SET(LCB_CC_STRING "vc11")
+    ELSEIF(MSVC_VERSION EQUAL 1800)
+        SET(LCB_CC_STRING "vc12")
+    ELSEIF(MSVC_VERSION EQUAL 1900)
+        SET(LCB_CC_STRING "vc14")
+    ENDIF()
+ELSE()
+    IF(UNIX)
+        SET(LCB_CC_STRING "gcc")
+        EXECUTE_PROCESS(
+            COMMAND
+                uname -m
+            COMMAND
+                tr -d '\n'
+            OUTPUT_VARIABLE
+                LCB_ARCH_STRING)
+    ELSE()
+        IF(CMAKE_SIZEOF_VOID_P EQUAL 8)
+            SET(LCB_ARCH_STRING "amd64")
+        ELSE()
+            SET(LCB_ARCH_STRING "x86")
+        ENDIF()
+        SET(LCB_CC_STRING "mingw")
+    ENDIF()
+ENDIF()

data/ext/libcouchbase/cmake/Modules/GetVersionInfo.cmake

@@ -0,0 +1,70 @@
+# Gets the libcouchbase version
+# Sets:
+#  LCB_VERSION: Version string
+#  LCB_CHANGESET: SCM Revision number
+#  LCB_VERSION_HEX Numeric hex version
+#  LCB_VERSION_MAJOR
+#  LCB_VERSION_MINOR
+#  LCB_VERSION_PATCH
+
+## Try git first ##
+FIND_PROGRAM(GIT_EXECUTABLE NAMES git git.exe)
+MACRO(RUNGIT outvar)
+    EXECUTE_PROCESS(COMMAND git ${ARGN}
+        OUTPUT_VARIABLE ${outvar}
+        WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
+        OUTPUT_STRIP_TRAILING_WHITESPACE)
+ENDMACRO()
+
+if (GIT_EXECUTABLE AND NOT LCB_SKIP_GIT_VERSION)
+    RUNGIT(LCB_REVDESCRIBE describe --long --abbrev=10)
+    RUNGIT(LCB_VERSION describe --abbrev=10)
+    STRING(REPLACE "-" "_" LCB_VERSION "${LCB_VERSION}")
+    MESSAGE(STATUS "Sanitized VERSION=${LCB_VERSION}")
+    RUNGIT(LCB_VERSION_CHANGESET rev-parse HEAD)
+
+    EXECUTE_PROCESS(
+        COMMAND echo ${LCB_VERSION}
+        COMMAND awk -F. "{printf \"0x%0.2d%0.2d%0.2d\", $1, $2, $3}"
+        WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
+        OUTPUT_VARIABLE LCB_VERSION_HEX)
+ENDIF()
+
+IF(LCB_VERSION)
+    # Have the version information
+    CONFIGURE_FILE(${LCB_GENINFODIR}/distinfo.cmake.in ${LCB_GENINFODIR}/distinfo.cmake)
+ENDIF()
+
+# library version
+IF(NOT LCB_VERSION AND EXISTS ${LCB_GENINFODIR}/distinfo.cmake)
+    INCLUDE(${LCB_GENINFODIR}/distinfo.cmake)
+ENDIF()
+
+IF (NOT LCB_VERSION)
+    SET(LCB_NOGITVERSION ON)
+    SET(LCB_VERSION "2.9.5")
+ENDIF()
+IF (NOT LCB_VERSION_CHANGESET)
+    SET(LCB_VERSION_CHANGESET "0xdeadbeef")
+ENDIF()
+IF (NOT LCB_VERSION_HEX)
+    SET(LCB_VERSION_HEX 0x020905)
+ENDIF()
+
+# Now parse the version string
+STRING(REPLACE "." ";" LCB_VERSION_LIST "${LCB_VERSION}")
+LIST(GET LCB_VERSION_LIST 0 LCB_VERSION_MAJOR)
+LIST(GET LCB_VERSION_LIST 1 LCB_VERSION_MINOR)
+LIST(GET LCB_VERSION_LIST 2 LCB_VERSION_PATCH)
+
+# Determine the SONAME for the library
+IF(APPLE)
+    SET(LCB_SONAME_MAJOR "3")
+ELSE()
+    SET(LCB_SONAME_MAJOR "2")
+ENDIF()
+SET(LCB_SONAME_FULL "${LCB_SONAME_MAJOR}.0.61")
+
+MESSAGE(STATUS
+    "libcouchbase ${LCB_VERSION_MAJOR},${LCB_VERSION_MINOR},${LCB_VERSION_PATCH}")
+MESSAGE(STATUS "Building libcouchbase ${LCB_VERSION}/${LCB_VERSION_CHANGESET}")