joosy 0.1.0.alpha → 1.0.0.RC1

data/app/assets/javascripts/joosy/core/resource/rest.js.coffee

@@ -0,0 +1,244 @@
+#
+# Resource with REST/JSON backend
+#
+class Joosy.Resource.REST extends Joosy.Resource.Generic
+
+  #
+  # Implements `@collection` default behavior.
+  # Changes the default fallback to Joosy.Resource.RESTCollection.
+  #
+  __collection: ->
+    named = @__entityName.camelize().pluralize() + 'Collection'
+    if window[named] then window[named] else Joosy.Resource.RESTCollection
+
+  #
+  # Builds member path based on the given id.
+  #
+  # @param [String] id          ID of entity to build member path for
+  # @param [Hash] options       See {Joosy.Resource.REST.find} for possible options
+  #
+  # @example Basic usage
+  #   Resource.memberPath(1, from: 'foo') # /resources/1/foo
+  #
+  @memberPath: (id, options={}) ->
+    path  = ("/" + @::__entityName.pluralize())
+    path  = @__source if @__source? && !options.parent?
+    path += "/#{id}"
+
+    if options.parent instanceof Joosy.Resource.Generic
+      path = options.parent.memberPath() + path
+    else if options.parent?
+      path = options.parent + path
+
+    path += "/#{options.from}" if options.from?
+    path
+
+  #
+  # Builds member path
+  #
+  # @param [Hash] options       See {Joosy.Resource.REST.find} for possible options
+  #
+  # @example Basic usage
+  #   resource.memberPath(from: 'foo') # /resources/1/foo
+  #
+  memberPath: (options={}) ->
+    @constructor.memberPath @id(), options
+
+  #
+  # Builds collection path
+  #
+  # @param [Hash] options       See {Joosy.Resource.REST.find} for possible options
+  #
+  # @example Basic usage
+  #   Resource.collectionPath() # /resources/
+  #
+  @collectionPath: (options={}) ->
+    path = ("/" + @::__entityName.pluralize())
+    path = @__source if @__source? && !options.parent?
+
+    if options.parent instanceof Joosy.Resource.Generic
+      path = options.parent.memberPath() + path
+    else if options.parent?
+      path = options.parent + path
+
+    path += "/#{options.from}" if options.from?
+    path
+
+  #
+  # Builds collection path
+  #
+  # @see Joosy.Resource.REST.collectionPath
+  #
+  collectionPath: ->
+    @constructor.collectionPath()
+
+  #
+  # Sends the GET query using collectionPath.
+  # Callback will get parsed JSON object as a parameter.
+  #
+  # @param [Hash] options         Options to proxy to collectionPath
+  # @param [Function] callback    Resulting callback
+  #
+  @get: (options, callback) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+    @__query @collectionPath(options), 'GET', options.params, callback
+
+  #
+  # Sends the POST query using collectionPath.
+  # Callback will get parsed JSON object as a parameter.
+  #
+  # @param [Hash] options         Options to proxy to collectionPath
+  # @param [Function] callback    Resulting callback
+  #
+  @post: (options, callback) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+    @__query @collectionPath(options), 'POST', options.params, callback
+
+  #
+  # Sends the PUT query using collectionPath.
+  # Callback will get parsed JSON object as a parameter.
+  #
+  # @param [Hash] options         Options to proxy to collectionPath
+  # @param [Function] callback    Resulting callback
+  #
+  @put: (options, callback) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+    @__query @collectionPath(options), 'PUT', options.params, callback
+
+  #
+  # Sends the DELETE query using collectionPath.
+  # Callback will get parsed JSON object as a parameter.
+  #
+  # @param [Hash] options         Options to proxy to collectionPath
+  # @param [Function] callback    Resulting callback
+  #
+  @delete: (options, callback) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+    @__query @collectionPath(options), 'DELETE', options.params, callback
+
+  #
+  # Sends the GET query using memberPath.
+  # Callback will get parsed JSON object as a parameter.
+  #
+  # @param [Hash] options         Options to proxy to memberPath
+  # @param [Function] callback    Resulting callback
+  #
+  get: (options, callback) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+    @constructor.__query @memberPath(options), 'GET', options.params, callback
+
+  #
+  # Sends the POST query using memberPath.
+  # Callback will get parsed JSON object as a parameter.
+  #
+  # @param [Hash] options         Options to proxy to memberPath
+  # @param [Function] callback    Resulting callback
+  #
+  post: (options, callback) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+    @constructor.__query @memberPath(options), 'POST', options.params, callback
+
+  #
+  # Sends the PUT query using memberPath.
+  # Callback will get parsed JSON object as a parameter.
+  #
+  # @param [Hash] options         Options to proxy to memberPath
+  # @param [Function] callback    Resulting callback
+  #
+  put: (options, callback) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+    @constructor.__query @memberPath(options), 'PUT', options.params, callback
+
+  #
+  # Sends the DELETE query using memberPath.
+  # Callback will get parsed JSON object as a parameter.
+  #
+  # @param [Hash] options         Options to proxy to memberPath
+  # @param [Function] callback    Resulting callback
+  #
+  delete: (options, callback) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+    @constructor.__query @memberPath(options), 'DELETE', options.params, callback
+
+  #
+  # Requests the required resources from backend
+  #
+  # @param [String] where         Possible values: 'all', id.
+  #   'all' will query for collection from collectionPath.
+  #   Everything else will be considered as an id string and will make resource 
+  #   query for single instance from memberPath.
+  # @param [Hash] options         Path modification options
+  # @param [Function] callback    Resulting callback 
+  #   (will receive retrieved Collection/Resource)
+  #
+  # @option options [Joosy.Resource.REST] parent            Sets the given resource as a base path
+  #   i.e. /parents/1/resources
+  # @option options [String] parent                         Sets the given staring as a base path
+  #   i.e. /trololo/resources
+  # @option options [String] from                           Adds the given string as a last path element
+  #   i.e. /resources/trololo
+  # @option options [Hash] params                           Passes the given params to the query
+  #
+  @find: (where, options={}, callback=false) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+
+    if where == 'all'
+      result = new (@::__collection()) this, options
+
+      @__query @collectionPath(options), 'GET', options.params, (data) =>
+        result.load data
+        callback?(result)
+    else
+      result = @build where
+      @__query @memberPath(where, options), 'GET', options.params, (data) =>
+        result.load data
+        callback?(result)
+
+    result
+
+  @__query: (path, method, params, callback) ->
+    options =
+      data: params
+      type: method
+      cache: false
+      dataType: 'json'
+
+    if Object.isFunction(callback)
+      options.success = callback
+    else
+      Joosy.Module.merge options, callback
+
+    $.ajax path, options
+
+  #
+  # Refetches the data from backend and triggers `changed`
+  #
+  # @param [Hash] options         See {Joosy.Resource.REST.find} for possible options
+  # @param [Function] callback    Resulting callback 
+  #
+  reload: (options={}, callback=false) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+
+    @constructor.__query @memberPath(options), 'GET', options.params, (data) =>
+      @load data
+      callback? this

data/app/assets/javascripts/joosy/core/resource/rest_collection.js.coffee

@@ -0,0 +1,24 @@
+#
+# Collection of REST Resources
+#
+# @include Joosy.Modules.Log
+# @include Joosy.Modules.Events
+#
+class Joosy.Resource.RESTCollection extends Joosy.Resource.Collection
+  @include Joosy.Modules.Log
+  @include Joosy.Modules.Events
+
+  #
+  # Refetches the data from backend and triggers `changed`
+  #
+  # @param [Hash] options         See {Joosy.Resource.REST.find} for possible options
+  # @param [Function] callback    Resulting callback 
+  #
+  reload: (options={}, callback=false) ->
+    if Object.isFunction(options)
+      callback = options
+      options  = {}
+
+    @model.__query @model.collectionPath(options), 'GET', options.params, (data) =>
+      @load data
+      callback?(data)

data/app/assets/javascripts/joosy/core/router.js.coffee

@@ -0,0 +1,201 @@
+#= require joosy/core/joosy
+
+#
+# Router. Reacts on a hash change event and loads proper pages
+#
+# Example:
+#   Joosy.Router.map
+#     404             : (path) -> alert "Page '#{path}' was not found :("
+#     '/'             : Welcome.IndexPage
+#     '/resources'    :
+#     '/'           : Resource.IndexPage
+#     '/:id'        : Resource.ShowPage
+#     '/:id/edit'   : Resource.EditPage
+#     '/new'        : Resource.EditPage
+#
+# @mixin
+#
+Joosy.Router =
+  #
+  # The Object containing route parts in keys and pages/lambdas in values
+  #
+  rawRoutes: Object.extended()
+
+  #
+  # Flattern routes mapped to regexps (to check if current route is what we
+  # need) and actual executors
+  #
+  routes: Object.extended()
+
+  #
+  # The regexp to restrict the next loading url. By default set to false and
+  # therefore no restrictions apply.
+  #
+  restrictPattern: false
+
+  #
+  # Set the restriction pattern. If the requested url does not match this it
+  # will not load. Set `false` to avoid check.
+  #
+  restrict: (@restrictPattern) ->
+
+  #
+  # Clears the routes
+  #
+  reset: ->
+    @rawRoutes = Object.extended()
+    @routes = Object.extended()
+
+  #
+  # Registers the set of raw routes
+  # This method will only store routes and will not make them act immediately
+  # Routes get registered only once at system initialization during #__setupRoutes call
+  #
+  # @param [Object] routes        Set of routes in inner format (see class description)
+  #
+  map: (routes) ->
+    Joosy.Module.merge @rawRoutes, routes
+
+  #
+  # Changes current hash with shebang (#!) and therefore triggers new route loading
+  # to be loaded
+  #
+  # @param [String] to                       Route to navigate to
+  #
+  # @option options [Boolean] respond        If false just changes hash without responding
+  # @option options [Boolean] replaceState   If true uses replaces history entry instead of adding. Works only in browsers supporting history.pushState
+  #
+  navigate: (to, options={}) ->
+    path = to.replace /^\#?\!?/, '!'
+    if options.respond != false
+      location.hash = path
+    else
+      if !history.pushState
+        @__ignoreRequest = to
+        location.hash = path
+        setTimeout =>
+          @__ignoreRequest = false
+        , 2 # jQuery.hashchange checks hash changing every 1ms
+      else
+        history[if options.replaceState then 'replaceState' else 'pushState'] {}, '', '#'+path
+
+  #
+  # Inits the routing system and loads the current route
+  # Binds the window hashchange event and therefore should only be called once
+  # during system startup
+  #
+  __setupRoutes: ->
+    @__prepareRoutes @rawRoutes
+    @__respondRoute location.hash
+    $(window).hashchange =>
+      @__respondRoute location.hash unless @__ignoreRequest && location.hash.match(@__ignoreRequest)
+
+  #
+  # Compiles routes to map object
+  # Object will contain regexp string as key and lambda/Page to load as value
+  #
+  # @param [Object] routes        Raw routes to prepare
+  # @param [String] namespace     Inner cursor for recursion
+  #
+  __prepareRoutes: (routes, namespace='') ->
+    if !namespace && routes[404]
+      @wildcardAction = routes[404]
+      delete routes[404]
+
+    Object.each routes, (path, response) =>
+      path = (namespace + path).replace /\/{2,}/, '/'
+      if response && (Object.isFunction(response) || response.prototype?)
+        Joosy.Module.merge @routes, @__prepareRoute(path, response)
+      else
+        @__prepareRoutes response, path
+
+  #
+  # Compiles one single route
+  #
+  # @param [String] path            Full path from raw route
+  # @param [Joosy.Page] response    Page that should be loaded at this route
+  # @param [Function] response      Lambda to call at this route
+  #
+  __prepareRoute: (path, response) ->
+    matchPath = path.replace(/\/:([^\/]+)/g, '/([^/]+)').replace(/^\/?/, '^/?').replace(/\/?$/, '/?$')
+    result    = Object.extended()
+
+    result[matchPath] =
+      capture: (path.match(/\/:[^\/]+/g) || []).map (str) ->
+        str.substr 2
+      action: response
+    result
+
+  #
+  # Searches the corresponding route through compiled routes
+  #
+  # @param [String] hash        Hash value to search route for
+  #
+  __respondRoute: (hash) ->
+    Joosy.Modules.Log.debug "Router> Answering '#{hash}'"
+    fullPath = hash.replace /^#!?/, ''
+
+    if (@restrictPattern && fullPath.match(@restrictPattern) == null)
+      @trigger 'restricted', fullPath
+      return
+    else
+      @trigger 'responded', fullPath
+
+    @currentPath = fullPath
+    found = false
+    queryArray = fullPath.split '&'
+    path       = queryArray.shift()
+    urlParams  = @__paramsFromQueryArray queryArray
+
+    for regex, route of @routes when @routes.hasOwnProperty regex
+      if vals = path.match new RegExp(regex)
+        params = @__paramsFromRouteMatch(vals, route).merge urlParams
+
+        if Joosy.Module.hasAncestor route.action, Joosy.Page
+          Joosy.Application.setCurrentPage route.action, params
+        else
+          route.action.call this, params
+
+        found = true
+        break
+
+    if !found && @wildcardAction?
+      if Joosy.Module.hasAncestor @wildcardAction, Joosy.Page
+        Joosy.Application.setCurrentPage @wildcardAction, urlParams
+      else
+        @wildcardAction path, urlParams
+
+  #
+  # Collects params from route placeholders (/foo/:placeholder)
+  #
+  # @param [Array] vals         Array of value gathered by regexp
+  # @param [Object] route       Compiled route
+  # @returns [Object]           Hash of params
+  #
+  __paramsFromRouteMatch: (vals, route) ->
+    params = Object.extended()
+
+    vals.shift()
+    for param in route.capture
+      params[param] = vals.shift()
+
+    params
+
+  #
+  # Collects params from query routes (/foo/&a=b)
+  #
+  # @param [Array] queryArray   Array of query string split by '&' sign
+  # @returns [Object]           Hash of params
+  #
+  __paramsFromQueryArray: (queryArray) ->
+    params = Object.extended()
+
+    if queryArray
+      $.each queryArray, ->
+        unless @isBlank()
+          pair = @split '='
+          params[pair[0]] = pair[1]
+
+    params
+
+Joosy.Module.merge Joosy.Router, Joosy.Modules.Events

data/app/assets/javascripts/joosy/core/templaters/rails_jst.js.coffee

@@ -0,0 +1,37 @@
+#= require joosy/core/joosy
+
+#
+# Rails JST template precompilation binding
+#
+class Joosy.Templaters.RailsJST
+  constructor: (@applicationName) ->
+
+  #
+  # Gets template lambda by its full name
+  #
+  # @param [String] name      Template name 'foo/bar'
+  #
+  buildView: (name) ->
+    unless template = JST[location = "#{@applicationName}/templates/#{name}-#{I18n?.locale}"]
+      template = JST[location = "#{@applicationName}/templates/#{name}"]
+
+    unless template
+      throw new Error "Template '#{name}' not found. Checked at: #{location}"
+
+    template
+
+  #
+  # Gets full name of template by several params
+  #
+  # @param [String] section     Section of templates like pages/layouts/...
+  # @param [String] template    Internal template path
+  # @param [String] entity      Entity to lookup template path by its namespace
+  #
+  resolveTemplate: (section, template, entity) ->
+    if template.startsWith '/'
+      return template.substr 1
+
+    path = entity.constructor?.__namespace__?.map('underscore') || []
+    path.unshift section
+
+    "#{path.join '/'}/#{template}"

data/app/assets/javascripts/joosy/core/widget.js.coffee

@@ -0,0 +1,85 @@
+#= require joosy/core/joosy
+#= require joosy/core/modules/module
+#= require joosy/core/modules/log
+#= require joosy/core/modules/events
+#= require joosy/core/modules/container
+#= require joosy/core/modules/renderer
+#= require joosy/core/modules/filters
+
+#
+# Base class for all of your Joosy Layouts.
+#
+# @todo Add link to the 5th chapter of guides here.
+#
+# @example Sample widget
+#   class @FooWidget extends Joosy.Widget
+#     @view 'foo'
+#
+# @include Joosy.Modules.Log
+# @include Joosy.Modules.Events
+# @include Joosy.Modules.Container
+# @include Joosy.Modules.Renderer
+# @include Joosy.Modules.Filters
+# @include Joosy.Modules.TimeManager
+#
+class Joosy.Widget extends Joosy.Module
+  @include Joosy.Modules.Log
+  @include Joosy.Modules.Events
+  @include Joosy.Modules.Container
+  @include Joosy.Modules.Renderer
+  @include Joosy.Modules.Filters
+  @include Joosy.Modules.TimeManager
+
+  #
+  # By default widget will not render on load
+  #
+  __renderer: false
+
+  #
+  # Initial data that will be passed to view on load
+  # False (and not {}) by default to have a chance to check if data was loaded
+  #
+  data: false
+
+  #
+  # Proxy to Joosy.Router.navigate
+  #
+  navigate: (args...) ->
+    Joosy.Router.navigate args...
+
+  #
+  # This is required by {Joosy.Modules.Renderer}
+  # Sets the base template dir to app_name/templates/widgets
+  #
+  __renderSection: ->
+    'widgets'
+
+  #
+  # Widget bootstrap proccess
+  #
+  #   * Rendering (if required)
+  #   * {Joosy.Modules.Container.refreshElements}
+  #   * {Joosy.Modules.Container.__delegateEvents}
+  #
+  # @param [Joosy.Page, Joosy.Layout]     Page or Layout to attach to
+  # @param [jQuery] container             Container to attach to
+  #
+  __load: (@parent, @container, render=true) ->
+    if render && @__renderer
+      @swapContainer @container, @__renderer(@data || {})
+    @refreshElements()
+    @__delegateEvents()
+    @__runAfterLoads()
+
+    this
+
+  #
+  # Layout destruction proccess.
+  #
+  #   * {Joosy.Modules.TimeManager.__clearTime}
+  #   * {Joosy.Modules.Renderer.__removeMetamorphs}
+  #
+  __unload: ->
+    @__clearTime()
+    @__removeMetamorphs()
+    @__runAfterUnloads()