jekyll-chalk 0.1.0 → 0.1.1

data/assets/bower/turbolinks5/src/turbolinks/snapshot.coffee

@@ -0,0 +1,47 @@
+class Turbolinks.Snapshot
+  @wrap: (value) ->
+    if value instanceof this
+      value
+    else
+      @fromHTML(value)
+
+  @fromHTML: (html) ->
+    element = document.createElement("html")
+    element.innerHTML = html
+    @fromElement(element)
+
+  @fromElement: (element) ->
+    new this
+      head: element.querySelector("head")
+      body: element.querySelector("body")
+
+  constructor: ({head, body}) ->
+    @head = head ? document.createElement("head")
+    @body = body ? document.createElement("body")
+
+  clone: ->
+    new Snapshot
+      head: @head.cloneNode(true)
+      body: @body.cloneNode(true)
+
+  getRootLocation: ->
+    root = @getSetting("root") ? "/"
+    new Turbolinks.Location root
+
+  getCacheControlValue: ->
+    @getSetting("cache-control")
+
+  hasAnchor: (anchor) ->
+    try @body.querySelector("[id='#{anchor}']")?
+
+  isPreviewable: ->
+    @getCacheControlValue() isnt "no-preview"
+
+  isCacheable: ->
+    @getCacheControlValue() isnt "no-cache"
+
+  # Private
+
+  getSetting: (name) ->
+    [..., element] = @head.querySelectorAll("meta[name='turbolinks-#{name}']")
+    element?.getAttribute("content")

data/assets/bower/turbolinks5/src/turbolinks/snapshot_cache.coffee

@@ -0,0 +1,43 @@
+class Turbolinks.SnapshotCache
+  constructor: (@size) ->
+    @keys = []
+    @snapshots = {}
+
+  has: (location) ->
+    key = keyForLocation(location)
+    key of @snapshots
+
+  get: (location) ->
+    return unless @has(location)
+    snapshot = @read(location)
+    @touch(location)
+    snapshot
+
+  put: (location, snapshot) ->
+    @write(location, snapshot)
+    @touch(location)
+    snapshot
+
+  # Private
+
+  read: (location) ->
+    key = keyForLocation(location)
+    @snapshots[key]
+
+  write: (location, snapshot) ->
+    key = keyForLocation(location)
+    @snapshots[key] = snapshot
+
+  touch: (location) ->
+    key = keyForLocation(location)
+    index = @keys.indexOf(key)
+    @keys.splice(index, 1) if index > -1
+    @keys.unshift(key)
+    @trim()
+
+  trim: ->
+    for key in @keys.splice(@size)
+      delete @snapshots[key]
+
+  keyForLocation = (location) ->
+    Turbolinks.Location.wrap(location).toCacheKey()

data/assets/bower/turbolinks5/src/turbolinks/snapshot_renderer.coffee

@@ -0,0 +1,88 @@
+#= require ./renderer
+#= require ./head_details
+
+class Turbolinks.SnapshotRenderer extends Turbolinks.Renderer
+  constructor: (@currentSnapshot, @newSnapshot) ->
+    @currentHeadDetails = new Turbolinks.HeadDetails @currentSnapshot.head
+    @newHeadDetails = new Turbolinks.HeadDetails @newSnapshot.head
+    @newBody = @newSnapshot.body
+
+  render: (callback) ->
+    if @trackedElementsAreIdentical()
+      @mergeHead()
+      @renderView =>
+        @replaceBody()
+        @focusFirstAutofocusableElement()
+        callback()
+    else
+      @invalidateView()
+
+  mergeHead: ->
+    @copyNewHeadStylesheetElements()
+    @copyNewHeadScriptElements()
+    @removeCurrentHeadProvisionalElements()
+    @copyNewHeadProvisionalElements()
+
+  replaceBody: ->
+    @activateBodyScriptElements()
+    @importBodyPermanentElements()
+    @assignNewBody()
+
+  trackedElementsAreIdentical: ->
+    @currentHeadDetails.getTrackedElementSignature() is @newHeadDetails.getTrackedElementSignature()
+
+  copyNewHeadStylesheetElements: ->
+    for element in @getNewHeadStylesheetElements()
+      document.head.appendChild(element)
+
+  copyNewHeadScriptElements: ->
+    for element in @getNewHeadScriptElements()
+      document.head.appendChild(@createScriptElement(element))
+
+  removeCurrentHeadProvisionalElements: ->
+    for element in @getCurrentHeadProvisionalElements()
+      document.head.removeChild(element)
+
+  copyNewHeadProvisionalElements: ->
+    for element in @getNewHeadProvisionalElements()
+      document.head.appendChild(element)
+
+  importBodyPermanentElements: ->
+    for replaceableElement in @getNewBodyPermanentElements()
+      if element = @findCurrentBodyPermanentElement(replaceableElement)
+        replaceableElement.parentNode.replaceChild(element, replaceableElement)
+
+  activateBodyScriptElements: ->
+    for replaceableElement in @getNewBodyScriptElements()
+      element = @createScriptElement(replaceableElement)
+      replaceableElement.parentNode.replaceChild(element, replaceableElement)
+
+  assignNewBody: ->
+    document.body = @newBody
+
+  focusFirstAutofocusableElement: ->
+    @findFirstAutofocusableElement()?.focus()
+
+  getNewHeadStylesheetElements: ->
+    @newHeadDetails.getStylesheetElementsNotInDetails(@currentHeadDetails)
+
+  getNewHeadScriptElements: ->
+    @newHeadDetails.getScriptElementsNotInDetails(@currentHeadDetails)
+
+  getCurrentHeadProvisionalElements: ->
+    @currentHeadDetails.getProvisionalElements()
+
+  getNewHeadProvisionalElements: ->
+    @newHeadDetails.getProvisionalElements()
+
+  getNewBodyPermanentElements: ->
+    @newBody.querySelectorAll("[id][data-turbolinks-permanent]")
+
+  findCurrentBodyPermanentElement: (element) ->
+    document.body.querySelector("##{element.id}[data-turbolinks-permanent]")
+
+  getNewBodyScriptElements: ->
+    @newBody.querySelectorAll("script")
+
+  findFirstAutofocusableElement: ->
+    document.body.querySelector("[autofocus]")

data/assets/bower/turbolinks5/src/turbolinks/start.coffee

@@ -0,0 +1,18 @@
+Turbolinks.start = ->
+  if installTurbolinks()
+    Turbolinks.controller ?= createController()
+    Turbolinks.controller.start()
+
+installTurbolinks = ->
+  window.Turbolinks ?= Turbolinks
+  moduleIsInstalled()
+
+createController = ->
+  controller = new Turbolinks.Controller
+  controller.adapter = new Turbolinks.BrowserAdapter(controller)
+  controller
+
+moduleIsInstalled = ->
+  window.Turbolinks is Turbolinks
+
+Turbolinks.start() if moduleIsInstalled()

data/assets/bower/turbolinks5/src/turbolinks/view.coffee

@@ -0,0 +1,34 @@
+#= require ./snapshot
+#= require ./snapshot_renderer
+#= require ./error_renderer
+
+class Turbolinks.View
+  constructor: (@delegate) ->
+    @element = document.documentElement
+
+  getRootLocation: ->
+    @getSnapshot().getRootLocation()
+    
+  getSnapshot: ->
+    Turbolinks.Snapshot.fromElement(@element)
+
+  render: ({snapshot, error, isPreview}, callback) ->
+    @markAsPreview(isPreview)
+    if snapshot?
+      @renderSnapshot(snapshot, callback)
+    else
+      @renderError(error, callback)
+
+  # Private
+
+  markAsPreview: (isPreview) ->
+    if isPreview
+      @element.setAttribute("data-turbolinks-preview", "")
+    else
+      @element.removeAttribute("data-turbolinks-preview")
+
+  renderSnapshot: (snapshot, callback) ->
+    Turbolinks.SnapshotRenderer.render(@delegate, callback, @getSnapshot(), Turbolinks.Snapshot.wrap(snapshot))
+
+  renderError: (error, callback) ->
+    Turbolinks.ErrorRenderer.render(@delegate, callback, error)

data/assets/bower/turbolinks5/src/turbolinks/visit.coffee

@@ -0,0 +1,162 @@
+#= require ./http_request
+
+class Turbolinks.Visit
+  constructor: (@controller, location, @action) ->
+    @identifier = Turbolinks.uuid()
+    @location = Turbolinks.Location.wrap(location)
+    @adapter = @controller.adapter
+    @state = "initialized"
+    @timingMetrics = {}
+
+  start: ->
+    if @state is "initialized"
+      @recordTimingMetric("visitStart")
+      @state = "started"
+      @adapter.visitStarted(this)
+
+  cancel: ->
+    if @state is "started"
+      @request?.cancel()
+      @cancelRender()
+      @state = "canceled"
+
+  complete: ->
+    if @state is "started"
+      @recordTimingMetric("visitEnd")
+      @state = "completed"
+      @adapter.visitCompleted?(this)
+      @controller.visitCompleted(this)
+
+  fail: ->
+    if @state is "started"
+      @state = "failed"
+      @adapter.visitFailed?(this)
+
+  changeHistory: ->
+    unless @historyChanged
+      actionForHistory = if @location.isEqualTo(@referrer) then "replace" else @action
+      method = getHistoryMethodForAction(actionForHistory)
+      @controller[method](@location, @restorationIdentifier)
+      @historyChanged = true
+
+  issueRequest: ->
+    if @shouldIssueRequest() and not @request?
+      @progress = 0
+      @request = new Turbolinks.HttpRequest this, @location, @referrer
+      @request.send()
+
+  getCachedSnapshot: ->
+    if snapshot = @controller.getCachedSnapshotForLocation(@location)
+      if not @location.anchor? or snapshot.hasAnchor(@location.anchor)
+        if @action is "restore" or snapshot.isPreviewable()
+          snapshot
+
+  hasCachedSnapshot: ->
+    @getCachedSnapshot()?
+
+  loadCachedSnapshot: ->
+    if snapshot = @getCachedSnapshot()
+      isPreview = @shouldIssueRequest()
+      @render ->
+        @cacheSnapshot()
+        @controller.render({snapshot, isPreview}, @performScroll)
+        @adapter.visitRendered?(this)
+        @complete() unless isPreview
+
+  loadResponse: ->
+    if @response?
+      @render ->
+        @cacheSnapshot()
+        if @request.failed
+          @controller.render(error: @response, @performScroll)
+          @adapter.visitRendered?(this)
+          @fail()
+        else
+          @controller.render(snapshot: @response, @performScroll)
+          @adapter.visitRendered?(this)
+          @complete()
+
+  followRedirect: ->
+    if @redirectedToLocation and not @followedRedirect
+      @location = @redirectedToLocation
+      @controller.replaceHistoryWithLocationAndRestorationIdentifier(@redirectedToLocation, @restorationIdentifier)
+      @followedRedirect = true
+
+  # HTTP Request delegate
+
+  requestStarted: ->
+    @recordTimingMetric("requestStart")
+    @adapter.visitRequestStarted?(this)
+
+  requestProgressed: (@progress) ->
+    @adapter.visitRequestProgressed?(this)
+
+  requestCompletedWithResponse: (@response, redirectedToLocation) ->
+    @redirectedToLocation = Turbolinks.Location.wrap(redirectedToLocation) if redirectedToLocation?
+    @adapter.visitRequestCompleted(this)
+
+  requestFailedWithStatusCode: (statusCode, @response) ->
+    @adapter.visitRequestFailedWithStatusCode(this, statusCode)
+
+  requestFinished: ->
+    @recordTimingMetric("requestEnd")
+    @adapter.visitRequestFinished?(this)
+
+  # Scrolling
+
+  performScroll: =>
+    unless @scrolled
+      if @action is "restore"
+        @scrollToRestoredPosition() or @scrollToTop()
+      else
+        @scrollToAnchor() or @scrollToTop()
+      @scrolled = true
+
+  scrollToRestoredPosition: ->
+    position = @restorationData?.scrollPosition
+    if position?
+      @controller.scrollToPosition(position)
+      true
+
+  scrollToAnchor: ->
+    if @location.anchor?
+      @controller.scrollToAnchor(@location.anchor)
+      true
+
+  scrollToTop: ->
+    @controller.scrollToPosition(x: 0, y: 0)
+
+  # Instrumentation
+
+  recordTimingMetric: (name) ->
+    @timingMetrics[name] ?= new Date().getTime()
+
+  getTimingMetrics: ->
+    Turbolinks.copyObject(@timingMetrics)
+
+  # Private
+
+  getHistoryMethodForAction = (action) ->
+    switch action
+      when "replace" then "replaceHistoryWithLocationAndRestorationIdentifier"
+      when "advance", "restore" then "pushHistoryWithLocationAndRestorationIdentifier"
+
+  shouldIssueRequest: ->
+    if @action is "restore"
+      not @hasCachedSnapshot()
+    else
+      true
+
+  cacheSnapshot: ->
+    unless @snapshotCached
+      @controller.cacheSnapshot()
+      @snapshotCached = true
+
+  render: (callback) ->
+    @cancelRender()
+    @frame = requestAnimationFrame =>
+      @frame = null
+      callback.call(this)
+
+  cancelRender: ->
+    cancelAnimationFrame(@frame) if @frame

data/assets/bower/turbolinks5/test/src/fixtures/additional_assets.html

@@ -0,0 +1,12 @@
+<!DOCTYPE html>
+<html>
+  <head>
+    <meta charset="utf-8">
+    <title>Additional assets</title>
+    <link rel="stylesheet" type="text/css" href="/test.css">
+    <script src="/turbolinks.js" data-turbolinks-track="reload"></script>
+  </head>
+  <body>
+    <h1>Additional assets</h1>
+  </body>
+</html>

data/assets/bower/turbolinks5/test/src/fixtures/body_script.html

@@ -0,0 +1,18 @@
+<!DOCTYPE html>
+<html>
+  <head>
+    <meta charset="utf-8">
+    <title>Body script</title>
+    <script src="/turbolinks.js" data-turbolinks-track="reload"></script>
+  </head>
+  <body>
+    <h1>Body script</h1>
+    <script>
+      if ("bodyScriptEvaluationCount" in window) {
+        window.bodyScriptEvaluationCount++
+      } else {
+        window.bodyScriptEvaluationCount = 1
+      }
+    </script>
+  </body>
+</html>

data/assets/bower/turbolinks5/test/src/fixtures/eval_false_script.html

@@ -0,0 +1,18 @@
+<!DOCTYPE html>
+<html>
+  <head>
+    <meta charset="utf-8">
+    <title>data-turbolinks-eval=false script</title>
+    <script src="/turbolinks.js" data-turbolinks-track="reload"></script>
+  </head>
+  <body>
+    <h1>data-turbolinks-eval=false script</h1>
+    <script data-turbolinks-eval="false">
+      if ("bodyScriptEvaluationCount" in window) {
+        window.bodyScriptEvaluationCount++
+      } else {
+        window.bodyScriptEvaluationCount = 1
+      }
+    </script>
+  </body>
+</html>