mongo_browser 0.1.3 → 0.2.0.rc2

data/spec/javascripts/app/controllers/collections_spec.js.coffee

@@ -0,0 +1,78 @@
+describe "collections", ->
+  beforeEach module("mb.controllers")
+  beforeEach module("mb.dialogs")
+  beforeEach module("mocks")
+
+  $scope = null
+  $httpBackend = null
+  alerts = null
+
+  beforeEach inject ($injector, $rootScope, $controller) ->
+    alerts = $injector.get("alerts")
+
+    $routeParams = $injector.get("$routeParams")
+    $routeParams.dbName = "test_database"
+
+    $httpBackend = $injector.get("$httpBackend")
+    $httpBackend.when("GET", "/api/databases/test_database/collections.json")
+        .respond([])
+    $httpBackend.when("GET", "/api/databases/test_database/stats.json")
+        .respond({})
+
+    $scope = $rootScope.$new()
+    $controller "collections",
+      $scope: $scope
+
+    $httpBackend.flush()
+
+  afterEach ->
+    $httpBackend.verifyNoOutstandingExpectation()
+    $httpBackend.verifyNoOutstandingRequest()
+
+  describe "#isLoading", ->
+    it "returns true when the resouce it loading", ->
+      $scope.loading = true
+      expect($scope.isLoading()).toBeTruthy()
+
+    it "otherwise returns false", ->
+      $scope.loading = false
+      expect($scope.isLoading()).toBeFalsy()
+
+  # TODO refactor this spec
+  describe "#delete", ->
+    collection = null
+
+    beforeEach ->
+      collection = dbName: "test_database", name: "dummy-collection-id"
+
+    it "shows a confirmation dialog", inject (dialogsHandler) ->
+      spyOn(dialogsHandler, "confirm")
+
+
+      $scope.delete(collection)
+
+      expect(dialogsHandler.confirm).toHaveBeenCalledWith \
+          "Deleting dummy-collection-id. Are you sure?",
+          jasmine.any(Function)
+
+    describe "when the dialog was confirmed", ->
+      beforeEach inject (dialogsHandler) ->
+        $httpBackend.when("DELETE", "/api/databases/test_database/collections.json?id=dummy-collection-id")
+            .respond([])
+
+        spyOn(alerts, "info")
+        $scope.delete(collection)
+        dialogsHandler.confirmed()
+
+      it "sends a delete request", ->
+        $httpBackend.flush()
+
+      it "displays a flash message", ->
+        $httpBackend.flush()
+        expect(alerts.info).toHaveBeenCalledWith("Collection dummy-collection-id has been deleted.")
+
+    describe "when the dialog was disposed", ->
+      it "does nothing", inject (dialogsHandler) ->
+        # When
+        $scope.delete(name: "dummy-collection-id")
+        dialogsHandler.disposed()

data/spec/javascripts/app/controllers/databases_spec.js.coffee

@@ -0,0 +1,55 @@
+describe "databases", ->
+  beforeEach module("mb.controllers")
+  beforeEach module("mb.dialogs")
+  beforeEach module("mocks")
+
+  $scope = null
+  $httpBackend = null
+  alerts = null
+
+  beforeEach inject ($injector, $rootScope, $controller) ->
+    alerts = $injector.get("alerts")
+
+    $httpBackend = $injector.get("$httpBackend")
+    $httpBackend.when("GET", "/api/databases.json").respond([])
+
+    $scope = $rootScope.$new()
+    $controller "databases",
+        $scope: $scope
+
+    $httpBackend.flush()
+
+  afterEach ->
+    $httpBackend.verifyNoOutstandingExpectation()
+    $httpBackend.verifyNoOutstandingRequest()
+
+  # TODO rewrite this spec
+  describe "#delete", ->
+    it "shows a confirmation dialog", inject (dialogsHandler) ->
+      spyOn(dialogsHandler, "confirm")
+      $scope.delete(name: "test_database_name")
+      expect(dialogsHandler.confirm).toHaveBeenCalledWith \
+          "Deleting test_database_name. Are you sure?",
+          jasmine.any(Function)
+
+    describe "when the dialog was confirmed", ->
+      beforeEach inject (dialogsHandler) ->
+        $httpBackend.when("DELETE", "/api/databases.json?id=test_database_name")
+            .respond([])
+
+        spyOn(alerts, "info")
+        $scope.delete(name: "test_database_name")
+        dialogsHandler.confirmed()
+
+      it "sends a delete request", ->
+        $httpBackend.flush()
+
+      it "displays a flash message", ->
+        $httpBackend.flush()
+        expect(alerts.info).toHaveBeenCalledWith("Database test_database_name has been deleted.")
+
+    describe "when the dialog was disposed", ->
+      it "does nothing", inject (dialogsHandler) ->
+        # When
+        $scope.delete(name: "test_database_name")
+        dialogsHandler.disposed()

data/spec/javascripts/app/controllers/documents_spec.js.coffee

@@ -0,0 +1,62 @@
+describe "documents", ->
+  beforeEach module("mb.controllers")
+  beforeEach module("mb.dialogs")
+  beforeEach module("mocks")
+
+  $scope = null
+  $httpBackend = null
+  alerts = null
+
+  beforeEach inject ($injector, $rootScope, $controller) ->
+    alerts = $injector.get("alerts")
+
+    $routeParams = $injector.get("$routeParams")
+    $routeParams.dbName = "test_database"
+    $routeParams.collectionName = "test_collection"
+
+    $httpBackend = $injector.get('$httpBackend')
+    $httpBackend.when("GET", "/api/databases/test_database/collections/test_collection/documents.json?page=1")
+        .respond([])
+    $httpBackend.when("GET", "/api/databases/test_database/collections/test_collection/stats.json")
+        .respond({})
+
+    $scope = $rootScope.$new()
+    $controller "documents",
+      $scope: $scope
+
+    $httpBackend.flush()
+
+  afterEach ->
+    $httpBackend.verifyNoOutstandingExpectation()
+    $httpBackend.verifyNoOutstandingRequest()
+
+  # TODO rewrite this spec
+  describe "#delete", ->
+    it "shows a confirmation dialog", inject (dialogsHandler) ->
+      spyOn(dialogsHandler, "confirm")
+      $scope.delete(id: "dummy-document-id")
+      expect(dialogsHandler.confirm).toHaveBeenCalledWith \
+          "Are you sure?",
+          jasmine.any(Function)
+
+    describe "when the dialog was confirmed", ->
+      beforeEach inject (dialogsHandler) ->
+        $httpBackend.when("DELETE", "/api/databases/test_database/collections/test_collection/documents.json?id=dummy-document-id")
+            .respond([])
+
+        spyOn(alerts, "info")
+        $scope.delete(id: "dummy-document-id")
+        dialogsHandler.confirmed()
+
+      it "sends a delete request", ->
+        $httpBackend.flush()
+
+      it "displays a flash message", ->
+        $httpBackend.flush()
+        expect(alerts.info).toHaveBeenCalledWith("Document dummy-document-id has been deleted.")
+
+    describe "when the dialog was disposed", ->
+      it "does nothing", inject (dialogsHandler) ->
+        # When
+        $scope.delete(id: "dummy-document-id")
+        dialogsHandler.disposed()

data/spec/javascripts/app/controllers/main_spec.js.coffee

@@ -0,0 +1,20 @@
+describe "main", ->
+  beforeEach module("mb.controllers")
+
+  $scope = null
+  $httpBackend = null
+
+  beforeEach inject ($injector, $rootScope, $controller) ->
+    $scope = $rootScope.$new()
+
+    $httpBackend = $injector.get('$httpBackend')
+    $httpBackend.when("GET", "/api/version.json").respond([])
+
+    $controller "main",
+      $scope: $scope
+
+    $httpBackend.flush()
+
+  it "fetches the app version", ->
+    $httpBackend.verifyNoOutstandingExpectation()
+    $httpBackend.verifyNoOutstandingRequest()

data/spec/javascripts/app/controllers/server_info_spec.js.coffee

@@ -0,0 +1,21 @@
+describe "serverInfo", ->
+  beforeEach module("mb.controllers")
+  beforeEach module("mocks")
+
+  $scope = null
+  $httpBackend = null
+
+  beforeEach inject ($injector, $rootScope, $controller) ->
+    $scope = $rootScope.$new()
+
+    $httpBackend = $injector.get('$httpBackend')
+    $httpBackend.when("GET", "/api/server_info.json").respond([])
+
+    $controller "serverInfo",
+      $scope: $scope
+
+    $httpBackend.flush()
+
+  it "fetches information about the server", ->
+    $httpBackend.verifyNoOutstandingExpectation()
+    $httpBackend.verifyNoOutstandingRequest()

data/spec/javascripts/app/directives_spec.js.coffee

@@ -0,0 +1,58 @@
+describe "directives", ->
+  beforeEach module("mb.directives")
+
+  $scope = null
+  element = null
+
+  describe "osEsc", ->
+    beforeEach inject ($compile, $rootScope) ->
+      $scope = $rootScope.$new()
+      $scope.bar = ->
+
+      element = $compile('<input type="text" on-esc="bar()" />')($scope)
+      $scope.$digest()
+
+    it "calls the given function when the ESC was pressed", ->
+      spyOn($scope, 'bar')
+
+      event = jQuery.Event("keyup", keyCode: 27)
+      element.trigger(event)
+
+      expect($scope.bar).toHaveBeenCalled()
+
+    it "does nothing on other keys", ->
+      spyOn($scope, 'bar')
+
+      event = jQuery.Event("keyup", keyCode: 13)
+      element.trigger(event)
+
+      expect($scope.bar).not.toHaveBeenCalled()
+
+  describe "deleteButton", ->
+    beforeEach inject ($compile, $rootScope) ->
+      $scope = $rootScope.$new()
+      $scope.bar = ->
+
+      template = """
+                 <div>
+                   <delete-button ng-click="bar()" />
+                 </div>
+                 """
+      element = $compile(template)($scope)
+      $scope.$digest()
+
+    it "renders bar button", ->
+      button = element.find("a")
+
+      expect(button.length).toBe(1)
+      expect(button.hasClass("btn")).toBeTruthy()
+      expect(button.hasClass("btn-danger")).toBeTruthy()
+      expect(button.text()).toContain("Delete")
+
+    it "ng-click", ->
+      spyOn($scope, 'bar')
+
+      button = element.find("button")
+      button.click()
+
+      expect($scope.bar).not.toHaveBeenCalled()

data/spec/javascripts/app/filters_spec.js.coffee

@@ -0,0 +1,99 @@
+describe "filters", ->
+  beforeEach module("mb.filters")
+
+  describe "humanSize", ->
+    filter = null
+
+    beforeEach inject (humanSizeFilter) ->
+      filter = humanSizeFilter
+
+    it "formats bytes", ->
+      expect(filter(1)).toEqual("1 Bytes")
+      expect(filter(1000)).toEqual("1000 Bytes")
+      expect(filter(1023)).toEqual("1023 Bytes")
+
+    it "formats kilobytes", ->
+      expect(filter(1024)).toEqual("1 KB")
+
+    it "formats megabytes", ->
+      megabyte = 1024 * 1024
+
+      expect(filter(megabyte)).toEqual("1 MB")
+      expect(filter(250 * megabyte)).toEqual("250 MB")
+
+    it "formats gigabytes", ->
+      gigabyte = 1024 * 1024 * 1024
+
+      expect(filter(gigabyte)).toEqual("1 GB")
+      expect(filter(2.6 * gigabyte)).toEqual("3 GB")
+
+  describe "jsonDocument", ->
+    filter = null
+
+    beforeEach inject (jsonDocumentFilter) ->
+      filter = jsonDocumentFilter
+
+    it "can highlight strings", ->
+      o = { foo: "bar" }
+
+      expect(filter(o)).toContain('<span class="key">foo:</span>')
+      expect(filter(o)).toContain('<span class="string">"bar"</span>')
+
+    it "can highlight numbers", ->
+      o = { bar: 123.99 }
+
+      expect(filter(o)).toContain('<span class="key">bar:</span>')
+      expect(filter(o)).toContain('<span class="number">123.99</span>')
+
+    it "can highlight booleans", ->
+      o = { foo: false }
+
+      expect(filter(o)).toContain('<span class="key">foo:</span>')
+      expect(filter(o)).toContain('<span class="boolean">false</span>')
+
+    it "can highlight nulls", ->
+      o = { foo: null }
+
+      expect(filter(o)).toContain('<span class="key">foo:</span>')
+      expect(filter(o)).toContain('<span class="null">null</span>')
+
+    it "can format ObjectId", ->
+      o = {
+        _id: { $oid: "50bfc4b6dac5d5630800017a" },
+        foo: "something",
+        comapany_id: { $oid: "50bfc4b6dac5d56308000119" }
+      }
+
+      expect(filter(o)).toContain('<span class="key">_id:</span>')
+      expect(filter(o)).toContain('ObjectId(<span class="string">"50bfc4b6dac5d5630800017a"</span>)')
+
+      expect(filter(o)).toContain('<span class="key">comapany_id:</span>')
+      expect(filter(o)).toContain('ObjectId(<span class="string">"50bfc4b6dac5d56308000119"</span>)')
+
+  # url helpers
+
+  describe "#collectionsPath", ->
+    filter = null
+
+    beforeEach inject (collectionsPathFilter) ->
+      filter = collectionsPathFilter
+
+    it "without parameters generates an url with placeholders", ->
+      expect(filter()).toEqual("/databases/:dbName/collections")
+
+    it "generates an url for the given database collections", ->
+      database = { name: "foo_bar" }
+      expect(filter(database)).toEqual("/databases/foo_bar/collections")
+
+  describe "#documentsPath", ->
+    filter = null
+
+    beforeEach inject (documentsPathFilter) ->
+      filter = documentsPathFilter
+
+    it "without parameters generates an url with placeholders", ->
+      expect(filter()).toEqual("/databases/:dbName/collections/:collectionName/documents")
+
+    it "generates na url for the given collection documents", ->
+      collection = { dbName: "foo", name: "bars" }
+      expect(filter(collection)).toEqual("/databases/foo/collections/bars/documents")

data/spec/javascripts/app/modules/dialogs_spec.js.coffee

@@ -0,0 +1,51 @@
+describe "mb.dialogs", ->
+  beforeEach module("mb.dialogs")
+
+  describe "dialogsHandler", ->
+    beforeEach inject ($window) ->
+      $window.bootbox = "dummy bootbox"
+
+    it "by default is set to bootbox", inject (dialogsHandler) ->
+      expect(dialogsHandler).toEqual("dummy bootbox")
+
+  describe "confirmationDialog", ->
+    beforeEach module("mocks")
+
+    it "is defined", inject (confirmationDialog) ->
+      expect(confirmationDialog).toBeDefined()
+
+    it "calls the handler", inject (confirmationDialog, dialogsHandler) ->
+      # Given
+      spyOn(dialogsHandler, "confirm")
+
+      # When
+      confirmationDialog(message: "This is a test message")
+
+      # Then
+      expect(dialogsHandler.confirm).toHaveBeenCalledWith \
+        "This is a test message",
+        jasmine.any(Function)
+
+    describe "when the dialog was confirmed", ->
+      it "calls the given #onOk callback", inject (confirmationDialog, dialogsHandler) ->
+        # Given
+        onOk = jasmine.createSpy("#onOk callback")
+        confirmationDialog(onOk: onOk)
+
+        # When
+        dialogsHandler.confirmed()
+
+        # Then
+        expect(onOk).toHaveBeenCalled()
+
+    describe "when the dialog was disposed", ->
+      it "calls the given #onOk callback", inject (confirmationDialog, dialogsHandler) ->
+        # Given
+        onCancel= jasmine.createSpy("#onCancel callback")
+        confirmationDialog(onCancel: onCancel)
+
+        # When
+        dialogsHandler.disposed()
+
+        # Then
+        expect(onCancel).toHaveBeenCalled()

data/spec/javascripts/app/modules/pager_spec.js.coffee

@@ -0,0 +1,104 @@
+describe "mb.pager", ->
+  beforeEach module("mb.pager")
+
+  describe "pager service", ->
+    it "is defined", inject (pager) ->
+      expect(pager).toBeDefined()
+
+    it "can be instantiated", inject (pager) ->
+      p = pager(totalPages: 99, outerWindow: 0)
+
+      expect(p.page).toEqual(1)
+      expect(p.totalPages).toEqual(99)
+      expect(p.innerWindow).toEqual(4)
+      expect(p.outerWindow).toEqual(0)
+
+    describe "windowedPageNumbers", ->
+
+      it "calculates windowed visible links", inject (pager) ->
+        prepare = pager(page: 6, totalPages: 11, innerWindow: 1, outerWindow: 1)
+        expect(prepare.windowedPageNumbers()).toEqual [1, 2, null, 5, 6, 7, null, 10, 11]
+
+      it "eliminates small gaps", inject (pager) ->
+        prepare = pager(page: 6, totalPages: 11, innerWindow: 2, outerWindow: 1)
+        # pages 4 and 8 appear instead of the gap
+        expect(prepare.windowedPageNumbers()).toEqual [1..11]
+
+      it "supports having no windows at all", inject (pager) ->
+        prepare = pager(page: 4, totalPages: 7, innerWindow: 0, outerWindow: 0)
+        expect(prepare.windowedPageNumbers()).toEqual [1, null, 4, null, 7]
+
+      it "adjusts upper limit if lower is out of bounds", inject (pager) ->
+        prepare = pager(page: 1, totalPages: 10, innerWindow: 2, outerWindow: 1)
+        expect(prepare.windowedPageNumbers()).toEqual [1, 2, 3, 4, 5, null, 9, 10]
+
+      it "adjusts lower limit if upper is out of bounds", inject (pager) ->
+        prepare = pager(page: 10, totalPages: 10, innerWindow: 2, outerWindow: 1)
+        expect(prepare.windowedPageNumbers()).toEqual [1, 2, null, 6, 7, 8, 9, 10]
+
+  describe "pager controller", ->
+    $scope = null
+
+    beforeEach inject ($rootScope, $controller) ->
+      $scope = $rootScope.$new()
+      $controller("pager", $scope: $scope)
+
+      $scope.page = 2
+      $scope.totalPages = 10
+
+    describe "#setPage", ->
+      it "sets the current page", ->
+        $scope.setPage(3)
+        expect($scope.page).toBe(3)
+
+      describe "when the new page number is < 1", ->
+        it "sets to the first page", ->
+          for newPage in [1, 0, -1]
+            $scope.setPage(newPage)
+            expect($scope.page).toBe(1)
+
+      describe "when the new page is > totalPages", ->
+        it "sets to the last page", ->
+          for newPage in [10, 11, 12]
+            $scope.setPage(newPage)
+            expect($scope.page).toBe(10)
+
+    describe "#next", ->
+      it "sets to the next page", ->
+        $scope.page = 9
+        $scope.next()
+        expect($scope.page).toBe(10)
+
+      describe "when the current page is the last page", ->
+        it "sets does nothig", ->
+          $scope.page = 9
+          $scope.next()
+          expect($scope.page).toBe(10)
+
+    describe "#hasNext", ->
+      it "return true when there is a next page", ->
+        $scope.page = 9
+        expect($scope.hasNext()).toBeTruthy()
+
+        $scope.page = 10
+        expect($scope.hasNext()).toBeFalsy()
+
+    describe "#prev", ->
+      it "sets to the prev page", ->
+        $scope.page = 9
+        $scope.prev()
+        expect($scope.page).toBe(8)
+
+      describe "when the current page is the last first", ->
+        it "sets does nothig", ->
+          $scope.page = 1
+          $scope.prev()
+          expect($scope.page).toBe(1)
+
+    describe "#hasPrev", ->
+      it "return true when there is a previous page", ->
+        $scope.page = 9
+        expect($scope.hasPrev()).toBeTruthy()
+
+        $scope.page = 1
+        expect($scope.hasPrev()).toBeFalsy()

data/spec/javascripts/app/modules/table_filter_spec.js.coffee

@@ -0,0 +1,76 @@
+describe "mb.tableFilter", ->
+  beforeEach module("mb.tableFilter")
+
+  describe "tableFilter controller", ->
+    $scope = null
+
+    beforeEach inject ($controller, $rootScope) ->
+      $scope = $rootScope.$new()
+      $controller("tableFilter", $scope: $scope)
+
+    describe "#isEmpty", ->
+      it "returns true when the value is empty", ->
+        for value in [null, undefined, ""]
+          $scope.value = value
+          expect($scope.isEmpty()).toBeTruthy()
+
+      it "returs false when the value is not empty", ->
+        $scope.value = "foo"
+        expect($scope.isEmpty()).toBeFalsy()
+
+    describe "#clear", ->
+      it "clears the filter value", ->
+        $scope.value = "foo"
+        $scope.clear()
+
+        expect($scope.value).toEqual("")
+
+  describe "tableFilter", ->
+    $scope = null
+    element = null
+
+    beforeEach module("app/assets/templates/table_filter.html")
+
+    beforeEach inject ($rootScope, $compile) ->
+      $scope = $rootScope
+
+      tpl = """
+            <div>
+              <table-filter value="filterValue" placeholder="Enter database name"></table-filter>
+            </div>
+            """
+      element = $compile(tpl)($scope)
+      $scope.$digest()
+
+    it "sets the valid placeholder", ->
+      input = element.find("input[type='text']")
+      expect(input.attr('placeholder')).toEqual("Enter database name")
+
+    it "binds the filter value", ->
+      $scope.$apply -> $scope.filterValue = "Test filter value"
+
+      input = element.find("input[type='text']")
+      expect(input.val()).toEqual("Test filter value")
+
+    describe "the clear button", ->
+      button = null
+
+      beforeEach ->
+        button = element.find("button")
+
+      it "is initially disabled", ->
+        expect(button).toHaveCssClass("disabled")
+
+      describe "when value is not empty", ->
+        beforeEach ->
+          $scope.$apply -> $scope.filterValue = "some value"
+
+        it "is enabled", ->
+          expect(button).not.toHaveCssClass("disabled")
+
+      describe "when the value is empty", ->
+        beforeEach ->
+          $scope.$apply -> $scope.filterValue = ""
+
+        it "is disabled", ->
+          expect(button).toHaveCssClass("disabled")