js-routes-zigexn 1.3.3

data/lib/routes.js.coffee

@@ -0,0 +1,368 @@
+###
+File generated by js-routes GEM_VERSION
+Based on Rails routes of APP_CLASS
+###
+# root is this
+root = (exports ? this)
+
+ParameterMissing = (@message) -> #
+ParameterMissing:: = new Error()
+defaults =
+  prefix: PREFIX
+  default_url_options: DEFAULT_URL_OPTIONS
+
+NodeTypes = NODE_TYPES
+SpecialOptionsKey = SPECIAL_OPTIONS_KEY
+DeprecatedBehavior = DEPRECATED_BEHAVIOR
+
+ReservedOptions = [
+  'anchor'
+  'trailing_slash'
+  'host'
+  'port'
+  'protocol'
+]
+
+Utils =
+
+  default_serializer: (object, prefix = null) ->
+    return "" unless object?
+    if !prefix and !(@get_object_type(object) is "object")
+      throw new Error("Url parameters should be a javascript hash")
+
+    s = []
+    switch @get_object_type(object)
+      when "array"
+        for element, i in object
+          s.push @default_serializer(element, prefix + "[]")
+      when "object"
+        for own key, prop of object
+          if !prop? and prefix?
+            prop = ""
+
+          if prop?
+            key = "#{prefix}[#{key}]" if prefix?
+            s.push @default_serializer(prop, key)
+      else
+        if object?
+          s.push "#{encodeURIComponent(prefix.toString())}=#{encodeURIComponent(object.toString())}"
+
+    return "" unless s.length
+    s.join("&")
+
+  custom_serializer: SERIALIZER
+  serialize: (object) ->
+    if @custom_serializer? and @get_object_type(@custom_serializer) is "function"
+      @custom_serializer(object)
+    else
+      @default_serializer(object)
+
+  clean_path: (path) ->
+    path = path.split("://")
+    last_index = path.length - 1
+    path[last_index] = path[last_index].replace(/\/+/g, "/")
+    path.join "://"
+
+  extract_options: (number_of_params, args) ->
+    last_el = args[args.length - 1]
+    if (args.length > number_of_params and last_el == undefined) or (last_el? and "object" is @get_object_type(last_el) and !@looks_like_serialized_model(last_el))
+      options = args.pop() || {}
+      delete options[SpecialOptionsKey]
+      options
+    else
+      {}
+
+  looks_like_serialized_model: (object) ->
+    !object[SpecialOptionsKey] and ("id" of object or "to_param" of object)
+
+
+  path_identifier: (object) ->
+    return "0"  if object is 0
+    # null, undefined, false or ''
+    return "" unless object
+    property = object
+    if @get_object_type(object) is "object"
+      if "to_param" of object
+        throw new ParameterMissing("Route parameter missing: to_param") unless object.to_param?
+        property = object.to_param
+      else if "id" of object
+        throw new ParameterMissing("Route parameter missing: id") unless object.id?
+        property = object.id
+      else
+        property = object
+
+      property = property.call(object) if @get_object_type(property) is "function"
+    property.toString()
+
+  clone: (obj) ->
+    return obj if !obj? or "object" isnt @get_object_type(obj)
+    copy = obj.constructor()
+    copy[key] = attr for own key, attr of obj
+    copy
+
+  merge: (xs...) ->
+    tap = (o, fn) -> fn(o); o
+    if xs?.length > 0
+      tap {}, (m) -> m[k] = v for k, v of x for x in xs
+
+  normalize_options: (parts, required_parts, default_options, actual_parameters) ->
+    options = @extract_options(parts.length, actual_parameters)
+
+    if actual_parameters.length > parts.length
+      throw new Error("Too many parameters provided for path")
+
+    use_all_parts = DeprecatedBehavior or actual_parameters.length > required_parts.length
+    parts_options = {}
+
+    for own key of options
+      use_all_parts = true
+      if @indexOf(parts, key) >= 0
+        parts_options[key] = value
+
+    options = @merge(defaults.default_url_options, default_options, options)
+    result = {}
+    url_parameters = {}
+    result['url_parameters'] = url_parameters
+    for own key, value of options
+      if @indexOf(ReservedOptions, key) >= 0
+        result[key] = value
+      else
+        url_parameters[key] = value
+
+    route_parts = if use_all_parts then parts else required_parts
+    i = 0
+    for part in route_parts when i < actual_parameters.length
+      unless parts_options.hasOwnProperty(part)
+        url_parameters[part] = actual_parameters[i]
+        ++i
+
+    result
+
+  build_route: (parts, required_parts, default_options, route, full_url, args) ->
+    args = Array::slice.call(args)
+
+    options = @normalize_options(parts, required_parts, default_options, args)
+    parameters = options['url_parameters']
+
+    # path
+    result = "#{@get_prefix()}#{@visit(route, parameters)}"
+    url = Utils.clean_path(result)
+    # set trailing_slash
+    url = url.replace(/(.*?)[\/]?$/, "$1/") if options['trailing_slash'] is true
+    # set additional url params
+    if (url_params = @serialize(parameters)).length
+      url += "?#{url_params}"
+    # set anchor
+    url += if options.anchor then "##{options.anchor}" else ""
+    if full_url
+      url = @route_url(options) + url
+    url
+
+  #
+  # This function is JavaScript impelementation of the
+  # Journey::Visitors::Formatter that builds route by given parameters
+  # from route binary tree.
+  # Binary tree is serialized in the following way:
+  # [node type, left node, right node ]
+  #
+  # @param  {Boolean} optional  Marks the currently visited branch as optional.
+  # If set to `true`, this method will not throw when encountering
+  # a missing parameter (used in recursive calls).
+  #
+  visit: (route, parameters, optional = false) ->
+    [type, left, right] = route
+    switch type
+      when NodeTypes.GROUP
+        @visit left, parameters, true
+      when NodeTypes.STAR
+        @visit_globbing left, parameters, true
+      when NodeTypes.LITERAL, NodeTypes.SLASH, NodeTypes.DOT
+        left
+      when NodeTypes.CAT
+        left_part = @visit(left, parameters, optional)
+        right_part = @visit(right, parameters, optional)
+        if optional and ((@is_optional_node(left[0]) and not left_part) or
+                                     ((@is_optional_node(right[0])) and not right_part))
+          return ""
+        "#{left_part}#{right_part}"
+      when NodeTypes.SYMBOL
+        value = parameters[left]
+        if value?
+          delete parameters[left]
+          return @path_identifier(value)
+        if optional
+          "" # missing parameter
+        else
+          throw new ParameterMissing("Route parameter missing: #{left}")
+      #
+      # I don't know what is this node type
+      # Please send your PR if you do
+      #
+      # when NodeTypes.OR:
+      else
+        throw new Error("Unknown Rails node type")
+
+
+  is_optional_node: (node) -> @indexOf([NodeTypes.STAR, NodeTypes.SYMBOL, NodeTypes.CAT], node) >= 0
+
+  #
+  # This method build spec for route
+  #
+  build_path_spec: (route, wildcard=false) ->
+    [type, left, right] = route
+    switch type
+      when NodeTypes.GROUP
+        "(#{@build_path_spec(left)})"
+      when NodeTypes.CAT
+        "#{@build_path_spec(left)}#{@build_path_spec(right)}"
+      when NodeTypes.STAR
+        @build_path_spec(left, true)
+      when NodeTypes.SYMBOL
+        if wildcard is true
+          "#{if left[0] is '*' then '' else '*'}#{left}"
+        else
+          ":#{left}"
+      when NodeTypes.SLASH, NodeTypes.DOT, NodeTypes.LITERAL
+        left
+      # Not sure about this one
+      # when NodeTypes.OR
+      else throw new Error("Unknown Rails node type")
+
+  #
+  # This method convert value for globbing in right value for rails route
+  #
+  visit_globbing: (route, parameters, optional) ->
+    [type, left, right] = route
+    # fix for rails 4 globbing
+    route[1] = left = left.replace(/^\*/i, "") if left.replace(/^\*/i, "") isnt left
+    value = parameters[left]
+    return @visit(route, parameters, optional) unless value?
+    parameters[left] = switch @get_object_type(value)
+      when "array"
+        value.join("/")
+      else
+        value
+    @visit route, parameters, optional
+
+  #
+  # This method check and return prefix from options
+  #
+  get_prefix: ->
+    prefix = defaults.prefix
+    prefix = (if prefix.match("/$") then prefix else "#{prefix}/") if prefix isnt ""
+    prefix
+
+  #
+  # route function: create route path function and add spec to it
+  #
+  route: (parts_table, default_options, route_spec, full_url) ->
+    required_parts = []
+    parts = []
+    for [part, required] in parts_table
+      parts.push(part)
+      required_parts.push(part) if required
+
+    path_fn = -> Utils.build_route(
+      parts, required_parts, default_options, route_spec, full_url, arguments
+    )
+    path_fn.required_params = required_parts
+    path_fn.toString = -> Utils.build_path_spec(route_spec)
+    path_fn
+
+
+  route_url: (route_defaults) ->
+    return route_defaults if typeof route_defaults == 'string'
+    protocol = route_defaults.protocol || Utils.current_protocol()
+    hostname = route_defaults.host || window.location.hostname
+    port = route_defaults.port || (Utils.current_port() unless route_defaults.host)
+    port = if port then ":#{port}" else ''
+
+    protocol + "://" + hostname + port
+
+
+  has_location: ->
+    typeof window != 'undefined' && typeof window.location != 'undefined'
+
+  current_host: ->
+    if @has_location() then window.location.hostname else null
+
+  current_protocol: () ->
+    if @has_location() && window.location.protocol != ''
+      # location.protocol includes the colon character
+      window.location.protocol.replace(/:$/, '')
+    else
+      'http'
+
+  current_port: () ->
+    if @has_location() && window.location.port != ''
+      window.location.port
+    else
+      ''
+
+  #
+  # This is helper method to define object type.
+  # The typeof operator is probably the biggest design flaw of JavaScript, simply because it's basically completely broken.
+  #
+  # Value               Class      Type
+  # -------------------------------------
+  # "foo"               String     string
+  # new String("foo")   String     object
+  # 1.2                 Number     number
+  # new Number(1.2)     Number     object
+  # true                Boolean    boolean
+  # new Boolean(true)   Boolean    object
+  # new Date()          Date       object
+  # new Error()         Error      object
+  # [1,2,3]             Array      object
+  # new Array(1, 2, 3)  Array      object
+  # new Function("")    Function   function
+  # /abc/g              RegExp     object
+  # new RegExp("meow")  RegExp     object
+  # {}                  Object     object
+  # new Object()        Object     object
+  #
+  # What is why I use Object.prototype.toString() to know better type of variable. Or use jQuery.type, if it available.
+  # _classToTypeCache used for perfomance cache of types map (underscore at the beginning mean private method - of course it doesn't realy private).
+  #
+  _classToTypeCache: null
+  _classToType: ->
+    return @_classToTypeCache if @_classToTypeCache?
+    @_classToTypeCache = {}
+    for name in "Boolean Number String Function Array Date RegExp Object Error".split(" ")
+      @_classToTypeCache["[object #{name}]"] = name.toLowerCase()
+    @_classToTypeCache
+  get_object_type: (obj) ->
+    return root.jQuery.type(obj) if root.jQuery and root.jQuery.type?
+    return "#{obj}" unless obj?
+    (if typeof obj is "object" or typeof obj is "function" then @_classToType()[Object::toString.call(obj)] or "object" else typeof obj)
+
+  # indexOf helper
+  indexOf: (array, element) -> if Array::indexOf then array.indexOf(element) else @indexOfImplementation(array, element)
+  indexOfImplementation: (array, element) ->
+    result = -1
+    (result = i for el, i in array when el is element)
+    result
+
+  namespace: (root, namespace, routes) ->
+    parts = namespace.split(".")
+    return routes if parts.length == 0
+    for part, index in parts
+      if index < parts.length - 1
+        root = (root[part] or= {})
+      else
+        return root[part] = routes
+
+  make: ->
+    routes = ROUTES
+    routes.options = defaults
+    routes.default_serializer = (object, prefix) ->
+      Utils.default_serializer(object, prefix)
+    Utils.namespace(root, NAMESPACE, routes)
+  
+# Set up Routes appropriately for the environment.
+if typeof define is "function" and define.amd
+  # AMD
+  define [], -> Utils.make()
+else
+  # Browser globals
+  Utils.make()

data/lib/tasks/js_routes.rake

@@ -0,0 +1,8 @@
+namespace :js do
+  desc "Make a js file that will have functions that will return restful routes/urls."
+  task routes: :environment do
+    require "js-routes"
+
+    JsRoutes.generate!
+  end
+end

data/spec/dummy/config/routes.rb

@@ -0,0 +1,55 @@
+App.routes.draw do
+  resource "3df1b2d050ae5a96eac8565c9daef37a"
+  resource "341f9e69e3db1c344de2fc6551885711"
+  resource "0e1bcb2dc1ce4d80ec15cae9140fb99a"
+  resource "15b91c612530bfc69c70d121c8713da4"
+  resource "49e12936168a64dce4d4ec148104fb5a"
+  resource "d878104611f88952aba49965c1d2d573"
+  resource "0e94bfc3c8aaee5ea09579fe73cbdaff"
+  resource "e1c2dd2ea9c63b380eb0947a0e1f49aa"
+  resource "587c6e26ad7f9a6aa09f81add77b16f5"
+  resource "8e00bfffebe0c874d6dad1c7b8c7cd6b"
+  resource "394482d3515e7e49989a8496afa7d367"
+  resource "4ab9c701622cba87eae50795564abe1c"
+  resource "af4b4a2ea501fefbdb8367eb108b2e14"
+  resource "116d17a93932a9a3e5bd2750665582f9"
+  resource "315f0a62063288cd56373c8a00870596"
+  resource "d5357ec6df4589f81ca8689cf0231667"
+  resource "560a3b8cf807e873843cd889400cd52b"
+  resource "361de6041f545e67db1aeaa6206c8ac7"
+  resource "28b0a54de4a0884386f1e324edc13194"
+  resource "ab77f21a956d956295187806cdf38cd1"
+  resource "0b8a362fd486247fb7c41898709b9815"
+  resource "5efa0a96733bc027b3309ffb54d1d1d0"
+  resource "70a3ee535c59fcf59c58b6d39178833c"
+  resource "5095fc05868c673ce450524f78cd28d3"
+  resource "79b994cfbc79432d644a3b83804f4924"
+  resource "e25125c477cd451fd74a76eaaebc9165"
+  resource "672fbfb432687e2fee7d0e799cc10ea4"
+  resource "2eb8350243305659082eb92b2e5b702c"
+  resource "08c9973b624e10b10dc7235659c81346"
+  resource "fee0d4b123529a2c652bef0ec0116ef2"
+  resource "8422445d2aa176b7733473164c461a2e"
+  resource "c24b8252b235431ca3df21a6ac119062"
+  resource "c08c66c7fc40e9937ff84a86f6c6d18a"
+  resource "964851acca72064d861188150e848d55"
+  resource "d02927a4fd37b37c03dbad5d3c7a4753"
+  resource "2a69df680ff9bd8d3855d9ce5a4e51f7"
+  resource "d8daed677f9a9a6926005afbdeebcf73"
+  resource "83d4db872f5f148e9ead108d483fec78"
+  resource "09f9fb4250595d26f4149b76fcfa957d"
+  resource "956cdb4d3cbf36bb9ccb7c7fcc36a602"
+  resource "02816449a6c929f55f8bad958f25d25a"
+  resource "2dd7ae38bd72f7e8b26aafb5f002d634"
+  resource "c7c9aaa3f7131f1e7dbc9325b3426d3e"
+  resource "7556e7d17c2a26acbad7d5fa86e6e640"
+  resource "d03081ef427a227a808c708282fdc86b"
+  resource "8f610d21e6e499c1eea98ca08191c05f"
+  resource "b6b412ae8a369f6bfc7f312245eacc8c"
+  resource "e9bcda8b00879c49bd7f05afee59a28e"
+  resource "6e89f4baddd4044b42be7c2d3b382567"
+  resource "5959c376d15a609f2e74f4f351d0a565"
+  resource "3b7e418511c305c78f2d2c292a3a1289"
+  resource "87acf6bf6e8191ff8900f420b33d5268"
+  resource "648a9b17078423f29f42aa2ecac1cc7d"
+end

data/spec/js_routes/amd_compatibility_spec.rb

@@ -0,0 +1,42 @@
+require "spec_helper"
+
+describe JsRoutes, "compatibility with AMD/require.js"  do
+
+  before(:each) do
+    evaljs("window.GlobalCheck = {};")
+    evaljs("window.define = function (requirs, callback) { window.GlobalCheck['js-routes'] = callback.call(this); return window.GlobalCheck['js-routes']; };")
+    evaljs("window.define.amd = { jQuery: true };")
+    strRequire =<<EOF
+    window.require = function (r, callback) {
+      var allArgs, i;
+
+      allArgs = (function() {
+        var _i, _len, _results;
+        _results = [];
+        for (_i = 0, _len = r.length; _i < _len; _i++) {
+          i = r[_i];
+          _results.push(window.GlobalCheck[i]);
+        }
+        return _results;
+      })();
+
+      return callback.apply(null, allArgs);
+    };
+EOF
+    evaljs(strRequire)
+    evaljs(JsRoutes.generate({}))
+  end
+
+  it "should working from global scope" do
+    expect(evaljs("Routes.inboxes_path()")).to eq(routes.inboxes_path())
+  end
+
+  it "should working from define function" do
+    expect(evaljs("Routes.inboxes_path()")).to eq(evaljs("GlobalCheck['js-routes'].inboxes_path()"))
+  end
+
+  it "should working from require" do
+    expect(evaljs("require(['js-routes'], function(r){ return r.inboxes_path(); })")).to eq(routes.inboxes_path())
+  end
+
+end