miga-base 0.7.26.0 → 1.0.0.1

data/utils/enveomics/Scripts/BlastTab.recplot2.R

@@ -0,0 +1,48 @@
+#!/usr/bin/env Rscript
+
+# @author  Luis M. Rodriguez-R
+# @license Artistic-2.0
+
+#= Load stuff
+suppressPackageStartupMessages(library(enveomics.R))
+args <- commandArgs(trailingOnly = FALSE)
+enveomics_R <- file.path(dirname(
+  sub("^--file=", "", args[grep("^--file=", args)])),
+  "lib", "enveomics.R")
+
+#= Generate interface
+opt <- enve.cliopts(enve.recplot2,
+  file.path(enveomics_R, "man", "enve.recplot2.Rd"),
+  positional_arguments=c(1,4),
+  usage="usage: %prog [options] output.Rdata [output.pdf [width height]]",
+  mandatory=c("prefix"),
+  o_desc=list(pos.breaks="Breaks in the positions histogram.",
+    pos.breaks.tsv="File with (absolute) coordinates of breaks in the position histogram",
+    id.breaks="Breaks in the identity histogram.",
+    id.summary="Function summarizing the identity bins. By default: sum.",
+    peaks.col="Color of peaks, mandatory for peak-finding (e.g., darkred).",
+    peaks.method="Method to detect peaks; one of emauto, em, or mower."),
+  p_desc=paste("","Produce recruitment plot objects provided that",
+    "BlastTab.catsbj.pl has been previously executed.", sep="\n\t"),
+  ignore=c("plot"),
+  defaults=c(pos.breaks.tsv=NA, id.metric="identity", peaks.col=NA,
+    peaks.method="emauto"))
+
+#= Run it!
+if(length(opt$args)>1){
+  args = as.list(opt$args[-1])
+  for(i in 2:3) if(length(args)>=i) args[[i]] <- as.numeric(args[[i]])
+  do.call("pdf", args)
+}else{
+  opt$options[["plot"]] <- FALSE
+}
+pc <- opt$options[["peaks.col"]]
+if(!is.na(pc) && pc=="NA") opt$options[["peaks.col"]] <- NA
+if(!is.null(opt$options[["peaks.method"]])){
+  opt$options[["peaks.opts"]] <- list(method=opt$options[["peaks.method"]])
+  opt$options[["peaks.method"]] <- NULL
+}
+rp <- do.call("enve.recplot2", opt$options)
+save(rp, file=opt$args[1])
+if(length(opt$args)>1) dev.off()
+

data/utils/enveomics/Scripts/BlastTab.seqdepth.pl

@@ -0,0 +1,86 @@
+#!/usr/bin/env perl
+#
+# @author: Luis M Rodriguez-R <lmrodriguezr at gmail dot com>
+# @license: artistic license 2.0
+# @update: Mar-23-2015
+#
+
+use strict;
+use warnings;
+use List::Util qw/min max sum/;
+
+my $fna = shift @ARGV;
+$fna or die "
+Usage:
+   cat blast1... | $0 genes_or_ctgs.fna > genes_or_ctgs.cov
+
+   blast1...		One or more Tabular BLAST files of reads vs genes (or contigs).
+   genes_or_ctgs.fna	A FastA file containing the genes or the contigs (db).
+   genes_or_ctgs.cov	The output file.
+   
+Output:
+   A tab-delimited file with the following columns:
+   1. Subject ID
+   2. Average sequencing depth
+   3. Median sequencing depth
+   4. Number of mapped reads
+   5. Length of the subject sequence
+
+";
+
+my $size  = {};
+my $gene  = {};
+my $reads = {};
+
+SIZE:{
+   local $/=">";
+   print STDERR "== Reading fasta\n";
+   open FNA, "<", $fna or die "Cannot read the file: $fna: $!\n";
+   my $i=0;
+   while(<FNA>){
+      chomp;
+      my @g = split /\n/, $_, 2;
+      next unless $g[1];
+      #$g[1] =~ s/[^A-Za-z]//g;
+      #$size->{$g[0]} = length $g[1];
+      $g[0] =~ s/\s.*//;
+      $size->{$g[0]} = ( $g[1] =~ tr/[A-Za-z]// );
+      print STDERR " Measuring sequence ".($i).": $g[0]      \r" unless ++$i%500;
+   }
+   close FNA;
+   print STDERR " Found $i sequences".(" "x30)."\n";
+}
+
+MAP:{
+   print STDERR "== Reading mapping\n";
+   my $i=0;
+   while(<>){
+      my @ln = split /\t/;
+      $gene->{$ln[1]} ||= [];
+      for my $pos (min($ln[8], $ln[9]) .. max($ln[8], $ln[9])){ ($gene->{$ln[1]}->[$pos]||=0)++ }
+      ($reads->{$ln[1]} ||= 0)++;
+      print STDERR " Saving hit ".($i).": $ln[1]      \r" unless ++$i%5000;
+   }
+   print STDERR " Found $i hits".(" "x30)."\n";
+}
+
+OUT:{
+   print STDERR "== Creating output\n";
+   my $i=0;
+   for my $g (keys %$gene){
+      $gene->{$g}->[$_] ||= 0 for (0 .. $size->{$g});
+      my @sorted = sort {$a <=> $b} @{$gene->{$g}};
+      die "Cannot find gene in $fna: $g.\n" unless exists $size->{$g};
+      printf "%s\t%.6f\t%d\t%d\t%d\n", $g,
+	   sum(@{$gene->{$g}})/$size->{$g},
+	   $sorted[$#sorted/2],
+	   $reads->{$g},
+	   $size->{$g};
+      delete $gene->{$g};
+      print STDERR " Saving sequence $g:".($i)."\r" unless ++$i%500;
+   }
+   print STDERR " Saved $i sequences".(" "x30)."\n";
+}
+
+print STDERR " done.\n";
+

data/utils/enveomics/Scripts/BlastTab.seqdepth_ZIP.pl

@@ -0,0 +1,119 @@
+#!/usr/bin/env perl
+#
+# @author: Luis M Rodriguez-R <lmrodriguezr at gmail dot com>
+# @license: artistic license 2.0
+# @update: Mar-23-2015
+#
+
+use strict;
+use warnings;
+use List::Util qw/min max sum/;
+
+my $fna = shift @ARGV;
+$fna or die "
+Description:
+   Estimates the average sequencing depth of subject sequences (genes or contigs)
+   assuming a Zero-Inflated Poisson distribution (ZIP) to correct for non-covered
+   positions. It uses the corrected method of moments estimators (CMMEs) as described
+   by Beckett et al [1]. Note that [1] has a mistake in eq. (2.4), that should be:
+      pi-hat-MM = 1 - (X-bar / lambda-hat-MM)
+   
+   Also note that a more elaborated mixture distribution can arise from coverage
+   histograms (e.g., see [2] for an additional correction called 'tail distribution'
+   and mixtures involving negative binomial) so take these results cum grano salis.
+
+Usage:
+   cat blast1... | $0 genes_or_ctgs.fna > genes_or_ctgs.cov
+
+   blast1...		One or more Tabular BLAST files of reads vs genes (or contigs).
+   genes_or_ctgs.fna	A FastA file containing the genes or the contigs (db).
+   genes_or_ctgs.cov	The output file.
+   
+Output:
+   A tab-delimited file with the following columns (the one you want is #2):
+   1. Subject ID
+   2. Estimated average sequencing depth (CMME lambda)
+   3. Zero-inflation (CMME pi)
+   4. Observed average sequencing depth
+   5. Observed median sequencing depth
+   6. Observed median sequencing depth excluding zeroes
+   7. Number of mapped reads
+   8. Length of the subject sequence
+
+References:
+   [1] http://anisette.ucs.louisiana.edu/Academic/Sciences/MATH/stage/stat2012.pdf
+   [2] Lindner et al, Bioinformatics, 2013.
+
+";
+
+my $size  = {};
+my $gene  = {};
+my $reads = {};
+
+SIZE:{
+   local $/=">";
+   print STDERR "== Reading fasta\n";
+   open FNA, "<", $fna or die "Cannot read the file: $fna: $!\n";
+   my $i=0;
+   while(<FNA>){
+      chomp;
+      my @g = split /\n/, $_, 2;
+      next unless $g[1];
+      #$g[1] =~ s/[^A-Za-z]//g;
+      #$size->{$g[0]} = length $g[1];
+      $g[0] =~ s/\s.*//;
+      $size->{$g[0]} = ( $g[1] =~ tr/[A-Za-z]// );
+      print STDERR " Measuring sequence ".($i).": $g[0]      \r" unless ++$i%500;
+   }
+   close FNA;
+   print STDERR " Found $i sequences".(" "x30)."\n";
+}
+
+MAP:{
+   print STDERR "== Reading mapping\n";
+   my $i=0;
+   while(<>){
+      my @ln = split /\t/;
+      $gene->{$ln[1]} ||= [];
+      for my $pos (min($ln[8], $ln[9]) .. max($ln[8], $ln[9])){ ($gene->{$ln[1]}->[$pos]||=0)++ }
+      ($reads->{$ln[1]} ||= 0)++;
+      print STDERR " Saving hit ".($i).": $ln[1]      \r" unless ++$i%5000;
+   }
+   print STDERR " Found $i hits".(" "x30)."\n";
+}
+
+OUT:{
+   print STDERR "== Creating output\n";
+   my $i=0;
+   for my $g (keys %$gene){
+      unless(exists $size->{$g}){
+         warn "Warning: Cannot find gene in $fna: $g.\n";
+	 next;
+      }
+      $gene->{$g}->[$_] ||= 0 for (0 .. $size->{$g});
+      die "Hits out-of-boundaries in gene $g: $#{$gene->{$g}} != $size->{$g}.\n" if $#{$gene->{$g}} != $size->{$g};
+      my @sorted = sort {$a <=> $b} @{$gene->{$g}};
+      my @sorted_nz = grep { $_>0 } @sorted;
+      my $xbar = sum(@{$gene->{$g}})/$size->{$g};
+      my $xsqbar = sum(map { ($_ - $xbar)**2 } @{$gene->{$g}})/($size->{$g}-1); 
+      my $var = $xsqbar - $xbar**2;
+      my $lambdaMM = $xbar + ($var/$xbar) - 1;
+      my $piMM = $lambdaMM==0 ? 0 : 1 - $xbar/$lambdaMM;
+      printf "%s\t%.6f\t%.6f\t%.6f\t%d\t%d\t%d\t%d\n", $g,
+	   ($xbar >= $var ? $xbar : $lambdaMM),
+	   ($xbar >= $var ? 0 : $piMM),
+	   #$lambdaMM,
+	   #$piMM,
+	   sum(@{$gene->{$g}})/$size->{$g},
+	   $sorted[$#sorted/2],
+	   $sorted_nz[$#sorted_nz/2],
+	   $reads->{$g},
+	   $size->{$g};
+      delete $gene->{$g};
+      print STDERR " Saving sequence $g:".($i)."   \r" unless ++$i%500;
+   }
+   print STDERR " Saved $i sequences".(" "x30)."   \n";
+}
+
+print STDERR " done.\n";
+

data/utils/enveomics/Scripts/BlastTab.seqdepth_nomedian.pl

@@ -0,0 +1,86 @@
+#!/usr/bin/env perl
+#
+# @author: Luis M Rodriguez-R <lmrodriguezr at gmail dot com>
+# @license: artistic license 2.0
+# @update: Mar-23-2015
+#
+
+use strict;
+use warnings;
+use List::Util qw/min max sum/;
+
+my $fna = shift @ARGV;
+$fna or die "
+Usage:
+   cat blast1... | $0 genes_or_ctgs.fna > genes_or_ctgs.cov
+
+   blast1...		One or more Tabular BLAST files of reads vs genes (or contigs).
+   genes_or_ctgs.fna	A FastA file containing the genes or the contigs (db).
+   genes_or_ctgs.cov	The output file.
+
+Output:
+   A tab-delimited file with the following columns:
+   1. Subject ID
+   2. Average sequencing depth
+   3. Number of mapped reads
+   4. Length of the subject sequence
+
+Note:
+   The values reported by this script may differ from those of BlastTab.seqdepth.pl,
+   because this script uses the aligned length of the read while BlastTab.seqdepth.pl
+   uses the aligned length of the subject sequence. 
+
+";
+
+my $size  = {};
+my $gene  = {};
+my $reads = {};
+
+SIZE:{
+   local $/=">";
+   print STDERR "== Reading fasta\n";
+   open FNA, "<", $fna or die "Cannot read the file: $fna: $!\n";
+   my $i=0;
+   while(<FNA>){
+      chomp;
+      my @g = split /\n/, $_, 2;
+      next unless $g[1];
+      #$g[1] =~ s/[^A-Za-z]//g;
+      #$size->{$g[0]} = length $g[1];
+      $g[0] =~ s/\s.*//;
+      $size->{$g[0]} = ( $g[1] =~ tr/[A-Za-z]// );
+      print STDERR " Measuring sequence ".($i).": $g[0]      \r" unless ++$i%500;
+   }
+   close FNA;
+   print STDERR " Found $i sequences".(" "x30)."\n";
+}
+
+MAP:{
+   print STDERR "== Reading mapping\n";
+   my $i=0;
+   while(<>){
+      my @ln = split /\t/;
+      $gene->{$ln[1]} ||= 0;
+      $gene->{$ln[1]} += abs($ln[6]-$ln[7])+1;
+      ($reads->{$ln[1]} ||= 0)++;
+      print STDERR " Saving hit ".($i).": $ln[1]      \r" unless ++$i%5000;
+   }
+   print STDERR " Found $i hits".(" "x30)."\n";
+}
+
+OUT:{
+   print STDERR "== Creating output\n";
+   my $i=0;
+   for my $g (keys %$gene){
+      die "Cannot find gene in $fna: $g.\n" unless exists $size->{$g};
+      printf "%s\t%.6f\t%d\t%d\n", $g,
+	   $gene->{$g}/$size->{$g},
+	   $reads->{$g},
+	   $size->{$g};
+      print STDERR " Saving sequence $g:".($i)."\r" unless ++$i%500;
+   }
+   print STDERR " Saved $i sequences".(" "x30)."\n";
+}
+
+print STDERR " done.\n";
+

data/utils/enveomics/Scripts/BlastTab.subsample.pl

@@ -0,0 +1,47 @@
+#!/usr/bin/env perl
+#
+# @author  Luis M Rodriguez-R <lmrodriguezr at gmail dot com>
+# @license artistic license 2.0
+# @update  Mar-23-2015
+#
+
+use strict;
+use warnings;
+
+my($blast, $fasta) = @ARGV;
+($blast and $fasta) or die "
+Description:
+   Filters a BLAST output including only the hits produced by
+   any of the given sequences as query.
+
+Usage:
+   $0 blast.tab sample.fa > out.tab
+
+   blast.tab	BLAST output to be filtered (tabular format).
+   sample.fa	Sequences to use as query.
+   out.tab	The filtered BLAST output (tabular format).
+
+";
+
+print STDERR "== Reading sequences\n";
+my $seq = {};
+open FASTA, "<", $fasta or die "Cannot read the file: $fasta: $!\n";
+while(<FASTA>){
+   next unless /^>(\S+)/;
+   $seq->{$1} = 1;
+}
+close FASTA;
+print STDERR " ".(scalar keys %$seq)." sequences to be used as query.\n";
+
+print STDERR "== Reading BLAST\n";
+my ($N,$n)=(0,0);
+open BLAST, "<", $blast or die "Cannot read the file: $blast: $!\n";
+while(my $ln = <BLAST>){
+   next if $ln=~/^#/;
+   $N++; my ($qry) = split /\t/, $ln;
+   next unless exists $seq->{$qry};
+   $n++; print $ln;
+}
+close BLAST;
+print STDERR " Reported $n entries out of $N.\n";
+

data/utils/enveomics/Scripts/BlastTab.sumPerHit.pl

@@ -0,0 +1,114 @@
+#!/usr/bin/env perl
+#
+# @author  Luis M. Rodriguez-R <lmrodriguezr at gmail dot com>
+# @update  Mar-23-2016
+# @license artistic license 2.0
+#
+
+use warnings;
+use strict;
+use Getopt::Std;
+
+sub HELP_MESSAGE {
+die "
+.Description
+   Sums the weights of all the queries hitting each subject.  Often (but not
+   necessarily) the BLAST files contain only best matches.  The weights can be
+   any number, but a common use of this Script is to add up counts (weights are
+   integers).  For example, in a BLAST of predicted genes vs some annotation
+   source, the weights could be the number of reads recruited by each gene.
+
+.Usage:
+   $0 [options] blast... > out-file
+
+   blast... *	One or more BLAST files.
+   out-file	A two-columns tab-delimited file containing the summed weights
+   		per hit.
+   
+   -w <str>	Weights file: A two-columns tab-delimited file containing the
+   		name (column 1) and the weight (column 2) of each query.
+   -s <float>	Minimum score.  By default: 0.
+   -i <float>	Minimum identity (in percentage).  By default: 0.
+   -m <int>	Maximum number of queries.  Set to 0 for all.  By default: 0.
+   -n		Normalize weights by the number of hits per query.
+   -z		Add zero when weight is not found (by default: doesn't list
+   		them).
+   -q		Run quietly.
+   -h		Display this message and exit.
+
+   * Mandatory
+
+.Note:
+   The weights (-w parameter) are optional, but its use is encouraged.  When
+   weights are not passed, the script simply assumes all queries to be equally
+   weighted (unity), a result that can be faster to compute with, for example:
+      cat blast | cut -f 2 | sort | uniq -c | awk '{print \$2\"\\t\"\$1}' > out
+   It is equivalent to simply count the number of times that each subject
+   occurs.
+"
+}
+
+my %o = ();
+getopts('w:s:i:m:znqh', \%o);
+$o{h} and &HELP_MESSAGE;
+$o{s}||=0;
+$o{i}||=0;
+$o{m}||=0;
+
+my %count;
+if($o{w}){
+   print STDERR "Reading counts.\n" unless $o{q};
+   open COUNT, "<", $o{w} or die "Cannot open file: $o{w}: $!\n";
+   %count = map {split /\t/} <COUNT>;
+   close COUNT;
+}
+
+print STDERR "Reading BLASTs.\n" unless $o{q};
+my $qry = '';
+my $hits = 0;
+my @buf = ();
+my $qries = 0;
+my $noQry = 0;
+my $ln1   = 0;
+my %out = ();
+BFILE: for my $blast (@ARGV){
+   print STDERR " o $blast\n" unless $o{q};
+   open BLAST, "<", $blast or die "Cannot open file: $blast: $!\n";
+   BLINE: while(<BLAST>){
+      chomp;
+      my @ln = split /\t/;
+      $ln1 ||= $#ln;
+      die "Bad line $.: $_\n" unless $#ln==$ln1;
+      next if ($o{s} and $ln[11]<$o{s}) or ($o{i} and $ln[2]<$o{i});
+      unless(exists $count{$ln[0]}){
+	 $noQry++;
+	 if(not $o{w}){
+	    $count{$ln[0]}=1;
+	 }elsif($o{z}){
+	    $count{$ln[0]}=0;
+	 }else{
+	    next BLINE;
+	 }
+      }
+      
+      if($qry ne $ln[0]){
+	 $qries++;
+	 ($out{$_->[0]}||=0) += ($_->[1]/($o{n}?$hits:1)) for @buf;
+	 last BFILE if $o{m} and $qries >= $o{m};
+	 @buf = ();
+	 $qry  = $ln[0];
+	 $hits = 0;
+      }
+      
+      push @buf, [$ln[1], $count{$ln[0]}];
+      $hits++;
+   }
+   ($out{$_->[0]}||=0) += ($_->[1]/($o{n}?$hits:1)) for @buf;
+   close BLAST;
+}
+print STDERR "Warning: Couldn't find $noQry queries\n" if $noQry and $o{w};
+
+for my $h (keys %out){
+   print "$h\t".$out{$h}."\n";
+}
+