libmongocrypt-helper 1.7.0.0.1001 → 1.7.4.0.1000

data/ext/libmongocrypt/libmongocrypt/cmake/IntelDFP.cmake

@@ -0,0 +1,409 @@
+
+include (FetchContent)
+find_program (GIT_EXECUTABLE git)
+find_program (PATCH_EXECUTABLE patch)
+
+set (_default_url "${PROJECT_SOURCE_DIR}/third-party/IntelRDFPMathLib20U2.tar.xz")
+
+set (INTEL_DFP_LIBRARY_URL "${_default_url}"
+     CACHE STRING "The URL of an Intel DFP library to use")
+set (INTEL_DFP_LIBRARY_URL_HASH
+     "SHA256=ac157e69c05556f3fa468ab34caeb1114a3b88ae18241bd41cc57b85a02dd314"
+     CACHE STRING "The hash of the archive that lives at INTEL_DFP_LIBRARY_URL (Spelled: <ALGO>=<digest>)")
+option (INTEL_DFP_LIBRARY_PATCH_ENABLED
+        "Whether to apply the s390x compatibility patch to the Intel DFP library" ON)
+
+set (_hash_arg)
+if (NOT INTEL_DFP_LIBRARY_URL_SHA256 STREQUAL "no-verify")
+    set (_hash_arg URL_HASH "${INTEL_DFP_LIBRARY_URL_HASH}")
+endif ()
+
+# Make the PATCH_COMMAND a no-op if it was disabled
+set (patch_command)
+if (NOT INTEL_DFP_LIBRARY_PATCH_ENABLED)
+    set (patch_command "${CMAKE_COMMAND}" -E true)
+elseif (GIT_EXECUTABLE)
+    set (patch_command "${GIT_EXECUTABLE}" --work-tree=<SOURCE_DIR> apply)
+else ()
+    set (patch_command "${PATCH_EXECUTABLE}" --dir=<SOURCE_DIR>)
+endif ()
+
+# NOTE: The applying of the patch expects the correct input directly from the
+#       expanded archive. If the patch needs to be reapplied, you may see errors
+#       about trying to update the intel_dfp component. If you are seeing such
+#       errors, delete the `_deps/` subdirectory in the build tree and
+#       re-run CMake the project.
+FetchContent_Declare (
+    intel_dfp
+    URL "${_default_url}"
+    ${_hash_arg}
+    PATCH_COMMAND
+        ${patch_command}
+            -p 4 # Strip four path components
+            "${PROJECT_SOURCE_DIR}/etc/mongo-inteldfp-s390x.patch"
+            "${PROJECT_SOURCE_DIR}/etc/mongo-inteldfp-MONGOCRYPT-571.patch"
+            --verbose
+    )
+
+FetchContent_GetProperties (intel_dfp)
+if (NOT intel_dfp_POPULATED)
+    message (STATUS "Obtaining Intel Decimal FP library: ${INTEL_DFP_LIBRARY_URL}")
+    FetchContent_Populate (intel_dfp)
+endif ()
+
+# This list of sources matches the ones used within MongoDB server. The
+# "<library>" prefix is replaced below.
+# Refer: https://github.com/mongodb/mongo/blob/e9be40f47a77af1931773ad671d4927c0fe6969a/src/third_party/IntelRDFPMathLib20U1/SConscript
+set (_dfp_sources
+    "<library>/float128/dpml_exception.c"
+    "<library>/float128/dpml_four_over_pi.c"
+    "<library>/float128/dpml_ux_bessel.c"
+    "<library>/float128/dpml_ux_bid.c"
+    "<library>/float128/dpml_ux_cbrt.c"
+    "<library>/float128/dpml_ux_erf.c"
+    "<library>/float128/dpml_ux_exp.c"
+    "<library>/float128/dpml_ux_int.c"
+    "<library>/float128/dpml_ux_inv_hyper.c"
+    "<library>/float128/dpml_ux_inv_trig.c"
+    "<library>/float128/dpml_ux_lgamma.c"
+    "<library>/float128/dpml_ux_log.c"
+    "<library>/float128/dpml_ux_mod.c"
+    "<library>/float128/dpml_ux_ops.c"
+    "<library>/float128/dpml_ux_ops_64.c"
+    "<library>/float128/dpml_ux_pow.c"
+    "<library>/float128/dpml_ux_powi.c"
+    "<library>/float128/dpml_ux_sqrt.c"
+    "<library>/float128/dpml_ux_trig.c"
+    "<library>/float128/sqrt_tab_t.c"
+    "<library>/src/bid128.c"
+    "<library>/src/bid128_2_str_tables.c"
+    "<library>/src/bid128_acos.c"
+    "<library>/src/bid128_acosh.c"
+    "<library>/src/bid128_add.c"
+    "<library>/src/bid128_asin.c"
+    "<library>/src/bid128_asinh.c"
+    "<library>/src/bid128_atan.c"
+    "<library>/src/bid128_atan2.c"
+    "<library>/src/bid128_atanh.c"
+    "<library>/src/bid128_cbrt.c"
+    "<library>/src/bid128_compare.c"
+    "<library>/src/bid128_cos.c"
+    "<library>/src/bid128_cosh.c"
+    "<library>/src/bid128_div.c"
+    "<library>/src/bid128_erf.c"
+    "<library>/src/bid128_erfc.c"
+    "<library>/src/bid128_exp.c"
+    "<library>/src/bid128_exp10.c"
+    "<library>/src/bid128_exp2.c"
+    "<library>/src/bid128_expm1.c"
+    "<library>/src/bid128_fdimd.c"
+    "<library>/src/bid128_fma.c"
+    "<library>/src/bid128_fmod.c"
+    "<library>/src/bid128_frexp.c"
+    "<library>/src/bid128_hypot.c"
+    "<library>/src/bid128_ldexp.c"
+    "<library>/src/bid128_lgamma.c"
+    "<library>/src/bid128_llrintd.c"
+    "<library>/src/bid128_log.c"
+    "<library>/src/bid128_log10.c"
+    "<library>/src/bid128_log1p.c"
+    "<library>/src/bid128_log2.c"
+    "<library>/src/bid128_logb.c"
+    "<library>/src/bid128_logbd.c"
+    "<library>/src/bid128_lrintd.c"
+    "<library>/src/bid128_lround.c"
+    "<library>/src/bid128_minmax.c"
+    "<library>/src/bid128_modf.c"
+    "<library>/src/bid128_mul.c"
+    "<library>/src/bid128_nearbyintd.c"
+    "<library>/src/bid128_next.c"
+    "<library>/src/bid128_nexttowardd.c"
+    "<library>/src/bid128_noncomp.c"
+    "<library>/src/bid128_pow.c"
+    "<library>/src/bid128_quantexpd.c"
+    "<library>/src/bid128_quantize.c"
+    "<library>/src/bid128_rem.c"
+    "<library>/src/bid128_round_integral.c"
+    "<library>/src/bid128_scalb.c"
+    "<library>/src/bid128_scalbl.c"
+    "<library>/src/bid128_sin.c"
+    "<library>/src/bid128_sinh.c"
+    "<library>/src/bid128_sqrt.c"
+    "<library>/src/bid128_string.c"
+    "<library>/src/bid128_tan.c"
+    "<library>/src/bid128_tanh.c"
+    "<library>/src/bid128_tgamma.c"
+    "<library>/src/bid128_to_int16.c"
+    "<library>/src/bid128_to_int32.c"
+    "<library>/src/bid128_to_int64.c"
+    "<library>/src/bid128_to_int8.c"
+    "<library>/src/bid128_to_uint16.c"
+    "<library>/src/bid128_to_uint32.c"
+    "<library>/src/bid128_to_uint64.c"
+    "<library>/src/bid128_to_uint8.c"
+    "<library>/src/bid32_acos.c"
+    "<library>/src/bid32_acosh.c"
+    "<library>/src/bid32_add.c"
+    "<library>/src/bid32_asin.c"
+    "<library>/src/bid32_asinh.c"
+    "<library>/src/bid32_atan.c"
+    "<library>/src/bid32_atan2.c"
+    "<library>/src/bid32_atanh.c"
+    "<library>/src/bid32_cbrt.c"
+    "<library>/src/bid32_compare.c"
+    "<library>/src/bid32_cos.c"
+    "<library>/src/bid32_cosh.c"
+    "<library>/src/bid32_div.c"
+    "<library>/src/bid32_erf.c"
+    "<library>/src/bid32_erfc.c"
+    "<library>/src/bid32_exp.c"
+    "<library>/src/bid32_exp10.c"
+    "<library>/src/bid32_exp2.c"
+    "<library>/src/bid32_expm1.c"
+    "<library>/src/bid32_fdimd.c"
+    "<library>/src/bid32_fma.c"
+    "<library>/src/bid32_fmod.c"
+    "<library>/src/bid32_frexp.c"
+    "<library>/src/bid32_hypot.c"
+    "<library>/src/bid32_ldexp.c"
+    "<library>/src/bid32_lgamma.c"
+    "<library>/src/bid32_llrintd.c"
+    "<library>/src/bid32_log.c"
+    "<library>/src/bid32_log10.c"
+    "<library>/src/bid32_log1p.c"
+    "<library>/src/bid32_log2.c"
+    "<library>/src/bid32_logb.c"
+    "<library>/src/bid32_logbd.c"
+    "<library>/src/bid32_lrintd.c"
+    "<library>/src/bid32_lround.c"
+    "<library>/src/bid32_minmax.c"
+    "<library>/src/bid32_modf.c"
+    "<library>/src/bid32_mul.c"
+    "<library>/src/bid32_nearbyintd.c"
+    "<library>/src/bid32_next.c"
+    "<library>/src/bid32_nexttowardd.c"
+    "<library>/src/bid32_noncomp.c"
+    "<library>/src/bid32_pow.c"
+    "<library>/src/bid32_quantexpd.c"
+    "<library>/src/bid32_quantize.c"
+    "<library>/src/bid32_rem.c"
+    "<library>/src/bid32_round_integral.c"
+    "<library>/src/bid32_scalb.c"
+    "<library>/src/bid32_scalbl.c"
+    "<library>/src/bid32_sin.c"
+    "<library>/src/bid32_sinh.c"
+    "<library>/src/bid32_sqrt.c"
+    "<library>/src/bid32_string.c"
+    "<library>/src/bid32_sub.c"
+    "<library>/src/bid32_tan.c"
+    "<library>/src/bid32_tanh.c"
+    "<library>/src/bid32_tgamma.c"
+    "<library>/src/bid32_to_bid128.c"
+    "<library>/src/bid32_to_bid64.c"
+    "<library>/src/bid32_to_int16.c"
+    "<library>/src/bid32_to_int32.c"
+    "<library>/src/bid32_to_int64.c"
+    "<library>/src/bid32_to_int8.c"
+    "<library>/src/bid32_to_uint16.c"
+    "<library>/src/bid32_to_uint32.c"
+    "<library>/src/bid32_to_uint64.c"
+    "<library>/src/bid32_to_uint8.c"
+    "<library>/src/bid64_acos.c"
+    "<library>/src/bid64_acosh.c"
+    "<library>/src/bid64_add.c"
+    "<library>/src/bid64_asin.c"
+    "<library>/src/bid64_asinh.c"
+    "<library>/src/bid64_atan.c"
+    "<library>/src/bid64_atan2.c"
+    "<library>/src/bid64_atanh.c"
+    "<library>/src/bid64_cbrt.c"
+    "<library>/src/bid64_compare.c"
+    "<library>/src/bid64_cos.c"
+    "<library>/src/bid64_cosh.c"
+    "<library>/src/bid64_div.c"
+    "<library>/src/bid64_erf.c"
+    "<library>/src/bid64_erfc.c"
+    "<library>/src/bid64_exp.c"
+    "<library>/src/bid64_exp10.c"
+    "<library>/src/bid64_exp2.c"
+    "<library>/src/bid64_expm1.c"
+    "<library>/src/bid64_fdimd.c"
+    "<library>/src/bid64_fma.c"
+    "<library>/src/bid64_fmod.c"
+    "<library>/src/bid64_frexp.c"
+    "<library>/src/bid64_hypot.c"
+    "<library>/src/bid64_ldexp.c"
+    "<library>/src/bid64_lgamma.c"
+    "<library>/src/bid64_llrintd.c"
+    "<library>/src/bid64_log.c"
+    "<library>/src/bid64_log10.c"
+    "<library>/src/bid64_log1p.c"
+    "<library>/src/bid64_log2.c"
+    "<library>/src/bid64_logb.c"
+    "<library>/src/bid64_logbd.c"
+    "<library>/src/bid64_lrintd.c"
+    "<library>/src/bid64_lround.c"
+    "<library>/src/bid64_minmax.c"
+    "<library>/src/bid64_modf.c"
+    "<library>/src/bid64_mul.c"
+    "<library>/src/bid64_nearbyintd.c"
+    "<library>/src/bid64_next.c"
+    "<library>/src/bid64_nexttowardd.c"
+    "<library>/src/bid64_noncomp.c"
+    "<library>/src/bid64_pow.c"
+    "<library>/src/bid64_quantexpd.c"
+    "<library>/src/bid64_quantize.c"
+    "<library>/src/bid64_rem.c"
+    "<library>/src/bid64_round_integral.c"
+    "<library>/src/bid64_scalb.c"
+    "<library>/src/bid64_scalbl.c"
+    "<library>/src/bid64_sin.c"
+    "<library>/src/bid64_sinh.c"
+    "<library>/src/bid64_sqrt.c"
+    "<library>/src/bid64_string.c"
+    "<library>/src/bid64_tan.c"
+    "<library>/src/bid64_tanh.c"
+    "<library>/src/bid64_tgamma.c"
+    "<library>/src/bid64_to_bid128.c"
+    "<library>/src/bid64_to_int16.c"
+    "<library>/src/bid64_to_int32.c"
+    "<library>/src/bid64_to_int64.c"
+    "<library>/src/bid64_to_int8.c"
+    "<library>/src/bid64_to_uint16.c"
+    "<library>/src/bid64_to_uint32.c"
+    "<library>/src/bid64_to_uint64.c"
+    "<library>/src/bid64_to_uint8.c"
+    "<library>/src/bid_binarydecimal.c"
+    "<library>/src/bid_convert_data.c"
+    "<library>/src/bid_decimal_data.c"
+    "<library>/src/bid_decimal_globals.c"
+    "<library>/src/bid_dpd.c"
+    "<library>/src/bid_feclearexcept.c"
+    "<library>/src/bid_fegetexceptflag.c"
+    "<library>/src/bid_feraiseexcept.c"
+    "<library>/src/bid_fesetexceptflag.c"
+    "<library>/src/bid_fetestexcept.c"
+    "<library>/src/bid_flag_operations.c"
+    "<library>/src/bid_from_int.c"
+    "<library>/src/bid_round.c"
+    "<library>/src/strtod128.c"
+    "<library>/src/strtod32.c"
+    "<library>/src/strtod64.c"
+    "<library>/src/wcstod128.c"
+    "<library>/src/wcstod32.c"
+    "<library>/src/wcstod64.c"
+    )
+# Put in the actual library path:
+string (REPLACE "<library>" "${intel_dfp_SOURCE_DIR}/LIBRARY" _dfp_sources "${_dfp_sources}")
+
+#[[
+    Intel DFP gives us a very blunt yet powerful hammer to avoid symbol
+    collision, since other library may also want a conflicting
+    DFP version: Just rename everything!
+
+    All function names are #defined with a `bid` or `binary` prefix, and are
+    aliased to their "actual" names with a `__bid` or `__binary` prefix,
+    respectively.
+
+    So we can ship our own decimal library without worry, we'll rename those
+    hidden symbols.
+]]
+file (READ "${intel_dfp_SOURCE_DIR}/LIBRARY/src/bid_conf.h" dfp_conf_content)
+string (REGEX REPLACE
+    #[[
+        Match every "#define X Y" where X begins with `"bid" or "binary", and Y
+        begins with "__bid" or "__binary". X and Y must be separated by one or
+        more spaces.
+    ]]
+    "#define ((bid|binary)[^ ]+ +)__(bid|binary)([^ +])"
+    # Replace Y with "__mongocrypt_bid" or "__mongocrypt_binary" as the new prefix.
+    "#define \\1 __mongocrypt_\\3\\4"
+    new_content "${dfp_conf_content}"
+    )
+if (NOT new_content STREQUAL dfp_conf_content)
+    # Only rewrite the file if we changed anything, otherwise we update build
+    # input timestamps and will trigger a rebuild of DFP.
+    file (WRITE "${intel_dfp_SOURCE_DIR}/LIBRARY/src/bid_conf.h" "${new_content}")
+endif ()
+
+# Define the object library
+add_library (intel_dfp_obj OBJECT ${_dfp_sources})
+# Build with -fPIC, since these objects may go into a static OR dynamic library.
+set_property (TARGET intel_dfp_obj PROPERTY POSITION_INDEPENDENT_CODE TRUE)
+
+# DFP needs information about the build target platform. Compute that:
+set (proc_lower $<LOWER_CASE:${CMAKE_SYSTEM_PROCESSOR}>)
+set (ia32_list i386 i486 i586 i686 pentium3 pentium4 athlon geode emscripted x86 arm)
+set (efi2_list aarch64 arm64 x86_64 ppc64le riscv64)
+
+set (is_linux $<PLATFORM_ID:Linux>)
+set (is_windows $<PLATFORM_ID:Windows>)
+set (is_unix $<NOT:${is_windows}>)
+
+# These compiler definitions may seem a bit strange, but the whole DFP library's
+# config process is strange. These options match those used in MongoDB server.
+target_compile_definitions (intel_dfp_obj PUBLIC
+    DECIMAL_CALL_BY_REFERENCE=0
+    DECIMAL_GLOBAL_ROUNDING=0
+    DECIMAL_GLOBAL_EXCEPTION_FLAGS=0
+    UNCHANGED_BINARY_STATUS_FLAGS=0
+    USE_COMPILER_F128_TYPE=0
+    USE_COMPILER_F80_TYPE=0
+    USE_NATIVE_QUAD_TYPE=0
+    $<${is_unix}:LINUX=1>
+    $<$<PLATFORM_ID:Darwin>:mach=1>
+    $<$<PLATFORM_ID:FreeBSD>:freebsd=1>
+    $<$<PLATFORM_ID:Linux>:linux=1>
+    $<${is_windows}:
+        WINDOWS=1
+        WNT=1
+        winnt=1
+    >
+    $<$<IN_LIST:${proc_lower},${ia32_list}>:
+        IA32=1
+        ia32=1
+    >
+    $<$<IN_LIST:${proc_lower},${efi2_list}>:
+        EFI2=1
+        efi2=1
+    >
+    $<$<STREQUAL:${proc_lower},s390x>:
+        s390x=1
+        BID_BIG_ENDIAN=1
+    >
+    )
+
+# Suppress warnings in the Intel library, as it generates a lot that aren't of interest
+target_compile_options (intel_dfp_obj PRIVATE -w)
+target_include_directories(intel_dfp_obj PUBLIC ${intel_dfp_SOURCE_DIR}/LIBRARY/src)
+
+# Define an interface library that attaches the built TUs to the consumer
+add_library (_mongocrypt_intel_dfp INTERFACE)
+add_library (mongocrypt::intel_dfp ALIAS _mongocrypt_intel_dfp)
+
+# Notify in-tree consumers that IntelDFP is available:
+target_compile_definitions (_mongocrypt_intel_dfp INTERFACE $<BUILD_INTERFACE:MONGOCRYPT_INTELDFP>)
+
+target_sources (_mongocrypt_intel_dfp
+    #[[
+        For targets *within this build* that link with mongocrypt::intel_dfp,
+        inject the generated TUs (object files) from the intel_dfp_obj library.
+
+        This will be stripped out of the interface library when it is installed,
+        since we don't want to ship the DFP object separately. Instead, users
+        will link to libmongocrypt, which will contain the necessary TUs for
+        the library (because they link to this interface library).
+    ]]
+    INTERFACE $<BUILD_INTERFACE:$<TARGET_OBJECTS:intel_dfp_obj>>
+    )
+target_link_libraries (_mongocrypt_intel_dfp
+    INTERFACE
+        $<BUILD_INTERFACE:intel_dfp_obj>
+        # We do want to propagate an interface requirement: Some platforms need a
+        # separate link library to support special math functions.
+        $<$<PLATFORM_ID:Linux>:m>
+    )
+
+# Give the installed target a name to indicate its hidden-ness
+set_property (TARGET _mongocrypt_intel_dfp PROPERTY EXPORT_NAME private::intel_dfp_interface)
+install (TARGETS _mongocrypt_intel_dfp EXPORT mongocrypt_targets)

data/ext/libmongocrypt/libmongocrypt/cmake/LTO.cmake

@@ -0,0 +1,57 @@
+
+set (MONGO_LTO "OFF"
+    CACHE STRING
+    "Enable cross-translation unit optimizations (A.K.A. IPO/LTO/LTCG) [OFF/DEFAULT/FAT/THIN]"
+    )
+set_property (CACHE MONGO_LTO PROPERTY STRINGS OFF DEFAULT FAT THIN)
+
+if (MONGO_LTO STREQUAL "OFF")
+    # Nothing to do
+    return ()
+endif ()
+
+# CMake will know if LTO is supported at any basic level
+include (CheckIPOSupported)
+check_ipo_supported (RESULT supported OUTPUT out)
+if (NOT supported)
+    message (SEND_ERROR "LTO is not supported by the compiler (requested by MONGO_LTO=${MONGO_LTO}):\n${out}")
+    return ()
+endif ()
+
+# Set the appropriate compile/link flags for LTO:
+set (_c_flags)
+set (_link_flags)
+if (MONGO_LTO STREQUAL "DEFAULT")
+    # Just use CMake's default INTERPROCEDURAL_OPTIMIZATION
+    message (STATUS "Enabling INTERPROCEDURAL_OPTIMIZATION")
+    set_property (DIRECTORY PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
+elseif (MONGO_LTO STREQUAL "THIN")
+    set (_c_flags -flto=thin)
+    set (_link_flags -flto=thin)
+elseif (MONGO_LTO STREQUAL "FAT")
+    set (_c_flags -flto -ffat-lto-objects)
+    set (_link_flags -flto=auto)
+else ()
+    message (SEND_ERROR "Unknown MONGO_LTO setting '${MONGO_LTO}'")
+    return ()
+endif ()
+
+# We need try_compile(), because we need more than one source file to accurately
+# check for LTO support
+try_compile (
+    MONGO_HAVE_LTO_${MONGO_LTO}
+    "${CMAKE_CURRENT_BINARY_DIR}/_mongo-lto-check/${MONGO_LTO}"
+    SOURCES "${CMAKE_CURRENT_LIST_DIR}/ltocheck-lib.c"
+            "${CMAKE_CURRENT_LIST_DIR}/ltocheck-main.c"
+    COMPILE_DEFINITIONS ${_c_flags}
+    LINK_LIBRARIES ${_link_flags}
+    OUTPUT_VARIABLE out
+    )
+
+if (NOT MONGO_HAVE_LTO_${MONGO_LTO})
+    message (SEND_ERROR "MONGO_LTO=${MONGO_LTO} is not supported by the current compiler:\n${out}")
+    return ()
+endif ()
+
+add_compile_options (${_c_flags})
+link_libraries (${_link_flags})

data/ext/libmongocrypt/libmongocrypt/cmake/MongoC-Warnings.cmake

@@ -0,0 +1,74 @@
+#[[
+   This file sets warning options for the directories in which it is include()'d
+
+   These warnings are intended to be ported to each supported platform, and
+   especially for high-value warnings that are very likely to catch latent bugs
+   early in the process before the code is even run.
+]]
+
+set (__is_gnu "$<C_COMPILER_ID:GNU>")
+set (__is_clang "$<OR:$<C_COMPILER_ID:Clang>,$<C_COMPILER_ID:AppleClang>>")
+set (__is_gnu_like "$<OR:${__is_gnu},${__is_clang}>")
+set (__is_msvc "$<C_COMPILER_ID:MSVC>")
+
+# "Old" GNU is GCC < 5, which is missing several warning options
+set (__is_old_gnu "$<AND:${__is_gnu},$<VERSION_LESS:$<C_COMPILER_VERSION>,5>>")
+set (__not_old_gnu "$<NOT:${__is_old_gnu}>")
+
+#[[
+   Define additional compile options, conditional on the compiler being used.
+   Each option should be prefixed by `gnu:`, `clang:`, `msvc:`, or `gnu-like:`.
+   Those options will be conditionally enabled for GCC, Clang, or MSVC.
+
+   These options are attached to the source directory and its children.
+]]
+function (mongoc_add_platform_compile_options)
+   foreach (opt IN LISTS ARGV)
+      if (NOT opt MATCHES "^(gnu-like|gnu|clang|msvc):(.*)")
+         message (SEND_ERROR "Invalid option '${opt}' (Should be prefixed by 'msvc:', 'gnu:', 'clang:', or 'gnu-like:'")
+         continue ()
+      endif ()
+      if (CMAKE_MATCH_1 STREQUAL "gnu-like")
+         add_compile_options ("$<${__is_gnu_like}:${CMAKE_MATCH_2}>")
+      elseif (CMAKE_MATCH_1 STREQUAL gnu)
+         add_compile_options ("$<${__is_gnu}:${CMAKE_MATCH_2}>")
+      elseif (CMAKE_MATCH_1 STREQUAL clang)
+         add_compile_options ("$<${__is_clang}:${CMAKE_MATCH_2}>")
+      elseif (CMAKE_MATCH_1 STREQUAL "msvc")
+         add_compile_options ("$<${__is_msvc}:${CMAKE_MATCH_2}>")
+      else ()
+         message (SEND_ERROR "Invalid option to mongoc_add_platform_compile_options(): '${opt}'")
+      endif ()
+   endforeach ()
+endfunction ()
+
+if (CMAKE_VERSION VERSION_LESS 3.3)
+   # On older CMake versions, we'll just always pass the warning options, even
+   # if the generate warnings for the C++ check file
+   set (is_c_lang "1")
+else ()
+   # $<COMPILE_LANGUAGE> is only valid in CMake 3.3+
+   set (is_c_lang "$<COMPILE_LANGUAGE:C>")
+endif ()
+
+# These below warnings should always be unconditional hard errors, as the code is
+# almost definitely broken
+mongoc_add_platform_compile_options (
+     # Implicit function or variable declarations
+     gnu-like:$<${is_c_lang}:-Werror=implicit> msvc:/we4013 msvc:/we4431
+     # Missing return types/statements
+     gnu-like:-Werror=return-type msvc:/we4716
+     # Incompatible pointer types
+     gnu-like:$<$<AND:${is_c_lang},${__not_old_gnu}>:-Werror=incompatible-pointer-types> msvc:/we4113
+     # Integral/pointer conversions
+     gnu-like:$<$<AND:${is_c_lang},${__not_old_gnu}>:-Werror=int-conversion> msvc:/we4047
+     # Discarding qualifiers
+     gnu:$<$<AND:${is_c_lang},${__not_old_gnu}>:-Werror=discarded-qualifiers>
+     clang:$<${is_c_lang}:-Werror=ignored-qualifiers>
+     msvc:/we4090
+     # Definite use of uninitialized value
+     gnu-like:-Werror=uninitialized msvc:/we4700
+
+     # Aside: Disable CRT insecurity warnings
+     msvc:/D_CRT_SECURE_NO_WARNINGS
+     )

data/ext/libmongocrypt/libmongocrypt/cmake/libmongocrypt-hidden-symbols.map

@@ -0,0 +1,8 @@
+mongocrypt {
+    local:
+        bson*;
+        bcon*;
+        jsonsl*;
+        _*;
+        kms*;
+};

data/ext/libmongocrypt/libmongocrypt/cmake/libmongocrypt-hidden-symbols.txt

@@ -0,0 +1,5 @@
+_bson*
+_bcon*
+_jsonsl*
+__*
+_kms*

data/ext/libmongocrypt/libmongocrypt/cmake/libmongocrypt-static.pc.in

@@ -0,0 +1,9 @@
+Name: ${PROJECT_NAME}
+Description: ${PROJECT_DESCRIPTION}
+Version: ${PROJECT_VERSION}
+Requires: ${PKG_CONFIG_STATIC_REQUIRES}
+prefix=${CMAKE_INSTALL_PREFIX}
+includedir=${PKG_CONFIG_INCLUDEDIR}
+libdir=${PKG_CONFIG_LIBDIR}
+Libs: ${PKG_CONFIG_STATIC_LIBS}
+Cflags: ${PKG_CONFIG_STATIC_CFLAGS}

data/ext/libmongocrypt/libmongocrypt/cmake/libmongocrypt.pc.in

@@ -0,0 +1,10 @@
+Name: ${PROJECT_NAME}
+Description: ${PROJECT_DESCRIPTION}
+Version: ${PROJECT_VERSION}
+Requires: ${PKG_CONFIG_REQUIRES}
+Requires.private: ${PKG_CONFIG_REQUIRES_PRIVATE}
+prefix=${CMAKE_INSTALL_PREFIX}
+includedir=${PKG_CONFIG_INCLUDEDIR}
+libdir=${PKG_CONFIG_LIBDIR}
+Libs: ${PKG_CONFIG_LIBS}
+Cflags: ${PKG_CONFIG_CFLAGS}

data/ext/libmongocrypt/libmongocrypt/cmake/ltocheck-lib.c

@@ -0,0 +1,6 @@
+
+extern int
+answer (int a, int b)
+{
+   return a + b;
+}

data/ext/libmongocrypt/libmongocrypt/cmake/ltocheck-main.c

@@ -0,0 +1,9 @@
+extern int
+answer (int, int);
+
+int
+main ()
+{
+   int a = answer (3, 4);
+   return a != 7;
+}

data/ext/libmongocrypt/libmongocrypt/cmake/mongocrypt-config.cmake

@@ -0,0 +1,42 @@
+include(CMakeFindDependencyMacro)
+find_dependency(kms_message 0.0.1)
+include("${CMAKE_CURRENT_LIST_DIR}/mongocrypt_targets.cmake")
+
+if (DEFINED MONGOCRYPT_LIBBSON_STATIC_USE)
+    # The user has named a library that should be linked as the static libbson library
+    set_property (
+        TARGET mongo::_mongocrypt-libbson_for_static
+        APPEND PROPERTY INTERFACE_LINK_LIBRARIES "$<LINK_ONLY:${MONGOCRYPT_LIBBSON_STATIC_USE}>"
+    )
+endif ()
+
+
+# BOOL: Whether the libmongocrypt dynamic library in this package needs to link to an external libbson.
+#   In the default configuration, the shared lib will include the TUs for a pinned version of libbson
+#   and will use linker scripts to "hide" these symbols from the outside world.
+#
+#   If the libmongocrypt package was built to link against a shared libbson library, then the
+#   libmongocrypt dynamic library will contain pending references to libbson symbols that will
+#   need to be resolved before the library can be used.
+#
+#   (Note: static libmongocrypt *always* needs to link against an external libbson, as it does not
+#    embed the libbson symbols.)
+set (_using_shared_libbson "@USE_SHARED_LIBBSON@")
+
+if (_using_shared_libbson AND DEFINED MONGOCRYPT_LIBBSON_SHARED_USE)
+    # The user has named a library that should be linked as the shared libbson library
+    set_property (
+        TARGET mongo::_mongocrypt-libbson_for_shared
+        APPEND PROPERTY INTERFACE_LINK_LIBRARIES "$<LINK_ONLY:${MONGOCRYPT_LIBBSON_SHARED_USE}>"
+    )
+endif ()
+
+set (_using_system_intel_dfp "@USE_SYSTEM_INTEL_DFP@")
+
+if (_using_system_intel_dfp)
+   find_library (_MONGOCRYPT_SYSTEM_INTEL_DFP_STATIC "${CMAKE_STATIC_LIBRARY_PREFIX}bidgcc000${CMAKE_STATIC_LIBRARY_SUFFIX}")
+   set_property (
+      TARGET mongo::_mongocrypt-intel_dfp
+      PROPERTY IMPORTED_LOCATION "${_MONGOCRYPT_SYSTEM_INTEL_DFP_STATIC}"
+      )
+endif ()