jasmine-headless-webkit-firstbanco 0.9.0.rc.2

data/vendor/assets/javascripts/headless_reporter_result.js

@@ -0,0 +1,79 @@
+(function() {
+
+  window.HeadlessReporterResult = (function() {
+
+    function HeadlessReporterResult(name, splitName) {
+      this.name = name;
+      this.splitName = splitName;
+      this.results = [];
+    }
+
+    HeadlessReporterResult.prototype.addResult = function(message) {
+      return this.results.push(message);
+    };
+
+    HeadlessReporterResult.prototype.toString = function() {
+      var bestChoice, line, output, result, _i, _len, _ref;
+      output = "\n" + this.name.foreground('red');
+      bestChoice = HeadlessReporterResult.findSpecLine(this.splitName);
+      if (bestChoice.file) {
+        output += (" (" + bestChoice.file + ":" + bestChoice.lineNumber + ")").foreground('blue');
+      }
+      _ref = this.results;
+      for (_i = 0, _len = _ref.length; _i < _len; _i++) {
+        result = _ref[_i];
+        line = result.message.foreground('red');
+        if (result.lineNumber) {
+          line += (" (line ~" + (bestChoice.lineNumber + result.lineNumber) + ")").foreground('red').bright();
+        }
+        output += "\n  " + line;
+        if (result.line != null) {
+          output += ("\n    " + result.line).foreground('yellow');
+        }
+      }
+      return output;
+    };
+
+    HeadlessReporterResult.findSpecLine = function(splitName) {
+      var bestChoice, file, index, lastLine, line, lineNumber, lines, newLineNumberInfo, _i, _len, _ref;
+      bestChoice = {
+        accuracy: 0,
+        file: null,
+        lineNumber: null
+      };
+      _ref = HeadlessReporterResult.specLineNumbers;
+      for (file in _ref) {
+        lines = _ref[file];
+        index = 0;
+        lineNumber = 0;
+        while (newLineNumberInfo = lines[splitName[index]]) {
+          if (newLineNumberInfo.length === 0) {
+            lineNumber = newLineNumberInfo[0];
+          } else {
+            lastLine = null;
+            for (_i = 0, _len = newLineNumberInfo.length; _i < _len; _i++) {
+              line = newLineNumberInfo[_i];
+              lastLine = line;
+              if (line > lineNumber) break;
+            }
+            lineNumber = lastLine;
+          }
+          index++;
+        }
+        if (index > bestChoice.accuracy) {
+          bestChoice = {
+            accuracy: index,
+            file: file,
+            lineNumber: lineNumber
+          };
+        }
+        if (index === splitName.length) break;
+      }
+      return bestChoice;
+    };
+
+    return HeadlessReporterResult;
+
+  })();
+
+}).call(this);

data/vendor/assets/javascripts/intense.coffee

@@ -0,0 +1,28 @@
+window.Intense = {
+  colors:
+    black: 0
+    red: 1
+    green: 2
+    yellow: 3
+    blue: 4
+    magenta: 5
+    cyan: 6
+    white: 7
+  methods:
+    foreground: (color) ->
+      if Intense.useColors
+        '\x1b' + "[3#{Intense.colors[color]}m#{this}" + '\x1b' + "[0m"
+      else
+        this
+    bright: ->
+      if Intense.useColors
+        '\x1b' + "[1m#{this}" + '\x1b' + "[0m"
+      else
+        this
+  useColors: true
+  moveBack: (count = 1) -> '\x1b' + "[#{count}D"
+}
+
+for method, code of Intense.methods
+  String.prototype[method] = code
+

data/vendor/assets/javascripts/jasmine-extensions.coffee

@@ -0,0 +1,97 @@
+if !jasmine?
+  throw new Error("jasmine not laoded!")
+
+if window.JHW
+  # Jasmine extensions
+  getSplitName = (parts) ->
+    parts.push(String(@description).replace(/[\n\r]/g, ' '))
+    parts
+
+  jasmine.Suite.prototype.getSuiteSplitName = ->
+    this.getSplitName(if @parentSuite then @parentSuite.getSuiteSplitName() else [])
+
+  jasmine.Spec.prototype.getSpecSplitName = ->
+    this.getSplitName(@suite.getSuiteSplitName())
+
+  jasmine.Suite.prototype.getSplitName = getSplitName
+  jasmine.Spec.prototype.getSplitName = getSplitName
+
+  jasmine.Spec.prototype.getJHWSpecInformation = ->
+    parts = this.getSpecSplitName()
+    specLineInfo = HeadlessReporterResult.findSpecLine(parts)
+    if specLineInfo.file
+      parts.push("#{specLineInfo.file}:#{specLineInfo.lineNumber}")
+    else
+      parts.push('')
+    parts.join("||")
+
+  jasmine.Spec.prototype.finishCallback = ->
+    JHW.ping()
+    this.env.reporter.reportSpecResults(this)
+
+  jasmine.Spec.prototype.fail = (e) ->
+    e = JHW.createCoffeeScriptFileException(e)
+
+    expectationResult = new jasmine.ExpectationResult({
+      passed: false,
+      message: if e then jasmine.util.formatException(e) else 'Exception',
+      trace: { stack: e.stack }
+    })
+    @results_.addResult(expectationResult)
+
+    this.env.reporter.reportException(e)
+
+  jasmine.NestedResults.isValidSpecLine = (line) ->
+    line.match(/^\s*expect/) != null || line.match(/^\s*return\s*expect/) != null
+
+  jasmine.NestedResults.parseFunction = (func) ->
+    lines = []
+    lineCount = 0
+    for line in func.split("\n")
+      if jasmine.NestedResults.isValidSpecLine(line)
+        line = line.replace(/^\s*/, '').replace(/\s*$/, '').replace(/^return\s*/, '')
+        lines.push([line, lineCount])
+      lineCount += 1
+    lines
+
+  jasmine.NestedResults.parseAndStore = (func) ->
+    if !jasmine.NestedResults.ParsedFunctions[func]
+      jasmine.NestedResults.ParsedFunctions[func] = jasmine.NestedResults.parseFunction(func)
+    jasmine.NestedResults.ParsedFunctions[func]
+
+  jasmine.NestedResults.ParsedFunctions = []
+
+  if !jasmine.WaitsBlock.prototype._execute
+    jasmine.WaitsBlock.prototype._execute = jasmine.WaitsBlock.prototype.execute
+    jasmine.WaitsForBlock.prototype._execute = jasmine.WaitsForBlock.prototype.execute
+
+    pauseAndRun = (onComplete) ->
+      JHW.timerPause()
+      jasmine.getEnv().reporter.reportSpecWaiting()
+
+      this._execute ->
+        jasmine.getEnv().reporter.reportSpecRunning()
+        JHW.timerDone()
+        onComplete()
+
+    jasmine.WaitsBlock.prototype.execute = pauseAndRun
+    jasmine.WaitsForBlock.prototype.execute = pauseAndRun
+
+    jasmine.NestedResults.prototype.addResult_ = jasmine.NestedResults.prototype.addResult
+    jasmine.NestedResults.prototype.addResult = (result) ->
+      result.expectations = []
+      # always three up?
+
+      result.expectations = jasmine.NestedResults.parseAndStore(arguments.callee.caller.caller.caller.toString())
+
+      this.addResult_(result)
+
+    for method in [ "reportSpecWaiting", "reportSpecRunning", "reportException" ]
+      generator = (method) ->
+        (args...) ->
+          for reporter in @subReporters_
+            if reporter[method]?
+              reporter[method](args...)
+
+      jasmine.MultiReporter.prototype[method] = generator(method)
+

data/vendor/assets/javascripts/jasmine.HeadlessReporter.Console.coffee

@@ -0,0 +1,8 @@
+#= require jasmine.HeadlessReporter.ConsoleBase
+#
+class jasmine.HeadlessReporter.Console extends jasmine.HeadlessReporter.ConsoleBase
+  displaySuccess: (spec) =>
+    this.print('.'.foreground('green'))
+
+  displayFailure: (spec) =>
+    this.print('F'.foreground('red'))

data/vendor/assets/javascripts/jasmine.HeadlessReporter.ConsoleBase.coffee

@@ -0,0 +1,92 @@
+#= require jasmine.HeadlessReporter
+
+class jasmine.HeadlessReporter.ConsoleBase extends jasmine.HeadlessReporter
+  constructor: (@callback = null) ->
+    super(@callback)
+
+    @position = 0
+    @positions = "|/-\\"
+
+  formatResultLine: (runtime) ->
+    line = []
+    line.push(@length)
+    line.push((if @length == 1 then "test" else "tests") + ',')
+
+    line.push(@failedCount)
+    line.push((if @failedCount == 1 then "failure" else "failures") + ',')
+
+    line.push(runtime)
+    line.push((if runtime == 1.0 then "sec" else "secs") + '.')
+
+    line.join(' ')
+
+  reportRunnerResults: (runner) ->
+    super()
+
+    this.print("\n")
+
+    resultLine = this.formatResultLine(this._runtime())
+
+    if @failedCount == 0
+      this.puts("PASS: #{resultLine}".foreground('green'))
+    else
+      this.puts("FAIL: #{resultLine}".foreground('red'))
+
+    for result in @results
+      this.puts(result.toString())
+
+    this.puts("\nTest ordering seed: --seed #{JHW.getSeed()}")
+
+  reportRunnerStarting: (runner) ->
+    super(runner)
+    this.puts("\nRunning Jasmine specs...".bright()) if !this.hasError()
+
+  reportSpecWaiting: ->
+    if !@timer
+      @timer = true
+      @first = true
+
+      this._waitRunner()
+
+  reportSpecRunning: ->
+    if @timer
+      clearTimeout(@timer)
+      @timer = null
+      this.print(Intense.moveBack())
+
+  reportSpecResults: (spec) ->
+    super(spec)
+
+    this._reportSpecResult(spec, {
+      success: (results) =>
+        this.displaySuccess(spec)
+      failure: (results) =>
+        this.displayFailure(spec)
+
+        this.reportFailureResult(results, new HeadlessReporterResult(spec.getFullName(), spec.getSpecSplitName()))
+    })
+
+  reportFailureResult: (results, failureResult) ->
+    testCount = 1
+
+    for result in results.getItems()
+      if result.type == 'expect' and !result.passed_
+        if foundLine = result.expectations[testCount - 1]
+          [ result.line, result.lineNumber ] = foundLine
+        failureResult.addResult(result)
+      testCount += 1
+    @results.push(failureResult)
+
+  _waitRunner: =>
+    @timer = setTimeout(
+      =>
+        if @timer
+          this.print(Intense.moveBack()) if !@first
+          this.print(@positions.substr(@position, 1).foreground('yellow'))
+          @position += 1
+          @position %= @positions.length
+          @first = false
+          this._waitRunner()
+      , 750
+    )
+

data/vendor/assets/javascripts/jasmine.HeadlessReporter.File.coffee

@@ -0,0 +1,24 @@
+#= require jasmine.HeadlessReporter
+#
+class jasmine.HeadlessReporter.File extends jasmine.HeadlessReporter
+  reportRunnerResults: (runner) ->
+    super(runner)
+
+    output = "TOTAL||#{@length}||#{@failedCount}||#{this._runtime()}||#{if JHW._hasErrors then "T" else "F"}"
+
+    this.puts(output)
+    this.puts("SEED||#{JHW.getSeed()}")
+
+  consoleLogUsed: (msg) ->
+    this.puts("CONSOLE||#{msg}")
+
+  reportSpecResults: (spec) ->
+    super(spec)
+
+    this._reportSpecResult(spec, {
+      success: (results) =>
+        this.puts("PASS||" + spec.getJHWSpecInformation())
+      failure: (results) =>
+        this.puts("FAIL||" + spec.getJHWSpecInformation())
+    })
+

data/vendor/assets/javascripts/jasmine.HeadlessReporter.Tap.coffee

@@ -0,0 +1,28 @@
+#= require jasmine.HeadlessReporter
+
+class jasmine.HeadlessReporter.Tap extends jasmine.HeadlessReporter
+  constructor: (@outputTarget = null) ->
+    super(@outputTarget)
+
+    @output = []
+
+  reportRunnerResults: (runner) ->
+    super(runner)
+
+    @output.unshift("1..#{@output.length}") if @output.length > 0
+
+    this.puts(@output.join("\n"))
+
+  reportSpecResults: (spec) ->
+    super(spec)
+
+    index = @output.length + 1
+    description = spec.getSpecSplitName().join(' ')
+
+    this._reportSpecResult(spec, {
+      success: (results) =>
+        @output.push("ok #{index} #{description}")
+      failure: (results) =>
+        @output.push("not ok #{index} #{description}")
+    })
+

data/vendor/assets/javascripts/jasmine.HeadlessReporter.Verbose.coffee

@@ -0,0 +1,64 @@
+#= require jasmine.HeadlessReporter.ConsoleBase
+#
+class jasmine.HeadlessReporter.Verbose extends jasmine.HeadlessReporter.ConsoleBase
+  @prereport = false
+
+  displaySuccess: (spec) =>
+    this.displaySpec(spec, 'green')
+
+  displayFailure: (spec) =>
+    this.displaySpec(spec, 'red')
+
+  displaySpec: (spec, color) =>
+    currentLastNames = (@lastNames || []).slice(0)
+    @lastNames = spec.getSpecSplitName()
+
+    for line in this.indentSpec(@lastNames, currentLastNames, color)
+      if line? and !_.isEmpty(line)
+        this.puts(line)
+
+  indentSpec: (current, last, color) =>
+    last = last.slice(0)
+
+    lines = []
+
+    for name in current
+      if last.shift() != name
+        lines.push(name)
+      else
+        lines.push(null)
+
+    this.indentLines(lines, color)
+
+  indentLines: (lines, color) =>
+    indent = ''
+
+    output = []
+
+    for line in lines
+      if line?
+        outputLine = indent
+        outputLine += this.colorLine(line, color)
+
+        output.push(outputLine)
+      indent += '  '
+
+    output
+
+  colorLine: (line, color) =>
+    line.foreground(color)
+
+  reportSpecStarting: (spec) =>
+    if jasmine.HeadlessReporter.Verbose.prereport
+      this.puts(spec.getSpecSplitName().join(' '))
+
+  reportException: (e) =>
+    e = JHW.createCoffeeScriptFileException(e)
+
+    if e.sourceURL && e.lineNumber
+      output = "#{e.sourceURL}:#{e.lineNumber} #{e.message}"
+    else
+      output = e.message ? e
+
+    this.puts(output.foreground('yellow'))
+

data/vendor/assets/javascripts/jasmine.HeadlessReporter.coffee

@@ -0,0 +1,58 @@
+if !jasmine?
+  throw new Error("jasmine not loaded!")
+
+class jasmine.HeadlessReporter
+  constructor: (@outputTarget = null) ->
+    @results = []
+    @failedCount = 0
+    @length = 0
+    @timer = null
+
+  hasError: ->
+    JHW._hasErrors
+
+  reportSpecStarting: (spec) ->
+    if this.hasError()
+      spec.finish()
+      spec.suite.finish()
+
+  reportSuiteResults: (suite) ->
+
+  reportRunnerStarting: (runner) ->
+    @startTime = new Date()
+
+  reportRunnerResults: (runner) ->
+    return if this.hasError()
+
+    if @failedCount != 0
+      JHW.hasSpecFailure()
+
+    JHW.finishSuite()
+
+    if window.JHW
+      window.onbeforeunload = null
+
+  reportSpecResults: (spec) ->
+    return if this.hasError()
+    JHW.ping()
+
+  _reportSpecResult: (spec, options) ->
+    results = spec.results()
+
+    @length++
+
+    if results.passed()
+      options.success(results, spec)
+    else
+      @failedCount++
+      options.failure(results, spec)
+
+  _runtime: ->
+    (new Date() - @startTime) / 1000.0
+
+  print: (output) =>
+    JHW.print(@outputTarget, output)
+
+  puts: (output) =>
+    JHW.print(@outputTarget, output + "\n")
+