mercury-rails 0.1.0

data/spec/javascripts/mercury/snippet_toolbar_spec.js.coffee

@@ -0,0 +1,186 @@
+require '/assets/mercury/mercury.js'
+
+describe "Mercury.SnippetToolbar", ->
+
+  template 'mercury/snippet_toolbar.html'
+
+  beforeEach ->
+    $.fx.off = true
+
+  afterEach ->
+    @snippetToolbar = null
+    delete(@snippetToolbar)
+    $(document).unbind('mercury:hide:toolbar')
+    $(document).unbind('mercury:show:toolbar')
+
+  describe "constructor", ->
+
+    beforeEach ->
+      spyOn(Mercury.SnippetToolbar.prototype, 'build').andCallFake(=>)
+      spyOn(Mercury.SnippetToolbar.prototype, 'bindEvents').andCallFake(=>)
+
+    it "expects document", ->
+      @snippetToolbar = new Mercury.SnippetToolbar($('document'))
+      expect(@snippetToolbar.document).toEqual($('document'))
+
+    it "accepts options", ->
+      @snippetToolbar = new Mercury.SnippetToolbar($('document'))
+      expect(@snippetToolbar.document).toEqual($('document'))
+
+
+  describe "#build", ->
+
+    it "builds an element", ->
+      @snippetToolbar = new Mercury.SnippetToolbar($('document'), {appendTo: '#test'})
+      html = $('<div>').html(@snippetToolbar.element).html()
+      expect(html).toContain('class="mercury-toolbar mercury-snippet-toolbar"')
+      expect(html).toContain('style="display:none"')
+
+    it "appends to any element", ->
+      @snippetToolbar = new Mercury.SnippetToolbar($('document'), {appendTo: '#snippet_toolbar_container'})
+      expect($('#snippet_toolbar_container .mercury-toolbar').length).toEqual(1)
+
+
+  describe "observed events", ->
+
+    beforeEach ->
+      @snippetToolbar = new Mercury.SnippetToolbar($('document'), {appendTo: '#test'})
+
+    describe "custom event: show:toolbar", ->
+
+      it "does nothing if there's no snippet", ->
+        spy = spyOn(Mercury.SnippetToolbar.prototype, 'show').andCallFake(=>)
+        Mercury.trigger('show:toolbar', {snippet: null})
+        expect(spy.callCount).toEqual(0)
+
+      it "calls show", ->
+        spy = spyOn(Mercury.SnippetToolbar.prototype, 'show').andCallFake(=>)
+        Mercury.trigger('show:toolbar', {snippet: $('#snippet')})
+        expect(spy.callCount).toEqual(1)
+
+    describe "custom event: hide:toolbar", ->
+
+      it "does nothing if it's not for the snippet toolbar", ->
+        spy = spyOn(Mercury.SnippetToolbar.prototype, 'hide').andCallFake(=>)
+        Mercury.trigger('hide:toolbar', {type: 'foo'})
+        expect(spy.callCount).toEqual(0)
+
+      it "calls hide", ->
+        spy = spyOn(Mercury.SnippetToolbar.prototype, 'hide').andCallFake(=>)
+        Mercury.trigger('hide:toolbar', {type: 'snippet'})
+        expect(spy.callCount).toEqual(1)
+
+    describe "mousemove", ->
+
+      it "clears the hide timeout", ->
+        spy = spyOn(window, 'clearTimeout').andCallFake(=>)
+        jasmine.simulate.mousemove($('#test .mercury-snippet-toolbar').get(0))
+        expect(spy.callCount).toEqual(1)
+
+    describe "mouseout", ->
+
+      it "calls hide", ->
+        spy = spyOn(Mercury.SnippetToolbar.prototype, 'hide').andCallFake(=>)
+        jasmine.simulate.mouseout($('#test .mercury-snippet-toolbar').get(0))
+        expect(spy.callCount).toEqual(1)
+
+
+  describe "#show", ->
+
+    beforeEach ->
+      @snippetToolbar = new Mercury.SnippetToolbar($('document'), {appendTo: '#test'})
+      @positionSpy = spyOn(Mercury.SnippetToolbar.prototype, 'position').andCallFake(=>)
+      @appearSpy = spyOn(Mercury.SnippetToolbar.prototype, 'appear').andCallFake(=>)
+
+    it "expects a snippet", ->
+      @snippetToolbar.show({snippet: 'foo'})
+      expect(@snippetToolbar.snippet).toEqual({snippet: 'foo'})
+
+    it "calls position", ->
+      @snippetToolbar.show()
+      expect(@positionSpy.callCount).toEqual(1)
+
+    it "calls appear", ->
+      @snippetToolbar.show()
+      expect(@appearSpy.callCount).toEqual(1)
+
+
+  describe "#position", ->
+
+    beforeEach ->
+      Mercury.displayRect = {top: 20}
+      @snippetToolbar = new Mercury.SnippetToolbar($('document'), {appendTo: '#test'})
+      @snippetToolbar.snippet = $('#snippet')
+
+    it "positions itself based on the snippet", ->
+      @snippetToolbar.element.show()
+      @snippetToolbar.position()
+      if $.browser.webkit
+        expect(@snippetToolbar.element.offset()).toEqual({top: 18, left : 200})
+      else
+        expect(@snippetToolbar.element.offset()).toEqual({top: 14, left : 200})
+
+
+  describe "#appear", ->
+
+    beforeEach ->
+      @snippetToolbar = new Mercury.SnippetToolbar($('document'), {appendTo: '#test'})
+
+    it "clears the hide timeout", ->
+      spy = spyOn(window, 'clearTimeout').andCallFake(=>)
+      @snippetToolbar.appear()
+      expect(spy.callCount).toEqual(1)
+
+    it "sets visible", ->
+      @snippetToolbar.appear()
+      expect(@snippetToolbar.visible).toEqual(true)
+
+    it "shows the element", ->
+      @snippetToolbar.appear()
+      expect(@snippetToolbar.element.css('display')).toEqual('block')
+
+
+  describe "#hide", ->
+
+    beforeEach ->
+      @snippetToolbar = new Mercury.SnippetToolbar($('document'), {appendTo: '#test'})
+
+    it "it clears the hide timeout", ->
+      spy = spyOn(window, 'clearTimeout').andCallFake(=>)
+      @snippetToolbar.hide()
+      expect(spy.callCount).toEqual(1)
+
+    describe "immediately", ->
+
+      beforeEach ->
+        @snippetToolbar.element.show()
+
+      it "hides the element", ->
+        @snippetToolbar.hide(true)
+        expect(@snippetToolbar.element.css('display')).toEqual('none')
+
+      it "sets visible", ->
+        @snippetToolbar.visible = true
+        @snippetToolbar.hide(true)
+        expect(@snippetToolbar.visible).toEqual(false)
+
+    describe "not immediately", ->
+
+      beforeEach ->
+        @snippetToolbar.element.show()
+        @setTimeoutSpy = spyOn(window, 'setTimeout')
+
+      it "sets a timeout", ->
+        @setTimeoutSpy.andCallFake(=>)
+        @snippetToolbar.hide()
+        expect(@setTimeoutSpy.callCount).toEqual(1)
+
+      it "hides the element", ->
+        @setTimeoutSpy.andCallFake((callback) => callback())
+        @snippetToolbar.hide()
+        expect(@snippetToolbar.element.css('display')).toEqual('none')
+
+      it "sets visible", ->
+        @setTimeoutSpy.andCallFake((callback) => callback())
+        @snippetToolbar.hide()
+        expect(@snippetToolbar.visible).toEqual(false)

data/spec/javascripts/mercury/statusbar_spec.js.coffee

@@ -0,0 +1,78 @@
+require '/assets/mercury/mercury.js'
+
+describe "Mercury.Statusbar", ->
+
+  template 'mercury/statusbar.html'
+
+  beforeEach ->
+    @region = {
+      path: -> [{tagName: 'A'}, {tagName: 'B'}, {tagName: 'C'}]
+    }
+
+  afterEach ->
+    @statusbar = null
+    delete(@statusbar)
+
+  describe "constructor", ->
+
+    beforeEach ->
+      @buildSpy = spyOn(Mercury.Statusbar.prototype, 'build')
+      @bindEventsSpy = spyOn(Mercury.Statusbar.prototype, 'bindEvents')
+      @statusbar = new Mercury.Statusbar({appendTo: '#test', foo: 'bar'})
+
+    it "accepts options", ->
+      expect(@statusbar.options.foo).toEqual('bar')
+
+    it "calls build", ->
+      expect(@buildSpy.callCount).toEqual(1)
+
+    it "calls bindEvents", ->
+      expect(@bindEventsSpy.callCount).toEqual(1)
+
+
+  describe "#height", ->
+
+    beforeEach ->
+      spyOn(Mercury.Statusbar.prototype, 'bindEvents').andCallFake(=>)
+      @statusbar = new Mercury.Statusbar({appendTo: '#test'})
+
+    it "knows it's own height", ->
+      expect(@statusbar.height()).toEqual(20) # styled with css in the template
+
+
+  describe "#build", ->
+
+    beforeEach ->
+      spyOn(Mercury.Statusbar.prototype, 'bindEvents').andCallFake(=>)
+      @statusbar = new Mercury.Statusbar({appendTo: '#statusbar_container'})
+
+    it "builds an element", ->
+      expect($('#test .mercury-statusbar').length).toEqual(1)
+
+    it "can append to any element", ->
+      expect($('#statusbar_container .mercury-statusbar').length).toEqual(1)
+
+
+  describe "observed events ", ->
+
+    beforeEach ->
+      spyOn(Mercury.Statusbar.prototype, 'build').andCallFake(=>)
+      @statusbar = new Mercury.Statusbar({appendTo: '#test'})
+
+    describe "custom event: region:update", ->
+
+      it "calls setPath if a region was provided", ->
+        spy = spyOn(Mercury.Statusbar.prototype, 'setPath').andCallFake(=>)
+
+        Mercury.trigger('region:update', {region: @region})
+        expect(spy.callCount).toEqual(1)
+
+
+  describe "#setPath", ->
+
+    beforeEach ->
+      @statusbar = new Mercury.Statusbar({appendTo: '#test'})
+
+    it "builds a path and displays it", ->
+      @statusbar.setPath(@region.path())
+      expect($('.mercury-statusbar').html()).toEqual('<span><strong>Path: </strong></span><a>c</a> » <a>b</a> » <a>a</a>')

data/spec/javascripts/mercury/table_editor_spec.js.coffee

@@ -0,0 +1,192 @@
+require '/assets/mercury/mercury.js'
+
+describe "Mercury.tableEditor", ->
+
+  template 'mercury/table_editor.html'
+
+  beforeEach ->
+    @table = $('#table1')
+    @cell = @table.find('th, td').first()
+
+  describe "singleton method", ->
+
+    beforeEach ->
+      @loadSpy = spyOn(Mercury.tableEditor, 'load').andCallFake(=>)
+
+    it "calls load", ->
+      Mercury.tableEditor(@table, @cell)
+      expect(@loadSpy.callCount).toEqual(1)
+
+    it "returns the function object", ->
+      ret = Mercury.tableEditor(@table, @cell)
+      expect(ret).toEqual(Mercury.tableEditor)
+
+
+  describe "#load", ->
+
+    it "expects a table and a table cell", ->
+      Mercury.tableEditor(@table, @cell)
+      expect(Mercury.tableEditor.table).toEqual(@table)
+      expect(Mercury.tableEditor.cell).toEqual(@cell)
+
+    it "sets row based on where the cell is", ->
+      Mercury.tableEditor(@table, @cell)
+      expect(Mercury.tableEditor.row.get(0)).toEqual(@table.find('tr').get(0))
+
+    it "gets the column count", ->
+      Mercury.tableEditor(@table, @cell)
+      expect(Mercury.tableEditor.columnCount).toEqual(6)
+
+    it "gets the row count", ->
+      Mercury.tableEditor(@table, @cell)
+      expect(Mercury.tableEditor.rowCount).toEqual(8)
+
+
+  describe "#getColumnCount", ->
+
+    it "gets the column count from the alpha row", ->
+      Mercury.tableEditor(@table, @cell)
+      expect(Mercury.tableEditor.columnCount).toEqual(6)
+
+
+  describe "#getRowCount", ->
+
+    it "gets the row count", ->
+      Mercury.tableEditor(@table, @cell)
+      expect(Mercury.tableEditor.rowCount).toEqual(8)
+
+
+  describe "#cellIndexFor", ->
+
+    it "gives the right index for different cells", ->
+      cell = @table.find('#row1 td:nth-child(1n)').get(0)
+      expect(Mercury.tableEditor.cellIndexFor(cell)).toEqual(0)
+
+      cell = @table.find('#row2 th:nth-child(2n)').get(0)
+      expect(Mercury.tableEditor.cellIndexFor(cell)).toEqual(1)
+
+      cell = @table.find('#row2 th:nth-child(6n)').get(0)
+      expect(Mercury.tableEditor.cellIndexFor(cell)).toEqual(5)
+
+      cell = @table.find('#row3 td:nth-child(4n)').get(0)
+      expect(Mercury.tableEditor.cellIndexFor(cell)).toEqual(5)
+
+      cell = @table.find('#row7 td:nth-child(2n)').get(0)
+      expect(Mercury.tableEditor.cellIndexFor(cell)).toEqual(2)
+
+
+  describe "#cellSignatureFor", ->
+
+    it "returns an object with cell information", ->
+      cell = @table.find('#row2 th:nth-child(3n)').get(0)
+      sig = Mercury.tableEditor.cellSignatureFor(cell)
+      expect(sig.width).toEqual(1)
+      expect(sig.height).toEqual(2)
+      expect(sig.right).toEqual(3)
+
+      cell = @table.find('#row2 th:nth-child(5n)').get(0)
+      sig = Mercury.tableEditor.cellSignatureFor(cell)
+      expect(sig.width).toEqual(1)
+      expect(sig.height).toEqual(4)
+      expect(sig.right).toEqual(5)
+
+      cell = @table.find('#row7 td:nth-child(1n)').get(0)
+      sig = Mercury.tableEditor.cellSignatureFor(cell)
+      expect(sig.width).toEqual(2)
+      expect(sig.height).toEqual(1)
+      expect(sig.right).toEqual(2)
+
+  describe "#findCellByOptionsFor", ->
+
+    it "finds a matching cell in a specific row, based on right", ->
+      row = @table.find('#row2').get(0)
+      sig = Mercury.tableEditor.findCellByOptionsFor(row, { right: 5 })
+      expect(sig.cell.get(0)).toEqual(@table.find('#row2 th:nth-child(5n)').get(0))
+
+    it "finds a cell based on left", ->
+      row = @table.find('#row5').get(0)
+      sig = Mercury.tableEditor.findCellByOptionsFor(row, { left: 5 })
+      expect(sig.cell.get(0)).toEqual(@table.find('#row5 th:nth-child(5n)').get(0))
+
+    it "finds a cell based on left and width", ->
+      row = @table.find('#row7').get(0)
+      sig = Mercury.tableEditor.findCellByOptionsFor(row, { left: 2, width: 4 })
+      expect(sig.cell.get(0)).toEqual(@table.find('#row7 td:nth-child(2n)').get(0))
+
+    describe "when a cell isn't there", ->
+
+      beforeEach ->
+        @row = @table.find('#row3').get(0)
+
+      it "returns null", ->
+        sig = Mercury.tableEditor.findCellByOptionsFor(@row, { left: 2 })
+        expect(sig).toEqual(null)
+
+      it "can force to an adjacent cell", ->
+        sig = Mercury.tableEditor.findCellByOptionsFor(@row, { left: 2, forceAdjacent: true })
+        expect(sig.cell.get(0)).toEqual(@table.find('#row3 td:nth-child(2n)').get(0))
+        expect(sig.direction).toEqual('after')
+
+
+  describe "#findCellByIntersectionFor", ->
+
+    it "finds cells that intersect vertically, based on the signature of another cell", ->
+      sig = Mercury.tableEditor.cellSignatureFor(@table.find('#row6 td:nth-child(3n)'))
+      intersectingSig = Mercury.tableEditor.findCellByIntersectionFor(@table.find('#row7'), sig)
+      expect(intersectingSig.cell.get(0)).toEqual(@table.find('#row7 td:nth-child(2n)').get(0))
+
+
+  describe "#columnsFor", ->
+
+    it "returns the total number of cells and colspans for a given collection of cells", ->
+      expect(Mercury.tableEditor.columnsFor(@table.find('#row7 td'))).toEqual(6)
+
+
+  describe "#colspanFor", ->
+
+    it "returns the colspan of a given cell", ->
+      cell = @table.find('#row7 td:nth-child(2n)')
+      expect(Mercury.tableEditor.colspanFor(cell)).toEqual(4)
+
+    it "defaults to 1", ->
+      cell = @table.find('#row6 td:first-child')
+      expect(Mercury.tableEditor.colspanFor(cell)).toEqual(1)
+
+
+  describe "#rowspanFor", ->
+
+    it "returns the rowspan of a given cell", ->
+      cell = @table.find('#row2 th:nth-child(5n)')
+      expect(Mercury.tableEditor.rowspanFor(cell)).toEqual(4)
+
+    it "defaults to 1", ->
+      cell = @table.find('#row6 td:first-child')
+      expect(Mercury.tableEditor.rowspanFor(cell)).toEqual(1)
+
+
+  describe "setColspanFor", ->
+
+    beforeEach ->
+      @cell = @table.find('#row2 th:first-child')
+
+    it "sets the colspan for a cell", ->
+      Mercury.tableEditor.setColspanFor(@cell, 20)
+      expect(@cell.attr('colspan')).toEqual('20')
+
+    it "removes the attribute if it's 1", ->
+      Mercury.tableEditor.setColspanFor(@cell, 1)
+      expect(@cell.attr('colspan')).toEqual(undefined)
+
+
+  describe "setRowspanFor", ->
+
+    beforeEach ->
+      @cell = @table.find('#row2 th:first-child')
+
+    it "sets the rowspan for a cell", ->
+      Mercury.tableEditor.setRowspanFor(@cell, 20)
+      expect(@cell.attr('rowspan')).toEqual('20')
+
+    it "removes the attribute if it's 1", ->
+      Mercury.tableEditor.setRowspanFor(@cell, 1)
+      expect(@cell.attr('rowspan')).toEqual(undefined)