manatee 0.0.1.pre1

data/app/assets/javascripts/manatee/helpers/form_builder.jsh.coffee

@@ -0,0 +1,24 @@
+
+# _to_partial_path
+# button
+# check_box
+# collection_check_boxes
+# collection_radio_buttons
+# collection_select
+# date_select
+# datetime_select
+# emitted_hidden_id?
+# fields_for
+# file_field
+# grouped_collection_select
+# hidden_field
+# label
+# multipart=
+# new
+# radio_button
+# select
+# submit
+# time_select
+# time_zone_select
+# to_model
+# to_partial_path

data/app/assets/javascripts/manatee/helpers/form_options.jsh.coffee

@@ -0,0 +1,267 @@
+optionsNullSelector = (value) ->
+  false
+
+optionsStringSelectorBuilder = (_reference) ->
+  reference = _reference
+  (value) ->
+    value.toString() && reference == value.toString()
+
+optionsArraySelectorBuilder = (_reference)->
+  reference = []
+  for index, ref_value of _reference
+    reference.push ref_value.toString()
+  (value) ->
+    value && reference.indexOf(value.toString()) > -1
+
+disabledAndSelector = (options, selected_selector, disabled_selector) ->
+  options['selected'] = true if selected_selector(options['value'])
+  options['disabled'] = true if disabled_selector(options['value'])
+
+stringOption = (value, selected_selector, disabled_selector) ->
+  options = { value: value }
+  disabledAndSelector options, selected_selector, disabled_selector
+  @contentTag 'option', @htmlEscape(value), @htmlEscapeAttributes(options)
+
+selectorForOptions = (reference) ->
+  reference = reference.toString() if typeof reference == 'number' || reference == true || reference == false
+
+  return [ reference,                               optionsNullSelector ] if typeof reference == 'function'
+  return [ optionsNullSelector,                     optionsNullSelector ] if reference == null || reference == undefined
+  return [ optionsStringSelectorBuilder(reference), optionsNullSelector ] if typeof reference == 'string'
+  return [ optionsArraySelectorBuilder(reference),  optionsNullSelector ] if reference instanceof Array
+
+  [ selectorForOptions( reference['selected'] )[0], selectorForOptions( reference['disabled'] )[0] ]
+
+collectionValueForSelector = (_selector, value_method) ->
+  selector = _selector
+  (value) ->
+    selector value[value_method]
+
+selectorForOptionsFromCollection = (reference, _value_method) ->
+  value_method = _value_method
+  reference    = reference.toString() if typeof reference == 'number' || reference == true || reference == false
+
+  return [ reference, optionsNullSelector           ] if typeof reference == 'function'
+  return [ optionsNullSelector, optionsNullSelector ] if reference == null || reference == undefined
+  return [ collectionValueForSelector(optionsStringSelectorBuilder(reference), value_method), optionsNullSelector ] if typeof reference == 'string'
+  return [ collectionValueForSelector(optionsArraySelectorBuilder(reference), value_method),  optionsNullSelector ] if reference instanceof Array
+
+  [ selectorForOptionsFromCollection( reference['selected'], _value_method )[0], selectorForOptionsFromCollection( reference['disabled'], _value_method )[0] ]
+
+collectionFetcherBlock = (_accessor_method) ->
+  accessor_method = _accessor_method
+  if typeof accessor_method == 'function'
+    accessor_method
+  else
+    (object) ->
+      object[accessor_method]
+
+extractNamePrefixAndMethod = ((object, method_or_prefix_and_method) ->
+  [ prefix, method ] = if typeof method_or_prefix_and_method == 'string'
+    class_name = object['_class'] || object['_type'] || object['class'] || object['type']
+    if class_name
+      class_name = class_name() if typeof class_name == 'function'
+      [ @underscore(class_name), method_or_prefix_and_method ]
+    else
+      [ null, method_or_prefix_and_method ]
+  else
+    method_or_prefix_and_method
+
+  name = if prefix then prefix + '[' + method + ']' else method
+  [ name, prefix, method ]).bind(this)
+
+multipleHiddenInput = ((name, options) ->
+  multiple_hidden_input = if options['multiple']
+    name = name + '[]' if name[-2..-1] != '[]'
+    if options['include_hidden'] == true || options['include_hidden'] == undefined
+      @tag 'input', type: 'hidden', name: name, value: '', disabled: options['disabled']
+    else
+      ''
+  else
+    ''
+  options['include_hidden'] = undefined
+  [ name, multiple_hidden_input ]).bind(this)
+
+
+
+helper 'optionsForSelect', (container, selectors) ->
+  return container.toString()   if typeof container == 'string' || typeof value == 'number' || value == true || value == false
+  return container().toString() if typeof container == 'function'
+
+  [ selected_selector, disabled_selector ] = selectorForOptions selectors
+
+  unless container instanceof Array
+    array_container = []
+    for index, value of container
+      array_container.push [ index, value ]
+    container = array_container
+
+  select_options = ''
+  for index, value of container
+    value = value.toString() if typeof value == 'number' || value == true || value == false
+    value = '' if value == null
+
+    if typeof value == 'string'
+      select_options += stringOption.call(this, value, selected_selector, disabled_selector)
+    if value instanceof Array
+      [ content, value_option, options ] = if value.length == 3
+        [ value[0], value[1], @_clone(value[2]) ]
+      else if value.length == 2
+        if typeof value[1] == 'object'
+          [ value[0], value[0], @_clone(value[1]) ]
+        else
+          [ value[0], value[1], {} ]
+      else
+        [ value[0], value[0], {} ]
+
+      content   = content.toString() if typeof content == 'number' || content == true || content == false
+      content ||= ''
+
+      value_option       = value_option.toString() if typeof value_option == 'number' || value_option == true || value_option == false
+      options['value'] ||= value_option || content
+
+      disabledAndSelector options, selected_selector, disabled_selector
+      select_options += @contentTag 'option', @htmlEscape(content), @htmlEscapeAttributes(options)
+
+  select_options
+
+helper 'optionsFromCollectionForSelect', (collection, value_method, text_method, selectors) ->
+  [ selected_selector, disabled_selector ] = selectorForOptionsFromCollection selectors, value_method
+  selectors = { selected: [], disabled: [] }
+
+  text_fetcher  = collectionFetcherBlock text_method
+  value_fetcher = collectionFetcherBlock value_method
+
+  container = []
+  for index, object of collection
+    options = if object instanceof Array && object.length == 3
+      object[2]
+    else
+      {}
+    value = value_fetcher object
+    container.push [ text_fetcher(object), value, options ]
+    selectors['selected'].push(value) if selected_selector(object)
+    selectors['disabled'].push(value) if disabled_selector(object)
+
+  @optionsForSelect container, selectors
+
+helper 'groupedOptionsForSelect', (grouped_options, selectors, options = {}) ->
+  [ selected_selector, disabled_selector ] = selectorForOptions selectors
+
+  options_for_select = ''
+  if options['prompt']
+    prompt = if typeof options['prompt'] == 'string' || options['prompt'] == 'number'
+      options['prompt'].toString()
+    else
+      @translate 'helpers.select.prompt', default: 'Please select'
+    options_for_select += @contentTag( 'option', @htmlEscape(prompt), { value: '' } )
+
+  for index, options_in_group of grouped_options
+    [ options_in_group, optgroup_options ] = if options['divider']
+      if grouped_options instanceof Array
+        [ options_in_group, { label: options['divider'] } ]
+    else
+      if grouped_options instanceof Array
+        optgroup_options          = options_in_group[2] || {}
+        optgroup_options['label'] = options_in_group[0]
+        [ options_in_group[1], optgroup_options ]
+      else
+        [ options_in_group, { label: index } ]
+
+    options_for_select += @contentTag('optgroup', @optionsForSelect(options_in_group, selectors), @htmlEscapeAttributes(optgroup_options) )
+
+  options_for_select
+
+helper 'optionGroupsFromCollectionForSelect', (collection, group_method, group_label_method, option_key_method, option_value_method, selectors) ->
+  group_fetcher       = collectionFetcherBlock group_method
+  group_label_fetcher = collectionFetcherBlock group_label_method
+
+  options_for_select = ''
+  for index, object of collection
+    options_for_select += @contentTag('optgroup', @optionsFromCollectionForSelect(group_fetcher(object), option_key_method, option_value_method, selectors), { label: @htmlEscape( group_label_fetcher object ) } )
+
+  options_for_select
+
+# EXPLAIN: When object is a Ruby object, two things can happen:
+#          1. If it don't responds to method [], class if infered by .class method
+#          2. If it responds to method [], class is infered by object['_class'] || object['_type'] || object['class'] || object['type'] in that order
+#
+# IMPORTANT: Removed 'required' option, it seems too much cryptic to be used
+# TODO: Add index option
+helper 'selectForObject', (object, method_or_prefix_and_method, choices_or_options, options_or_choices) ->
+  [ name, prefix, method ] = extractNamePrefixAndMethod object, method_or_prefix_and_method
+
+  [ choices, options ] = if typeof options_or_choices == 'function'
+    [ options_or_choices, @_clone( choices_or_options || {} ) ]
+  else
+    [ choices_or_options, @_clone( options_or_choices || {} ) ]
+
+  [ name, multiple_hidden_input ] = multipleHiddenInput name, options
+
+  # reference = options['selected'] || object[method]
+  # options['selected'] = undefined
+  # pre_selector = selectorForOptions( reference )[0]
+  # selector = (value) ->
+  #   selected = pre_selector value
+  #   # Welcome black magic!
+  #   options['prompt'] = undefined if selected
+  #   selected
+
+  selector = if options['selected'] == null
+    undefined
+  else
+    reference    = options['selected'] || object[method]
+    pre_selector = selectorForOptions( reference )[0]
+    (value) ->
+      selected = pre_selector value
+      # Welcome black magic!
+      options['prompt'] = undefined if selected
+      selected
+  options['selected'] = undefined
+
+  if typeof choices == 'object'
+    unless choices instanceof Array
+      array_choices = []
+      for index, value of choices
+        array_choices.push [ index, value ]
+      choices = array_choices
+
+    if choices[1] instanceof Array
+      choices_options            = {}
+      choices_options['divider'] = options['divider'] unless options['divider'] == undefined
+      options['divider']         = undefined
+      return multiple_hidden_input + @selectTag(name, @groupedOptionsForSelect(choices, selector, choices_options), options)
+
+  multiple_hidden_input + @selectTag(name, @optionsForSelect(choices, selector), options)
+
+helper 'collectionSelectForObject', (object, method_or_prefix_and_method, collection, value_method, text_method, options)->
+  [ name, prefix, method ] = extractNamePrefixAndMethod object, method_or_prefix_and_method
+
+  options = if options != undefined then @_clone(options) else {}
+
+  [ name, multiple_hidden_input ] = multipleHiddenInput name, options
+
+  selector = if options['selected'] == null
+    undefined
+  else
+    reference    = options['selected'] || object[method]
+    pre_selector = selectorForOptionsFromCollection( reference, value_method )[0]
+    (value) ->
+      selected = pre_selector value
+      # Welcome black magic!
+      options['prompt'] = undefined if selected
+      selected
+  options['selected'] = undefined
+
+  choices = @optionsFromCollectionForSelect collection, value_method, text_method, selector
+  multiple_hidden_input + @selectTag(name, choices, options)
+
+# TODO: Finish form_options helpers
+# collection_check_boxes
+# collection_radio_buttons
+# collection_select
+# grouped_collection_select
+
+# TODO: Think about implementing or not time zone helpers
+# time_zone_options_for_select
+# time_zone_select

data/app/assets/javascripts/manatee/helpers/form_tag.jsh.coffee

@@ -0,0 +1,204 @@
+sanitizeToId = (name) ->
+  name = name.toString()
+  name = name[0..-3] if name[-2..-1] == '[]'
+  name.replace(/\]/g, '').replace /[^-a-zA-Z0-9:.]/g, '_'
+
+humanizeToLabel = (name) ->
+  sanitized = name.toString().replace(/\]/g, '').replace /[^-a-zA-Z0-9:.]/g, ' '
+  sanitized[0].toUpperCase() + sanitized.slice(1);
+
+fieldTagBuilder = (_type) ->
+  type = _type
+  (name, value = null, options = {}) ->
+    html_options            = @_clone options
+    html_options['type']    = type
+    html_options['name']    = name
+    html_options['id']      = sanitizeToId(name) if html_options['id'] == undefined
+    html_options['value'] ||= value if value
+    @tag 'input', html_options
+
+for i, type of ['color', 'date', 'datetime', 'email', 'file', 'hidden', 'month', 'number', 'password', 'range', 'search', 'text', 'time', 'url', 'week']
+  helper (type+'FieldTag'), fieldTagBuilder.call(this, type)
+
+helper 'datetimeLocalFieldTag', fieldTagBuilder.call(this, 'datetime-local')
+helper 'telephoneFieldTag',     fieldTagBuilder.call(this, 'tel')
+
+alias  'phoneFieldTag', 'telephoneFieldTag'
+
+helper 'buttonTag', (content_or_options = null, options_or_content = {}) ->
+  [content, options] = @_contentOrOptions content_or_options, options_or_content
+
+  content = content.call(this) if typeof content == 'function'
+  options['name'] ||= 'button'
+  options['type'] ||= 'submit'
+  @contentTag 'button', (content || 'Button'), options
+
+helper 'checkBoxTag', (name, value = 1, checked = false, options = {}) ->
+  html_options = @_clone options
+  html_options['type']    = 'checkbox'
+  html_options['name']    = name
+  html_options['value']   = value
+  html_options['checked'] = 'checked' if checked
+  html_options['id']      = sanitizeToId(name) if html_options['id'] == undefined
+  @tag 'input', html_options
+alias  'checkboxTag', 'checkBoxTag'
+
+helper 'fieldSetTag', (legend = null, content_or_options = '', options_or_content = {}) ->
+  [content, options] = if typeof legend == 'function'
+    content_and_options = [ legend, {} ]
+    legend = null
+    content_and_options
+  else
+    @_contentOrOptions content_or_options, options_or_content, ''
+
+  content = content.call(this)                      if typeof content == 'function'
+  content = @contentTag('legend', legend) + content if legend && legend != ''
+  @contentTag 'fieldset', content, options
+
+alias  'fieldsetTag', 'fieldSetTag'
+
+buildFormOptions = (url, options) ->
+  method                      = (options['method'] || 'post').toLowerCase()
+  options['action']           = url
+  options['method']           = if method == 'get' then 'get' else 'post'
+  options['accept-charset'] ||= 'UTF-8'
+
+  if options['multipart']
+    options['enctype']   = 'multipart/form-data'
+    options['multipart'] = undefined
+
+  options['data-remote'] = 'true' if options['remote']
+  options['remote'] = undefined
+
+  enforce_utf8 = options['enforce_utf8'] == undefined || options['enforce_utf8']
+  options['enforce_utf8'] = undefined
+
+  authenticity_token = if ( @_context.protectFromForgery && options['authenticity_token'] == undefined ) || options['authenticity_token']
+    if options['authenticity_token'] == undefined || options['authenticity_token'] == true then @csrfToken else options['authenticity_token']
+  else
+    false
+  options['authenticity_token'] = undefined
+
+  [ method, enforce_utf8, authenticity_token ]
+
+buildFormContent = (content, method, enforce_utf8, authenticity_token) ->
+  form_content = ''
+
+  method_enforcer = method != 'get' && method != 'post'
+  form_content += '<div style="display:none">'
+  if enforce_utf8 || authenticity_token || method_enforcer
+    form_content += @utf8EnforcerTag()                        if enforce_utf8
+    form_content += @methodHiddenTag(method)                  if method_enforcer
+    form_content += @authenticityTokenTag(authenticity_token) if authenticity_token
+  form_content += '</div>'
+
+  content = content.call(this) if typeof content == 'function'
+
+  form_content + content
+
+helper 'formTag', (url = '/', content_or_options, options_or_content) ->
+  [content, options] = if typeof url == 'function'
+    content_and_options = [url, {}]
+    url = '/'
+    content_and_options
+  else
+    @_contentOrOptions content_or_options, options_or_content, ''
+
+  [ method, enforce_utf8, authenticity_token ] = buildFormOptions.call this, url, options
+
+  @contentTag 'form', buildFormContent.call(this, content, method, enforce_utf8, authenticity_token), options
+
+helper 'imageSubmitTag', (source, options = {}) ->
+  options           = @_clone options
+  options['src']  ||= @imagePath source
+  options['type'] ||= 'image'
+  options['alt']  ||= @imageAlt source
+  @tag 'input', options
+
+helper 'labelTag', (name, content_or_options = null, options_or_content = {}) ->
+  [content, options] = if typeof name == 'function'
+    content_and_options = [name, {}]
+    name = null
+    content_and_options
+  else
+    @_contentOrOptions content_or_options, options_or_content
+
+  content        ||= humanizeToLabel name
+  options['for'] ||= sanitizeToId(name) if name
+  @contentTag 'label', content, options
+
+helper 'radioButtonTag', (name, value, checked = false, options = {}) ->
+  options = @_clone options
+  options['type']    = 'radio'
+  options['name']    = name
+  options['value']   = value
+  options['checked'] = 'checked' if checked
+  options['id']    ||= sanitizeToId(name) + '_' + sanitizeToId(value)
+  @tag 'input', options
+
+helper 'selectTag', (name, option_tags = '', options = {}) ->
+  options = @_clone options
+
+  if options['include_blank']
+    blank_content = if options['include_blank'] == true then '' else @htmlEscape( options['include_blank'] )
+    option_tags = @contentTag('option', blank_content, value: '') + option_tags
+  options['include_blank'] = undefined
+
+  if options['prompt']
+    prompt_content = if options['prompt'] == true then @translate('helpers.select.prompt', default: 'Please select') else @htmlEscape( options['prompt'] )
+    option_tags = @contentTag('option', prompt_content, value: '') + option_tags
+  options['prompt'] = undefined
+
+  html_name = if options['multiple']
+    unless name.toString()[-2..-1] == '[]'
+      name + '[]'
+  else
+    name
+
+  options['multiple'] = undefined if options['multiple'] == false
+
+  options['id']     = sanitizeToId(name) if options['id'] == undefined
+  options['name'] ||= name
+  @contentTag 'select', option_tags, options
+
+helper 'submitTag', (value = "Save changes", options = {}) ->
+  options = @_clone options
+  options['type']  ||= 'submit'
+  options['name']  ||= 'commit'
+  options['value'] ||= value
+  @tag 'input', options
+
+handleSizeAttribute = (options) ->
+  if typeof options['size'] == 'string'
+    size = options['size'].toLowerCase()
+    if (/\d+X\d+/i).test(size)
+      xIndex = size.lastIndexOf('x');
+      options['cols'] ||= size.substring 0, xIndex
+      options['rows'] ||= size.substring xIndex+1
+  options['size'] = undefined
+
+helper 'textAreaTag', (name, content_or_options = '', options_or_content = {}) ->
+  [content, options] = @_contentOrOptions content_or_options, options_or_content
+  handleSizeAttribute options
+
+  content = content.call(this) if typeof content == 'function'
+  content ||= ''
+
+  if typeof options['escape'] == 'undefined' || options['escape']
+    content = @htmlEscape content
+  options['escape'] = undefined
+
+  options['id']     = sanitizeToId(name) if options['id'] == undefined
+  options['name'] ||= name
+  @contentTag 'textarea', "\n"+content, options
+
+alias 'textareaTag', 'textAreaTag'
+
+helper 'authenticityTokenTag', (authenticity_token) ->
+  @tag 'input', type: 'hidden', name: @_context.requestForgeryProtectionToken, value: authenticity_token
+
+helper 'methodHiddenTag', (method) ->
+  @tag 'input', type: 'hidden', name: '_method', value: method
+
+helper 'utf8EnforcerTag', () ->
+  @tag 'input', type: 'hidden', name: 'utf8', value: "&#x2713;"