memcached 1.2.6 → 1.2.7

data/ext/libmemcached-0.32/m4/pandora_ensure_gcc_version.m4

@@ -0,0 +1,36 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl If the user is on a Mac and didn't ask for a specific compiler
+dnl You're gonna get 4.2.
+AC_DEFUN([PANDORA_MAC_GCC42],
+  [AS_IF([test "$GCC" = "yes"],[
+    AS_IF([test "$host_vendor" = "apple" -a "x${ac_cv_env_CC_set}" = "x"],[
+      AS_IF([test -f /usr/bin/gcc-4.2],
+        [
+          CPP="/usr/bin/gcc-4.2 -E"
+          CC=/usr/bin/gcc-4.2
+          CXX=/usr/bin/g++-4.2
+        ])
+    ])
+  ])
+])
+
+dnl 
+AC_DEFUN([PANDORA_ENSURE_GCC_VERSION],[
+  AC_REQUIRE([PANDORA_MAC_GCC42])
+  AC_CACHE_CHECK([if GCC is recent enough], [ac_cv_gcc_recent],
+    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+#if !defined(__GNUC__) || (__GNUC__ < 4) || ((__GNUC__ >= 4) && (__GNUC_MINOR__ < 1))
+# error GCC is Too Old!
+#endif
+      ]])],
+      [ac_cv_gcc_recent=yes],
+      [ac_cv_gcc_recent=no])])
+  AS_IF([test "$ac_cv_gcc_recent" = "no" -a "$host_vendor" = "apple"],
+    AC_MSG_ERROR([Your version of GCC is too old. At least version 4.2 is required on OSX. You may need to install a version of XCode >= 3.1.2]))
+  AS_IF([test "$ac_cv_gcc_recent" = "no"],
+    AC_MSG_ERROR([Your version of GCC is too old. At least version 4.1 is required]))
+])

data/ext/libmemcached-0.32/m4/pandora_have_better_malloc.m4

@@ -0,0 +1,54 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([PANDORA_HAVE_BETTER_MALLOC],[
+  AC_REQUIRE([AC_FUNC_MALLOC])
+  AC_REQUIRE([AC_FUNC_REALLOC])
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  AC_ARG_ENABLE([umem],
+    [AS_HELP_STRING([--enable-umem],
+       [Enable linking with libumem @<:@default=off@:>@])],
+    [ac_enable_umem="$enableval"],
+    [ac_enable_umem="no"])
+  
+  AC_ARG_ENABLE([tcmalloc],
+    [AS_HELP_STRING([--enable-tcmalloc],
+       [Enable linking with tcmalloc @<:@default=off@:>@])],
+    [ac_enable_tcmalloc="$enableval"],
+    [ac_enable_tcmalloc="no"])
+  
+  AC_ARG_ENABLE([mtmalloc],
+    [AS_HELP_STRING([--disable-mtmalloc],
+       [Enable linking with mtmalloc @<:@default=on@:>@])],
+    [ac_enable_mtmalloc="$enableval"],
+    [ac_enable_mtmalloc="yes"])
+  
+  save_LIBS="${LIBS}"
+  LIBS=
+  AS_IF([test "x$ac_enable_umem" = "xyes"],[
+    AC_CHECK_LIB(umem,malloc,[],[])
+  ],[
+    case "$target_os" in
+      *linux*)
+        AS_IF([test "x$ac_enable_tcmalloc" != "xno"],[
+          AC_CHECK_LIB(tcmalloc-minimal,malloc,[],[])
+          AS_IF([test "x$ac_cv_lib_tcmalloc_minimal_malloc" != "xyes"],[
+            AC_CHECK_LIB(tcmalloc,malloc,[],[])
+          ])
+        ])
+        ;;
+      *solaris*)
+        AS_IF([test "x$ac_enable_mtmalloc" != "xno"],[
+          AC_CHECK_LIB(mtmalloc,malloc,[],[])
+        ])
+        ;;
+    esac
+  ])
+  BETTER_MALLOC_LIBS="${LIBS}"
+  LIBS="${save_LIBS}"
+  AC_SUBST([BETTER_MALLOC_LIBS])
+
+])

data/ext/libmemcached-0.32/m4/pandora_have_sasl.m4

@@ -0,0 +1,133 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_SASL],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for sasl
+  dnl --------------------------------------------------------------------
+  AC_ARG_ENABLE([sasl],
+    [AS_HELP_STRING([--disable-sasl],
+      [Build with sasl support @<:@default=on@:>@])],
+    [ac_enable_sasl="$enableval"],
+    [ac_enable_sasl="yes"])
+
+  AS_IF([test "x$ac_enable_sasl" = "xyes"],
+    [
+      AC_LIB_HAVE_LINKFLAGS(sasl,,[
+        #include <stdlib.h>
+        #include <sasl/sasl.h>
+      ],[
+        sasl_server_init(NULL, NULL);
+      ])
+
+      AS_IF([test "x${ac_cv_libsasl}" != "xyes" ],
+            [
+              AC_LIB_HAVE_LINKFLAGS(sasl2,,[
+                #include <stdlib.h>
+                #include <sasl/sasl.h>
+              ],[
+                sasl_server_init(NULL, NULL);
+              ])
+              HAVE_LIBSASL="$HAVE_LIBSASL2"
+              LIBSASL="$LIBSASL2"
+              LIBSASL_PREFIX="$LIBSASL2_PREFIX"
+	      LTLIBSASL="$LT_LIBSASL2"
+            ])
+    ])
+
+  AS_IF([test "x${ac_cv_libsasl}" = "xyes" -o "x${ac_cv_libsasl2}" = "xyes"],
+        [ac_cv_sasl=yes],
+        [ac_cv_sasl=no])
+
+  AM_CONDITIONAL(HAVE_LIBSASL, [test "x${ac_cv_libsasl}" = "xyes"])
+  AM_CONDITIONAL(HAVE_LIBSASL2, [test "x${ac_cv_libsasl2}" = "xyes"])
+  AM_CONDITIONAL(HAVE_SASL, [test "x${ac_cv_sasl}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_SASL],[
+  AC_REQUIRE([_PANDORA_SEARCH_SASL])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_SASL],[
+  AC_REQUIRE([_PANDORA_SEARCH_SASL])
+  AS_IF([test "x${ac_cv_sasl}" = "xno"],
+    AC_MSG_ERROR([SASL (libsasl or libsasl2) is required for ${PACKAGE}]))
+])
+
+AC_DEFUN([_PANDORA_SEARCH_LIBSASL],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libsasl
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libsasl],
+    [AS_HELP_STRING([--disable-libsasl],
+      [Build with libsasl support @<:@default=on@:>@])],
+    [ac_enable_libsasl="$enableval"],
+    [ac_enable_libsasl="yes"])
+
+  AS_IF([test "x$ac_enable_libsasl" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(sasl,,[
+      #include <stdlib.h>
+      #include <sasl/sasl.h>
+    ],[
+      sasl_server_init(NULL, NULL);
+    ])
+  ],[
+    ac_cv_libsasl="no"
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBSASL, [test "x${ac_cv_libsasl}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBSASL],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBSASL])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBSASL],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBSASL])
+  AS_IF([test "x${ac_cv_libsasl}" = "xno"],
+    AC_MSG_ERROR([libsasl is required for ${PACKAGE}]))
+])
+
+AC_DEFUN([_PANDORA_SEARCH_LIBSASL2],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libsasl2
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libsasl2],
+    [AS_HELP_STRING([--disable-libsasl2],
+      [Build with libsasl2 support @<:@default=on@:>@])],
+    [ac_enable_libsasl2="$enableval"],
+    [ac_enable_libsasl2="yes"])
+
+  AS_IF([test "x$ac_enable_libsasl2" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(sasl2,,[
+      #include <stdlib.h>
+      #include <sasl2/sasl2.h>
+    ],[
+      sasl2_server_init(NULL, NULL);
+    ])
+  ],[
+    ac_cv_libsasl2="no"
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBSASL2, [test "x${ac_cv_libsasl2}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBSASL2],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBSASL2])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBSASL2],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBSASL2])
+  AS_IF([test "x${ac_cv_libsasl2}" = "xno"],
+    AC_MSG_ERROR([libsasl2 is required for ${PACKAGE}]))
+])

data/ext/libmemcached-0.32/m4/pandora_header_assert.m4

@@ -0,0 +1,23 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl PANDORA_HEADER_ASSERT
+dnl ----------------
+dnl Check whether to enable assertions.
+AC_DEFUN([PANDORA_HEADER_ASSERT],
+[
+  AC_MSG_CHECKING([whether to enable assertions])
+  AC_ARG_ENABLE([assert],
+    [AS_HELP_STRING([--disable-assert],
+       [Turn off assertions])],
+    [ac_cv_assert="no"],
+    [ac_cv_assert="yes"])
+  AC_MSG_RESULT([$ac_cv_assert])
+
+  AS_IF([test "$ac_cv_assert" = "yes"], 
+    [AC_CHECK_HEADERS(assert.h)],
+    [AC_DEFINE(NDEBUG, 1, [Define to 1 if assertions should be disabled.])])
+])
+

data/ext/libmemcached-0.32/m4/pandora_libtool.m4

@@ -0,0 +1,15 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([PANDORA_LIBTOOL],[
+  AC_REQUIRE([AC_PROG_LIBTOOL])
+  dnl By requiring AC_PROG_LIBTOOL, we should force the macro system to read
+  dnl libtool.m4, where in 2.2 AC_PROG_LIBTOOL is an alias for LT_INIT
+  dnl Then, if we're on 2.2, we should have LT_LANG, so we'll call it.
+  m4_ifdef([LT_LANG],[
+    LT_LANG(C)
+    LT_LANG(C++)
+  ])
+])

data/ext/libmemcached-0.32/m4/pandora_optimize.m4

@@ -0,0 +1,79 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([PANDORA_OPTIMIZE],[
+  dnl Build optimized or debug version ?
+  dnl First check for gcc and g++
+  AS_IF([test "$GCC" = "yes" -a "$INTELCC" = "no"],[
+
+    dnl The following is required for portable results of floating point 
+    dnl calculations on PowerPC. The same must also be done for IA-64, but 
+    dnl this options is missing in the IA-64 gcc backend.
+    case "$target_cpu" in
+      *ppc* | *powerpc*)
+        AM_CFLAGS="-mno-fused-madd ${AM_CFLAGS}"
+        AM_CXXFLAGS="-mno-fused-madd ${AM_CXXFLAGS}"
+      ;;
+    esac
+
+    dnl Once we can use a modern autoconf, we can replace the std=gnu99 here
+    dnl with using AC_CC_STD_C99 above
+    CC="${CC} -std=gnu99"
+
+    AM_CPPFLAGS="-ggdb3 ${AM_CPPFLAGS}"
+
+    DEBUG_CFLAGS="-O0"
+    DEBUG_CXXFLAGS="-O0"
+
+    OPTIMIZE_CFLAGS="-O3"
+    OPTIMIZE_CXXFLAGS="-O3"
+  ])
+  AS_IF([test "$INTELCC" = "yes"],[
+    dnl Once we can use a modern autoconf, we can replace the std=gnu99 here
+    dnl with using AC_CC_STD_C99 above
+    CC="${CC} -std=c99"
+
+    AM_CPPFLAGS="-g ${AM_CPPFLAGS}"
+
+    DEBUG_CFLAGS="-O0"
+    DEBUG_CXXFLAGS="-O0"
+
+    OPTIMIZE_CFLAGS="-xHOST -O3 -no-prec-div -static"
+    OPTIMIZE_CXXFLAGS="${OPTIMIZE_CFLAGS}"
+
+  ])
+  AS_IF([test "$SUNCC" = "yes"],[
+    dnl Once we can use a modern autoconf, we can replace the -xc99=all here
+    dnl with using AC_CC_STD_C99 above
+    CC="${CC} -xc99=all"
+    CXX="${CXX} -xlang=c99"
+
+    AM_CFLAGS="-g -mt -xstrconst -Xa ${AM_CFLAGS}"
+    AM_CXXFLAGS="-mt -compat=5 -library=stlport4 -template=no%extdef ${AM_CXXFLAGS}"
+
+    DEBUG_CXXFLAGS="-g"
+
+    dnl TODO: Make a test for -xO4 usability here
+    OPTIMIZE_FLAGS="-xO3 -xlibmil -xdepend -xbuiltin"
+    OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS}"
+    OPTIMIZE_CXXFLAGS="-g0 ${OPTIMIZE_FLAGS}"
+
+  ])
+
+  AC_ARG_WITH([debug],
+    [AS_HELP_STRING([--with-debug],
+       [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
+    [with_debug=$withval],
+    [with_debug=no])
+  AS_IF([test "$with_debug" = "yes"],[
+    # Debugging. No optimization.
+    AM_CFLAGS="${AM_CFLAGS} ${DEBUG_CFLAGS} -DDEBUG"
+    AM_CXXFLAGS="${AM_CXXFLAGS} ${DEBUG_CXXFLAGS} -DDEBUG"
+  ],[
+    # Optimized version. No debug
+    AM_CFLAGS="${AM_CFLAGS} ${OPTIMIZE_CFLAGS}"
+    AM_CXXFLAGS="${AM_CXXFLAGS} ${OPTIMIZE_CXXFLAGS}"
+  ])
+])

data/ext/libmemcached-0.32/m4/pandora_shared_ptr.m4

@@ -0,0 +1,56 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl We check two things: where is the memory include file, and in what
+dnl namespace does shared_ptr reside.
+dnl We include AC_COMPILE_IFELSE for all the combinations we've seen in the
+dnl wild:
+dnl 
+dnl  GCC 4.3: namespace: std::  #include <memory>
+dnl  GCC 4.2: namespace: tr1::  #include <tr1/memory>
+dnl  GCC 4.2: namespace: boost::  #include <boost/shared_ptr.hpp>
+dnl
+dnl We define one of HAVE_HAVE_TR1_SHARED_PTR or HAVE_BOOST_SHARED_PTR
+dnl depending on location, and SHARED_PTR_NAMESPACE to be the namespace in
+dnl which shared_ptr is defined.
+dnl 
+
+AC_DEFUN([PANDORA_SHARED_PTR],[
+  AC_REQUIRE([PANDORA_CHECK_CXX_STANDARD])
+  AC_LANG_PUSH(C++)
+  AC_CHECK_HEADERS(memory tr1/memory boost/shared_ptr.hpp)
+  AC_CACHE_CHECK([the location of shared_ptr header file],
+    [ac_cv_shared_ptr_h],[
+      for namespace in std tr1 std::tr1 boost
+      do
+        AC_COMPILE_IFELSE(
+          [AC_LANG_PROGRAM([[
+#if defined(HAVE_MEMORY)
+# include <memory>
+#endif
+#if defined(HAVE_TR1_MEMORY)
+# include <tr1/memory>
+#endif
+#if defined(HAVE_BOOST_SHARED_PTR_HPP)
+# include <boost/shared_ptr.hpp>
+#endif
+#include <string>
+
+using $namespace::shared_ptr;
+using namespace std;
+            ]],[[
+shared_ptr<string> test_ptr(new string("test string"));
+            ]])],
+            [
+              ac_cv_shared_ptr_namespace="${namespace}"
+              break
+            ],[ac_cv_shared_ptr_namespace=missing])
+       done
+  ])
+  AC_DEFINE_UNQUOTED([SHARED_PTR_NAMESPACE],
+                     ${ac_cv_shared_ptr_namespace},
+                     [The namespace in which SHARED_PTR can be found])
+  AC_LANG_POP()
+])

data/ext/libmemcached-0.32/m4/pandora_vc_build.m4

@@ -0,0 +1,32 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([PANDORA_BUILDING_FROM_VC],[
+
+  ac_cv_building_from_vc=no
+
+  AS_IF([test -d "${srcdir}/.bzr"],[
+    ac_cv_building_from_bzr=yes
+    ac_cv_building_from_vc=yes
+    ],[
+    ac_cv_building_from_bzr=no
+  ])
+
+  AS_IF([test -d "${srcdir}/.svn"],[
+    ac_cv_building_from_svn=yes
+    ac_cv_building_from_vc=yes
+    ],[
+    ac_cv_building_from_svn=no
+  ])
+
+  AS_IF([test -d "${srcdir}/.hg"],[
+    ac_cv_building_from_hg=yes
+    ac_cv_building_from_vc=yes
+    ],[
+    ac_cv_building_from_hg=no
+  ])
+
+])
+  

data/ext/libmemcached-0.32/m4/pandora_warnings.m4

@@ -0,0 +1,262 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl AC_PANDORA_WARNINGS([less-warnings|warnings-always-on])
+dnl   less-warnings turn on a limited set of warnings
+dnl   warnings-always-on always set warnings=error regardless of tarball/vc
+
+dnl @TODO: remove less-warnings option as soon as Drizzle is clean enough to
+dnl        allow it
+ 
+AC_DEFUN([PANDORA_WARNINGS],[
+  m4_define([PW_LESS_WARNINGS],[no])
+  m4_define([PW_WARN_ALWAYS_ON],[no])
+  ifdef([m4_define],,[define([m4_define],   defn([define]))])
+  ifdef([m4_undefine],,[define([m4_undefine],   defn([undefine]))])
+  m4_foreach([pw_arg],[$*],[
+    m4_case(pw_arg,
+      [less-warnings],[
+        m4_undefine([PW_LESS_WARNINGS])
+        m4_define([PW_LESS_WARNINGS],[yes])
+      ],
+      [warnings-always-on],[
+        m4_undefine([PW_WARN_ALWAYS_ON])
+        m4_define([PW_WARN_ALWAYS_ON],[yes])
+    ]) 
+  ])
+
+  AC_REQUIRE([PANDORA_BUILDING_FROM_VC])
+  m4_if(PW_WARN_ALWAYS_ON, [yes],
+    [ac_cv_warnings_as_errors=yes],
+    AS_IF([test "$ac_cv_building_from_vc" = "yes"],
+          [ac_cv_warnings_as_errors=yes],
+          [ac_cv_warnings_as_errors=no]))
+
+  AC_ARG_ENABLE([profiling],
+      [AS_HELP_STRING([--enable-profiling],
+         [Toggle profiling @<:@default=off@:>@])],
+      [ac_profiling="$enableval"],
+      [ac_profiling="no"])
+
+  AC_ARG_ENABLE([coverage],
+      [AS_HELP_STRING([--enable-coverage],
+         [Toggle coverage @<:@default=off@:>@])],
+      [ac_coverage="$enableval"],
+      [ac_coverage="no"])
+
+  AS_IF([test "$GCC" = "yes"],[
+
+    AS_IF([test "$ac_profiling" = "yes"],[
+      CC_PROFILING="-pg"
+      save_LIBS="${LIBS}"
+      LIBS=""
+      AC_CHECK_LIB(c_p, read)
+      LIBC_P="${LIBS}"
+      LIBS="${save_LIBS}"
+      AC_SUBST(LIBC_P)
+    ],[
+      CC_PROFILING=" "
+    ])
+
+    AS_IF([test "$ac_coverage" = "yes"],
+          [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
+	 
+    AS_IF([test "$ac_cv_warnings_as_errors" = "yes"],
+          [W_FAIL="-Werror"])
+
+    AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
+      [ac_cv_safe_to_use_fdiagnostics_show_option_],
+      [save_CFLAGS="$CFLAGS"
+       CFLAGS="-fdiagnostics-show-option ${AM_CFLAGS} ${CFLAGS}"
+       AC_COMPILE_IFELSE(
+         [AC_LANG_PROGRAM([],[])],
+         [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
+         [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
+       CFLAGS="$save_CFLAGS"])
+
+    AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
+          [
+            F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
+          ])
+
+    AC_CACHE_CHECK([whether it is safe to use -Wconversion],
+      [ac_cv_safe_to_use_wconversion_],
+      [save_CFLAGS="$CFLAGS"
+       dnl Use -Werror here instead of ${W_FAIL} so that we don't spew
+       dnl conversion warnings to all the tarball folks
+       CFLAGS="-Wconversion -Werror -pedantic ${AM_CFLAGS} ${CFLAGS}"
+       AC_COMPILE_IFELSE(
+         [AC_LANG_PROGRAM([[
+#include <stdbool.h>
+void foo(bool a)
+{
+  (void)a;
+}
+         ]],[[
+foo(0);
+         ]])],
+         [ac_cv_safe_to_use_wconversion_=yes],
+         [ac_cv_safe_to_use_wconversion_=no])
+       CFLAGS="$save_CFLAGS"])
+
+    AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
+      [W_CONVERSION="-Wconversion"
+      AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
+        [ac_cv_safe_to_use_Wconversion_],
+        [save_CFLAGS="$CFLAGS"
+         dnl Use -Werror here instead of ${W_FAIL} so that we don't spew
+         dnl conversion warnings to all the tarball folks
+         CFLAGS="-Wconversion -Werror -pedantic ${AM_CFLAGS} ${CFLAGS}"
+         AC_COMPILE_IFELSE(
+           [AC_LANG_PROGRAM(
+             [[
+#include <netinet/in.h>
+             ]],[[
+uint16_t x= htons(80);
+             ]])],
+           [ac_cv_safe_to_use_Wconversion_=yes],
+           [ac_cv_safe_to_use_Wconversion_=no])
+         CFLAGS="$save_CFLAGS"])
+
+      AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
+            [NO_CONVERSION="-Wno-conversion"])
+    ])
+
+    NO_STRICT_ALIASING="-fno-strict-aliasing -Wno-strict-aliasing"
+    NO_SHADOW="-Wno-shadow"
+
+    AS_IF([test "$INTELCC" = "yes"],[
+      m4_if(PW_LESS_WARNINGS,[no],[
+        BASE_WARNINGS="-w1 -Wall -Werror -Wcheck -Wformat -Wp64 -Woverloaded-virtual -Wcast-qual"
+      ],[
+        BASE_WARNINGS="-w1 -Wall -Wcheck -Wformat -Wp64 -Woverloaded-virtual -Wcast-qual -diag-disable 981"
+      ])
+      CC_WARNINGS="${BASE_WARNINGS}"
+      CXX_WARNINGS="${BASE_WARNINGS}"
+    ],[
+      m4_if(PW_LESS_WARNINGS,[no],[
+        BASE_WARNINGS_FULL="-Wformat=2 ${W_CONVERSION} -Wstrict-aliasing"
+        CC_WARNINGS_FULL="-Wswitch-default -Wswitch-enum -Wwrite-strings"
+        CXX_WARNINGS_FULL="-Weffc++ -Wold-style-cast"
+      ],[
+        BASE_WARNINGS_FULL="-Wformat ${NO_STRICT_ALIASING}"
+      ])
+
+      AS_IF([test "${ac_cv_assert}" = "no"],
+            [NO_UNUSED="-Wno-unused-variable -Wno-unused-parameter"])
+  
+      BASE_WARNINGS="${W_FAIL} -pedantic -Wall -Wextra -Wundef -Wshadow ${NO_UNUSED} ${F_DIAGNOSTICS_SHOW_OPTION} ${CFLAG_VISIBILITY} ${BASE_WARNINGS_FULL}"
+      CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wmissing-declarations -Wcast-align ${CC_WARNINGS_FULL}"
+      CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wno-long-long ${CXX_WARNINGS_FULL}"
+
+      AC_CACHE_CHECK([whether it is safe to use -Wmissing-declarations from C++],
+        [ac_cv_safe_to_use_Wmissing_declarations_],
+        [AC_LANG_PUSH(C++)
+         save_CXXFLAGS="$CXXFLAGS"
+         CXXFLAGS="-Werror -pedantic -Wmissing-declarations ${AM_CXXFLAGS}"
+         AC_COMPILE_IFELSE([
+           AC_LANG_PROGRAM(
+           [[
+#include <stdio.h>
+           ]], [[]])
+        ],
+        [ac_cv_safe_to_use_Wmissing_declarations_=yes],
+        [ac_cv_safe_to_use_Wmissing_declarations_=no])
+        CXXFLAGS="$save_CXXFLAGS"
+        AC_LANG_POP()
+      ])
+      AS_IF([test "$ac_cv_safe_to_use_Wmissing_declarations_" = "yes"],
+            [CXX_WARNINGS="${CXX_WARNINGS} -Wmissing-declarations"])
+  
+      AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
+        [ac_cv_safe_to_use_Wlogical_op_],
+        [save_CFLAGS="$CFLAGS"
+         CFLAGS="${W_FAIL} -pedantic -Wlogical-op ${AM_CFLAGS} ${CFLAGS}"
+         AC_COMPILE_IFELSE([
+           AC_LANG_PROGRAM(
+           [[
+#include <stdio.h>
+           ]], [[]])
+        ],
+        [ac_cv_safe_to_use_Wlogical_op_=yes],
+        [ac_cv_safe_to_use_Wlogical_op_=no])
+      CFLAGS="$save_CFLAGS"])
+      AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
+            [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
+  
+      AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
+        [ac_cv_safe_to_use_Wredundant_decls_],
+        [AC_LANG_PUSH(C++)
+         save_CXXFLAGS="${CXXFLAGS}"
+         CXXFLAGS="${W_FAIL} -pedantic -Wredundant-decls ${AM_CXXFLAGS}"
+         AC_COMPILE_IFELSE(
+           [AC_LANG_PROGRAM([
+template <typename E> struct C { void foo(); };
+template <typename E> void C<E>::foo() { }
+template <> void C<int>::foo();
+            AC_INCLUDES_DEFAULT])],
+            [ac_cv_safe_to_use_Wredundant_decls_=yes],
+            [ac_cv_safe_to_use_Wredundant_decls_=no])
+          CXXFLAGS="${save_CXXFLAGS}"
+          AC_LANG_POP()])
+      AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
+            [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
+            [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
+  
+      NO_REDUNDANT_DECLS="-Wno-redundant-decls"
+      PROTOSKIP_WARNINGS="-Wno-effc++ -Wno-shadow"
+      
+    ])
+  ])
+
+  AS_IF([test "$SUNCC" = "yes"],[
+
+    AS_IF([test "$ac_profiling" = "yes"],
+          [CC_PROFILING="-xinstrument=datarace"])
+
+    AS_IF([test "$ac_cv_warnings_as_errors" = "yes"],
+          [W_FAIL="-errwarn=%all"])
+
+    AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
+      [ac_cv_paste_result],
+      [
+        save_CFLAGS="${CFLAGS}"
+        CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
+        AC_COMPILE_IFELSE(
+          [AC_LANG_PROGRAM([
+            AC_INCLUDES_DEFAULT
+          ],[
+            int x= 0;])],
+          [ac_cv_paste_result=yes],
+          [ac_cv_paste_result=no])
+        CFLAGS="${save_CFLAGS}"
+      ])
+    AS_IF([test $ac_cv_paste_result = yes],
+      [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
+
+
+    m4_if(PW_LESS_WARNINGS, [no],[
+      CC_WARNINGS_FULL="-erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
+      CXX_WARNINGS_FULL="-erroff=inllargeuse"
+    ],[
+      CC_WARNINGS_FULL="-erroff=E_ATTRIBUTE_NOT_VAR"
+      CXX_WARNINGS_FULL="-erroff=attrskipunsup,doubunder,reftotemp,inllargeuse,truncwarn1,signextwarn,inllargeint"
+    ])
+
+    CC_WARNINGS="-v -errtags=yes ${W_FAIL} ${CC_WARNINGS_FULL}"
+    CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${CXX_WARNINGS_FULL} ${W_FAIL}"
+    PROTOSKIP_WARNINGS="-erroff=attrskipunsup,doubunder,reftotemp,wbadinitl,identexpected,inllargeuse,truncwarn1,signextwarn"
+    NO_UNREACHED="-erroff=E_STATEMENT_NOT_REACHED"
+
+  ])
+
+  AC_SUBST(NO_CONVERSION)
+  AC_SUBST(NO_REDUNDANT_DECLS)
+  AC_SUBST(NO_UNREACHED)
+  AC_SUBST(NO_SHADOW)
+  AC_SUBST(NO_STRICT_ALIASING)
+  AC_SUBST(PROTOSKIP_WARNINGS)
+
+])