javonet-ruby-sdk 2.4.8 → 2.4.10

data/lib/javonet-ruby-sdk/Binaries/Perl/MacOs/X64/deps/lib/perl5/CPAN/Requirements/Dynamic.pm

@@ -1,384 +0,0 @@
-package CPAN::Requirements::Dynamic;
-$CPAN::Requirements::Dynamic::VERSION = '0.001';
-use strict;
-use warnings;
-
-use Carp 'croak';
-use Parse::CPAN::Meta;
-
-sub _version_satisfies {
-	my ($version, $range) = @_;
-	require CPAN::Meta::Requirements::Range;
-	return CPAN::Meta::Requirements::Range->with_string_requirement($range)->accepts($version);
-}
-
-sub _is_interactive {
-	return -t STDIN && (-t STDOUT || !(-f STDOUT || -c STDOUT));
-}
-
-sub _read_line {
-	return undef if $ENV{PERL_MM_USE_DEFAULT} || !_is_interactive && eof STDIN;;
-
-	my $answer = <STDIN>;
-	chomp $answer if defined $answer;
-	return $answer;
-}
-
-sub _prompt {
-	my ($mess, $default) = @_;
-
-	local $|=1;
-	print "$mess [$default]";
-	my $answer = _read_line;
-	$answer = $default if !defined $answer or !length $answer;
-
-	return $answer;
-}
-
-my %default_commands = (
-	can_xs => sub {
-		my ($self) = @_;
-		require ExtUtils::HasCompiler;
-		return ExtUtils::HasCompiler::can_compile_extension(config => $self->{config});
-	},
-	can_run => sub {
-		my ($self, $command) = @_;
-		require IPC::Cmd;
-		return IPC::Cmd::can_run($command);
-	},
-	config_defined => sub {
-		my ($self, $entry) = @_;
-		return $self->{config}->get($entry) eq 'define';
-	},
-	has_env => sub {
-		my ($self, $entry) = @_;
-		return !!$ENV{$entry};
-	},
-	has_module => sub {
-		my ($self, $module, $range) = @_;
-		require Module::Metadata;
-		my $data = Module::Metadata->new_from_module($module);
-		return !!0 unless $data;
-		return !!1 if not defined $range;
-		return _version_satisfies($data->version($module), $range);
-	},
-	has_perl => sub {
-		my ($self, $range) = @_;
-		return _version_satisfies($], $range);
-	},
-	is_extended => sub {
-		return !!$ENV{EXTENDED_TESTING};
-	},
-	is_interactive => sub {
-		return _is_interactive;
-	},
-	is_os => sub {
-		my ($self, @wanted) = @_;
-		return !!grep { $_ eq $^O } @wanted
-	},
-	is_os_type => sub {
-		my ($self, $wanted) = @_;
-		require Perl::OSType;
-		return Perl::OSType::is_os_type($wanted);
-	},
-	is_smoker => sub {
-		return !!$ENV{AUTOMATED_TESTING};
-	},
-	prompt_default_yes => sub {
-		my ($self, $message) = @_;
-		return _prompt("$message [Y/n]", "y") =~ /^y/i;
-	},
-	prompt_default_no => sub {
-		my ($self, $message) = @_;
-		return _prompt("$message [y/N]", "n") =~ /^y/i;
-	},
-	want_pureperl => sub {
-		my ($self) = @_;
-		return !!$self->{pureperl_only};
-	},
-	want_xs => sub {
-		my ($self) = @_;
-		return !!0 if $self->{pureperl_only};
-		require ExtUtils::HasCompiler;
-		return ExtUtils::HasCompiler::can_compile_extension(config => $self->{config});
-	},
-	want_compiled => sub {
-		my ($self) = @_;
-		return defined $self->{pureperl_only} && $self->{pureperl_only} == 0;
-	},
-);
-
-sub new {
-	my ($class, %args) = @_;
-	return bless {
-		config        => $args{config}   || do { require ExtUtils::Config; ExtUtils::Config->new },
-		prereqs       => $args{prereqs}  || do { require CPAN::Meta::Prereqs; CPAN::Meta::Prereqs->new },
-		commands      => $args{commands} || \%default_commands,
-		pureperl_only => $args{pureperl_only},
-	}, $class;
-}
-
-sub _get_command {
-	my ($self, $name) = @_;
-	if ($name eq 'or') {
-		return sub {
-			my ($self, @each) = @_;
-			for my $elem (@each) {
-				return !!1 if $self->_run_condition($elem);
-			}
-			return !!0;
-		};
-	} elsif ($name eq 'and') {
-		return sub {
-			my ($self, @each) = @_;
-			for my $elem (@each) {
-				return !!0 if not $self->_run_condition($elem);
-			}
-			return !!1;
-		};
-	} else {
-		return $self->{commands}{$name} || croak "No such command $name";
-	}
-}
-
-sub _run_condition {
-	my ($self, $condition) = @_;
-
-	my $negate = !!0;
-	my ($function, @arguments) = @{ $condition };
-	while ($function eq 'not') {
-		$function = shift @arguments;
-		$negate = !$negate;
-	}
-
-	my $method = $self->_get_command($function);
-	my $primary = $self->$method(@arguments);
-	return $negate ? !$primary : $primary;
-}
-
-sub evaluate {
-	my ($self, $argument) = @_;
-	my $version = $argument->{version};
-	croak "Dynamic prereqs spec version $version is not supported" if int $version > 1;
-	my @prereqs;
-
-	for my $entry (@{ $argument->{expressions} }) {
-		if ($self->_run_condition($entry->{condition})) {
-			if ($entry->{error}) {
-				die "$entry->{error}\n";
-			} elsif (my $prereqs = $entry->{prereqs}) {
-				my $phase = $entry->{phase} || 'runtime';
-				my $relation = $entry->{relation} || 'requires';
-				my $prereqs = { $phase => { $relation => $entry->{prereqs} } };
-				push @prereqs, CPAN::Meta::Prereqs->new($prereqs);
-			}
-		}
-	}
-
-	return $self->{prereqs}->with_merged_prereqs(\@prereqs);
-}
-
-sub evaluate_file {
-	my ($self, $filename) = @_;
-	my $structure = Parse::CPAN::Meta->load_file($filename);
-	return $self->evaluate($structure);
-}
-
-1;
-
-# ABSTRACT: Dynamic prerequisites in meta files
-
-__END__
-
-=pod
-
-=encoding UTF-8
-
-=head1 NAME
-
-CPAN::Requirements::Dynamic - Dynamic prerequisites in meta files
-
-=head1 VERSION
-
-version 0.001
-
-=head1 SYNOPSIS
-
- my $result = $dynamic->evaluate({
-   expressions => [
-     {
-       condition => [ 'has_perl' => 'v5.20.0' ],
-       prereqs => { Bar => "1.3" },
-     },
-     {
-       condition => [ is_os => 'linux' ],
-       prereqs => { Baz => "1.4" },
-     },
-     {
-       condition => [ config_defined => 'usethreads' ],
-       prereqs => { Quz => "1.5" },
-     },
-     {
-       condition => [ has_module => 'CPAN::Meta', '2' ],
-       prereqs => { Wuz => "1.6" },
-     },
-     {
-       condition => [ and =>
-         [ config_defined => 'usethreads' ],
-         [ is_os => 'openbsd' ],
-       ],
-       prereqs => { Euz => "1.7" },
-     },
-     {
-       condition => [ not => is_os_type => 'Unix'],
-       error => 'OS unsupported',
-     },
-   ],
- });
-
-=head1 DESCRIPTION
-
-This module implements a format for describing dynamic prerequisites of a distribution.
-
-=head1 METHODS
-
-=head2 new(%options)
-
-This constructor takes two (optional but recommended) named arguments
-
-=over 4
-
-=item * config
-
-This is an L<ExtUtils::Config|ExtUtils::Config> (compatible) object for reading configuration.
-
-=item * pureperl_only
-
-This should be the value of the C<pureperl-only> flag.
-
-=back
-
-=head2 evaluate(%options)
-
-This takes a hash with two named arguments: C<version> and C<expressions>. The former is the version of the format, it currently defaults to 1. The latter is a list of hashes that can contain the following keys:
-
-=over 4
-
-=item * condition
-
-The condition of the dynamic requirement. This is an array with a name as first values and zero or more arguments following it. The semantics are described below under L</Conditions>
-
-=item * prereqs
-
-The prereqs is a hash with modules for keys and the required version as values (e.g. C<< { Foo => '1.234' } >>).
-
-=item * phase
-
-The phase of the requirements. This defaults to C<'runtime'>. Other valid values include C<'build'> and C<'test'>.
-
-=item * relation
-
-The relation of the requirements. This defaults to C<'requires'>, but other valid values include C<'recommends'>, C<'suggests'> and C<'conflicts'>.
-
-=item * error
-
-It will die with this error if set. The two messages C<"No support for OS"> and C<"OS unsupported"> have special meaning to CPAN Testers and are generally encouraged for situations that indicate not a failed build but an impossibility to build.
-
-=back
-
-C<condition> and one of C<prereqs> or C<error> are mandatory.
-
-=head2 evaluate_file($filename)
-
-This takes a filename, that can be either a YAML file or a JSON file, and evaluates it.
-
-=head2 Conditions
-
-=head3 can_xs
-
-This returns true if a compiler appears to be available.
-
-=head3 can_run($command)
-
-Returns true if a C<$command> can be run.
-
-=head3 config_defined($variable)
-
-This returns true if a specific configuration variable is defined.
-
-=head3 has_env($variable)
-
-This returns true if the environmental variable with the name in C<$variable> is true.
-
-=head3 has_module($module, $version = 0)
-
-Returns true if a module is installed on the system. If a C<$version> is given, it will also check if that version is provided. C<$version> is interpreted exactly as in the CPAN::Meta spec.
-
-=head3 has_perl($version)
-
-Returns true if the perl version satisfies C<$version>. C<$version> is interpreted exactly as in the CPAN::Meta spec (e.g. C<1.2> equals C<< '>= 1.2' >>).
-
-=head3 is_extended
-
-Returns true if extended testing is asked for.
-
-=head3 is_interactive
-
-Returns true if installed from a terminal that can answer prompts.
-
-=head3 is_os(@systems)
-
-Returns true if the OS name equals any of C<@systems>.
-
-=head3 is_os_type($type)
-
-Returns true if the OS type equals C<$type>. Typical values of C<$type> are C<'Unix'> or C<'Windows'>.
-
-=head3 is_smoker
-
-Returns true when running on a smoker.
-
-=head3 has_env
-
-This returns true if the given environmental variable is true.
-
-=head3 prompt_default_no
-
-This will ask a yes/no question to the user, defaulting to no.
-
-=head3 prompt_default_yes
-
-This will ask a yes/no question to the user, defaulting to yes.
-
-=head3 want_pureperl
-
-This returns true if the user has indicated they want a pure-perl build.
-
-=head3 want_compiled
-
-This returns true if the user has explicitly indicated they do not want a pure-perl build.
-
-=head3 not
-
-This takes an expression and negates its value.
-
-=head3 or
-
-This takes list of arrayrefs, each containing a condition expression. If at least one of the conditions is true this will also return true.
-
-=head3 and
-
-This takes a list of arrayrefs, each containing a condition expression. If all of the conditions are true this will also return true.
-
-=head1 AUTHOR
-
-Leon Timmermans <fawaka@gmail.com>
-
-=head1 COPYRIGHT AND LICENSE
-
-This software is copyright (c) 2023 by Leon Timmermans.
-
-This is free software; you can redistribute it and/or modify it under
-the same terms as the Perl 5 programming language system itself.
-
-=cut

data/lib/javonet-ruby-sdk/Binaries/Perl/MacOs/X64/deps/lib/perl5/ExtUtils/HasCompiler.pm

@@ -1,308 +0,0 @@
-package ExtUtils::HasCompiler;
-$ExtUtils::HasCompiler::VERSION = '0.025';
-use strict;
-use warnings;
-
-use base 'Exporter';
-our @EXPORT_OK = qw/can_compile_loadable_object can_compile_static_library can_compile_extension/;
-our %EXPORT_TAGS = (all => \@EXPORT_OK);
-
-use Config;
-use Carp 'carp';
-use File::Basename 'basename';
-use File::Spec::Functions qw/catfile catdir rel2abs curdir/;
-use File::Temp qw/tempdir tempfile/;
-
-my $tempdir = tempdir('HASCOMPILERXXXX', CLEANUP => 1, DIR => rel2abs(curdir));
-
-my $loadable_object_format = <<'END';
-#define PERL_NO_GET_CONTEXT
-#include "EXTERN.h"
-#include "perl.h"
-#include "XSUB.h"
-
-#ifndef PERL_UNUSED_VAR
-#define PERL_UNUSED_VAR(var)
-#endif
-
-XS(exported) {
-#ifdef dVAR
-	dVAR;
-#endif
-	dXSARGS;
-
-	PERL_UNUSED_VAR(cv); /* -W */
-	PERL_UNUSED_VAR(items); /* -W */
-
-	XSRETURN_IV(42);
-}
-
-#ifndef XS_EXTERNAL
-#define XS_EXTERNAL(foo) XS(foo)
-#endif
-
-/* we don't want to mess with .def files on mingw */
-#if defined(WIN32) && defined(__GNUC__)
-#  define EXPORT __declspec(dllexport)
-#else
-#  define EXPORT
-#endif
-
-EXPORT XS_EXTERNAL(boot_%s) {
-#ifdef dVAR
-	dVAR;
-#endif
-	dXSARGS;
-
-	PERL_UNUSED_VAR(cv); /* -W */
-	PERL_UNUSED_VAR(items); /* -W */
-
-	newXS("%s::exported", exported, __FILE__);
-}
-
-END
-
-my $counter = 1;
-my %prelinking = map { $_ => 1 } qw/MSWin32 VMS aix/;
-
-sub can_compile_loadable_object {
-	my %args = @_;
-
-	my $output = $args{output} || \*STDOUT;
-
-	my $config = $args{config} || 'ExtUtils::HasCompiler::Config';
-	return if not $config->get('usedl');
-
-	my ($source_handle, $source_name) = tempfile('TESTXXXX', DIR => $tempdir, SUFFIX => '.c', UNLINK => 1);
-	my $basename = basename($source_name, '.c');
-	my $abs_basename = catfile($tempdir, $basename);
-
-	my ($cc, $ccflags, $optimize, $cccdlflags, $ld, $ldflags, $lddlflags, $libperl, $perllibs, $archlibexp, $_o, $dlext) = map { $config->get($_) } qw/cc ccflags optimize cccdlflags ld ldflags lddlflags libperl perllibs archlibexp _o dlext/;
-
-	my $incdir = catdir($archlibexp, 'CORE');
-	my $object_file = $abs_basename.$_o;
-	my $loadable_object = "$abs_basename.$dlext";
-
-	my @commands;
-	if ($^O eq 'MSWin32' && $cc =~ /^cl/) {
-		push @commands, qq{$cc $ccflags $cccdlflags $optimize /I "$incdir" /c $source_name /Fo$object_file};
-		push @commands, qq{$ld $object_file $lddlflags $libperl $perllibs /out:$loadable_object /def:$abs_basename.def /pdb:$abs_basename.pdb};
-	}
-	elsif ($^O eq 'VMS') {
-		# Mksymlists is only the beginning of the story.
-		open my $opt_fh, '>>', "$abs_basename.opt" or do { carp "Couldn't append to '$abs_basename.opt'"; return };
-		print $opt_fh "PerlShr/Share\n";
-		close $opt_fh;
-
-		my $incdirs = $ccflags =~ s{ /inc[^=]+ (?:=)+ (?:\()? ( [^\/\)]* ) }{}xi ? "$1,$incdir" : $incdir;
-		push @commands, qq{$cc $ccflags $optimize /include=($incdirs) $cccdlflags $source_name /obj=$object_file};
-		push @commands, qq{$ld $ldflags $lddlflags=$loadable_object $object_file,$abs_basename.opt/OPTIONS,${incdir}perlshr_attr.opt/OPTIONS' $perllibs};
-	}
-	else {
-		my @extra;
-		my $inc = qq{"-I$incdir"};
-		if ($^O eq 'MSWin32') {
-			my $lib = '-l' . ($libperl =~ /lib([^.]+)\./)[0];
-			push @extra, "$abs_basename.def", $lib, $perllibs;
-		}
-		elsif ($^O =~ /^(cygwin|msys)$/) {
-			push @extra, catfile($incdir, $config->get('useshrplib') ? 'libperl.dll.a' : 'libperl.a');
-		}
-		elsif ($^O eq 'aix') {
-			$lddlflags =~ s/\Q$(BASEEXT)\E/$abs_basename/;
-			$lddlflags =~ s/\Q$(PERL_INC)\E/$incdir/;
-		}
-		elsif ($^O eq 'android') {
-			push @extra, qq{"-L$incdir"}, '-lperl', $perllibs;
-		}
-		elsif ($^O eq 'darwin' && $config->get('perlpath') eq '/usr/bin/perl' && ($config->get('osvers') =~ /(\d+)/)[0] >= 18) {
-			$inc = qq{-iwithsysroot "$incdir"};
-		}
-		push @commands, qq{$cc $ccflags $optimize $inc $cccdlflags -c $source_name -o $object_file};
-		push @commands, qq{$ld $object_file -o $loadable_object $lddlflags @extra};
-	}
-
-	if ($prelinking{$^O}) {
-		require ExtUtils::Mksymlists;
-		ExtUtils::Mksymlists::Mksymlists(NAME => $basename, FILE => $abs_basename, IMPORTS => {});
-	}
-
-	my $shortname = '_Loadable' . $counter++;
-	my $package = "ExtUtils::HasCompiler::$shortname";
-	printf $source_handle $loadable_object_format, $basename, $package or do { carp "Couldn't write to $source_name: $!"; return };
-	close $source_handle or do { carp "Couldn't close $source_name: $!"; return };
-
-	for my $command (@commands) {
-		print $output "$command\n" if not $args{quiet};
-		system $command and do { carp "Couldn't execute $command: $!"; return };
-	}
-
-	# Skip loading when cross-compiling
-	return 1 if exists $args{skip_load} ? $args{skip_load} : $config->get('usecrosscompile');
-
-	require DynaLoader;
-	local @DynaLoader::dl_require_symbols = "boot_$basename";
-	my $handle = DynaLoader::dl_load_file(rel2abs($loadable_object), 0);
-	if ($handle) {
-		my $symbol = DynaLoader::dl_find_symbol($handle, "boot_$basename") or do { carp "Couldn't find boot symbol for $basename"; return };
-		my $compilet = DynaLoader::dl_install_xsub('__ANON__::__ANON__', $symbol, $source_name);
-		my $ret = eval { $compilet->(); $package->exported } or carp $@;
-		delete $ExtUtils::HasCompiler::{"$shortname\::"};
-		eval { DynaLoader::dl_unload_file($handle) } or carp $@;
-		return defined $ret && $ret == 42;
-	}
-	else {
-		carp "Couldn't load $loadable_object: " . DynaLoader::dl_error();
-		return;
-	}
-}
-
-my %static_unsupported_on = map { $_ => 1 } qw/VMS aix MSWin32 cygwin/;
-sub can_compile_static_library {
-	my %args = @_;
-
-	my $output = $args{output} || \*STDOUT;
-
-	my $config = $args{config} || 'ExtUtils::HasCompiler::Config';
-	return if $config->get('useshrplib') eq 'true';
-
-	my ($source_handle, $source_name) = tempfile('TESTXXXX', DIR => $tempdir, SUFFIX => '.c', UNLINK => 1);
-	my $basename = basename($source_name, '.c');
-	my $abs_basename = catfile($tempdir, $basename);
-
-	my ($cc, $ccflags, $optimize, $ar, $full_ar, $ranlib, $archlibexp, $_o, $lib_ext) = map { $config->get($_) } qw/cc ccflags optimize ar full_ar ranlib archlibexp _o lib_ext/;
-	my $incdir = catdir($archlibexp, 'CORE');
-	my $object_file = "$abs_basename$_o";
-	my $static_library = $abs_basename.$lib_ext;
-
-	my @commands;
-	if ($static_unsupported_on{$^O}) {
-		return;
-	}
-	else {
-		my $my_ar = length $full_ar ? $full_ar : $ar;
-		push @commands, qq{$cc $ccflags $optimize "-I$incdir" -c $source_name -o $object_file};
-		push @commands, qq{$my_ar cr $static_library $object_file};
-		push @commands, qq{$ranlib $static_library} if $ranlib ne ':';
-	}
-
-	my $shortname = '_Loadable' . $counter++;
-	my $package = "ExtUtils::HasCompiler::$shortname";
-	printf $source_handle $loadable_object_format, $basename, $package or do { carp "Couldn't write to $source_name: $!"; return };
-	close $source_handle or do { carp "Couldn't close $source_name: $!"; return };
-
-	for my $command (@commands) {
-		print $output "$command\n" if not $args{quiet};
-		system $command and do { carp "Couldn't execute $command: $!"; return };
-	}
-	return 1;
-}
-
-sub can_compile_extension {
-	my %args = @_;
-	$args{config} ||= 'ExtUtils::HasCompiler::Config';
-	my $linktype = $args{linktype} || ($args{config}->get('usedl') ? 'dynamic' : 'static');
-	return $linktype eq 'static' ? can_compile_static_library(%args) : can_compile_loadable_object(%args);
-}
-
-sub ExtUtils::HasCompiler::Config::get {
-	my (undef, $key) = @_;
-	return $ENV{uc $key} || $Config{$key};
-}
-
-1;
-
-# ABSTRACT: Check for the presence of a compiler
-
-__END__
-
-=pod
-
-=encoding UTF-8
-
-=head1 NAME
-
-ExtUtils::HasCompiler - Check for the presence of a compiler
-
-=head1 VERSION
-
-version 0.025
-
-=head1 SYNOPSIS
-
- use ExtUtils::HasCompiler 'can_compile_extension';
- if (can_compile_extension()) {
-   ...
- }
- else {
-   ...
- }
-
-=head1 DESCRIPTION
-
-This module tries to check if the current system is capable of compiling, linking and loading an XS module.
-
-B<Notice>: this is an early release, interface stability isn't guaranteed yet.
-
-=head1 FUNCTIONS
-
-=head2 can_compile_loadable_object(%opts)
-
-This checks if the system can compile, link and load a perl loadable object. It may take the following options:
-
-=over 4
-
-=item * quiet
-
-Do not output the executed compilation commands.
-
-=item * config
-
-An L<ExtUtils::Config|ExtUtils::Config> (compatible) object for configuration.
-
-=item * skip_load
-
-This causes can_compile_loadable_object to not try to load the generated object. This defaults to true on a cross-compiling perl.
-
-=back
-
-=head2 can_compile_static_library(%opts)
-
-This checks if the system can compile and link a perl static library. It does not check it it can compile a new perl with it. It may take the following options:
-
-=over 4
-
-=item * quiet
-
-Do not output the executed compilation commands.
-
-=item * config
-
-An L<ExtUtils::Config|ExtUtils::Config> (compatible) object for configuration.
-
-=back
-
-=head2 can_compile_extension(%opts)
-
-This will call either C<can_compile_loadable_object>, or C<can_compile_static_library>, depending on which is the default on your configuration. In addition to the arguments listed above, it can take one more optional argument:
-
-=over 4
-
-=item * linktype
-
-This will force the linktype to be either static or dynamic. Dynamic compilation on a static perl won't work, but static libraries can be viable on a dynamic perl.
-
-=back
-
-=head1 AUTHOR
-
-Leon Timmermans <fawaka@gmail.com>
-
-=head1 COPYRIGHT AND LICENSE
-
-This software is copyright (c) 2014 by Leon Timmermans.
-
-This is free software; you can redistribute it and/or modify it under
-the same terms as the Perl 5 programming language system itself.
-
-=cut