hamcrest4qunit 1.3.0

data/app/assets/javascripts/hamcrest4qunit/matchers/compounds.js.coffee

@@ -0,0 +1,134 @@
+h4q.allOf = ->
+  args = h4q.argumentsToArray arguments
+  matchers = []
+  for m in args
+    if m instanceof Matcher
+      matchers.push m
+    else
+      matchers.push equalTo m
+
+  new Matcher
+    matchers: matchers
+    _matches: (v, msg) ->
+      msg.appendText("was").appendValue v
+
+      hasError = false
+      for m in @matchers
+        msgtmp = new Description()
+        res = m.matches v, msgtmp
+        unless res
+          hasError = true
+
+      not hasError
+
+    _describeTo: (msg) ->
+      l = @matchers.length
+      msg.appendText '('
+      @matchers.map (o, i) ->
+        msgtmp = new Description()
+        if i is l-1
+          msg.appendText "and"
+        else if i > 0
+          msg.appendText ","
+
+        o.describeTo msg
+
+      msg.appendText ')'
+
+h4q.anyOf = ->
+  args = h4q.argumentsToArray arguments
+  matchers = []
+  for m in args
+    if m instanceof Matcher
+      matchers.push m
+    else
+      matchers.push equalTo m
+
+  new Matcher
+    matchers: matchers
+    _matches: (v, msg) ->
+      msg.appendText("was ").appendValue v
+      hasMatches = false
+      hasError = false
+      for m in @matchers
+        msgtmp = new Description()
+        res = m.matches v, msgtmp
+        if res
+          hasMatches = true
+
+      hasMatches
+
+    _describeTo: (msg) ->
+      msg.appendText '('
+      l = @matchers.length
+      @matchers.map (o,i) ->
+        if i is l - 1
+          msg.appendText "or"
+        else if i > 0
+          msg.appendText ","
+
+        o.describeTo msg
+
+      msg.appendText ')'
+
+h4q.both = (m) ->
+  new Matcher
+    matchA: if m instanceof Matcher then m else equalTo m
+    and: (m) ->
+      this.matchB = if m instanceof Matcher then m else equalTo m
+      this
+
+    _matches: (v,msg) ->
+      unless @matchB?
+        throw new Error
+          message: "the both..and matcher require an 'and' assertion"
+
+      msgtmp1 = new Description()
+      msgtmp2 = new Description();
+
+      res1 = @matchA.matches v, msgtmp1
+      res2 = @matchB.matches v, msgtmp2
+
+      if res1 and res2
+        msg.appendText("was").appendValue v
+      else
+        msg.appendText msgtmp1 unless res1
+
+
+        msg.appendText "and" unless res1 or res2
+
+        msg.appendText msgtmp2 unless res2
+
+      res1 and res2
+
+    _describeTo: (msg) ->
+      unless @matchB?
+        throw new hasError
+          message: "the both..and matcher require an 'and' assertion"
+
+      msg.appendText("both").appendDescriptionOf(@matchA)
+         .appendText("and").appendDescriptionOf(@matchB)
+
+h4q.either = (m) ->
+  new Matcher
+    matchA: if m instanceof Matcher then m else equalTo m
+    or: (m) ->
+      @matchB = if m instanceof Matcher then m else equalTo m
+      this
+
+    _matches: (v, msg) ->
+      msg.appendText("was").appendValue v
+      unless @matchB?
+        throw new Error
+          message: "the either..or matcher require an 'or' assertion"
+
+      msgtmp = new Description()
+      @matchA.matches(v, msgtmp) or @matchB.matches(v, msgtmp)
+
+    _describeTo: (msg) ->
+      unless @matchB?
+        throw new Error
+          message: "the either..or matcher require an 'or' assertion"
+
+      msg.appendText("either").appendDescriptionOf(@matchA)
+         .appendText("or").appendDescriptionOf(@matchB)

data/app/assets/javascripts/hamcrest4qunit/matchers/core.js.coffee

@@ -0,0 +1,126 @@
+h4q.equalTo = (m) ->
+  new Matcher
+    value: m
+    _describeTo: (msg) -> msg.appendValue @value
+    _matches: (v, msg) ->
+      msg.appendText("was").appendValue v
+      if v instanceof Array and @value instanceof Array
+        l = v.length
+        if @value.length isnt l
+          msg.appendText("with a length of").appendValue l
+          return false
+        else
+          hasError = false
+
+          for i in [0..l-1]
+            if `v[i] != this.value[i]`
+              msg.appendText "and" if hasError
+
+              msg.appendText ("with")
+                 .appendValue(v[i])
+                 .appendText ("at index")
+                 .appendValue(i)
+                 .appendText ("instead of")
+                 .appendValue(@value[i])
+              hasError = true
+
+          if hasError
+            msg.diff = QUnit.diff QUnit.jsDump.parse(@value),
+                                  QUnit.jsDump.parse(v)
+
+          return not hasError
+
+      return true if `v == this.value`
+
+      msg.diff = QUnit.diff QUnit.jsDump.parse(@value), QUnit.jsDump.parse(v)
+      return false
+
+h4q.strictlyEqualTo = (m) ->
+  new Matcher
+    value: m,
+    _matches: (v, msg) ->
+        msg.appendText("was ").appendValue v
+
+        return true if v is @value
+
+        msg.diff = QUnit.diff  QUnit.jsDump.parse(m),
+                               QUnit.jsDump.parse(v)
+        return false
+
+    _describeTo: (msg) ->
+      msg.appendText("a value strictly equal to").appendValue @value
+
+h4q.not = (m) ->
+  new Matcher
+    submatch: m
+    _matches: (v, msg) ->
+      if @submatch instanceof Matcher
+        not @submatch.matches v, msg
+      else
+        msg.appendText("was").appendValue v
+        v isnt @submatch
+
+    _describeTo: (msg) ->
+      if @submatch instanceof Matcher
+        msg.appendText "not"
+        @submatch.describeTo msg
+      else
+        msg.appendText("not").appendValue @submatch
+
+h4q.nullValue = ->
+  new Matcher
+    _matches: (v, msg) ->
+      msg.appendText("was").appendValue v
+      not v?
+
+    _describeTo: (msg) ->
+      msg.appendValue null
+
+h4q.notNullValue = ->
+  new Matcher
+    _matches: (v, msg) ->
+      msg.appendText("was").appendValue v
+      v?
+    _describeTo: (msg) ->
+      msg.appendText("not").appendValue null
+
+h4q.anything = ->
+  new Matcher
+    _matches: (v, msg) ->
+      msg.appendText("was").appendValue v
+      true
+
+    _describeTo: (msg) ->
+      msg.clearMessage().appendText "anything"
+
+h4q.isA = (type) ->
+  new Matcher
+    type:type
+    _matches: (v, msg) ->
+      msg.appendText("was").appendValue v
+      typeof v is @type
+    _describeTo: (msg) ->
+      msg.appendText(aPrefix @type).appendRawValue @type
+
+h4q.describedAs = (m, t) ->
+  unless m?  and m instanceof Matcher
+    throw new Error message: "describedAs first argument must
+                              be a valid Matcher instance"
+
+  unless t? and typeof t is "string"
+    throw new Error message: "describedAs second argument must
+                              be a valid string"
+
+  extraArgs = h4q.argumentsToArray arguments
+  extraArgs.shift()
+  extraArgs.shift()
+
+  new Matcher
+    description: t
+    matcher: m
+    extraArgs: extraArgs
+    _matches: (v,msg) ->
+      @matcher.matches v, msg
+    _describeTo: (msg) ->
+      msg.appendText h4q.tokenReplace.apply null,
+                                            [@description].concat extraArgs

data/app/assets/javascripts/hamcrest4qunit/matchers/dates.js.coffee

@@ -0,0 +1,166 @@
+h4q.dateAfterOrEqualTo = (d) -> h4q.dateAfter d, true
+h4q.dateAfter = (d, inclusive) ->
+  unless d? and d instanceof Date
+    throw new Error message: "dateAfter must have a valid comparison date"
+
+  new Matcher
+    date: d
+    included: inclusive
+    inclusive: ->
+      @included = true
+      this
+
+    _matches: (v,msg) ->
+      unless v? and v instanceof Date
+        msg.appendText("was").appendValue( v )
+        false
+      else
+        if @included
+          if v >= @date
+            msg.appendText("was").appendRawValue v.toString()
+            true
+          else
+            msg.appendRawValue(v.toString())
+               .appendText("is not after or equal to")
+               .appendRawValue(@date.toString())
+            false
+        else
+          if v > @date
+            msg.appendText("was").appendRawValue(v.toString())
+            true
+          else
+            msg.appendRawValue(v.toString())
+               .appendText("is not after")
+               .appendRawValue(@date.toString())
+            false
+
+    _describeTo: (msg) ->
+      if @included
+        msg.appendText("a date after or equal to")
+           .appendRawValue(@date.toString())
+      else
+        msg.appendText("a date after").appendRawValue(@date.toString())
+
+h4q.dateBeforeOrEqualTo = (d) -> h4q.dateBefore d, true
+h4q.dateBefore = (d,inclusive) ->
+  unless d? and d instanceof Date
+    throw new Error message: "dateBefore must have a valid comparison date"
+
+  new Matcher
+    date: d
+    included: inclusive
+    inclusive: ->
+      @included = true
+      this
+    _matches: (v,msg) ->
+      unless v? and v instanceof Date
+        msg.appendText("was").appendValue(v)
+        false
+      else
+
+        if @included
+          if v <= @date
+            msg.appendText("was").appendRawValue(v.toString())
+            true
+          else
+            msg.appendRawValue(v.toString())
+               .appendText("is not before or equal to")
+               .appendRawValue(@date.toString())
+            false
+        else
+          if v < @date
+            msg.appendText("was").appendRawValue(v.toString())
+            true
+          else
+            msg.appendRawValue(v.toString())
+               .appendText("is not before")
+               .appendRawValue(@date.toString())
+            false
+
+    _describeTo: (msg) ->
+      if @included
+        msg.appendText("a date before or equal to")
+           .appendRawValue(@date.toString())
+      else
+        msg.appendText("a date before").appendRawValue(@date.toString())
+
+h4q.dateBetween = (a,b,inclusive) ->
+
+  unless a? and a instanceof Date
+    throw new Error message: "dateBetween must have a valid first date"
+
+  unless b? and b instanceof Date
+    throw new Error message: "dateBetween must have a valid first date"
+
+  if b <= a
+    throw new Error
+      message: "dateBetween second date must be after the first date"
+
+  new Matcher
+    a: a
+    b: b
+    included: inclusive
+    inclusive: ->
+      @included = true
+      this
+
+    _matches: (v, msg) ->
+      unless v? and v instanceof Date
+        msg.appendText("was").appendValue(v)
+        false
+      else
+        if @included
+          if v < @a
+            msg.appendRawValue(v.toString())
+               .appendText("is before the min date")
+               .appendRawValue(@a.toString())
+            false
+          else if( v > @b )
+            msg.appendRawValue(v.toString())
+               .appendText("is after the max date")
+               .appendRawValue(@b.toString())
+            false
+          else
+            msg.appendText("was").appendRawValue(v.toString())
+            true
+        else
+          if v <= @a
+            msg.appendRawValue(v.toString())
+               .appendText("is before or equal to the min date")
+               .appendRawValue(@a.toString())
+            false
+          else if v >= @b
+            msg.appendRawValue(v.toString())
+               .appendText("is after or equal to the max date")
+               .appendRawValue(@b.toString())
+            false
+          else
+            msg.appendText("was").appendRawValue(v.toString())
+            true
+
+    _describeTo: (msg) ->
+      msg.appendText("a date between")
+         .appendRawValue(@a.toString())
+         .appendText("and")
+         .appendRawValue(@b.toString())
+      if @included
+        msg.appendText("inclusive")
+
+h4q.dateEquals = (d) ->
+  unless d? and d instanceof Date
+    throw new Error
+      message: "dateEquals expect a valid Date object as argument"
+
+  new Matcher
+    date: d
+    _matches: (v,msg) ->
+      unless v? and v instanceof Date
+        msg.appendText("was").appendValue(v)
+        false
+      else
+        msg.appendText("was").appendRawValue(v.toString())
+        v.getTime() is @date.getTime()
+
+    _describeTo: (msg) ->
+      msg.appendText("a Date equal to").appendRawValue(@date.toString())
+

data/app/assets/javascripts/hamcrest4qunit/matchers/dom.js.coffee

@@ -0,0 +1,73 @@
+h4q.equalToNode = (node) ->
+  unless node?
+    throw new Error message: "equalToNode expect an argument"
+  else unless node instanceof Node
+    throw new Error message: "equalToNode except a Node object as argument"
+
+  new Matcher
+    node: node
+    _matches: (v,msg) ->
+      unless v? and v instanceof Node
+        msg.appendText("was").appendValue(v)
+        false
+      else
+        msg.appendText("was\n").appendRawValue(h4q.nodeToString v)
+        if v.isEqualNode(@node)
+          true
+        else
+          msg.diff = QUnit.diff nodeToString(@node), h4q.nodeToString(v)
+          false
+
+    _describeTo: (msg) ->
+      msg.appendText("a Node equal to\n")
+         .appendRawValue(nodeToString @node)
+
+h4q.hasAttribute = (a, m) ->
+
+  unless a?
+    throw new Error message: "hasAttribute expect an attribute name"
+  else if typeof a isnt "string"
+    throw new Error message: "attribute name must be a string"
+
+  m = equalTo(m) if m? and not (m instanceof Matcher)
+
+  new Matcher
+    attribute: a
+    matcher: m
+    _matches: (v,msg) ->
+      unless v? and v instanceof Node
+        msg.appendText("was").appendValue(v)
+        false
+      else
+        if v.attributes[@attribute]?
+          if @matcher
+            av = v.attributes[@attribute].value
+            mismatchMsg = new Description()
+            if !@matcher.matches av, mismatchMsg
+              msg.appendText("attribute")
+                 .appendRawValue(@attribute)
+                 .appendText("value")
+                 .appendText(mismatchMsg)
+                 .appendText("in\n")
+                 .appendRawValue(h4q.nodeToString v)
+              msg.diff = mismatchMsg.diff
+              false
+            else
+              msg.appendText("was\n").appendRawValue(h4q.nodeToString v)
+              true
+          else
+            msg.appendText("was\n").appendRawValue(h4q.nodeToString v)
+            true
+        else
+          msg.appendRawValue(h4q.nodeToString v)
+             .appendText("do not have an attribute")
+             .appendRawValue(@attribute)
+          false
+
+    _describeTo: (msg) ->
+      msg.appendText("a Node with an attribute")
+         .appendRawValue(@attribute)
+
+      if @matcher
+        msg.appendText("of which value is").appendDescriptionOf(@matcher)
+