houston-roadmaps 0.1.0

data/app/assets/javascripts/houston/roadmaps/views/edit_milestone_view.coffee

@@ -0,0 +1,97 @@
+class Roadmaps.EditMilestoneView extends Roadmaps.ShowMilestoneView
+  template: HandlebarsTemplates['houston/roadmaps/milestone/edit']
+
+  events:
+    'click .remove-button': 'removeTicket'
+    'click .inline-editable-link': 'startInlineEdit'
+    'click .btn-cancel': 'cancelInlineEdit'
+    'click #save_goal': 'saveGoal'
+    'click #save_feedback_query': 'saveFeedbackQuery'
+
+  initialize: ->
+    @openTickets = @options.openTickets
+    super
+
+  render: ->
+    super
+
+    @newTicketView = new FindOrCreateTicketView
+      ticketTracker: @projectTicketTracker
+      tickets: @openTickets
+      addTicket: _.bind(@addTicket, @)
+      createTicket: _.bind(@createTicket, @)
+    @$el.find('#find_or_create_ticket_view').appendView @newTicketView
+
+    $('#tickets').sortable
+      handle: '.ticket-handle'
+      helper: (e, ui)-> ui.children().each(-> $(@).width $(@).width()); ui
+      stop: (e, ui)-> ui.item.children().css('width', '')
+      update: (e, ui)->
+        $tickets = $('#tickets .ticket')
+        ids = _.map $tickets, (el)-> +$(el).attr('data-id')
+        $.put "#{window.location.pathname}/ticket_order", {order: ids}
+    @
+
+
+
+  addTicket: (ticket)->
+    $.post("/roadmap/milestones/#{@id}/tickets/#{ticket.id}")
+      .success => @_addTicket(ticket)
+
+  createTicket: (summary)->
+    $.post("/roadmap/milestones/#{@id}/tickets", {summary: summary})
+      .success (ticket)=> @_addTicket(ticket)
+
+  _addTicket: (ticket)->
+    unless @tickets.get(ticket.id)
+      @tickets.push new Ticket(ticket)
+      @rerenderTickets()
+      @renderBurndownChart(@tickets.models)
+    $(".ticket[data-id=#{ticket.id}]").highlight()
+
+
+
+  removeTicket: (e)->
+    e.preventDefault()
+    e.stopImmediatePropagation()
+    $button = $(e.target)
+    $button.prop 'disabled', true
+    $ticket = $button.closest('.ticket')
+    $ticket.addClass('deleting')
+    id = +$ticket.attr('data-id')
+    $.destroy("/roadmap/milestones/#{@id}/tickets/#{id}")
+      .error =>
+        $button.prop 'disabled', false
+        $ticket.removeClass('deleting')
+      .success =>
+        @tickets.remove @tickets.get(id)
+        $ticket.remove()
+
+
+
+  startInlineEdit: (e)->
+    $(e.target).closest('.inline-editable')
+      .addClass('in-edit')
+      .find('input, textarea').focus()
+
+  cancelInlineEdit: (e)->
+    e.preventDefault()
+    $(e.target).closest('.inline-editable').removeClass('in-edit')
+
+  saveGoal: (e)->
+    goal = $('#goal').val()
+    $.put("/roadmap/milestones/#{@id}", milestone: {goal: goal})
+      .success =>
+        @milestone.goal = goal
+        @render()
+      .error (response)=>
+        alertify.error(response.responseText)
+
+  saveFeedbackQuery: (e)->
+    feedbackQuery = $('#feedback_query').val()
+    $.put("/roadmap/milestones/#{@id}", milestone: {feedback_query: feedbackQuery})
+      .success =>
+        @milestone.feedbackQuery = feedbackQuery
+        @render()
+      .error (response)=>
+        alertify.error(response.responseText)

data/app/assets/javascripts/houston/roadmaps/views/edit_roadmap_view.coffee

@@ -0,0 +1,80 @@
+class Roadmaps.EditRoadmapView extends Backbone.View
+  template: HandlebarsTemplates['houston/roadmaps/roadmap/show']
+  renderGoal: HandlebarsTemplates['houston/roadmaps/roadmap/goal']
+
+  initialize: ->
+    super
+    @roadmapId = @options.id
+    @milestonesUrl = "/roadmaps/#{@roadmapId}/milestones"
+    @milestones = @options.milestones
+    @goals = @options.goals
+
+    $('#reset_roadmap').click _.bind(@reset, @)
+    $('#save_roadmap').click _.bind(@save, @)
+
+
+    @milestones.bind 'change', @milestoneChanged, @
+    @milestones.bind 'add', @milestoneChanged, @
+    @milestones.bind 'remove', @milestoneChanged, @
+
+  render: ->
+    @$el.html @template()
+    @$goals = @$el.find('#goals')
+    @$goals_view = @$el.find('#goals_view')
+    @roadmap = new Roadmaps.EditGanttChart @milestones,
+      removeMilestoneByDroppingOn: @$goals_view
+      showWeekends: true
+    @roadmap.render()
+    @milestoneChanged()
+
+    setTop = =>
+      roadmapBottom = $('#roadmap').position().top + $('#roadmap').height() - 10
+      @$goals_view.css(top: roadmapBottom)
+    setTop()
+    $(window).resize(setTop)
+    addResizeListener $('#roadmap')[0], setTop
+
+    @
+
+  milestoneChanged: ->
+    @indicateIfRoadmapHasChanged()
+    @renderGoals()
+
+  indicateIfRoadmapHasChanged: ->
+    @$el.find('.buttons button')
+      .prop 'disabled', @milestones.changes().length is 0
+
+  renderGoals: ->
+    html = ""
+    @goals.outsideOf(@milestones.unremoved()).each (goal) =>
+      html += @renderGoal goal.toJSON()
+    @$goals.html(html)
+
+    @roadmap.dragFrom @$goals.find('.goal'), @goals
+    @
+
+
+
+  reset: (e)->
+    e.preventDefault()
+    @milestones.revert()
+
+  save: (e)->
+    e.preventDefault()
+    if message = prompt('Commit message:')
+      $buttons = $('#reset_roadmap, #save_roadmap')
+      changes = @milestones.changes()
+      $buttons.prop('disabled', true)
+      $.put(@milestonesUrl,
+        roadmap: changes
+        message: message)
+        .success =>
+          $buttons.prop('disabled', false)
+          @milestones.url = @milestonesUrl
+          @milestones.fetch
+            parse: true
+            wait: true
+        .error (response)->
+          $buttons.prop('disabled', false)
+          errors = Errors.fromResponse(response)
+          errors.renderToAlert()

data/app/assets/javascripts/houston/roadmaps/views/gantt_thumbnail_view.coffee

@@ -0,0 +1,173 @@
+class Roadmaps.ThumbnailGanttChart
+  today: new Date()
+
+  constructor: (options)->
+    @milestones = options.milestones
+    @parent = options.parent
+    @viewport = options.viewport
+    @showToday = options.showToday
+    @markers = options.markers
+    @milestones.bind 'add', @update, @
+    @milestones.bind 'remove', @update, @
+    @milestones.bind 'change', @update, @
+    @milestones.bind 'reset', @update, @
+    $(window).resize (e)=>
+      @updateWindow() if e.target is window
+
+  render: ->
+    @height = 46
+    @graphHeight = @height - 18
+
+    el = @parent.append('div')
+      .attr('class', 'roadmap-thumbnail')
+      .attr('style', "position: relative; height: #{@height}px;")
+
+    svg = el.append('svg')
+        .attr('height', @height)
+      .append('g')
+        .attr('transform', "translate(0,0)")
+
+    @roadmap = svg.append('g')
+      .attr('class', 'roadmap-bands')
+
+    @viewer = el.selectAll('.roadmap-thumbnail-viewer')
+      .data([@viewport])
+
+    view = @
+    @viewer.enter()
+      .append('div')
+        .attr('class', 'roadmap-thumbnail-viewer')
+        .attr('style', "top: 1px; height: #{@height - 2}px; left: 1px;")
+        .each ->
+          $(@).draggable
+            axis: 'x'
+            containment: 'parent'
+            drag: (e, ui)->
+              start = view.x.invert(ui.position.left)
+              offset = start - view.viewport.get('start')
+              end = new Date(+view.viewport.get('end') + offset)
+              view.viewport.set(start: start, end: end)
+          .resizable
+            handles: 'e'
+            containment: 'parent'
+            resize: (e, ui)->
+              end = view.x.invert(ui.position.left + ui.size.width)
+              view.viewport.set(end: end)
+
+    @xAxis = svg.append('g')
+      .attr('class', 'x axis')
+      .attr('transform', "translate(0,#{@graphHeight})")
+
+    @updateWindow()
+
+  updateWindow: ->
+    width = $('#roadmap').width() || 960
+    return if @width is width
+    @width = width
+
+    @parent.select('.roadmap-thumbnail').transition(150).attr('width', @width)
+
+    @update()
+
+  update: ->
+    visibleMilestones = _.select @milestones.toJSON(), (m)-> m.startDate and m.endDate and !m.removed
+
+    if visibleMilestones.length > 0
+      @startDate = 3.weeks().before d3.min(visibleMilestones, (m)-> m.startDate)
+      @endDate = 12.weeks().after d3.max(visibleMilestones, (m)-> m.endDate)
+    else
+      @startDate = 3.weeks().ago()
+      @endDate = 12.weeks().fromNow()
+
+    @startDate = @viewport.get('start') if @viewport.get('start') < @startDate
+    @endDate = @viewport.get('end') if @viewport.get('end') > @endDate
+
+    @x = d3.time.scale()
+      .domain([@startDate, @endDate])
+      .range([0, @width])
+    timeline = d3.svg.axis()
+      .scale(@x)
+      .orient('bottom')
+      .innerTickSize(4)
+    @xAxis.transition(150).call(timeline)
+
+    @viewer.attr('style', (viewport)=> "top: 1px; height: #{@height - 2}px; left: #{@x(viewport.get('start'))}px; width: #{@x(viewport.get('end')) - @x(viewport.get('start'))}px;")
+
+
+
+    milestoneBands = d3.nest()
+      .key (milestone)-> milestone.band
+      .entries(visibleMilestones)
+
+    bands = @roadmap.selectAll('.roadmap-thumbnail-band')
+      .data(milestoneBands, (band)-> band.key)
+
+    bands.enter()
+      .append('g')
+        .attr('class', 'roadmap-thumbnail-band')
+        .attr('transform', (d, i)-> "translate(0,#{2 + i * 6})")
+
+    bands.exit().remove()
+
+    milestones = bands.selectAll('.roadmap-thumbnail-milestone')
+      .data(((band)-> band.values), (milestone)-> milestone.cid)
+
+    # update
+    milestones
+      .attr 'class', (milestone)->
+        css = ['roadmap-thumbnail-milestone']
+        css.push 'completed' if milestone.completed
+        css.join(' ')
+      .transition(150)
+        .attr('height', (milestone)-> milestone.lanes * 6 - 1)
+        .attr('width', (milestone)=> @x(milestone.endDate) - @x(milestone.startDate))
+        .attr('x', (milestone)=> @x(milestone.startDate))
+
+    # enter
+    milestones.enter().append('rect')
+      .attr('rx', 1)
+      .attr('ry', 1)
+      .attr('height', (milestone)-> milestone.lanes * 6 - 1)
+      .attr('width', (milestone)=> @x(milestone.endDate) - @x(milestone.startDate))
+      .attr('x', (milestone)=> @x(milestone.startDate))
+      .attr 'class', (milestone)->
+        css = ['roadmap-thumbnail-milestone']
+        css.push 'completed' if milestone.completed
+        css.join(' ')
+
+    # exit
+    milestones.exit().remove()
+
+
+    if @showToday
+      todayLine = @roadmap.selectAll('.thumbnail-roadmap-today')
+        .data([@today])
+
+      todayLine.enter()
+        .append('rect')
+          .attr('class', 'thumbnail-roadmap-today')
+          .attr('height', @graphHeight - 1)
+          .attr('width', 1)
+          .attr('x', (date)=> @x(date))
+          .attr('y', 1)
+
+      todayLine
+        .attr('x', (date)=> @x(date))
+
+
+
+    markers = @roadmap.selectAll('.thumbnail-roadmap-marker')
+      .data(@markers)
+
+    markers.enter()
+      .append('rect')
+        .attr('class', 'thumbnail-roadmap-marker')
+        .attr('height', @graphHeight - 1)
+        .attr('width', 1)
+        .attr('x', ({date})=> @x(date))
+        .attr('y', 1)
+
+    markers
+      .attr('x', ({date})=> @x(date))
+
+    markers.exit().remove()

data/app/assets/javascripts/houston/roadmaps/views/goal_view.coffee

@@ -0,0 +1,18 @@
+class window.GoalView extends Neat.ModelEditor
+  tagName: 'tr'
+
+  render: ->
+    super
+    @$el.attr 'data-cid', @model.cid
+    @$el.toggleClass 'new', !@model.get('id')
+    @
+
+  cancelEdit: (e)->
+    return super if @model.id
+
+    # Canceling editing a new goal cancels adding a goal
+    @model.collection.remove @model
+
+  onSaveError: (goal, response) ->
+    errors = Errors.fromResponse(response)
+    errors.renderToAlert()

data/app/assets/javascripts/houston/roadmaps/views/project_goals_view.coffee

@@ -0,0 +1,30 @@
+class Roadmaps.ProjectGoalsView extends Neat.CollectionEditor
+  renderNewGoalModal: HandlebarsTemplates['houston/roadmaps/goals/new']
+  resource: 'goals'
+  viewPath: 'houston/roadmaps/goals'
+  pageSize: Infinity
+
+  initialize: ->
+    @project = @options.project
+    @can = @options.can
+    @goals = @collection = @options.goals
+    super
+
+    $('#new_goal_button').click (e) =>
+      @newGoal(e)
+
+
+
+  render: ->
+    super
+    $('.table-sortable').tablesorter()
+    @
+
+
+
+  newGoal: (e)->
+    e.preventDefault() if e
+    goal = new Roadmaps.Goal
+      projectId: @project.id
+    @goals.unshift goal
+    @edit @views[0]

data/app/assets/javascripts/houston/roadmaps/views/roadmap_history_view.coffee

@@ -0,0 +1,67 @@
+class Roadmaps.RoadmapHistoryView extends Backbone.View
+  el: '#roadmap_history_view'
+  milestones: {}
+
+  events:
+    'click :radio': 'changeCommit'
+
+  initialize: ->
+    @commits = @options.commits
+    @commitId = @options.commitId
+
+    dup = (milestones)-> _.clone(milestone) for milestone in milestones
+
+    # The current state of the Roadmap
+    # is the result of the last commit
+    currentMilestones = @options.milestones
+    @milestones[0] = dup(currentMilestones)
+
+    for commit in @commits
+      for change in commit.changes
+        milestone = _(currentMilestones).findWhere(id: change.milestoneId)
+        continue unless milestone
+
+        if change.number is 1
+          currentMilestones = _(currentMilestones).without(milestone)
+        else
+          for attribute, [before, after] of change.modifications
+            milestone[attribute] = before
+
+      @milestones[commit.id] = dup(currentMilestones)
+
+    @visibleMilestones = new Roadmaps.Milestones()
+    @updateRoadmap()
+
+    @roadmap = new Roadmaps.GanttChart(@visibleMilestones, @options)
+    @template = HandlebarsTemplates['houston/roadmaps/roadmap/history']
+    super
+
+  render: ->
+    @$el.html @template
+      commits: @commits
+
+    $form = @$el.find('form')
+    $form.css(bottom: 42) if App.meta('env') is 'development'
+
+    setTop = ->
+      roadmapBottom = $('#roadmap').position().top + $('#roadmap').height() - 10
+      $form.css(top: roadmapBottom)
+    setTop()
+    $(window).resize(setTop)
+    addResizeListener $('#roadmap')[0], setTop
+
+    @$el.find(':radio').first().prop('checked', true)
+    @roadmap.render()
+    @
+
+  changeCommit: (e)->
+    $radio = $(e.target)
+    $commit = $radio.closest('.roadmap-commit')
+    $commit.prevAll().andSelf().addClass('roadmap-commit-reverted')
+    $commit.nextAll().removeClass('roadmap-commit-reverted')
+    @commitId = +$radio.val()
+    @updateRoadmap()
+
+  updateRoadmap: ->
+    milestones = @milestones[@commitId]
+    @visibleMilestones.reset milestones, parse: true