georgia 0.7.0

data/app/assets/javascripts/georgia/application.js

@@ -0,0 +1,20 @@
+//= require jquery
+//= require jquery.ui.core
+//= require jquery.ui.sortable
+//= require jquery.ui.tooltip
+//= require jquery_ujs
+//= require jquery-fileupload/basic
+//= require select2
+//= require shadowbox
+//= require mousetrap
+
+//= require ckeditor/init
+//= require_tree ./ckeditor
+
+//= require ./vendor/moment
+//= require_tree ./vendor
+//= require_tree ./components
+//= require ./bootstrap-vendor
+//= require ./featured-image
+//= require ./keybindings
+//= require ./toggle

data/app/assets/javascripts/georgia/bootstrap-vendor.js.coffee

@@ -0,0 +1,13 @@
+jQuery ->
+  Shadowbox.init()
+  $('.js-focus').focus()
+  $('.js-tooltip').tooltip()
+  $('.js-select2').select2()
+  $('.js-datepicker').datetimepicker(
+    icons:
+      time: "fa fa-clock-o"
+      date: "fa fa-calendar"
+      up: "fa fa-arrow-up"
+      down: "fa fa-arrow-down"
+  )
+  $(".modal").on('shown.bs.modal', () -> $(this).find('input:text:visible:first').focus())

data/app/assets/javascripts/georgia/ckeditor/config.js

@@ -0,0 +1,22 @@
+var CKEDITOR_BASEPATH = '/assets/ckeditor/';
+CKEDITOR.config.ignoreEmptyParagraph = false;
+CKEDITOR.config.allowedContent = true;
+CKEDITOR.config.baseHref = '/assets/ckeditor/';
+CKEDITOR.config.height = 400;
+CKEDITOR.config.width = '95.5%';
+CKEDITOR.config.toolbarStartupExpanded = false;
+CKEDITOR.config.toolbarGroups = [
+  { name: 'document', groups: [ 'mode', 'document', 'doctools' ] },
+  { name: 'clipboard', groups: [ 'clipboard', 'undo' ] },
+  { name: 'editing', groups: [ 'find', 'selection', 'spellchecker' ] },
+  '/',
+  { name: 'basicstyles', groups: [ 'basicstyles', 'cleanup' ] },
+  { name: 'paragraph', groups: [ 'list', 'indent', 'blocks', 'align' ] },
+  { name: 'links' },
+  { name: 'insert' },
+  '/',
+  { name: 'styles' },
+  { name: 'colors' },
+  { name: 'tools' },
+  { name: 'others' }
+];

data/app/assets/javascripts/georgia/components/asset-replacer.js.coffee

@@ -0,0 +1,25 @@
+class @AssetReplacer
+
+  constructor: (element, options={}) ->
+    @element = $(element)
+    @input = @element.find('.js-replace-asset')
+    @form = @element.find('form')
+    @btn = @input.prev()
+    @actions = @element.find('.media-actions')
+    @bindEvents()
+
+  bindEvents: () =>
+    @input.on('change', @change)
+    @element.on('mouseover', @toggleActions)
+    @element.on('mouseout', @toggleActions)
+
+  change: (e) =>
+    @form.submit()
+    @btn.html("<i class='fa fa-spinner fa-spin'></i> Uploading...")
+
+  toggleActions: (e) =>
+    @actions.toggle()
+
+jQuery ->
+  $('.js-media-editable').each (index, el) ->
+    new AssetReplacer(el)

data/app/assets/javascripts/georgia/components/asset-uploader.js.coffee

@@ -0,0 +1,44 @@
+# We use fileuploadalways callback because the response from the server is not accepted as successful
+# See other callbacks here: https://github.com/blueimp/jQuery-File-Upload/wiki/Options#callback-options
+class @AssetUploader
+
+  constructor: (element, options={}) ->
+    @el = $(element)
+    @btn = @el.prev()
+    @progress = $('#progress')
+    @progressBar = $('#progress .progress-bar')
+    @bindEvents()
+
+  bindEvents: () =>
+    @el.fileupload(dataType: 'jsonp')
+    # @el.on('fileuploadadd', @fileuploadadd)
+    @el.on('fileuploadsend', @fileuploadsend)
+    @el.on('fileuploadalways', @fileuploadalways)
+    @el.on('fileuploadprogressall', @fileuploadprogressall)
+
+  fileuploadadd: (e, data) -> data.submit()
+
+  fileuploadsend: (e, data) =>
+    @btn.html("<i class='fa fa-spinner fa-spin'></i> Uploading...")
+    @progress.modal('show')
+
+  fileuploadalways: (e, data) =>
+    @progress.modal('hide')
+    @btn.html("<i class='fa fa-check'></i> Uploaded")
+    setTimeout(
+      -> @btn.html("<i class='fa fa-plus'></i> Select files...")
+      1500
+    )
+
+  fileuploadprogressall: (e, data) =>
+    progress = parseInt(data.loaded / data.total * 100, 10)
+    @progressBar
+      .css('width', "#{progress}%")
+      .attr('aria-valuenow', "#{progress}%")
+
+$.fn.uploadable = ->
+  @each ->
+    new AssetUploader(this)
+
+jQuery ->
+  $('.js-file-upload').uploadable()

data/app/assets/javascripts/georgia/components/flash.js.coffee

@@ -0,0 +1,15 @@
+class Flash
+  constructor: (message, type)->
+    flash = $(".flash-container")
+    flash.html("")
+
+    $('<div/>',
+      class: "flash-#{type}",
+      text: message
+    ).appendTo(".flash-container")
+
+    flash.click -> $(@).fadeOut()
+    flash.show()
+    setTimeout (-> flash.fadeOut()), 5000
+
+@Flash = Flash

data/app/assets/javascripts/georgia/components/forms/menu.js.coffee

@@ -0,0 +1,66 @@
+class @MenuForm
+
+  constructor: (element) ->
+    @element = $(element)
+    @links = @element.find('li')
+    @addLinkBtn = $('.js-add-link')
+    @treeInput = $('.js-menu-ancestry')
+    @setBindings()
+
+  setBindings: () =>
+    @bindAddLink()
+    @bindRemoveLink()
+    @loadPortlets()
+    @loadNestedSortable()
+
+  loadPortlets: =>
+    $.each(@links, -> new LinkPortlet($(this)))
+
+  addLink: (event) =>
+    event.preventDefault()
+    $('.blank-state').remove()
+    $.ajax(type: 'POST', url: "/admin/links", data: {menu_id: @element.data('menu-id')} )
+      .done( (data) =>
+        @element.append(data)
+        portlet = $(data)
+        new LinkPortlet(portlet)
+      )
+
+  removeLink: (event) =>
+    event.preventDefault()
+    portlet = $(event.currentTarget).closest('.portlet')
+    portlet.find('input.js-destroy').val('1')
+    portlet.hide()
+
+  bindRemoveLink: () =>
+    $('body').on('click', '.js-remove-link', @removeLink)
+
+  bindAddLink: () =>
+    @addLinkBtn.on('click', @addLink)
+
+  loadNestedSortable: () =>
+    @element.nestedSortable(
+      forcePlaceholderSize: true
+      items: 'li'
+      handle: '.handle'
+      helper: 'clone'
+      opacity: .6
+      placeholder: 'placeholder'
+      revert: 250
+      tabSize: 25
+      tolerance: 'pointer'
+      maxLevels: 3
+      isTree: true
+      expandOnHover: 700
+      startCollapsed: true
+      update: () =>
+        @treeInput.val(@element.nestedSortable('serialize'))
+    )
+
+$.fn.menuForm = () ->
+  @each ->
+    new MenuForm($(this))
+
+jQuery ->
+  $('.js-nested-sortable').each () ->
+    $(this).menuForm()

data/app/assets/javascripts/georgia/components/forms/revision.js.coffee

@@ -0,0 +1,22 @@
+class @RevisionForm
+
+  constructor: (element) ->
+    @element = $(element)
+    @title   = @element.find('.header-title')
+    @titleTrigger = @title.find('a')
+    @setBindings()
+
+  setBindings: () =>
+    @titleTrigger.on('mouseover', @toggleIcon)
+    @titleTrigger.on('mouseout', @toggleIcon)
+    @titleTrigger.on('click', @showInput)
+
+  toggleIcon:  =>
+    @title.find('i').toggle()
+  showInput: =>
+    @title.find('input').show()
+    @title.find('h1').hide()
+
+jQuery ->
+  $('.js-revision-form').each () ->
+    new RevisionForm(this)

data/app/assets/javascripts/georgia/components/forms/spinning.js.coffee

@@ -0,0 +1,51 @@
+class @SpinningForm
+
+  constructor: (element) ->
+    @element = $(element)
+    @submitBtn = @element.find("[type='submit']")
+    @setBindings()
+
+  setBindings: () =>
+    @element.on('ajax:beforeSend', (event, xhr, settings) =>
+      @disableBtn()
+      @submitBtn.html("<i class='fa fa-spinner fa-spin'>&nbsp;</i> Saving...")
+    )
+    @element.on('ajax:success', (event, xhr, status) =>
+      @submitBtn
+        .addClass('btn-info')
+        .html("<i class='fa fa-check'>&nbsp;</i> Saved")
+    )
+    @element.on('ajax:error', (event, xhr, status) =>
+      @submitBtn
+        .addClass('btn-danger')
+        .html("<i class='fa fa-exclamation-triangle'>&nbsp;</i> Oups!")
+    )
+    @element.on('ajax:complete', (event, xhr, status) =>
+      setTimeout(
+        () =>
+          @clearBtnClasses()
+          @enableBtn()
+          @submitBtn.html("<i class='fa fa-check'>&nbsp;</i> Save")
+        , 2000
+      )
+    )
+
+  disableBtn: () =>
+    @submitBtn.prop('disabled', true)
+
+  enableBtn: () =>
+    @submitBtn.prop('disabled', false)
+
+  clearBtnClasses: () =>
+    @submitBtn
+      .removeClass('btn-info')
+      .removeClass('btn-danger')
+
+
+$.fn.spinningForm = () ->
+  @each ->
+    new SpinningForm($(this))
+
+jQuery ->
+  $("form[data-remote='true']").each () ->
+    $(this).spinningForm()

data/app/assets/javascripts/georgia/components/media-library.js.coffee

@@ -0,0 +1,57 @@
+class @MediaLibrary
+
+  constructor: (element, target) ->
+    @element            = $(element)
+    @target             = null
+    @picturesContainer  = @element.find("[data-media='results']")
+    @search             = @element.find("[data-media='search']")
+    @search.bind('change', @update)
+    @element.on('click', "[data-media='results'] a[rel='next']", @changePage)
+    @element.on('click', "[data-media='results'] a[rel='previous']", @changePage)
+    @element.on('click', "[data-media='picture']", @select)
+    @update()
+
+  update: () =>
+    @loadSpinner()
+    url = '/admin/api/media/pictures'
+    @performQuery(url)
+
+  changePage: (event) =>
+    @stopEvent(event)
+    @loadSpinner()
+    url = $(event.currentTarget).attr('href')
+    @performQuery(url)
+
+  select: (event) =>
+    @stopEvent(event)
+    @closeMediaLibrary()
+    picture = $(event.currentTarget).clone()
+    @target.find('.js-media-image').html(picture)
+    @target.find('input').val(picture.data('media-id'))
+
+  performQuery: (url) ->
+    $.ajax(
+      url: url
+      data:
+        query: @query
+    ).done( (data) => @picturesContainer.html(data) )
+
+  setTarget: (target) => @target = $(target)
+  closeMediaLibrary: -> $('.js-close, .close').trigger('click')
+  loadSpinner: => @picturesContainer.html(@spinnerTag())
+  stopEvent: (event) ->
+    event.stopPropagation()
+    event.preventDefault()
+
+  query: => @search.val()
+  spinnerTag: -> "<div class='spinner'><i class='fa fa-spinner fa-4x'></i></div>"
+
+jQuery ->
+  # If the media library modal is loaded,
+  # Create a js object
+  # When the 'choose image' button is clicked, reset the target
+  if $("#media_library").length
+    mediaLibrary = new MediaLibrary($("#media_library"))
+    $('body').on('click', '.js-media-library', () ->
+      mediaLibrary.setTarget($(this).data('media'))
+    )

data/app/assets/javascripts/georgia/components/portlets/link.js.coffee

@@ -0,0 +1,14 @@
+class @LinkPortlet
+
+  constructor: (element) ->
+    @element = $(element)
+    @expandBtn = @element.find('> div > div.actions > .js-expand')
+    @setBindings()
+
+  setBindings: () =>
+    @expandBtn.on('click', @toggleExpand)
+
+  toggleExpand: () =>
+    @element.find('> ol').toggleClass('hide')
+    @expandBtn.find('i').toggleClass('hide')
+    @element.toggleClass('is-expanded')