laag-libjpeg-turbo 1.5.3.0

data/vendor/github.com/libjpeg-turbo/libjpeg-turbo/simd/jcsample-altivec.c

@@ -0,0 +1,158 @@
+/*
+ * AltiVec optimizations for libjpeg-turbo
+ *
+ * Copyright (C) 2015, D. R. Commander.  All Rights Reserved.
+ *
+ * This software is provided 'as-is', without any express or implied
+ * warranty.  In no event will the authors be held liable for any damages
+ * arising from the use of this software.
+ *
+ * Permission is granted to anyone to use this software for any purpose,
+ * including commercial applications, and to alter it and redistribute it
+ * freely, subject to the following restrictions:
+ *
+ * 1. The origin of this software must not be misrepresented; you must not
+ *    claim that you wrote the original software. If you use this software
+ *    in a product, an acknowledgment in the product documentation would be
+ *    appreciated but is not required.
+ * 2. Altered source versions must be plainly marked as such, and must not be
+ *    misrepresented as being the original software.
+ * 3. This notice may not be removed or altered from any source distribution.
+ */
+
+/* CHROMA DOWNSAMPLING */
+
+#include "jsimd_altivec.h"
+#include "jcsample.h"
+
+
+void
+jsimd_h2v1_downsample_altivec (JDIMENSION image_width, int max_v_samp_factor,
+                               JDIMENSION v_samp_factor,
+                               JDIMENSION width_blocks,
+                               JSAMPARRAY input_data, JSAMPARRAY output_data)
+{
+  int outrow, outcol;
+  JDIMENSION output_cols = width_blocks * DCTSIZE;
+  JSAMPROW inptr, outptr;
+
+  __vector unsigned char this0, next0, out;
+  __vector unsigned short this0e, this0o, next0e, next0o, outl, outh;
+
+  /* Constants */
+  __vector unsigned short pw_bias = { __4X2(0, 1) },
+    pw_one = { __8X(1) };
+  __vector unsigned char even_odd_index =
+    {0,2,4,6,8,10,12,14,1,3,5,7,9,11,13,15},
+    pb_zero = { __16X(0) };
+
+  expand_right_edge(input_data, max_v_samp_factor, image_width,
+                    output_cols * 2);
+
+  for (outrow = 0; outrow < v_samp_factor; outrow++) {
+    outptr = output_data[outrow];
+    inptr = input_data[outrow];
+
+    for (outcol = output_cols; outcol > 0;
+         outcol -= 16, inptr += 32, outptr += 16) {
+
+      this0 = vec_ld(0, inptr);
+      this0 = vec_perm(this0, this0, even_odd_index);
+      this0e = (__vector unsigned short)VEC_UNPACKHU(this0);
+      this0o = (__vector unsigned short)VEC_UNPACKLU(this0);
+      outl = vec_add(this0e, this0o);
+      outl = vec_add(outl, pw_bias);
+      outl = vec_sr(outl, pw_one);
+
+      if (outcol > 8) {
+        next0 = vec_ld(16, inptr);
+        next0 = vec_perm(next0, next0, even_odd_index);
+        next0e = (__vector unsigned short)VEC_UNPACKHU(next0);
+        next0o = (__vector unsigned short)VEC_UNPACKLU(next0);
+        outh = vec_add(next0e, next0o);
+        outh = vec_add(outh, pw_bias);
+        outh = vec_sr(outh, pw_one);
+      } else
+        outh = vec_splat_u16(0);
+
+      out = vec_pack(outl, outh);
+      vec_st(out, 0, outptr);
+    }
+  }
+}
+
+
+void
+jsimd_h2v2_downsample_altivec (JDIMENSION image_width, int max_v_samp_factor,
+                               JDIMENSION v_samp_factor,
+                               JDIMENSION width_blocks,
+                               JSAMPARRAY input_data, JSAMPARRAY output_data)
+{
+  int inrow, outrow, outcol;
+  JDIMENSION output_cols = width_blocks * DCTSIZE;
+  JSAMPROW inptr0, inptr1, outptr;
+
+  __vector unsigned char this0, next0, this1, next1, out;
+  __vector unsigned short this0e, this0o, next0e, next0o, this1e, this1o,
+    next1e, next1o, out0l, out0h, out1l, out1h, outl, outh;
+
+  /* Constants */
+  __vector unsigned short pw_bias = { __4X2(1, 2) },
+    pw_two = { __8X(2) };
+  __vector unsigned char even_odd_index =
+    { 0, 2, 4, 6, 8, 10, 12, 14, 1, 3, 5, 7, 9, 11, 13, 15 },
+    pb_zero = { __16X(0) };
+
+  expand_right_edge(input_data, max_v_samp_factor, image_width,
+                    output_cols * 2);
+
+  for (inrow = 0, outrow = 0; outrow < v_samp_factor;
+       inrow += 2, outrow++) {
+
+    inptr0 = input_data[inrow];
+    inptr1 = input_data[inrow + 1];
+    outptr = output_data[outrow];
+
+    for (outcol = output_cols; outcol > 0;
+         outcol -= 16, inptr0 += 32, inptr1 += 32, outptr += 16) {
+
+      this0 = vec_ld(0, inptr0);
+      this0 = vec_perm(this0, this0, even_odd_index);
+      this0e = (__vector unsigned short)VEC_UNPACKHU(this0);
+      this0o = (__vector unsigned short)VEC_UNPACKLU(this0);
+      out0l = vec_add(this0e, this0o);
+
+      this1 = vec_ld(0, inptr1);
+      this1 = vec_perm(this1, this1, even_odd_index);
+      this1e = (__vector unsigned short)VEC_UNPACKHU(this1);
+      this1o = (__vector unsigned short)VEC_UNPACKLU(this1);
+      out1l = vec_add(this1e, this1o);
+
+      outl = vec_add(out0l, out1l);
+      outl = vec_add(outl, pw_bias);
+      outl = vec_sr(outl, pw_two);
+
+      if (outcol > 8) {
+        next0 = vec_ld(16, inptr0);
+        next0 = vec_perm(next0, next0, even_odd_index);
+        next0e = (__vector unsigned short)VEC_UNPACKHU(next0);
+        next0o = (__vector unsigned short)VEC_UNPACKLU(next0);
+        out0h = vec_add(next0e, next0o);
+
+        next1 = vec_ld(16, inptr1);
+        next1 = vec_perm(next1, next1, even_odd_index);
+        next1e = (__vector unsigned short)VEC_UNPACKHU(next1);
+        next1o = (__vector unsigned short)VEC_UNPACKLU(next1);
+        out1h = vec_add(next1e, next1o);
+
+        outh = vec_add(out0h, out1h);
+        outh = vec_add(outh, pw_bias);
+        outh = vec_sr(outh, pw_two);
+      } else
+        outh = vec_splat_u16(0);
+
+      out = vec_pack(outl, outh);
+      vec_st(out, 0, outptr);
+    }
+  }
+}

data/vendor/github.com/libjpeg-turbo/libjpeg-turbo/simd/jcsample-mmx.asm

@@ -0,0 +1,323 @@
+;
+; jcsample.asm - downsampling (MMX)
+;
+; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
+;
+; Based on the x86 SIMD extension for IJG JPEG library
+; Copyright (C) 1999-2006, MIYASAKA Masaru.
+; For conditions of distribution and use, see copyright notice in jsimdext.inc
+;
+; This file should be assembled with NASM (Netwide Assembler),
+; can *not* be assembled with Microsoft's MASM or any compatible
+; assembler (including Borland's Turbo Assembler).
+; NASM is available from http://nasm.sourceforge.net/ or
+; http://sourceforge.net/project/showfiles.php?group_id=6208
+;
+; [TAB8]
+
+%include "jsimdext.inc"
+
+; --------------------------------------------------------------------------
+        SECTION SEG_TEXT
+        BITS    32
+;
+; Downsample pixel values of a single component.
+; This version handles the common case of 2:1 horizontal and 1:1 vertical,
+; without smoothing.
+;
+; GLOBAL(void)
+; jsimd_h2v1_downsample_mmx (JDIMENSION image_width, int max_v_samp_factor,
+;                            JDIMENSION v_samp_factor, JDIMENSION width_blocks,
+;                            JSAMPARRAY input_data, JSAMPARRAY output_data);
+;
+
+%define img_width(b)    (b)+8           ; JDIMENSION image_width
+%define max_v_samp(b)   (b)+12          ; int max_v_samp_factor
+%define v_samp(b)       (b)+16          ; JDIMENSION v_samp_factor
+%define width_blks(b)   (b)+20          ; JDIMENSION width_blocks
+%define input_data(b)   (b)+24          ; JSAMPARRAY input_data
+%define output_data(b)  (b)+28          ; JSAMPARRAY output_data
+
+        align   16
+        global  EXTN(jsimd_h2v1_downsample_mmx)
+
+EXTN(jsimd_h2v1_downsample_mmx):
+        push    ebp
+        mov     ebp,esp
+;       push    ebx             ; unused
+;       push    ecx             ; need not be preserved
+;       push    edx             ; need not be preserved
+        push    esi
+        push    edi
+
+        mov     ecx, JDIMENSION [width_blks(ebp)]
+        shl     ecx,3                   ; imul ecx,DCTSIZE (ecx = output_cols)
+        jz      near .return
+
+        mov     edx, JDIMENSION [img_width(ebp)]
+
+        ; -- expand_right_edge
+
+        push    ecx
+        shl     ecx,1                           ; output_cols * 2
+        sub     ecx,edx
+        jle     short .expand_end
+
+        mov     eax, INT [max_v_samp(ebp)]
+        test    eax,eax
+        jle     short .expand_end
+
+        cld
+        mov     esi, JSAMPARRAY [input_data(ebp)]       ; input_data
+        alignx  16,7
+.expandloop:
+        push    eax
+        push    ecx
+
+        mov     edi, JSAMPROW [esi]
+        add     edi,edx
+        mov     al, JSAMPLE [edi-1]
+
+        rep stosb
+
+        pop     ecx
+        pop     eax
+
+        add     esi, byte SIZEOF_JSAMPROW
+        dec     eax
+        jg      short .expandloop
+
+.expand_end:
+        pop     ecx                             ; output_cols
+
+        ; -- h2v1_downsample
+
+        mov     eax, JDIMENSION [v_samp(ebp)]   ; rowctr
+        test    eax,eax
+        jle     near .return
+
+        mov       edx, 0x00010000       ; bias pattern
+        movd      mm7,edx
+        pcmpeqw   mm6,mm6
+        punpckldq mm7,mm7               ; mm7={0, 1, 0, 1}
+        psrlw     mm6,BYTE_BIT          ; mm6={0xFF 0x00 0xFF 0x00 ..}
+
+        mov     esi, JSAMPARRAY [input_data(ebp)]       ; input_data
+        mov     edi, JSAMPARRAY [output_data(ebp)]      ; output_data
+        alignx  16,7
+.rowloop:
+        push    ecx
+        push    edi
+        push    esi
+
+        mov     esi, JSAMPROW [esi]             ; inptr
+        mov     edi, JSAMPROW [edi]             ; outptr
+        alignx  16,7
+.columnloop:
+
+        movq    mm0, MMWORD [esi+0*SIZEOF_MMWORD]
+        movq    mm1, MMWORD [esi+1*SIZEOF_MMWORD]
+        movq    mm2,mm0
+        movq    mm3,mm1
+
+        pand    mm0,mm6
+        psrlw   mm2,BYTE_BIT
+        pand    mm1,mm6
+        psrlw   mm3,BYTE_BIT
+
+        paddw   mm0,mm2
+        paddw   mm1,mm3
+        paddw   mm0,mm7
+        paddw   mm1,mm7
+        psrlw   mm0,1
+        psrlw   mm1,1
+
+        packuswb mm0,mm1
+
+        movq    MMWORD [edi+0*SIZEOF_MMWORD], mm0
+
+        add     esi, byte 2*SIZEOF_MMWORD       ; inptr
+        add     edi, byte 1*SIZEOF_MMWORD       ; outptr
+        sub     ecx, byte SIZEOF_MMWORD         ; outcol
+        jnz     short .columnloop
+
+        pop     esi
+        pop     edi
+        pop     ecx
+
+        add     esi, byte SIZEOF_JSAMPROW       ; input_data
+        add     edi, byte SIZEOF_JSAMPROW       ; output_data
+        dec     eax                             ; rowctr
+        jg      short .rowloop
+
+        emms            ; empty MMX state
+
+.return:
+        pop     edi
+        pop     esi
+;       pop     edx             ; need not be preserved
+;       pop     ecx             ; need not be preserved
+;       pop     ebx             ; unused
+        pop     ebp
+        ret
+
+; --------------------------------------------------------------------------
+;
+; Downsample pixel values of a single component.
+; This version handles the standard case of 2:1 horizontal and 2:1 vertical,
+; without smoothing.
+;
+; GLOBAL(void)
+; jsimd_h2v2_downsample_mmx (JDIMENSION image_width, int max_v_samp_factor,
+;                            JDIMENSION v_samp_factor, JDIMENSION width_blocks,
+;                            JSAMPARRAY input_data, JSAMPARRAY output_data);
+;
+
+%define img_width(b)    (b)+8           ; JDIMENSION image_width
+%define max_v_samp(b)   (b)+12          ; int max_v_samp_factor
+%define v_samp(b)       (b)+16          ; JDIMENSION v_samp_factor
+%define width_blks(b)   (b)+20          ; JDIMENSION width_blocks
+%define input_data(b)   (b)+24          ; JSAMPARRAY input_data
+%define output_data(b)  (b)+28          ; JSAMPARRAY output_data
+
+        align   16
+        global  EXTN(jsimd_h2v2_downsample_mmx)
+
+EXTN(jsimd_h2v2_downsample_mmx):
+        push    ebp
+        mov     ebp,esp
+;       push    ebx             ; unused
+;       push    ecx             ; need not be preserved
+;       push    edx             ; need not be preserved
+        push    esi
+        push    edi
+
+        mov     ecx, JDIMENSION [width_blks(ebp)]
+        shl     ecx,3                   ; imul ecx,DCTSIZE (ecx = output_cols)
+        jz      near .return
+
+        mov     edx, JDIMENSION [img_width(ebp)]
+
+        ; -- expand_right_edge
+
+        push    ecx
+        shl     ecx,1                           ; output_cols * 2
+        sub     ecx,edx
+        jle     short .expand_end
+
+        mov     eax, INT [max_v_samp(ebp)]
+        test    eax,eax
+        jle     short .expand_end
+
+        cld
+        mov     esi, JSAMPARRAY [input_data(ebp)]       ; input_data
+        alignx  16,7
+.expandloop:
+        push    eax
+        push    ecx
+
+        mov     edi, JSAMPROW [esi]
+        add     edi,edx
+        mov     al, JSAMPLE [edi-1]
+
+        rep stosb
+
+        pop     ecx
+        pop     eax
+
+        add     esi, byte SIZEOF_JSAMPROW
+        dec     eax
+        jg      short .expandloop
+
+.expand_end:
+        pop     ecx                             ; output_cols
+
+        ; -- h2v2_downsample
+
+        mov     eax, JDIMENSION [v_samp(ebp)]   ; rowctr
+        test    eax,eax
+        jle     near .return
+
+        mov       edx, 0x00020001       ; bias pattern
+        movd      mm7,edx
+        pcmpeqw   mm6,mm6
+        punpckldq mm7,mm7               ; mm7={1, 2, 1, 2}
+        psrlw     mm6,BYTE_BIT          ; mm6={0xFF 0x00 0xFF 0x00 ..}
+
+        mov     esi, JSAMPARRAY [input_data(ebp)]       ; input_data
+        mov     edi, JSAMPARRAY [output_data(ebp)]      ; output_data
+        alignx  16,7
+.rowloop:
+        push    ecx
+        push    edi
+        push    esi
+
+        mov     edx, JSAMPROW [esi+0*SIZEOF_JSAMPROW]   ; inptr0
+        mov     esi, JSAMPROW [esi+1*SIZEOF_JSAMPROW]   ; inptr1
+        mov     edi, JSAMPROW [edi]                     ; outptr
+        alignx  16,7
+.columnloop:
+
+        movq    mm0, MMWORD [edx+0*SIZEOF_MMWORD]
+        movq    mm1, MMWORD [esi+0*SIZEOF_MMWORD]
+        movq    mm2, MMWORD [edx+1*SIZEOF_MMWORD]
+        movq    mm3, MMWORD [esi+1*SIZEOF_MMWORD]
+
+        movq    mm4,mm0
+        movq    mm5,mm1
+        pand    mm0,mm6
+        psrlw   mm4,BYTE_BIT
+        pand    mm1,mm6
+        psrlw   mm5,BYTE_BIT
+        paddw   mm0,mm4
+        paddw   mm1,mm5
+
+        movq    mm4,mm2
+        movq    mm5,mm3
+        pand    mm2,mm6
+        psrlw   mm4,BYTE_BIT
+        pand    mm3,mm6
+        psrlw   mm5,BYTE_BIT
+        paddw   mm2,mm4
+        paddw   mm3,mm5
+
+        paddw   mm0,mm1
+        paddw   mm2,mm3
+        paddw   mm0,mm7
+        paddw   mm2,mm7
+        psrlw   mm0,2
+        psrlw   mm2,2
+
+        packuswb mm0,mm2
+
+        movq    MMWORD [edi+0*SIZEOF_MMWORD], mm0
+
+        add     edx, byte 2*SIZEOF_MMWORD       ; inptr0
+        add     esi, byte 2*SIZEOF_MMWORD       ; inptr1
+        add     edi, byte 1*SIZEOF_MMWORD       ; outptr
+        sub     ecx, byte SIZEOF_MMWORD         ; outcol
+        jnz     near .columnloop
+
+        pop     esi
+        pop     edi
+        pop     ecx
+
+        add     esi, byte 2*SIZEOF_JSAMPROW     ; input_data
+        add     edi, byte 1*SIZEOF_JSAMPROW     ; output_data
+        dec     eax                             ; rowctr
+        jg      near .rowloop
+
+        emms            ; empty MMX state
+
+.return:
+        pop     edi
+        pop     esi
+;       pop     edx             ; need not be preserved
+;       pop     ecx             ; need not be preserved
+;       pop     ebx             ; unused
+        pop     ebp
+        ret
+
+; For some reason, the OS X linker does not honor the request to align the
+; segment unless we do this.
+        align   16