lanes 0.0.1

data/client/javascripts/component/RecordFinder.coffee

@@ -0,0 +1,143 @@
+class FinderClause
+    constructor: -> super
+
+    templateName: 'record-finder/clause'
+
+    initialize: ->
+        window.fc = this.model
+
+    events:
+        'hidden.bs.dropdown': 'onQueryChange'
+        'click .del-clause': 'delClause'
+        'input input.query-string': 'onInput'
+
+    onInput: (ev)->
+        this.model.value = ev.target.value
+
+    bindings:
+        'model.description': '.query-field-description'
+
+    subviews:
+        fields:
+            component: 'RadioGroup'
+            data: 'model.fields'
+            container: '.fields'
+            options: { mappings: { id:'field'}, access: 'write' }
+
+        operators:
+            component: 'RadioGroup'
+            data: 'model.operators'
+            container: '.operators'
+            options: { mappings: { title:'name', visible: 'valid' }, access: 'write' }
+
+    delClause: ->
+        @model.remove()
+
+    onQueryChange: ->
+        this.$('input.query-string').focus()
+
+    render: ->
+        super
+        @defer @focus, delay: 500
+        this
+
+    focus: ->
+        this.$('input.query-string').focus()
+
+
+Lanes.Component.Base.extend(FinderClause)
+
+
+class FinderDialog
+    constructor: ->
+        super
+
+    events:
+        'click .add-clause': 'addClause'
+        'click .run-query':  'runQuery'
+        'select-row .skr-grid': 'onSelect'
+
+    subviews:
+        grid:
+            hook: 'grid'
+            component: 'Grid'
+            options: ->
+                { record_query: @record_query }
+        query_clauses:
+             container: '.query-clauses'
+             view: FinderClause, collection: 'clauses'
+
+    bodyTemplateName: 'record-finder/dialog'
+    bodyAttributes:
+        class: "record-finder"
+
+    session:
+        record_query: 'model'
+        clauses: 'collection'
+
+    initialize:(options)->
+        # @record_query = options.record_query
+        # @columns     = options.columns
+        # @model_type  = options.model_type
+
+        @clauses = @record_query.clauses
+
+        @debounceMethod( 'runQuery')
+        this.listenTo(@record_query,'change',@runQuery)
+        _.bindAll(this,'hide')
+
+    onSelect: (ev)->
+        @record = ev.detail.model
+        ev.preventDefault()
+        _.delay(this.hide, 500)
+
+    addClause: ->
+        @record_query.addNewClause()
+
+    runQuery: ->
+        this.grid.reload() if @record_query.isValid()
+
+Lanes.Component.ModalDialog.extend(FinderDialog)
+
+
+class RecordFinder
+    constructor: -> super
+    templateName: 'record-finder/field'
+    templateData: -> { field_name: @record_query.initial_field }
+
+    events:
+        "keyup .record-finder-query-string": "onKey"
+        "click .record-finder-query": "displayFinder"
+
+    session:
+        include_associations: 'array'
+        record_query: 'model'
+        query_field: [ 'string', false, 'code' ]
+
+    initialize:(options)->
+        @record_query = new Lanes.Data.Query(fields: options.fields, collection_class: options.query_using)
+
+    displayFinder: ->
+        finder = new FinderDialog( title: @title, record_query: @record_query )
+
+        finder.show().then( (dlg)->
+            dlg.remove().record
+        ).then( (record)=>
+            record.withAssociations(@.includeAssociations...) if record
+        ).then( (record)=>
+            @.fireEvent("display-record", record) if record
+        , (e)->Lanes.warn(e) )
+
+    onKey: (ev)->
+        qf=this.$('.record-finder-query-string')
+        if 13 == ev.keyCode
+            this.runQuery(ev)
+        else if qf.val().match( Lanes.Data.mixins.Lanes.sCodeField.INVALID )
+            qf.val( qf.val().replace( Lanes.Data.mixins.Lanes.sCodeField.INVALID, '' ) )
+
+    runQuery: (ev)->
+        code = this.$(ev.target).val()
+        @record_query.loadSingle(code.toUpperCase(),{ include: @includeAssociations })
+            .then( (reply)=> @fireEvent("display-record", reply.record) if reply.record )
+
+Lanes.Component.RecordFinder = Lanes.Component.Base.extend(RecordFinder)

data/client/javascripts/component/SelectField.coffee

@@ -0,0 +1,43 @@
+class SelectOption extends Lanes.View.Base
+    template: (scope)->
+        '<option></option>'
+
+    constructor: (options)->
+        @groupName=options.groupName
+        m = options.mappings
+        @bindings = {}
+        @bindings["model.#{m.id}"]       = { type: 'value', selector: 'option' }
+        @bindings["model.#{m.selected}"] = { type: 'booleanAttribute', selector: 'option', name:'selected' }
+        @bindings["model.#{m.title}"]    = 'option'
+        @bindings["model.#{m.visible}"]  = { type: 'toggle' } if m.visible
+        super
+
+
+class Lanes.Component.SelectField extends Lanes.Component.ChoicesInput
+
+    subviews:
+        fields:
+            hook: 'choices-input'
+            collection: 'selections'
+            options: 'subViewOptions'
+            view: SelectOption
+
+    session:
+        multiple: { type: 'boolean', default: false }
+
+    writeTemplate: ->
+        multiple = if this.multiple then "multiple" else ""
+        "<select class='form-control' #{multiple} name='#{this.field_name}' data-hook='choices-input'></select>"
+
+    readTemplate: ->
+        "<div class='ro-input' name='#{this.field_name}'></div>"
+
+    select: (option)->
+        if this.readOnly
+            this.$el.text( if option then option.code else "" )
+        else if option
+            id = option.get(@mappings.id)
+            option = this.query("option[value=\"#{id}\"]")
+            option.selected = true
+        else
+            this.$el.find(":selected").prop('selected',false)

data/client/javascripts/component/TaggedField.coffee

@@ -0,0 +1,27 @@
+class Lanes.Component.TaggedField extends Lanes.Component.ChoicesInput
+
+    writeTemplate: ->
+        multiple = if this.multiple then "multiple" else ""
+        "<select class='form-control' #{multiple} name='#{this.field_name}' data-hook='choices-input'></select>"
+
+    readTemplate: ->
+        "<div class='ro-input' name='#{this.field_name}'></div>"
+
+    session:
+        options: 'object'
+
+    initialize: (options)->
+        this.options=options.fieldOptions
+
+    onRender: ->
+        this.$el.magicSuggest(this.options)
+
+    # select: (option)->
+    #     if this.readOnly
+    #         this.$el.text( if option then option.code else "" )
+    #     else if option
+    #         id = option.get(@mappings.id)
+    #         option = this.query("option[value=\"#{id}\"]")
+    #         option.selected = true
+    #     else
+    #         this.$el.find(":selected").prop('selected',false)

data/client/javascripts/component/grid/Editor.coffee

@@ -0,0 +1,65 @@
+class Lanes.Component.Grid.Editor extends Lanes.Component.Base
+
+    session:
+        grid: 'object' # n.b. - not 'state'.  Doing so causes stack overflow since grid also has a 'editor' session var
+
+    events:
+        'click .save':   'saveChanges'
+        'click .cancel': 'cancelEditing'
+
+    constructor: (config)->
+        super
+        this.grid = this.parent
+
+    move: (row)->
+        if @row
+            @grid.fireEvent('cancel-edit',@row)
+        @row=row
+        @model = this.grid.modelForRow(@row)
+        this.render() unless this.rendered
+        this.grid.$('.dataTables_scrollBody').append(this.el)
+        this.updateFields()
+
+    render: ->
+        super
+        this.cacheJqElements({
+            form: 'form'
+        })
+
+    updateFields: ->
+        for input, index in this.$('input')
+            if definition = this.getColumn(input.name)
+                _.dom.setAttribute(input, 'value', this.model.get(definition.field) )
+        this.$('input').first().focus()
+
+    persistFields: ->
+        for input, index in this.$('input')
+            if definition = this.getColumn(input.name)
+                @model.set( definition.field, _.dom.getAttribute(input,'value') )
+
+    getColumn: (name)->
+        _.findWhere(this.grid.column_definitions, { field: name })
+
+    saveChanges: ->
+        this.persistFields()
+        @model.save().then => @updateGridRow()
+
+    updateGridRow: ->
+        @grid.fireEvent('row-updated', @row)
+        @grid.updateRow(@row,@model)
+        this.cancelEditing()
+
+    cancelEditing: ->
+        @grid.fireEvent('cancel-edit', @row)
+        this.detach()
+        this.model = null
+
+    deleteCurrent: ->
+        @model.destroy().then =>
+            @grid.removeRow(@row)
+            @cancelEditing()
+
+    fields: ->
+        _.map(this.form.children(), (input,index)->
+            { index: index, input: Lanes.$(input), column: this.grid.column_definitions[index] }
+        ,this)

data/client/javascripts/component/grid/PopOverEditor.coffee

@@ -0,0 +1,29 @@
+class Lanes.Component.Grid.PopOverEditor extends Lanes.Component.Grid.Editor
+
+    templateName: 'grid/popover-editor'
+    templateData: ->
+        { columns: this.grid.column_definitions }
+
+    session:
+        view: 'object'
+        title: 'string'
+
+    move: (row,ev)->
+        super
+        if @popover
+            @popover.destroy()
+        @popover = new Lanes.Component.PopOver({
+                parent: this
+                className: 'grid-popover-editor'
+                target: Lanes.$(ev.target)
+                title: this.title || this.calculated_title()
+                content: this.el
+                autoShow: true
+            })
+
+    calculated_title: ->
+        (if this.model.isNew() then "Create: " else "Edit: ") + this.model.constructor.name
+
+    cancelEditing: ->
+        @popover.destroy()
+        super

data/client/javascripts/component/grid/RowEditor.coffee

@@ -0,0 +1,31 @@
+class Lanes.Component.Grid.RowEditor extends Lanes.Component.Grid.Editor
+
+
+    templateName: 'grid/row-editor'
+
+    move: (row)->
+        super
+        pos = this.row.position()
+        this.$el.css({
+            left: pos.left, top: pos.top, width: this.row.width()
+        })
+        this.$('form').css({
+            height: this.row.height()
+        })
+        inputs = this.form.children()
+        for input, index in inputs
+            column = Lanes.$(this.row[0].cells[index])
+            definition = this.grid.column_definitions[index]
+            Lanes.$(input)
+                .width(column.width())
+                .css("left", column.position().left)
+                .val(this.model.get(definition.field))
+        this.form.find('.edit').first().focus()
+
+
+
+    render: ->
+        super
+        for cell in this.row[0].cells
+            this.form.append('<input class="edit">')
+        this

data/client/javascripts/component/grid/popover-editor.html

@@ -0,0 +1,18 @@
+<form class="form-horizontal" role="form">
+<% for field in @columns: %>
+  <div class="form-group">
+    <label for="field-<%= field.field %>" class="col-sm-2 control-label"><%= field.title %></label>
+    <div class="col-sm-10">
+      <input type="text" name="<%= field.field %>" class="form-control" id="field-<%= field.field %>" placeholder="">
+    </div>
+  </div>
+  <% end %>
+  <div class= buttons"">
+    <button type="button" class="btn btn-default cancel">
+      <i class="icon-cancel-circle"> Cancel</i>
+    </button>
+    <button type="button" class="btn btn-primary save">
+      <i class="icon-save"> Save</i>
+    </button>
+  </div>
+</form>

data/client/javascripts/component/grid/row-editor.html

@@ -0,0 +1,16 @@
+<div class="grid-row-editor">
+    <form>
+    </form>
+    <div class="controls">
+
+        <div class="buttons">
+            <button type="button" class="btn cancel">
+                <i class="icon-cancel-circle">Cancel</i>
+            </button>
+            <button type="button" class="btn save">
+                <i class="icon-save">Save</i>
+            </button>
+        </div>
+
+    </div>
+</div>

data/client/javascripts/component/grid.html

@@ -0,0 +1,4 @@
+<div class="lanes-grid">
+  <% if @grid.edit_records: %><%= h.toolbar( buttons: @buttons ) %><% end %>
+  <table cellspacing="0" width="100%"></table>
+</div>

data/client/javascripts/component/index.js

@@ -0,0 +1,5 @@
+//= require_self
+//= require ./Base
+//= require_tree .
+
+Lanes.namespace('Component');

data/client/javascripts/component/modal.html

@@ -0,0 +1,17 @@
+  <div class="modal-dialog modal-<%= @size %>">
+    <div class="modal-content">
+      <div class="modal-header">
+        <button type="button" class="close" data-dismiss="modal" aria-hidden="true">&times;</button>
+        <h4 class="modal-title" id="myModalLabel"><%= @title %></h4>
+      </div>
+      <div class="modal-body">
+          <%- @body %>
+      </div>
+      <div class="modal-footer">
+          <% for name, opts of @buttons: %>
+             <button type="button" name="<%= name %>" class="btn btn-<%= opts.type %>" <%='data-dismiss=modal' if opts.dismiss %>><%= opts.label %></button>
+          <% end %>
+        <!-- <button type="button" class="btn btn-primary">Save changes</button> -->
+      </div>
+    </div>
+  </div>

data/client/javascripts/component/popover.html

@@ -0,0 +1,5 @@
+<div class="popover <%= @className %>" role="tooltip">
+  <div class="arrow"></div>
+  <h3 class="popover-title"></h3>
+  <div class="popover-content"></div>
+</div>

data/client/javascripts/component/record-finder/clause.skr

@@ -0,0 +1,35 @@
+<div class="row clause">
+    <div class="col-xs-10">
+        <div class="input-group">
+
+            <div class="input-group-btn">
+                <button type="button" class="btn btn-default dropdown-toggle" data-toggle="dropdown">
+                    <span class="query-field-description"></span>
+                    <span class="caret"></span>
+                </button>
+                <div class="query dropdown dropdown-menu">
+                    <form>
+                        <div class="<%= h.grid_widths 6 %> fields">
+                        </div>
+                        <div class="<%= h.grid_widths 6 %> operators">
+                        </div>
+                    </form>
+                </div>
+            </div>
+            <input type="text" name="value" class="form-control query-string" <%= h.elid() %>>
+            <span class="input-group-btn">
+                <button type="button" class="btn btn-default del-clause">
+                    <i class="icon-trash-o"></i>
+                </button>
+                <button type="button" class="btn btn-default add-clause">
+                    <i class="icon-plus"></i>
+                </button>
+            </span>
+        </div><!-- /input-group -->
+    </div><!-- /.col-lg-6 -->
+    <div class="col-xs-2 action">
+        <button type="button" class="btn btn-default run-query">
+            <i class="icon-search"></i><span> Search</span>
+        </button>
+    </div>
+</div>

data/client/javascripts/component/record-finder/dialog.skr

@@ -0,0 +1,4 @@
+<div class="form-horizontal query-clauses" data-hook="form">
+</div>
+<div class="grid" data-hook="grid">
+</div>

data/client/javascripts/component/record-finder/field.skr

@@ -0,0 +1,8 @@
+<div class="input-group">
+    <input type="text" name="<%= @field_name %>" id="foo" class="form-control record-finder-query-string">
+    <span class="input-group-btn">
+        <button type="button" class="btn btn-default record-finder-query">
+            <i class="icon-search"></i>
+        </button>
+    </span>
+</div>

data/client/javascripts/data/Bootstrap.coffee

@@ -0,0 +1,8 @@
+Lanes.Data.Bootstrap = {
+
+    initialize: (options)->
+        Lanes.Data.Config.csrf_token = options.csrf
+        Lanes.Data.Config.api_path  = options.root
+        Lanes.Extensions.setBootstrapData(options.data);
+
+}

data/client/javascripts/data/ChangeSet.coffee

@@ -0,0 +1,50 @@
+class Lanes.Data.ChangeSet extends Lanes.Data.Model
+
+    constructor: ->
+        super
+        this.created_at = new Date
+        this.updateTimeAgo()
+
+    session:
+        update: 'object'
+        record: 'model'
+        time_ago: 'string'
+        created_at: { type: 'date', setOnce: true }
+
+    derived:
+        fields: { deps: ['update'], fn: -> _.keys(@update) }
+        displayed_fields: { deps:['fields'], fn: -> _.without(@fields, 'updated_by_id', 'updated_at') }
+
+    changeFor:(field)->
+        change = @update[field] || []
+        { from: change[0], to: change[1] }
+
+    associations:
+        by: { model: "User" }
+
+    value: ->
+        set={}
+        for field, change of @update
+            set[field] = change[1]
+        set
+
+    updateTimeAgo: ->
+        @time_ago = Lanes.Vendor.Moment( @created_at ).fromNow()
+
+
+class Lanes.Data.ChangeSetCollection extends Lanes.Data.BasicCollection
+
+    model: Lanes.Data.ChangeSet
+
+    constructor: (options)->
+        super([],options)
+        this.on("add", this.onAdd, this )
+
+    onAdd: (change)->
+        record = this.parent
+        while record
+            record.trigger('remote-update', record, change);
+            record = record.parent
+
+    comparator: (a,b)->
+        if b.created_at < a.created_at then -1 else if b.created_at > a.created_at then 1 else 0

data/client/javascripts/data/Collection.coffee

@@ -0,0 +1,111 @@
+CommonMethods = {
+    findIndexWhere: (attrs)->
+        found = -1
+        for index, model of @models
+            found = parseInt(index)
+            for key, value of attrs
+                if model.get(key) != value
+                    found = -1
+                    break
+            break if found != -1
+        found
+}
+
+class DataCollection
+
+    constructor: ->
+        @isLoaded=false
+        @errors=[]
+        Lanes.Vendor.Ampersand.Collection.apply(this, arguments)
+
+    isLoaded:->
+        @isLoaded
+
+    fetch: (options={})->
+        @isLoaded = true
+        wrapRequest(this,options)
+        super(options).then => @
+
+    ensureLoaded: ( callback )->
+        if ! @isLoaded && ! this.length
+            this.fetch({ success: callback })
+        else if callback
+            callback()
+
+    isDirty: ->
+        false
+
+    parse:(resp)->
+        resp['data']
+
+    viewJSON: (options)->
+        this.map( (model) ->
+            model.viewJSON(options)
+        )
+
+    url: ->
+        @model::urlRoot() + '.json'
+
+    sync: ->
+        Lanes.Data.Sync.apply(this,arguments)
+
+    _prepareModel: (attrs, options={})->
+        options.collection = this;
+        if this.isModel(attrs)
+            attrs
+        else
+            this.model.findOrCreate(attrs, options)
+
+    mixins:[
+        CommonMethods
+    ]
+
+copyServerMessages=(collection,msg)->
+    return unless msg
+    collection.errors = msg.errors || []
+    collection.lastServerMessage = msg.message
+
+wrapRequest = (collection, options)->
+    error   = options.error
+    success = options.success
+
+    options.error = (collection,resp)->
+        copyServerMessages(collection,resp.responseJSON)
+        error?.apply(options.scope, arguments)
+        Lanes.warn("request fail",resp)
+        options.complete?.apply(options.scope, arguments)
+    options.success = (collection,resp)->
+        copyServerMessages(collection,resp)
+        if resp.success
+            success?.apply(options.scope, arguments)
+        else
+            error?.apply(options.scope, arguments)
+        options.complete?.apply(options.scope, arguments)
+
+class BasicCollection
+    constructor: -> super
+    isLoaded: -> true
+    mixins:[
+        CommonMethods
+    ]
+
+
+class SubCollection
+    constructor: -> super
+    isLoaded: -> true
+    mixins:[
+        CommonMethods
+    ]
+
+    filter: ->
+        this._runFilters()
+
+Lanes.Data.SubCollection = Lanes.lib.MakeBaseClass( Lanes.Vendor.Ampersand.SubCollection, SubCollection )
+
+
+Lanes.Data.BasicCollection = Lanes.lib.MakeBaseClass(
+    Lanes.Vendor.Ampersand.Collection.extend(Lanes.Vendor.Ampersand.USCollection), BasicCollection
+)
+
+
+Lanes.Data.Collection = Lanes.lib.MakeBaseClass( Lanes.Vendor.Ampersand.RestCollection, DataCollection )

data/client/javascripts/data/Config.coffee

@@ -0,0 +1,15 @@
+class Config
+    constructor: -> super
+
+    session:
+        csrf_token: { type: 'string', setOnce: false }
+        api_path:   { type: 'string', setOnce: false }
+
+    # derived:
+    #     api_path:
+    #         deps: ['root_path']
+    #         fn: -> @root_path + "api"
+
+Lanes.Data.State.extend(Config)
+
+Lanes.Data.Config = new Config