joosy 0.1.0.RC1

data/app/assets/javascripts/joosy/core/page.js.coffee

@@ -0,0 +1,156 @@
+#= require joosy/core/joosy
+#= require joosy/core/modules/module
+#= require joosy/core/modules/log
+#= require joosy/core/modules/events
+#= require joosy/core/modules/container
+#= require joosy/core/modules/renderer
+#= require joosy/core/modules/time_manager
+#= require joosy/core/modules/widgets_manager
+#= require joosy/core/modules/filters
+
+class Joosy.Page extends Joosy.Module
+  @include Joosy.Modules.Log
+  @include Joosy.Modules.Events
+  @include Joosy.Modules.Container
+  @include Joosy.Modules.Renderer
+  @include Joosy.Modules.TimeManager
+  @include Joosy.Modules.WidgetsManager
+  @include Joosy.Modules.Filters
+
+  layout: false
+  previous: false
+  params: false
+  data: false
+
+  @fetch: (callback) ->
+    @::__fetch = callback
+
+  @scroll: (element, options={}) ->
+    @::__scrollElement = element
+    @::__scrollSpeed = options.speed || 500
+    @::__scrollMargin = options.margin || 0
+
+  @layout: (layoutClass) ->
+    @::__layoutClass = layoutClass
+
+  @beforePaint: (callback) -> @::__beforePaint = callback
+  @paint: (callback) -> @::__paint = callback
+  @afterPaint: (callback) -> @::__afterPaint = callback
+  @erase: (callback) -> @::__erase = callback
+
+  constructor: (@params, @previous) ->
+    @__layoutClass ||= ApplicationLayout
+
+    if @__runBeforeLoads(@params, @previous)
+      if !@previous?.layout?.uuid? || @previous?.__layoutClass != @__layoutClass
+        @__bootstrapLayout()
+      else
+        @__bootstrap()
+
+  navigate: (args...) -> Joosy.Router.navigate(args...)
+
+  __renderSection: ->
+    'pages'
+
+  __fixHeight: ->
+    $('html').css 'min-height', $(document).height()
+    
+  __releaseHeight: ->
+    $('html').css 'min-height', ''
+
+  __load: ->
+    @refreshElements()
+    @__delegateEvents()
+    @__setupWidgets()
+    @__runAfterLoads(@params, @previous)
+    if @__scrollElement
+      scroll = $(@__extractSelector(@__scrollElement)).offset()?.top + @__scrollMargin
+      Joosy.Modules.Log.debugAs @, "Scrolling to #{@__extractSelector(@__scrollElement)}"
+      $('html, body').animate {scrollTop: scroll}, @__scrollSpeed, =>
+        @__releaseHeight() if @__scrollSpeed != 0
+
+    Joosy.Modules.Log.debugAs @, "Page loaded"
+
+  __unload: ->
+    @clearTime()
+    @__unloadWidgets()
+    @__removeMetamorphs()
+    @__runAfterUnloads(@params, @previous)
+    delete @previous
+
+
+  __callSyncedThrough: (entity, receiver, params, callback) ->
+    if entity?[receiver]?
+      entity[receiver].apply entity, params.clone().add(callback)
+    else
+      callback()
+
+  # Boot Sequence:
+  #
+  # previous::erase  \
+  # previous::unload  \
+  # beforePaint        \
+  #                     > paint
+  # fetch             /
+  #
+  __bootstrap: ->
+    Joosy.Modules.Log.debugAs @, "Boostraping page"
+    @layout = @previous.layout
+
+    callbacksParams = [@layout.content()]
+    
+    @__fixHeight() if @__scrollElement && @__scrollSpeed != 0
+
+    @wait "stageClear dataReceived", =>
+      @__callSyncedThrough this, '__paint', callbacksParams, =>
+        # Page HTML
+        @swapContainer @layout.content(), @__renderer(@data || {})
+        @container = @layout.content()
+
+        # Loading
+        @__load()
+        
+        @layout.content()
+
+    @__callSyncedThrough @previous, '__erase', callbacksParams, =>
+      @previous?.__unload()
+      @__callSyncedThrough this, '__beforePaint', callbacksParams, =>
+        @trigger 'stageClear'
+
+    @__callSyncedThrough this, '__fetch', [], =>
+      Joosy.Modules.Log.debugAs @, "Fetch complete"
+      @trigger 'dataReceived'
+
+  __bootstrapLayout: ->
+    Joosy.Modules.Log.debugAs @, "Boostraping page with layout"
+    @layout = new @__layoutClass
+
+    callbacksParams = [Joosy.Application.content(), this]
+    
+    @__fixHeight() if @__scrollElement && @__scrollSpeed != 0
+
+    @wait "stageClear dataReceived", =>
+      @__callSyncedThrough @layout, '__paint', callbacksParams, =>
+        # Layout HTML
+        @swapContainer Joosy.Application.content(), @layout.__renderer
+          yield: => @layout.yield()
+
+        # Page HTML
+        @swapContainer @layout.content(), @__renderer(@data || {})
+        @container = @layout.content()
+
+        # Loading
+        @layout.__load Joosy.Application.content()
+        @__load()
+
+        Joosy.Application.content()
+
+    @__callSyncedThrough @previous?.layout, '__erase', callbacksParams, =>
+      @previous?.layout?.__unload?()
+      @previous?.__unload()
+      @__callSyncedThrough @layout, '__beforePaint', callbacksParams, =>
+        @trigger 'stageClear'
+
+    @__callSyncedThrough this, '__fetch', [], =>
+      Joosy.Modules.Log.debugAs @, "Fetch complete"
+      @trigger 'dataReceived'

data/app/assets/javascripts/joosy/core/preloader.js.coffee

@@ -0,0 +1,5 @@
+# Preloader stub
+@Preloader = Object.extended
+  load: (libraries, options) ->
+    @.merge options
+    @complete?.call window

data/app/assets/javascripts/joosy/core/resource/generic.js.coffee

@@ -0,0 +1,61 @@
+class Joosy.Resource.Generic extends Joosy.Module
+  @include Joosy.Modules.Log
+  @include Joosy.Modules.Events
+
+  @beforeLoad: (action) -> @::__beforeLoad = action
+
+  @create: ->
+    shim = ->
+      shim.__call.apply(shim, arguments)
+
+    if shim.__proto__
+      shim.__proto__ = @prototype
+    else
+      for key, value of @prototype
+        shim[key] = value
+        
+    shim.constructor = @
+    
+    @apply(shim, arguments)
+
+    shim
+
+  constructor: (data) ->
+    @__fillData(data)
+    
+  get: (path) ->
+    target = @__callTarget(path)
+    target[0][target[1]]
+
+  set: (path, value) ->
+    target = @__callTarget(path)    
+    target[0][target[1]] = value
+    @trigger 'changed'
+
+  __callTarget: (path) ->
+    if path.has(/\./) && !@e[path]?
+      path    = path.split '.'
+      keyword = path.pop()
+      target  = @e
+      
+      for part in path
+        target[part] ||= {}
+        target = target[part]
+
+      [target, keyword]
+    else
+      [@e, path]
+
+  __call: (path, value) ->
+    if value
+      @set path, value
+    else
+      @get path
+
+  __fillData: (data) ->
+    @e = @__prepareData(data)
+
+  __prepareData: (data) ->
+    data = Object.extended(data)
+    data = @__beforeLoad(data) if @__beforeLoad?
+    data

data/app/assets/javascripts/joosy/core/resource/rest.js.coffee

@@ -0,0 +1,76 @@
+#= require ./rest_collection
+
+class Joosy.Resource.REST extends Joosy.Resource.Generic
+
+  __primaryKey: 'id'
+
+  @entity: (name) -> @::__entityName = name
+  @source: (source) -> @::__source = source
+  @primary: (primary) -> @::__primaryKey = primary
+
+  constructor: (description) ->
+    if @constructor.__isId(description)
+      @id = description
+    else
+      super description
+      @id = @e[@__primaryKey]
+
+  @entityName: ->
+    unless @::hasOwnProperty '__entityName'
+      throw new Error "Joosy.Resource.REST does not have entity name"
+
+    @::__entityName
+
+  # Returns single entity if int/string given
+  # Returns collection if no value or Object (with parameters) given
+  @find: (description, callback, options) ->
+    if @__isId(description)
+      resource = new @(description)
+      resource.fetch callback, options
+      resource
+    else
+      if Object.isFunction(description) && !callback
+        callback = description
+        description = undefined
+      resources = new Joosy.Resource.RESTCollection(@, description)
+      resources.fetch callback, options
+      resources
+
+  fetch: (callback, options) ->
+    @constructor.__ajax 'get', @constructor.__buildSource(extension: @id), options, (e) =>
+      @__fillData(e)
+      callback?(this)
+
+    this
+
+  save: ->
+
+  destroy: (callback, options) ->
+    @constructor.__ajax 'delete', @constructor.__buildSource(extension: @id), options, (e) =>
+      callback?(this)
+
+    this
+
+  @__isId: (something) -> Object.isNumber(something) || Object.isString(something)
+
+  @__ajax: (method, url, options={}, callback) ->
+    $.ajax url, Object.extended(
+      type: method
+      success: callback
+      cache: false
+      dataType: 'json'
+    ).merge options
+
+  @__buildSource: (options={}) ->
+    unless @::hasOwnProperty '__source'
+      @::__source = "/" + @entityName().pluralize()
+
+    source = Joosy.buildUrl("#{@::__source}/#{options.extension || ''}", options.params)
+
+  __fillData: (data) ->
+    data = @__prepareData data
+    
+    if Object.isObject(data) && data[@constructor.entityName()] && data.keys().length == 1
+      @e = Object.extended data[@constructor.entityName()]
+    else
+      @e = data

data/app/assets/javascripts/joosy/core/resource/rest_collection.js.coffee

@@ -0,0 +1,48 @@
+class Joosy.Resource.RESTCollection extends Joosy.Module
+  @include Joosy.Modules.Log
+  @include Joosy.Modules.Events
+
+  data:  []
+  pages: Object.extended()
+
+  constructor: (@model, params={}) ->
+    @params = Object.extended(params)
+
+  # Clears the storage and attempts to import given JSON
+  reset: (entities) ->
+    @data  = @modelize entities
+    @pages = Object.extended().merge { 1: @data }
+
+    this
+
+  # Clears the storage and gets new data from server
+  fetch: (callback, options) ->
+    @model.__ajax 'get', @model.__buildSource(params: @params), options, (data) =>
+      @reset(data)
+      callback?(this)
+
+    this
+
+  # Returns the subset for requested page. Requests with &page=x if not found localy.
+  page: (number, callback=false) ->
+    if @pages[number]?
+      callback?(@pages[number])
+      return this
+
+    @model.__ajax 'get', @model.__buildSource(params: @params.merge(page: number)), {}, (data) =>
+      @pages[number] = @modelize data
+
+      @data = []
+      @pages.keys().sort().each (x) =>
+        @data.add @pages[x]
+
+      callback?(@pages[number])
+
+    this
+
+  modelize: (collection) ->
+    if collection instanceof Array
+      collection.map (x) =>
+        @model.create x
+    else
+      []

data/app/assets/javascripts/joosy/core/router.js.coffee

@@ -0,0 +1,89 @@
+#= require joosy/core/joosy
+
+Joosy.Router =
+  rawRoutes: Object.extended()
+  routes: Object.extended()
+
+  reset: ->
+    @rawRoutes = Object.extended()
+    @routes = Object.extended()
+
+  map: (routes) ->
+    @rawRoutes.merge routes
+
+  setupRoutes: ->
+    @prepareRoutes @rawRoutes
+
+    @respondRoute(location.hash)
+    $(window).hashchange => @respondRoute(location.hash)
+
+  prepareRoutes: (routes, namespace='') ->
+    if !namespace && routes[404]
+      @wildcardAction = routes[404]
+      delete routes[404]
+
+    routes.each (path, response) =>
+      path = (namespace + path).replace(/\/{2,}/, '/')
+      if response && (typeof(response) == 'function' || response.prototype?)
+        @routes.merge @prepareRoute path,response
+      else
+        @prepareRoutes Object.extended(response), path
+
+  prepareRoute: (path, response) ->
+    matchPath = path.replace(/\/:([^\/]+)/g, '/([^/]+)').replace(/^\/?/, '^/?').replace(/\/?$/, '/?$')
+    result    = Object.extended()
+
+    result[matchPath] =
+      capture: (path.match(/\/:[^\/]+/g) || []).map((str) -> str.substr(2))
+      action: response
+    result
+
+  respondRoute: (hash) ->
+    Joosy.Modules.Log.debug "Router> Answering '#{hash}'"
+
+    fullPath = hash.replace(/^#!?/, '')
+
+    @currentPath = fullPath
+    found = false
+
+    queryArray = fullPath.split('&')
+    path       = queryArray.shift()
+    urlParams  = @paramsFromQueryArray(queryArray)
+
+    for regex, route of @routes when @routes.hasOwnProperty(regex)
+      if vals = path.match(new RegExp(regex))
+        params = @paramsFromRouteMatch(vals, route).merge urlParams
+
+        if !Joosy.Module.hasAncestor(route.action, Joosy.Page)
+          route.action.call(this, params)
+        else
+          Joosy.Application.setCurrentPage(route.action, params)
+
+        found = true
+        break
+
+    if !found && @wildcardAction
+      @wildcardAction(path, urlParams)
+
+  paramsFromRouteMatch: (vals, route) ->
+    params = Object.extended()
+
+    vals.shift()
+    for param in route.capture
+      params[param] = vals.shift()
+
+    params
+
+  paramsFromQueryArray: (queryArray) ->
+    params = Object.extended()
+
+    if queryArray
+      $.each queryArray, () ->
+        if this != ''
+          pair = @split '='
+          params[pair[0]] = pair[1]
+
+    params
+
+  navigate: (to) ->
+    location.hash = '!' + to

data/app/assets/javascripts/joosy/core/templaters/rails_jst.js.coffee

@@ -0,0 +1,20 @@
+#= require joosy/core/joosy
+
+class Joosy.Templaters.RailsJST
+  constructor: (@applicationName) ->
+
+  buildView: (name) ->
+    template = JST[location = "#{@applicationName}/templates/#{name}"]
+
+    unless template
+      throw new Error "Template '#{name}' not found. Checked at: #{location}"
+
+    template
+
+  resolveTemplate: (section, template, entity) ->
+    return template.substr 1 if template.startsWith '/'
+
+    path = entity.constructor?.__namespace__?.map('underscore') || []
+    path.unshift(section)
+
+    "#{path.join('/')}/#{template}"