mongo_browser 0.1.3 → 0.2.0.rc2

data/.gitignore

@@ -11,3 +11,6 @@ Gemfile.lock
 .idea
 *.iml
 *.gem
+
+# ignore compiled templates
+app/assets/javascripts/templates/*.js

data/.travis.yml

@@ -3,10 +3,10 @@ language: ruby
 rvm:
   - 1.9.3
 
-before_install:
+before_script:
+  - "npm install -g grunt testacular@canary --quiet"
   - "export DISPLAY=:99.0"
   - "sh -e /etc/init.d/xvfb start"
 
 script:
-  - "rspec spec"
-  - "cucumber features"
+  - "./script/ci_all"

data/README.md

@@ -16,33 +16,9 @@ Run the application
 
     $ mongo_browser
 
-Run the application as a daemon
-
-    $ mongo_browser --demonize
-
-Application will be available by default at http://localhost:4567
+Application will be available by default at http://localhost:5678
 In order to run it on custom port number pass the `--port` option with selected port.
 
-Other options are:
-
-    $ mongo_browser --help
-    [17/11 16:10:06] Usage: mongo_browser [options]
-
-    v0.1.0
-
-    Options:
-            --version                    Show help/version info
-            --port PORT                  MongoBrowser port
-                                         (Default: 4567)
-            --mongodb-host HOST          Mongodb database host
-                                         (Default: localhost)
-            --mongodb-port PORT          Mongodb database port
-                                         (Default: 27017)
-            --demonize                   Run the app in the background
-            --log-level LEVEL            Set the logging level
-                                         (debug|info|warn|error|fatal)
-                                         (Default: info)
-
 ## Contributing
 
 1. Fork it

data/Rakefile

@@ -58,4 +58,3 @@ Rake::RDocTask.new do |rd|
 end
 
 task :default => [:test,:features]
-

data/app/assets/javascripts/app/controllers/alerts.js.coffee

@@ -0,0 +1,12 @@
+module = angular.module("mb.controllers")
+
+class AlertsController
+  constructor: (@$scope, @alerts) ->
+    @$scope.alertMessages = @alerts.messages
+
+    @$scope.disposeAlert = (id) =>
+      @alerts.dispose(id)
+
+AlertsController.$inject = ["$scope", "alerts"]
+
+module.controller "alerts", AlertsController

data/app/assets/javascripts/app/controllers/breadcrumbs.js.coffee

@@ -0,0 +1,25 @@
+module = angular.module("mb.controllers")
+
+# TODO find better solution for breadcrumbs
+class BreadcrumbsController
+  constructor: (@$rootScope, @$scope) ->
+
+    @$scope.showDatabase = => @$scope.dbName
+    @$scope.showCollection = => @$scope.collectionName
+
+    @$rootScope.$on "$routeChangeSuccess", (scope, route) =>
+      @$scope.dbName = route.params.dbName
+      @$scope.collectionName = route.params.collectionName
+
+      if @$scope.dbName
+        @$scope.database =
+          name: @$scope.dbName
+
+        if @$scope.collectionName
+          @$scope.collection =
+            dbName: @$scope.dbName
+            name: @$scope.collectionName
+
+BreadcrumbsController.$inject = ["$rootScope", "$scope"]
+
+module.controller "breadcrumbs", BreadcrumbsController

data/app/assets/javascripts/app/controllers/collections.js.coffee

@@ -0,0 +1,40 @@
+module = angular.module("mb.controllers")
+
+# TODO clenup this controller, see DatabasesController
+class CollectionsController
+  constructor: (@$scope, @$routeParams, @Collection, @$http, @confirmationDialog, @alerts) ->
+
+    @$scope.dbName = @$routeParams.dbName
+    @$scope.filterValue = ""
+
+    _onLoadComplete = (data) =>
+      @$scope.collections = data
+      @$scope.loading = false
+
+    @$scope.fetchCollections = =>
+      @$scope.loading = true
+      @$scope.collections = @Collection.query({ dbName: @$scope.dbName }, _onLoadComplete)
+
+    @$scope.fetchCollections()
+
+    # TODO create resource for this call
+    @$http.get("/api/databases/#{@$scope.dbName}/stats.json").success (data) =>
+      @$scope.dbStats = data
+
+    @$scope.isLoading = => @$scope.loading
+
+    @$scope.delete = (collection) =>
+      @confirmationDialog
+        message: "Deleting #{collection.name}. Are you sure?"
+        onOk: =>
+          resource = new @Collection()
+          params = dbName: collection.dbName, id: collection.name
+
+          resource.$delete params, =>
+            @alerts.info("Collection #{collection.name} has been deleted.")
+            @$scope.fetchCollections()
+
+CollectionsController.$inject = ["$scope", "$routeParams",
+  "Collection", "$http", "confirmationDialog", "alerts"]
+
+module.controller "collections", CollectionsController

data/app/assets/javascripts/app/controllers/databases.js.coffee

@@ -0,0 +1,39 @@
+module = angular.module("mb.controllers")
+
+class DatabasesController
+  constructor: (@$scope, @Database, @confirmationDialog, @alerts) ->
+    @loading = false
+    @fetchDatabases()
+
+    # Scope variables
+    @$scope.filterValue = ""
+
+    # Scope methods
+    @$scope.isLoading = -> @loading
+    @$scope.delete = (database) => @dropWithConfirmation(database)
+
+  fetchDatabases: ->
+    @loading = true
+    @Database.query(@onLoadComplete)
+
+  onLoadComplete: (data) =>
+    @$scope.databases = data
+    @loading = false
+
+  dropWithConfirmation: (database) =>
+    @confirmationDialog
+      message: "Deleting #{database.name}. Are you sure?"
+      onOk: => @drop(database)
+
+  drop: (database) ->
+    resource = new @Database()
+    params = id: database.name
+
+    resource.$delete params, =>
+      @alerts.info("Database #{database.name} has been deleted.")
+      @fetchDatabases()
+
+DatabasesController.$inject = ["$scope",
+  "Database", "confirmationDialog", "alerts"]
+
+module.controller "databases", DatabasesController

data/app/assets/javascripts/app/controllers/documents.js.coffee

@@ -0,0 +1,49 @@
+module = angular.module("mb.controllers")
+
+# TODO clenup this controller, see DatabasesController
+class DocumentsController
+  constructor: (@$scope, @$routeParams, @$http, @Document, @confirmationDialog, @alerts) ->
+    @$scope.dbName = @$routeParams.dbName
+    @$scope.collectionName = @$routeParams.collectionName
+
+    @$scope.isLoading = => @$scope.loading
+
+    _onLoadComplete = (data) =>
+      @$scope.loading = false
+
+      @$scope.documents = data.documents
+      @$scope.page = data.page
+      @$scope.totalPages = data.totalPages
+      @$scope.size = data.size
+
+    @$scope.fetchDocuments = (page = 1) =>
+      return if @$scope.isLoading() # TODO workaround for doule request
+      @$scope.loading = true
+
+      params = dbName: @$scope.dbName, collectionName: @$scope.collectionName, page: page
+      @Document.query(params, _onLoadComplete)
+
+    @$scope.page = 1
+    @$scope.fetchDocuments()
+
+    @$scope.$watch "page", (page) =>
+      @$scope.fetchDocuments(page)
+
+    # TODO create resource for this call
+    @$http.get("/api/databases/#{@$scope.dbName}/collections/#{@$scope.collectionName}/stats.json").success (data) =>
+      @$scope.collectionStats = data
+
+    @$scope.delete = (document) =>
+      @confirmationDialog
+        message: "Are you sure?"
+        onOk: =>
+          resource = new @Document()
+          params = dbName: @$scope.dbName, collectionName: @$scope.collectionName, id: document.id
+
+          resource.$delete params, =>
+            @alerts.info("Document #{document.id} has been deleted.")
+            @$scope.fetchDocuments()
+
+DocumentsController.$inject = ["$scope", "$routeParams", "$http", "Document", "confirmationDialog", "alerts"]
+
+module.controller "documents", DocumentsController

data/app/assets/javascripts/app/controllers/main.js.coffee

@@ -0,0 +1,10 @@
+module = angular.module("mb.controllers")
+
+class MainController
+  constructor: (@$scope, @$http) ->
+    @$http.get("/api/version.json").success (data) =>
+      @$scope.appVersion = data.version
+
+MainController.$inject = ["$scope", "$http"]
+
+module.controller "main", MainController

data/app/assets/javascripts/app/controllers/server_info.js.coffee

@@ -0,0 +1,14 @@
+module = angular.module("mb.controllers")
+
+class ServerInfo
+  constructor: (@$scope, @$http) ->
+    @$scope.loading = true
+    @$http.get("/api/server_info.json").success(@onLoadComplete)
+
+  onLoadComplete: (data) =>
+    @$scope.serverInfo = data
+    @$scope.loading = false
+
+ServerInfo.$inject = ["$scope", "$http"]
+
+module.controller "serverInfo", ServerInfo

data/app/assets/javascripts/app/controllers.js.coffee

@@ -0,0 +1,2 @@
+# Simply define a module for controllers..
+angular.module("mb.controllers", ["mb.services", "mb.resources"])

data/app/assets/javascripts/app/directives.js.coffee

@@ -0,0 +1,20 @@
+module = angular.module("mb.directives", [])
+
+# Handles ESC key
+module.directive "onEsc", ->
+  EscapeCode = 27
+
+  ($scope, $element, attrs) ->
+    $element.bind "keyup", (event) ->
+      return unless event.keyCode is EscapeCode
+      $scope.$apply(attrs.onEsc)
+
+module.directive "deleteButton", ->
+  replace: true
+  restrict: "E"
+  template: """
+            <a class="btn btn-danger">
+              <i class="icon-remove-circle"></i>
+              Delete
+            </a>
+            """

data/app/assets/javascripts/app/filters.js.coffee

@@ -0,0 +1,48 @@
+module = angular.module("mb.filters", [])
+
+module.filter "humanSize", -> (bytes) ->
+  sizes = ['Bytes', 'KB', 'MB', 'GB', 'TB', 'PB']
+  n = parseInt(Math.floor(Math.log(bytes) / Math.log(1024)), 10)
+  scaledSize = (bytes / Math.pow(1024, n)).toFixed(0)
+
+  "#{scaledSize} #{sizes[n]}"
+
+module.filter "jsonDocument", -> (document) ->
+  str = JSON.stringify(document, undefined, 2)
+
+  # Replace for the ObjectId
+  str = str.replace(/_id": {\s+"\$oid":\s+"(\w+)"\s+}/gm, '_id": ObjectId("$1")')
+
+  syntaxHighlight = (json) ->
+    json = json.replace(/&/g, "&amp;").replace(/</g, "&lt;").replace(/>/g, "&gt;")
+    json.replace /("(\\u[a-zA-Z0-9]{4}|\\[^u]|[^\\"])*"(\s*:)?|\b(true|false|null)\b|-?\d+(?:\.\d*)?(?:[eE][+\-]?\d+)?)/g, (match) ->
+      cls = "number"
+      if /^"/.test(match)
+        if /:$/.test(match)
+          # Remove quotes from a key
+          match = match.replace(/^"/, "").replace(/":$/, ":")
+
+          cls = "key"
+        else
+          cls = "string"
+      else if /true|false/.test(match)
+        cls = "boolean"
+      else
+        cls = "null" if /null/.test(match)
+
+      "<span class=\"#{cls}\">#{match}</span>"
+
+  "<pre>#{syntaxHighlight(str)}</pre>"
+
+module.filter "collectionsPath", ->
+  (database = {}) ->
+    dbName = database.name || ":dbName"
+
+    "/databases/#{dbName}/collections"
+
+module.filter "documentsPath", (collectionsPathFilter) ->
+  (collection = {}) ->
+    dbName = collection.dbName || ":dbName"
+    collectionName = collection.name || ":collectionName"
+
+    "#{collectionsPathFilter(name: dbName)}/#{collectionName}/documents"

data/app/assets/javascripts/app/modules/dialogs.js.coffee

@@ -0,0 +1,29 @@
+dialogs = angular.module("mb.dialogs", [])
+
+# Simple wrapper for http://bootboxjs.com library
+#
+# Usage:
+# handler.confirm "the message", (confirmed) ->
+#   doSomething() if confirmed
+dialogs.factory "dialogsHandler", -> bootbox
+
+dialogs.factory "confirmationDialog", [
+  "$log", "dialogsHandler", ($log, handler) ->
+
+    # Options:
+    #  message  - a message to display inside the dialog
+    #             default: "Are you sure?"
+    #  onOk     - a handler for Ok button
+    #  onCancel - a handler for Cancel button
+    (options = {}) ->
+      options.message ||= "Are you sure?"
+      $log.info("Displaying confirmation dialog:", options.message)
+
+      handler.confirm options.message, (confirmed) ->
+        if confirmed
+          $log.info("Confirmation dialog was confirmed")
+          (options.onOk || ->)()
+        else
+          $log.info("Confirmation dialog was disposed")
+          (options.onCancel || ->)()
+]

data/app/assets/javascripts/app/modules/pager.js.coffee

@@ -0,0 +1,87 @@
+pager = angular.module("mb.pager", [])
+
+# TODO create just a injectable function
+pager.factory "pager", ->
+  (options = {}) ->
+    page: options.page || 1
+    totalPages: options.totalPages
+    innerWindow: if options.innerWindow? then options.innerWindow else 4
+    outerWindow: if options.outerWindow? then options.outerWindow else 1
+
+    windowedPageNumbers: ->
+      windowFrom = @page - @innerWindow
+      windowTo = @page + @innerWindow
+
+      # adjust lower or upper limit if other is out of bounds
+      if windowTo > @totalPages
+        windowFrom -= windowTo - @totalPages
+        windowTo = @totalPages
+
+      if windowFrom < 1
+        windowFrom = 1
+        windowTo += windowTo - windowFrom
+        windowTo = @totalPages if windowTo > @totalPages
+
+      middle = [windowFrom..windowTo]
+
+      # left window
+      middleFirst = middle[0]
+      if @outerWindow + 3 < middleFirst # there's a gap
+        left = [1..(@outerWindow + 1)]
+        left.push(null)
+      else # runs into visible pages
+        left = [1...middleFirst]
+
+      # right window
+      middleLast = middle[middle.length - 1]
+      if @totalPages - @outerWindow - 2 > middleLast # again, gap
+        right = [(@totalPages - @outerWindow)..@totalPages]
+        right.unshift(null)
+      else # runs into visible pages
+        if middleLast < @totalPages
+          right = [(middleLast + 1)..@totalPages]
+        else
+          right = []
+
+      left.concat(middle).concat(right)
+
+# TODO block button when the resource is loading
+class PagerController
+  constructor: (@$scope, @pager) ->
+    @$scope.$watch "page", => @paginate()
+    @$scope.$watch "totalPages", => @paginate()
+
+    @$scope.setPage = (page) =>
+      return if page < 1 or page > @$scope.totalPages
+      @$scope.page = page
+
+    @$scope.next = =>
+      @$scope.page += 1 if @$scope.hasNext()
+
+    @$scope.hasNext = =>
+      @$scope.page < @$scope.totalPages
+
+    @$scope.prev = =>
+      @$scope.page -= 1 if @$scope.hasPrev()
+
+    @$scope.hasPrev = =>
+      @$scope.page > 1
+
+    @$scope.display = => @$scope.totalPages > 1
+
+  paginate: =>
+    prepare = @pager(page: @$scope.page, totalPages: @$scope.totalPages)
+    @$scope.windowedPageNumbers = prepare.windowedPageNumbers()
+
+pager.controller "pager", PagerController
+
+pager.directive "pager", ->
+  templateUrl: "/ng/templates/pager.html"
+  restrict: "E"
+  replace: true
+
+  scope:
+    page: "=page"
+    totalPages: "=totalPages"
+
+  controller: "pager"

data/app/assets/javascripts/app/modules/table_filter.js.coffee

@@ -0,0 +1,27 @@
+taleFilter = angular.module("mb.tableFilter", [])
+
+class TableFilterController
+  constructor: ($scope) ->
+    # Clears the filter value
+    $scope.clear = -> $scope.value = ""
+
+    # Reruns true when the filter is empty
+    $scope.isEmpty = -> !$scope.value
+
+TableFilterController.$inject = ["$scope"]
+
+taleFilter.controller "tableFilter", TableFilterController
+
+# Filter for databases and collections
+taleFilter.directive "tableFilter", ->
+  restrict: "E"
+  transclude: true
+
+  templateUrl: "/ng/templates/table_filter.html"
+  replace: true
+
+  scope:
+    placeholder: "@placeholder"
+    value: "=value"
+
+  controller: "tableFilter"

data/app/assets/javascripts/app/resources.js.coffee

@@ -0,0 +1,22 @@
+angular.module "mb.resources", ["ngResource", "mb.filters"], ($provide) ->
+
+  $provide.factory "Database", [
+    "$resource", (resource) ->
+
+      resource "/api/databases.json", {},
+        query: method: "GET", isArray: true
+  ]
+
+  $provide.factory "Collection", [
+    "$resource", "$filter", (resource, $filter) ->
+
+      resource "/api#{$filter("collectionsPath")()}.json", {},
+        query: method: "GET", isArray: true
+  ]
+
+  $provide.factory "Document", [
+    "$resource", "$filter", (resource, $filter) ->
+
+      resource "/api#{$filter("documentsPath")()}.json", {},
+        query: method: "GET", isArray: false
+  ]

data/app/assets/javascripts/app/services.js.coffee

@@ -0,0 +1,36 @@
+angular.module "mb.services", [], ($provide) ->
+
+  $provide.factory "alerts", [
+    "$log", "$timeout", ($log, $timeout) ->
+      lastId: 0
+      messages: []
+
+      # Returns a next id for the new message
+      nextId: ->
+        @lastId += 1
+
+      push: (type, text) ->
+        id = @nextId()
+        $log.info("Alert [#{id}, #{type}]", text)
+
+        @messages.push(id: id, type: type, text: text)
+        @delayedDispose(id)
+
+        id
+
+      # Helper methods for various alerts types
+      info: (text) -> @push("info", text)
+      error: (text) -> @push("error", text)
+
+      # Disposes a message with the given id
+      dispose: (id) ->
+        at = @messages.map((message) -> message.id).indexOf(id)
+        @messages.splice(at, 1)
+
+      # Dispose the message after the given time in milliseconds
+      delayedDispose: (id, timeout = 3000) ->
+        disposeTheAlert = =>
+          $log.info("Disposing alert", id, "after", timeout, "milliseconds")
+          @dispose(id)
+        $timeout(disposeTheAlert, timeout)
+  ]

data/app/assets/javascripts/app.js.coffee

@@ -0,0 +1,8 @@
+#= require app/services
+#= require app/resources
+#= require app/directives
+#= require app/filters
+#= require_tree ./app/modules
+
+#= require app/controllers
+#= require_tree ./app/controllers

data/app/assets/javascripts/application.js.coffee

@@ -1,7 +1,36 @@
-#= require ujs
-#= require app/table_filter
+#= require app
 
-$(document).ready ->
-  $("form.filter").each (index, form) ->
-    $form = $(form)
-    filter = new TableFilter($form)
+# App Module
+requires = [
+  "bootstrap", "ngSanitize",
+  "mb.controllers", "mb.directives", "mb.filters",
+  "mb.dialogs", "mb.pager", "mb.tableFilter"]
+
+angular.module("mb", requires)
+  .config [
+    "$routeProvider", "$locationProvider", (route, location) ->
+      route
+        # Main page, list of all available databases
+        .when "/",
+            templateUrl: "/ng/templates/databases.html",
+            controller: "databases"
+
+        # List of collections for the given database
+        .when "/databases/:dbName/collections",
+            templateUrl: "/ng/templates/collections.html",
+            controller: "collections"
+
+        # list of documents for the given collection
+        .when "/databases/:dbName/collections/:collectionName/documents",
+            templateUrl: "/ng/templates/documents.html",
+            controller: "documents"
+
+        # Information about the server
+        .when "/server_info",
+            templateUrl: "/ng/templates/server_info.html",
+            controller: "serverInfo"
+
+        .otherwise(redirectTo: "/")
+
+      location.html5Mode(true)
+  ]

data/app/assets/javascripts/templates.js.coffee

@@ -0,0 +1 @@
+#= require_tree ./templates

data/app/assets/javascripts/vendor.js.coffee

@@ -1,3 +1,8 @@
 #= require jquery
+#= require underscore
 #= require bootstrap
 #= require bootbox
+#= require angular/angular
+#= require angular/angular-bootstrap
+#= require angular/angular-resource
+#= require angular/angular-sanitize