guard-mthaml 0.1.0

data/vendor/coffeescript/coffeescript/tests/cases/assignment.coffee

@@ -0,0 +1,352 @@
+# Assignment
+# ----------
+
+# * Assignment
+# * Compound Assignment
+# * Destructuring Assignment
+# * Context Property (@) Assignment
+# * Existential Assignment (?=)
+
+test "context property assignment (using @)", ->
+  nonce = {}
+  addMethod = ->
+    @method = -> nonce
+    this
+  eq nonce, addMethod.call({}).method()
+
+test "unassignable values", ->
+  nonce = {}
+  for nonref in ['', '""', '0', 'f()'].concat CoffeeScript.RESERVED
+    eq nonce, (try CoffeeScript.compile "#{nonref} = v" catch e then nonce)
+
+# Compound Assignment
+
+test "boolean operators", ->
+  nonce = {}
+
+  a  = 0
+  a or= nonce
+  eq nonce, a
+
+  b  = 1
+  b or= nonce
+  eq 1, b
+
+  c = 0
+  c and= nonce
+  eq 0, c
+
+  d = 1
+  d and= nonce
+  eq nonce, d
+
+  # ensure that RHS is treated as a group
+  e = f = false
+  e and= f or true
+  eq false, e
+
+test "compound assignment as a sub expression", ->
+  [a, b, c] = [1, 2, 3]
+  eq 6, (a + b += c)
+  eq 1, a
+  eq 5, b
+  eq 3, c
+
+# *note: this test could still use refactoring*
+test "compound assignment should be careful about caching variables", ->
+  count = 0
+  list = []
+
+  list[++count] or= 1
+  eq 1, list[1]
+  eq 1, count
+
+  list[++count] ?= 2
+  eq 2, list[2]
+  eq 2, count
+
+  list[count++] and= 6
+  eq 6, list[2]
+  eq 3, count
+
+  base = ->
+    ++count
+    base
+
+  base().four or= 4
+  eq 4, base.four
+  eq 4, count
+
+  base().five ?= 5
+  eq 5, base.five
+  eq 5, count
+
+test "compound assignment with implicit objects", ->
+  obj = undefined
+  obj ?=
+    one: 1
+
+  eq 1, obj.one
+
+  obj and=
+    two: 2
+
+  eq undefined, obj.one
+  eq         2, obj.two
+
+test "compound assignment (math operators)", ->
+  num = 10
+  num -= 5
+  eq 5, num
+
+  num *= 10
+  eq 50, num
+
+  num /= 10
+  eq 5, num
+
+  num %= 3
+  eq 2, num
+
+test "more compound assignment", ->
+  a = {}
+  val = undefined
+  val ||= a
+  val ||= true
+  eq a, val
+
+  b = {}
+  val &&= true
+  eq val, true
+  val &&= b
+  eq b, val
+
+  c = {}
+  val = null
+  val ?= c
+  val ?= true
+  eq c, val
+
+
+# Destructuring Assignment
+
+test "empty destructuring assignment", ->
+  {} = [] = undefined
+
+test "chained destructuring assignments", ->
+  [a] = {0: b} = {'0': c} = [nonce={}]
+  eq nonce, a
+  eq nonce, b
+  eq nonce, c
+
+test "variable swapping to verify caching of RHS values when appropriate", ->
+  a = nonceA = {}
+  b = nonceB = {}
+  c = nonceC = {}
+  [a, b, c] = [b, c, a]
+  eq nonceB, a
+  eq nonceC, b
+  eq nonceA, c
+  [a, b, c] = [b, c, a]
+  eq nonceC, a
+  eq nonceA, b
+  eq nonceB, c
+  fn = ->
+    [a, b, c] = [b, c, a]
+  arrayEq [nonceA,nonceB,nonceC], fn()
+  eq nonceA, a
+  eq nonceB, b
+  eq nonceC, c
+
+test "#713", ->
+  nonces = [nonceA={},nonceB={}]
+  eq nonces, [a, b] = [c, d] = nonces
+  eq nonceA, a
+  eq nonceA, c
+  eq nonceB, b
+  eq nonceB, d
+
+test "destructuring assignment with splats", ->
+  a = {}; b = {}; c = {}; d = {}; e = {}
+  [x,y...,z] = [a,b,c,d,e]
+  eq a, x
+  arrayEq [b,c,d], y
+  eq e, z
+
+test "deep destructuring assignment with splats", ->
+  a={}; b={}; c={}; d={}; e={}; f={}; g={}; h={}; i={}
+  [u, [v, w..., x], y..., z] = [a, [b, c, d, e], f, g, h, i]
+  eq a, u
+  eq b, v
+  arrayEq [c,d], w
+  eq e, x
+  arrayEq [f,g,h], y
+  eq i, z
+
+test "destructuring assignment with objects", ->
+  a={}; b={}; c={}
+  obj = {a,b,c}
+  {a:x, b:y, c:z} = obj
+  eq a, x
+  eq b, y
+  eq c, z
+
+test "deep destructuring assignment with objects", ->
+  a={}; b={}; c={}; d={}
+  obj = {
+    a
+    b: {
+      'c': {
+        d: [
+          b
+          {e: c, f: d}
+        ]
+      }
+    }
+  }
+  {a: w, 'b': {c: d: [x, {'f': z, e: y}]}} = obj
+  eq a, w
+  eq b, x
+  eq c, y
+  eq d, z
+
+test "destructuring assignment with objects and splats", ->
+  a={}; b={}; c={}; d={}
+  obj = a: b: [a, b, c, d]
+  {a: b: [y, z...]} = obj
+  eq a, y
+  arrayEq [b,c,d], z
+
+test "destructuring assignment against an expression", ->
+  a={}; b={}
+  [y, z] = if true then [a, b] else [b, a]
+  eq a, y
+  eq b, z
+
+test "bracket insertion when necessary", ->
+  [a] = [0] ? [1]
+  eq a, 0
+
+# for implicit destructuring assignment in comprehensions, see the comprehension tests
+
+test "destructuring assignment with context (@) properties", ->
+  a={}; b={}; c={}; d={}; e={}
+  obj =
+    fn: () ->
+      local = [a, {b, c}, d, e]
+      [@a, {b: @b, c: @c}, @d, @e] = local
+  eq undefined, obj[key] for key in ['a','b','c','d','e']
+  obj.fn()
+  eq a, obj.a
+  eq b, obj.b
+  eq c, obj.c
+  eq d, obj.d
+  eq e, obj.e
+
+test "#1024", ->
+  eq 2 * [] = 3 + 5, 16
+
+test "#1005: invalid identifiers allowed on LHS of destructuring assignment", ->
+  disallowed = ['eval', 'arguments'].concat CoffeeScript.RESERVED
+  throws (-> CoffeeScript.compile "[#{disallowed.join ', '}] = x"), null, 'all disallowed'
+  throws (-> CoffeeScript.compile "[#{disallowed.join '..., '}...] = x"), null, 'all disallowed as splats'
+  t = tSplat = null
+  for v in disallowed when v isnt 'class' # `class` by itself is an expression
+    throws (-> CoffeeScript.compile t), null, t = "[#{v}] = x"
+    throws (-> CoffeeScript.compile tSplat), null, tSplat = "[#{v}...] = x"
+  doesNotThrow ->
+    for v in disallowed
+      CoffeeScript.compile "[a.#{v}] = x"
+      CoffeeScript.compile "[a.#{v}...] = x"
+      CoffeeScript.compile "[@#{v}] = x"
+      CoffeeScript.compile "[@#{v}...] = x"
+
+test "#2055: destructuring assignment with `new`", ->
+  {length} = new Array
+  eq 0, length
+
+
+# Existential Assignment
+
+test "existential assignment", ->
+  nonce = {}
+  a = false
+  a ?= nonce
+  eq false, a
+  b = undefined
+  b ?= nonce
+  eq nonce, b
+  c = null
+  c ?= nonce
+  eq nonce, c
+
+test "#1627: prohibit conditional assignment of undefined variables", ->
+  throws (-> CoffeeScript.compile "x ?= 10"),        null, "prohibit (x ?= 10)"
+  throws (-> CoffeeScript.compile "x ||= 10"),       null, "prohibit (x ||= 10)"
+  throws (-> CoffeeScript.compile "x or= 10"),       null, "prohibit (x or= 10)"
+  throws (-> CoffeeScript.compile "do -> x ?= 10"),  null, "prohibit (do -> x ?= 10)"
+  throws (-> CoffeeScript.compile "do -> x ||= 10"), null, "prohibit (do -> x ||= 10)"
+  throws (-> CoffeeScript.compile "do -> x or= 10"), null, "prohibit (do -> x or= 10)"
+  doesNotThrow (-> CoffeeScript.compile "x = null; x ?= 10"),        "allow (x = null; x ?= 10)"
+  doesNotThrow (-> CoffeeScript.compile "x = null; x ||= 10"),       "allow (x = null; x ||= 10)"
+  doesNotThrow (-> CoffeeScript.compile "x = null; x or= 10"),       "allow (x = null; x or= 10)"
+  doesNotThrow (-> CoffeeScript.compile "x = null; do -> x ?= 10"),  "allow (x = null; do -> x ?= 10)"
+  doesNotThrow (-> CoffeeScript.compile "x = null; do -> x ||= 10"), "allow (x = null; do -> x ||= 10)"
+  doesNotThrow (-> CoffeeScript.compile "x = null; do -> x or= 10"), "allow (x = null; do -> x or= 10)"
+  
+  throws (-> CoffeeScript.compile "-> -> -> x ?= 10"), null, "prohibit (-> -> -> x ?= 10)"
+  doesNotThrow (-> CoffeeScript.compile "x = null; -> -> -> x ?= 10"), "allow (x = null; -> -> -> x ?= 10)"
+  
+test "more existential assignment", ->
+  global.temp ?= 0
+  eq global.temp, 0
+  global.temp or= 100
+  eq global.temp, 100
+  delete global.temp
+
+test "#1348, #1216: existential assignment compilation", ->
+  nonce = {}
+  a = nonce
+  b = (a ?= 0)
+  eq nonce, b
+  #the first ?= compiles into a statement; the second ?= compiles to a ternary expression
+  eq a ?= b ?= 1, nonce
+  
+  if a then a ?= 2 else a = 3
+  eq a, nonce
+
+test "#1591, #1101: splatted expressions in destructuring assignment must be assignable", ->
+  nonce = {}
+  for nonref in ['', '""', '0', 'f()', '(->)'].concat CoffeeScript.RESERVED
+    eq nonce, (try CoffeeScript.compile "[#{nonref}...] = v" catch e then nonce)
+
+test "#1643: splatted accesses in destructuring assignments should not be declared as variables", ->
+  nonce = {}
+  accesses = ['o.a', 'o["a"]', '(o.a)', '(o.a).a', '@o.a', 'C::a', 'C::', 'f().a', 'o?.a', 'o?.a.b', 'f?().a']
+  for access in accesses
+    for i,j in [1,2,3] #position can matter
+      code =
+        """
+        nonce = {}; nonce2 = {}; nonce3 = {};
+        @o = o = new (class C then a:{}); f = -> o
+        [#{new Array(i).join('x,')}#{access}...] = [#{new Array(i).join('0,')}nonce, nonce2, nonce3]
+        unless #{access}[0] is nonce and #{access}[1] is nonce2 and #{access}[2] is nonce3 then throw new Error('[...]')
+        """
+      eq nonce, unless (try CoffeeScript.run code, bare: true catch e then true) then nonce
+  # subpatterns like `[[a]...]` and `[{a}...]`
+  subpatterns = ['[sub, sub2, sub3]', '{0: sub, 1: sub2, 2: sub3}']
+  for subpattern in subpatterns
+    for i,j in [1,2,3]
+      code =
+        """
+        nonce = {}; nonce2 = {}; nonce3 = {};
+        [#{new Array(i).join('x,')}#{subpattern}...] = [#{new Array(i).join('0,')}nonce, nonce2, nonce3]
+        unless sub is nonce and sub2 is nonce2 and sub3 is nonce3 then throw new Error('[sub...]')
+        """
+      eq nonce, unless (try CoffeeScript.run code, bare: true catch e then true) then nonce
+
+test "#1838: Regression with variable assignment", ->
+  name =
+  'dave'
+
+  eq name, 'dave'

data/vendor/coffeescript/coffeescript/tests/cases/booleans.coffee

@@ -0,0 +1,21 @@
+# Boolean Literals
+# ----------------
+
+# TODO: add method invocation tests: true.toString() is "true"
+
+test "#764 Booleans should be indexable", ->
+  toString = Boolean::toString
+
+  eq toString, true['toString']
+  eq toString, false['toString']
+  eq toString, yes['toString']
+  eq toString, no['toString']
+  eq toString, on['toString']
+  eq toString, off['toString']
+
+  eq toString, true.toString
+  eq toString, false.toString
+  eq toString, yes.toString
+  eq toString, no.toString
+  eq toString, on.toString
+  eq toString, off.toString

data/vendor/coffeescript/coffeescript/tests/cases/classes.coffee

@@ -0,0 +1,681 @@
+# Classes
+# -------
+
+# * Class Definition
+# * Class Instantiation
+# * Inheritance and Super
+
+test "classes with a four-level inheritance chain", ->
+
+  class Base
+    func: (string) ->
+      "zero/#{string}"
+
+    @static: (string) ->
+      "static/#{string}"
+
+  class FirstChild extends Base
+    func: (string) ->
+      super('one/') + string
+
+  SecondChild = class extends FirstChild
+    func: (string) ->
+      super('two/') + string
+
+  thirdCtor = ->
+    @array = [1, 2, 3]
+
+  class ThirdChild extends SecondChild
+    constructor: -> thirdCtor.call this
+
+    # Gratuitous comment for testing.
+    func: (string) ->
+      super('three/') + string
+
+  result = (new ThirdChild).func 'four'
+
+  ok result is 'zero/one/two/three/four'
+  ok Base.static('word') is 'static/word'
+
+  FirstChild::func = (string) ->
+    super('one/').length + string
+
+  result = (new ThirdChild).func 'four'
+
+  ok result is '9two/three/four'
+
+  ok (new ThirdChild).array.join(' ') is '1 2 3'
+
+
+test "constructors with inheritance and super", ->
+
+  identity = (f) -> f
+
+  class TopClass
+    constructor: (arg) ->
+      @prop = 'top-' + arg
+
+  class SuperClass extends TopClass
+    constructor: (arg) ->
+      identity super 'super-' + arg
+
+  class SubClass extends SuperClass
+    constructor: ->
+      identity super 'sub'
+
+  ok (new SubClass).prop is 'top-super-sub'
+
+
+test "Overriding the static property new doesn't clobber Function::new", ->
+
+  class OneClass
+    @new: 'new'
+    function: 'function'
+    constructor: (name) -> @name = name
+
+  class TwoClass extends OneClass
+  delete TwoClass.new
+
+  Function.prototype.new = -> new this arguments...
+
+  ok (TwoClass.new('three')).name is 'three'
+  ok (new OneClass).function is 'function'
+  ok OneClass.new is 'new'
+
+  delete Function.prototype.new
+
+
+test "basic classes, again, but in the manual prototype style", ->
+
+  Base = ->
+  Base::func = (string) ->
+    'zero/' + string
+  Base::['func-func'] = (string) ->
+    "dynamic-#{string}"
+
+  FirstChild = ->
+  SecondChild = ->
+  ThirdChild = ->
+    @array = [1, 2, 3]
+    this
+
+  ThirdChild extends SecondChild extends FirstChild extends Base
+
+  FirstChild::func = (string) ->
+    super('one/') + string
+
+  SecondChild::func = (string) ->
+    super('two/') + string
+
+  ThirdChild::func = (string) ->
+    super('three/') + string
+
+  result = (new ThirdChild).func 'four'
+
+  ok result is 'zero/one/two/three/four'
+
+  ok (new ThirdChild)['func-func']('thing') is 'dynamic-thing'
+
+
+test "super with plain ol' functions as the original constructors", ->
+
+TopClass = (arg) ->
+  @prop = 'top-' + arg
+  this
+
+SuperClass = (arg) ->
+  super 'super-' + arg
+  this
+
+SubClass = ->
+  super 'sub'
+  this
+
+SuperClass extends TopClass
+SubClass extends SuperClass
+
+ok (new SubClass).prop is 'top-super-sub'
+
+
+test "'@' referring to the current instance, and not being coerced into a call", ->
+
+  class ClassName
+    amI: ->
+      @ instanceof ClassName
+
+  obj = new ClassName
+  ok obj.amI()
+
+
+test "super() calls in constructors of classes that are defined as object properties", ->
+
+  class Hive
+    constructor: (name) -> @name = name
+
+  class Hive.Bee extends Hive
+    constructor: (name) -> super
+
+  maya = new Hive.Bee 'Maya'
+  ok maya.name is 'Maya'
+
+
+test "classes with JS-keyword properties", ->
+
+  class Class
+    class: 'class'
+    name: -> @class
+
+  instance = new Class
+  ok instance.class is 'class'
+  ok instance.name() is 'class'
+
+
+test "Classes with methods that are pre-bound to the instance, or statically, to the class", ->
+
+  class Dog
+    constructor: (name) ->
+      @name = name
+
+    bark: =>
+      "#{@name} woofs!"
+
+    @static = =>
+      new this('Dog')
+
+  spark = new Dog('Spark')
+  fido  = new Dog('Fido')
+  fido.bark = spark.bark
+
+  ok fido.bark() is 'Spark woofs!'
+
+  obj = func: Dog.static
+
+  ok obj.func().name is 'Dog'
+
+
+test "a bound function in a bound function", ->
+
+  class Mini
+    num: 10
+    generate: =>
+      for i in [1..3]
+        =>
+          @num
+
+  m = new Mini
+  eq (func() for func in m.generate()).join(' '), '10 10 10'
+
+
+test "contructor called with varargs", ->
+
+  class Connection
+    constructor: (one, two, three) ->
+      [@one, @two, @three] = [one, two, three]
+
+    out: ->
+      "#{@one}-#{@two}-#{@three}"
+
+  list = [3, 2, 1]
+  conn = new Connection list...
+  ok conn instanceof Connection
+  ok conn.out() is '3-2-1'
+
+
+test "calling super and passing along all arguments", ->
+
+  class Parent
+    method: (args...) -> @args = args
+
+  class Child extends Parent
+    method: -> super
+
+  c = new Child
+  c.method 1, 2, 3, 4
+  ok c.args.join(' ') is '1 2 3 4'
+
+
+test "classes wrapped in decorators", ->
+
+  func = (klass) ->
+    klass::prop = 'value'
+    klass
+
+  func class Test
+    prop2: 'value2'
+
+  ok (new Test).prop  is 'value'
+  ok (new Test).prop2 is 'value2'
+
+
+test "anonymous classes", ->
+
+  obj =
+    klass: class
+      method: -> 'value'
+
+  instance = new obj.klass
+  ok instance.method() is 'value'
+
+
+test "Implicit objects as static properties", ->
+
+  class Static
+    @static =
+      one: 1
+      two: 2
+
+  ok Static.static.one is 1
+  ok Static.static.two is 2
+
+
+test "nothing classes", ->
+
+  c = class
+  ok c instanceof Function
+
+
+test "classes with static-level implicit objects", ->
+
+  class A
+    @static = one: 1
+    two: 2
+
+  class B
+    @static = one: 1,
+    two: 2
+
+  eq A.static.one, 1
+  eq A.static.two, undefined
+  eq (new A).two, 2
+
+  eq B.static.one, 1
+  eq B.static.two, 2
+  eq (new B).two, undefined
+
+
+test "classes with value'd constructors", ->
+
+  counter = 0
+  classMaker = ->
+    inner = ++counter
+    ->
+      @value = inner
+
+  class One
+    constructor: classMaker()
+
+  class Two
+    constructor: classMaker()
+
+  eq (new One).value, 1
+  eq (new Two).value, 2
+  eq (new One).value, 1
+  eq (new Two).value, 2
+
+
+test "exectuable class bodies", ->
+
+  class A
+    if true
+      b: 'b'
+    else
+      c: 'c'
+
+  a = new A
+
+  eq a.b, 'b'
+  eq a.c, undefined
+
+
+test "mild metaprogramming", ->
+
+  class Base
+    @attr: (name) ->
+      @::[name] = (val) ->
+        if arguments.length > 0
+          @["_#{name}"] = val
+        else
+          @["_#{name}"]
+
+  class Robot extends Base
+    @attr 'power'
+    @attr 'speed'
+
+  robby = new Robot
+
+  ok robby.power() is undefined
+
+  robby.power 11
+  robby.speed Infinity
+
+  eq robby.power(), 11
+  eq robby.speed(), Infinity
+
+
+test "namespaced classes do not reserve their function name in outside scope", ->
+
+  one = {}
+  two = {}
+
+  class one.Klass
+    @label = "one"
+
+  class two.Klass
+    @label = "two"
+
+  eq typeof Klass, 'undefined'
+  eq one.Klass.label, 'one'
+  eq two.Klass.label, 'two'
+
+
+test "nested classes", ->
+
+  class Outer
+    constructor: ->
+      @label = 'outer'
+
+    class @Inner
+      constructor: ->
+        @label = 'inner'
+
+  eq (new Outer).label, 'outer'
+  eq (new Outer.Inner).label, 'inner'
+
+
+test "variables in constructor bodies are correctly scoped", ->
+
+  class A
+    x = 1
+    constructor: ->
+      x = 10
+      y = 20
+    y = 2
+    captured: ->
+      {x, y}
+
+  a = new A
+  eq a.captured().x, 10
+  eq a.captured().y, 2
+
+
+test "Issue #924: Static methods in nested classes", ->
+
+  class A
+    @B: class
+      @c = -> 5
+
+  eq A.B.c(), 5
+
+
+test "`class extends this`", ->
+
+  class A
+    func: -> 'A'
+
+  B = null
+  makeClass = ->
+    B = class extends this
+      func: -> super + ' B'
+
+  makeClass.call A
+
+  eq (new B()).func(), 'A B'
+
+
+test "ensure that constructors invoked with splats return a new object", ->
+
+  args = [1, 2, 3]
+  Type = (@args) ->
+  type = new Type args
+
+  ok type and type instanceof Type
+  ok type.args and type.args instanceof Array
+  ok v is args[i] for v, i in type.args
+
+  Type1 = (@a, @b, @c) ->
+  type1 = new Type1 args...
+
+  ok type1 instanceof   Type1
+  eq type1.constructor, Type1
+  ok type1.a is args[0] and type1.b is args[1] and type1.c is args[2]
+
+  # Ensure that constructors invoked with splats cache the function.
+  called = 0
+  get = -> if called++ then false else class Type
+  new get() args...
+
+test "`new` shouldn't add extra parens", ->
+
+  ok new Date().constructor is Date
+
+
+test "`new` works against bare function", ->
+
+  eq Date, new ->
+    eq this, new => this
+    Date
+
+
+test "#1182: a subclass should be able to set its constructor to an external function", ->
+  ctor = ->
+    @val = 1
+  class A
+  class B extends A
+    constructor: ctor
+  eq (new B).val, 1
+
+test "#1182: external constructors continued", ->
+  ctor = ->
+  class A
+  class B extends A
+    method: ->
+    constructor: ctor
+  ok B::method
+
+test "#1313: misplaced __extends", ->
+  nonce = {}
+  class A
+  class B extends A
+    prop: nonce
+    constructor: ->
+  eq nonce, B::prop
+
+test "#1182: execution order needs to be considered as well", ->
+  counter = 0
+  makeFn = (n) -> eq n, ++counter; ->
+  class B extends (makeFn 1)
+    @B: makeFn 2
+    constructor: makeFn 3
+
+test "#1182: external constructors with bound functions", ->
+  fn = ->
+    {one: 1}
+    this
+  class B
+  class A
+    constructor: fn
+    method: => this instanceof A
+  ok (new A).method.call(new B)
+
+test "#1372: bound class methods with reserved names", ->
+  class C
+    delete: =>
+  ok C::delete
+
+test "#1380: `super` with reserved names", ->
+  class C
+    do: -> super
+  ok C::do
+
+  class B
+    0: -> super
+  ok B::[0]
+
+test "#1464: bound class methods should keep context", ->
+  nonce  = {}
+  nonce2 = {}
+  class C
+    constructor: (@id) ->
+    @boundStaticColon: => new this(nonce)
+    @boundStaticEqual= => new this(nonce2)
+  eq nonce,  C.boundStaticColon().id
+  eq nonce2, C.boundStaticEqual().id
+
+test "#1009: classes with reserved words as determined names", -> (->
+  eq 'function', typeof (class @for)
+  ok not /\beval\b/.test (class @eval).toString()
+  ok not /\barguments\b/.test (class @arguments).toString()
+).call {}
+
+test "#1482: classes can extend expressions", ->
+  id = (x) -> x
+  nonce = {}
+  class A then nonce: nonce
+  class B extends id A
+  eq nonce, (new B).nonce
+
+test "#1598: super works for static methods too", ->
+
+  class Parent
+    method: ->
+      'NO'
+    @method: ->
+      'yes'
+
+  class Child extends Parent
+    @method: ->
+      'pass? ' + super
+
+  eq Child.method(), 'pass? yes'
+
+test "#1842: Regression with bound functions within bound class methods", ->
+
+  class Store
+    @bound: =>
+      do =>
+        eq this, Store
+
+  Store.bound()
+
+  # And a fancier case:
+
+  class Store
+
+    eq this, Store
+
+    @bound: =>
+      do =>
+        eq this, Store
+
+    @unbound: ->
+      eq this, Store
+
+    instance: =>
+      ok this instanceof Store
+
+  Store.bound()
+  Store.unbound()
+  (new Store).instance()
+
+test "#1876: Class @A extends A", ->
+  class A
+  class @A extends A
+
+  ok (new @A) instanceof A
+
+test "#1813: Passing class definitions as expressions", ->
+  ident = (x) -> x
+
+  result = ident class A then x = 1
+
+  eq result, A
+
+  result = ident class B extends A
+    x = 1
+
+  eq result, B
+
+test "#494: Named classes", ->
+
+  class A
+  eq A.name, 'A'
+
+  class A.B
+  eq A.B.name, 'B'
+
+  class A.B["C"]
+  ok A.B.C.name isnt 'C'
+
+test "#1966: external constructors should produce their return value", ->
+  ctor = -> {}
+  class A then constructor: ctor
+  ok (new A) not instanceof A
+
+test "#1980: regression with an inherited class with static function members", ->
+
+  class A
+
+  class B extends A
+    @static: => 'value'
+
+  eq B.static(), 'value'
+
+test "#1534: class then 'use strict'", ->
+  # [14.1 Directive Prologues and the Use Strict Directive](http://es5.github.com/#x14.1)
+  nonce = {}
+  error = 'do -> ok this'
+  strictTest = "do ->'use strict';#{error}"
+  return unless (try CoffeeScript.run strictTest, bare: yes catch e then nonce) is nonce
+
+  throws -> CoffeeScript.run "class then 'use strict';#{error}", bare: yes
+  doesNotThrow -> CoffeeScript.run "class then #{error}", bare: yes
+  doesNotThrow -> CoffeeScript.run "class then #{error};'use strict'", bare: yes
+
+  # comments are ignored in the Directive Prologue
+  comments = ["""
+  class
+    ### comment ###
+    'use strict'
+    #{error}""",
+  """
+  class
+    ### comment 1 ###
+    ### comment 2 ###
+    'use strict'
+    #{error}""",
+  """
+  class
+    ### comment 1 ###
+    ### comment 2 ###
+    'use strict'
+    #{error}
+    ### comment 3 ###"""
+  ]
+  throws (-> CoffeeScript.run comment, bare: yes) for comment in comments
+
+  # [ES5 §14.1](http://es5.github.com/#x14.1) allows for other directives
+  directives = ["""
+  class
+    'directive 1'
+    'use strict'
+    #{error}""",
+  """
+  class
+    'use strict'
+    'directive 2'
+    #{error}""",
+  """
+  class
+    ### comment 1 ###
+    'directive 1'
+    'use strict'
+    #{error}""",
+  """
+  class
+    ### comment 1 ###
+    'directive 1'
+    ### comment 2 ###
+    'use strict'
+    #{error}"""
+  ]
+  throws (-> CoffeeScript.run directive, bare: yes) for directive in directives