jquery_payment 0.0.2

checksums.yaml

@@ -0,0 +1,7 @@
+---
+SHA1:
+  metadata.gz: bbe943b4869a023e4fba27d4668edec3330d5e98
+  data.tar.gz: 6f73bb991dd38e166dbe948840549d71459216eb
+SHA512:
+  metadata.gz: ce56e8553f93bb46ae0028af09b8707a1cd9d9018fed95abefaae3bf733059ae8ba22024d3b5b0cb6e7da2186cdc3234da75312d1c99dfc12327b89486b4992f
+  data.tar.gz: b2ae9ae6513af5ed06f5a9e914e32bab9959ae558d423baceb11e85b584ca501acf47a2628e153f72aec40e5f8fa83b1e1d8ab7bfa899ab304d491a915aac6d5

data/.gitignore

@@ -0,0 +1,18 @@
+*.gem
+*.rbc
+.bundle
+.config
+.yardoc
+Gemfile.lock
+InstalledFiles
+_yardoc
+coverage
+doc/
+lib/bundler/man
+pkg
+rdoc
+spec/reports
+test/tmp
+test/version_tmp
+tmp
+.DS_Store

data/Gemfile

@@ -0,0 +1,4 @@
+source 'https://rubygems.org'
+
+# Specify your gem's dependencies in jquery_payment.gemspec
+gemspec

data/LICENSE

@@ -0,0 +1,20 @@
+The MIT License (MIT)
+
+Copyright (c) 2013 Victor
+
+Permission is hereby granted, free of charge, to any person obtaining a copy of
+this software and associated documentation files (the "Software"), to deal in
+the Software without restriction, including without limitation the rights to
+use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
+the Software, and to permit persons to whom the Software is furnished to do so,
+subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
+FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
+COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
+IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
+CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

data/README.md

@@ -0,0 +1,29 @@
+# JqueryPayment
+
+This is a gem wrapper for [jquery.payment](https://github.com/stripe/jquery.payment)
+
+## Installation
+
+Add this line to your application's Gemfile:
+
+    gem 'jquery_payment'
+
+And then execute:
+
+    $ bundle
+
+Or install it yourself as:
+
+    $ gem install jquery_payment
+
+## Usage
+
+
+
+## Contributing
+
+1. Fork it
+2. Create your feature branch (`git checkout -b my-new-feature`)
+3. Commit your changes (`git commit -am 'Add some feature'`)
+4. Push to the branch (`git push origin my-new-feature`)
+5. Create new Pull Request

data/Rakefile

@@ -0,0 +1 @@
+require "bundler/gem_tasks"

data/jquery_payment.gemspec

@@ -0,0 +1,26 @@
+# coding: utf-8
+lib = File.expand_path('../lib', __FILE__)
+$LOAD_PATH.unshift(lib) unless $LOAD_PATH.include?(lib)
+require 'jquery_payment/version'
+
+Gem::Specification.new do |spec|
+  spec.name          = "jquery_payment"
+  spec.version       = JqueryPayment::VERSION
+  spec.authors       = ["ampvchen"]
+  spec.email         = ["self@vchen.me"]
+  spec.description   = %q{jquery.payments gem wrapper}
+  spec.summary       = %q{jquery.payments gem wrapper}
+  spec.homepage      = ""
+  spec.license       = "MIT"
+
+  spec.files         = `git ls-files`.split($/)
+  spec.executables   = spec.files.grep(%r{^bin/}) { |f| File.basename(f) }
+  spec.test_files    = spec.files.grep(%r{^(test|spec|features)/})
+  spec.require_paths = ["lib"]
+
+  spec.add_development_dependency "bundler", "~> 1.3"
+  spec.add_development_dependency "rake"
+
+  # coffee-script
+  spec.add_dependency "coffee-script"
+end

data/lib/jquery_payment/version.rb

@@ -0,0 +1,3 @@
+module JqueryPayment
+  VERSION = "0.0.2"
+end

data/lib/jquery_payment.rb

@@ -0,0 +1,8 @@
+require "jquery_payment/version"
+
+module JqueryPayment
+  module Rails
+  	class Engine < ::Rails::Engine
+  	end
+  end
+end

data/vendor/assets/javascript/jquery.payment.coffee

@@ -0,0 +1,439 @@
+$            = jQuery
+$.payment    = {}
+$.payment.fn = {}
+$.fn.payment = (method, args...) ->
+  $.payment.fn[method].apply(this, args)
+
+# Utils
+
+defaultFormat = /(\d{1,4})/g
+
+cards = [
+  {
+      type: 'maestro'
+      pattern: /^(5018|5020|5038|6304|6759|676[1-3])/
+      format: defaultFormat
+      length: [12..19]
+      cvcLength: [3]
+      luhn: true
+  }
+  {
+      type: 'dinersclub'
+      pattern: /^(36|38|30[0-5])/
+      format: defaultFormat
+      length: [14]
+      cvcLength: [3]
+      luhn: true
+  }
+  {
+      type: 'laser'
+      pattern: /^(6706|6771|6709)/
+      format: defaultFormat
+      length: [16..19]
+      cvcLength: [3]
+      luhn: true
+  }
+  {
+      type: 'jcb'
+      pattern: /^35/
+      format: defaultFormat
+      length: [16]
+      cvcLength: [3]
+      luhn: true
+  }
+  {
+      type: 'unionpay'
+      pattern: /^62/
+      format: defaultFormat
+      length: [16..19]
+      cvcLength: [3]
+      luhn: false
+  }
+  {
+      type: 'discover'
+      pattern: /^(6011|65|64[4-9]|622)/
+      format: defaultFormat
+      length: [16]
+      cvcLength: [3]
+      luhn: true
+  }
+  {
+      type: 'mastercard'
+      pattern: /^5[1-5]/
+      format: defaultFormat
+      length: [16]
+      cvcLength: [3]
+      luhn: true
+  }
+  {
+      type: 'amex'
+      pattern: /^3[47]/
+      format: /(\d{1,4})(\d{1,6})?(\d{1,5})?/
+      length: [15]
+      cvcLength: [3..4]
+      luhn: true
+  }
+  {
+      type: 'visa'
+      pattern: /^4/
+      format: defaultFormat
+      length: [13..16]
+      cvcLength: [3]
+      luhn: true
+  }
+]
+
+cardFromNumber = (num) ->
+  num = (num + '').replace(/\D/g, '')
+  return card for card in cards when card.pattern.test(num)
+
+cardFromType = (type) ->
+  return card for card in cards when card.type is type
+
+luhnCheck = (num) ->
+  odd = true
+  sum = 0
+
+  digits = (num + '').split('').reverse()
+
+  for digit in digits
+    digit = parseInt(digit, 10)
+    digit *= 2 if (odd = !odd)
+    digit -= 9 if digit > 9
+    sum += digit
+
+  sum % 10 == 0
+
+hasTextSelected = ($target) ->
+  # If some text is selected
+  return true if $target.prop('selectionStart')? and
+    $target.prop('selectionStart') isnt $target.prop('selectionEnd')
+
+  # If some text is selected in IE
+  return true if document?.selection?.createRange?().text
+
+  false
+
+# Private
+
+# Format Card Number
+
+reFormatCardNumber = (e) ->
+  setTimeout =>
+    $target = $(e.currentTarget)
+    value   = $target.val()
+    value   = $.payment.formatCardNumber(value)
+    $target.val(value)
+
+formatCardNumber = (e) ->
+  # Only format if input is a number
+  digit = String.fromCharCode(e.which)
+  return unless /^\d+$/.test(digit)
+
+  $target = $(e.currentTarget)
+  value   = $target.val()
+  card    = cardFromNumber(value + digit)
+  length  = (value.replace(/\D/g, '') + digit).length
+
+  upperLength = 16
+  upperLength = card.length[card.length.length - 1] if card
+  return if length >= upperLength
+
+  # Return if focus isn't at the end of the text
+  return if $target.prop('selectionStart')? and
+    $target.prop('selectionStart') isnt value.length
+
+  if card && card.type is 'amex'
+    # Amex cards are formatted differently
+    re = /^(\d{4}|\d{4}\s\d{6})$/
+  else
+    re = /(?:^|\s)(\d{4})$/
+
+  # If '4242' + 4
+  if re.test(value)
+    e.preventDefault()
+    $target.val(value + ' ' + digit)
+
+  # If '424' + 2
+  else if re.test(value + digit)
+    e.preventDefault()
+    $target.val(value + digit + ' ')
+
+formatBackCardNumber = (e) ->
+  $target = $(e.currentTarget)
+  value   = $target.val()
+
+  return if e.meta
+
+  # Return unless backspacing
+  return unless e.which is 8
+
+  # Return if focus isn't at the end of the text
+  return if $target.prop('selectionStart')? and
+    $target.prop('selectionStart') isnt value.length
+
+  # Remove the trailing space
+  if /\d\s$/.test(value)
+    e.preventDefault()
+    $target.val(value.replace(/\d\s$/, ''))
+  else if /\s\d?$/.test(value)
+    e.preventDefault()
+    $target.val(value.replace(/\s\d?$/, ''))
+
+# Format Expiry
+
+formatExpiry = (e) ->
+  # Only format if input is a number
+  digit = String.fromCharCode(e.which)
+  return unless /^\d+$/.test(digit)
+
+  $target = $(e.currentTarget)
+  val     = $target.val() + digit
+
+  if /^\d$/.test(val) and val not in ['0', '1']
+    e.preventDefault()
+    $target.val("0#{val} / ")
+
+  else if /^\d\d$/.test(val)
+    e.preventDefault()
+    $target.val("#{val} / ")
+
+formatForwardExpiry = (e) ->
+  digit = String.fromCharCode(e.which)
+  return unless /^\d+$/.test(digit)
+
+  $target = $(e.currentTarget)
+  val     = $target.val()
+
+  if /^\d\d$/.test(val)
+    $target.val("#{val} / ")
+
+formatForwardSlash = (e) ->
+  slash = String.fromCharCode(e.which)
+  return unless slash is '/'
+
+  $target = $(e.currentTarget)
+  val     = $target.val()
+
+  if /^\d$/.test(val) and val isnt '0'
+    $target.val("0#{val} / ")
+
+formatBackExpiry = (e) ->
+  # If shift+backspace is pressed
+  return if e.meta
+
+  $target = $(e.currentTarget)
+  value   = $target.val()
+
+  # Return unless backspacing
+  return unless e.which is 8
+
+  # Return if focus isn't at the end of the text
+  return if $target.prop('selectionStart')? and
+    $target.prop('selectionStart') isnt value.length
+
+  # Remove the trailing space
+  if /\d(\s|\/)+$/.test(value)
+    e.preventDefault()
+    $target.val(value.replace(/\d(\s|\/)*$/, ''))
+  else if /\s\/\s?\d?$/.test(value)
+    e.preventDefault()
+    $target.val(value.replace(/\s\/\s?\d?$/, ''))
+
+#  Restrictions
+
+restrictNumeric = (e) ->
+  # Key event is for a browser shortcut
+  return true if e.metaKey or e.ctrlKey
+
+  # If keycode is a space
+  return false if e.which is 32
+
+  # If keycode is a special char (WebKit)
+  return true if e.which is 0
+
+  # If char is a special char (Firefox)
+  return true if e.which < 33
+
+  input = String.fromCharCode(e.which)
+
+  # Char is a number or a space
+  !!/[\d\s]/.test(input)
+
+restrictCardNumber = (e) ->
+  $target = $(e.currentTarget)
+  digit   = String.fromCharCode(e.which)
+  return unless /^\d+$/.test(digit)
+
+  return if hasTextSelected($target)
+
+  # Restrict number of digits
+  value = ($target.val() + digit).replace(/\D/g, '')
+  card  = cardFromNumber(value)
+
+  if card
+    value.length <= card.length[card.length.length - 1]
+  else
+    # All other cards are 16 digits long
+    value.length <= 16
+
+restrictExpiry = (e) ->
+  $target = $(e.currentTarget)
+  digit   = String.fromCharCode(e.which)
+  return unless /^\d+$/.test(digit)
+
+  return if hasTextSelected($target)
+
+  value = $target.val() + digit
+  value = value.replace(/\D/g, '')
+
+  return false if value.length > 6
+
+restrictCVC = (e) ->
+  $target = $(e.currentTarget)
+  digit   = String.fromCharCode(e.which)
+  return unless /^\d+$/.test(digit)
+
+  val     = $target.val() + digit
+  val.length <= 4
+
+setCardType = (e) ->
+  $target  = $(e.currentTarget)
+  val      = $target.val()
+  cardType = $.payment.cardType(val) or 'unknown'
+
+  unless $target.hasClass(cardType)
+    allTypes = (card.type for card in cards)
+
+    $target.removeClass('unknown')
+    $target.removeClass(allTypes.join(' '))
+
+    $target.addClass(cardType)
+    $target.toggleClass('identified', cardType isnt 'unknown')
+    $target.trigger('payment.cardType', cardType)
+
+# Public
+
+# Formatting
+
+$.payment.fn.formatCardCVC = ->
+  @payment('restrictNumeric')
+  @on('keypress', restrictCVC)
+  this
+
+$.payment.fn.formatCardExpiry = ->
+  @payment('restrictNumeric')
+  @on('keypress', restrictExpiry)
+  @on('keypress', formatExpiry)
+  @on('keypress', formatForwardSlash)
+  @on('keypress', formatForwardExpiry)
+  @on('keydown',  formatBackExpiry)
+  this
+
+$.payment.fn.formatCardNumber = ->
+  @payment('restrictNumeric')
+  @on('keypress', restrictCardNumber)
+  @on('keypress', formatCardNumber)
+  @on('keydown', formatBackCardNumber)
+  @on('keyup', setCardType)
+  @on('paste', reFormatCardNumber)
+  this
+
+# Restrictions
+
+$.payment.fn.restrictNumeric = ->
+  @on('keypress', restrictNumeric)
+  this
+
+# Validations
+
+$.payment.fn.cardExpiryVal = ->
+  $.payment.cardExpiryVal($(this).val())
+
+$.payment.cardExpiryVal = (value) ->
+  value = value.replace(/\s/g, '')
+  [month, year] = value.split('/', 2)
+
+  # Allow for year shortcut
+  if year?.length is 2 and /^\d+$/.test(year)
+    prefix = (new Date).getFullYear()
+    prefix = prefix.toString()[0..1]
+    year   = prefix + year
+
+  month = parseInt(month, 10)
+  year  = parseInt(year, 10)
+
+  month: month, year: year
+
+$.payment.validateCardNumber = (num) ->
+  num = (num + '').replace(/\s+|-/g, '')
+  return false unless /^\d+$/.test(num)
+
+  card = cardFromNumber(num)
+  return false unless card
+
+  num.length in card.length and
+    (card.luhn is false or luhnCheck(num))
+
+$.payment.validateCardExpiry = (month, year) =>
+  # Allow passing an object
+  if typeof month is 'object' and 'month' of month
+    {month, year} = month
+
+  return false unless month and year
+
+  month = $.trim(month)
+  year  = $.trim(year)
+
+  return false unless /^\d+$/.test(month)
+  return false unless /^\d+$/.test(year)
+  return false unless parseInt(month, 10) <= 12
+
+  if year.length is 2
+    prefix = (new Date).getFullYear()
+    prefix = prefix.toString()[0..1]
+    year   = prefix + year
+
+  expiry      = new Date(year, month)
+  currentTime = new Date
+
+  # Months start from 0 in JavaScript
+  expiry.setMonth(expiry.getMonth() - 1)
+
+  # The cc expires at the end of the month,
+  # so we need to make the expiry the first day
+  # of the month after
+  expiry.setMonth(expiry.getMonth() + 1, 1)
+
+  expiry > currentTime
+
+$.payment.validateCardCVC = (cvc, type) ->
+  cvc = $.trim(cvc)
+  return false unless /^\d+$/.test(cvc)
+
+  if type
+    # Check against a explicit card type
+    cvc.length in cardFromType(type)?.cvcLength
+  else
+    # Check against all types
+    cvc.length >= 3 and cvc.length <= 4
+
+$.payment.cardType = (num) ->
+  return null unless num
+  cardFromNumber(num)?.type or null
+
+$.payment.formatCardNumber = (num) ->
+  card = cardFromNumber(num)
+  return num unless card
+
+  upperLength = card.length[card.length.length - 1]
+
+  num = num.replace(/\D/g, '')
+  num = num[0..upperLength]
+
+  if card.format.global
+    num.match(card.format)?.join(' ')
+  else
+    groups = card.format.exec(num)
+    groups?.shift()
+    groups?.join(' ')

metadata

@@ -0,0 +1,95 @@
+--- !ruby/object:Gem::Specification
+name: jquery_payment
+version: !ruby/object:Gem::Version
+  version: 0.0.2
+platform: ruby
+authors:
+- ampvchen
+autorequire: 
+bindir: bin
+cert_chain: []
+date: 2013-10-22 00:00:00.000000000 Z
+dependencies:
+- !ruby/object:Gem::Dependency
+  name: bundler
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '1.3'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '1.3'
+- !ruby/object:Gem::Dependency
+  name: rake
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+- !ruby/object:Gem::Dependency
+  name: coffee-script
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :runtime
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+description: jquery.payments gem wrapper
+email:
+- self@vchen.me
+executables: []
+extensions: []
+extra_rdoc_files: []
+files:
+- .gitignore
+- Gemfile
+- LICENSE
+- README.md
+- Rakefile
+- jquery_payment.gemspec
+- lib/jquery_payment.rb
+- lib/jquery_payment/version.rb
+- vendor/assets/javascript/jquery.payment.coffee
+homepage: ''
+licenses:
+- MIT
+metadata: {}
+post_install_message: 
+rdoc_options: []
+require_paths:
+- lib
+required_ruby_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+required_rubygems_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+requirements: []
+rubyforge_project: 
+rubygems_version: 2.0.6
+signing_key: 
+specification_version: 4
+summary: jquery.payments gem wrapper
+test_files: []