geo_coder 0.1.0

data/src/liblwgeom/wktparse.tab.h

@@ -0,0 +1,145 @@
+/* A Bison parser, made by GNU Bison 2.3.  */
+
+/* Skeleton interface for Bison's Yacc-like parsers in C
+
+   Copyright (C) 1984, 1989, 1990, 2000, 2001, 2002, 2003, 2004, 2005, 2006
+   Free Software Foundation, Inc.
+
+   This program is free software; you can redistribute it and/or modify
+   it under the terms of the GNU General Public License as published by
+   the Free Software Foundation; either version 2, or (at your option)
+   any later version.
+
+   This program is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+   GNU General Public License for more details.
+
+   You should have received a copy of the GNU General Public License
+   along with this program; if not, write to the Free Software
+   Foundation, Inc., 51 Franklin Street, Fifth Floor,
+   Boston, MA 02110-1301, USA.  */
+
+/* As a special exception, you may create a larger work that contains
+   part or all of the Bison parser skeleton and distribute that work
+   under terms of your choice, so long as that work isn't itself a
+   parser generator using the skeleton or a modified version thereof
+   as a parser skeleton.  Alternatively, if you modify or redistribute
+   the parser skeleton itself, you may (at your option) remove this
+   special exception, which will cause the skeleton and the resulting
+   Bison output files to be licensed under the GNU General Public
+   License without this special exception.
+
+   This special exception was added by the Free Software Foundation in
+   version 2.2 of Bison.  */
+
+/* Tokens.  */
+#ifndef YYTOKENTYPE
+# define YYTOKENTYPE
+   /* Put the tokens into the symbol table, so that GDB and other debuggers
+      know about them.  */
+   enum yytokentype {
+     POINT = 258,
+     LINESTRING = 259,
+     POLYGON = 260,
+     MULTIPOINT = 261,
+     MULTILINESTRING = 262,
+     MULTIPOLYGON = 263,
+     GEOMETRYCOLLECTION = 264,
+     CIRCULARSTRING = 265,
+     COMPOUNDCURVE = 266,
+     CURVEPOLYGON = 267,
+     MULTICURVE = 268,
+     MULTISURFACE = 269,
+     POINTM = 270,
+     LINESTRINGM = 271,
+     POLYGONM = 272,
+     MULTIPOINTM = 273,
+     MULTILINESTRINGM = 274,
+     MULTIPOLYGONM = 275,
+     GEOMETRYCOLLECTIONM = 276,
+     CIRCULARSTRINGM = 277,
+     COMPOUNDCURVEM = 278,
+     CURVEPOLYGONM = 279,
+     MULTICURVEM = 280,
+     MULTISURFACEM = 281,
+     SRID = 282,
+     EMPTY = 283,
+     VALUE = 284,
+     LPAREN = 285,
+     RPAREN = 286,
+     COMMA = 287,
+     EQUALS = 288,
+     SEMICOLON = 289,
+     WKB = 290
+   };
+#endif
+/* Tokens.  */
+#define POINT 258
+#define LINESTRING 259
+#define POLYGON 260
+#define MULTIPOINT 261
+#define MULTILINESTRING 262
+#define MULTIPOLYGON 263
+#define GEOMETRYCOLLECTION 264
+#define CIRCULARSTRING 265
+#define COMPOUNDCURVE 266
+#define CURVEPOLYGON 267
+#define MULTICURVE 268
+#define MULTISURFACE 269
+#define POINTM 270
+#define LINESTRINGM 271
+#define POLYGONM 272
+#define MULTIPOINTM 273
+#define MULTILINESTRINGM 274
+#define MULTIPOLYGONM 275
+#define GEOMETRYCOLLECTIONM 276
+#define CIRCULARSTRINGM 277
+#define COMPOUNDCURVEM 278
+#define CURVEPOLYGONM 279
+#define MULTICURVEM 280
+#define MULTISURFACEM 281
+#define SRID 282
+#define EMPTY 283
+#define VALUE 284
+#define LPAREN 285
+#define RPAREN 286
+#define COMMA 287
+#define EQUALS 288
+#define SEMICOLON 289
+#define WKB 290
+
+
+
+
+#if ! defined YYSTYPE && ! defined YYSTYPE_IS_DECLARED
+typedef union YYSTYPE
+#line 22 "wktparse.y"
+{
+	double value;
+	const char* wkb;
+}
+/* Line 1489 of yacc.c.  */
+#line 124 "y.tab.h"
+	YYSTYPE;
+# define yystype YYSTYPE /* obsolescent; will be withdrawn */
+# define YYSTYPE_IS_DECLARED 1
+# define YYSTYPE_IS_TRIVIAL 1
+#endif
+
+extern YYSTYPE lwg_parse_yylval;
+
+#if ! defined YYLTYPE && ! defined YYLTYPE_IS_DECLARED
+typedef struct YYLTYPE
+{
+  int first_line;
+  int first_column;
+  int last_line;
+  int last_column;
+} YYLTYPE;
+# define yyltype YYLTYPE /* obsolescent; will be withdrawn */
+# define YYLTYPE_IS_DECLARED 1
+# define YYLTYPE_IS_TRIVIAL 1
+#endif
+
+extern YYLTYPE lwg_parse_yylloc;

data/src/liblwgeom/wktparse.y

@@ -0,0 +1,385 @@
+/*
+ * Written by Ralph Mason ralph.mason<at>telogis.com
+ *
+ * Copyright Telogis 2004
+ * www.telogis.com
+ *
+ */
+
+%{
+#include "wktparse.h"
+#include <unistd.h>
+#include <stdio.h>
+
+void set_zm(char z, char m);
+int lwg_parse_yylex(void);
+%}
+
+%start geometry
+
+%locations
+
+%union {
+	double value;
+	const char* wkb;
+}
+
+%token POINT LINESTRING POLYGON MULTIPOINT MULTILINESTRING MULTIPOLYGON GEOMETRYCOLLECTION CIRCULARSTRING COMPOUNDCURVE CURVEPOLYGON MULTICURVE MULTISURFACE
+%token POINTM LINESTRINGM POLYGONM MULTIPOINTM MULTILINESTRINGM MULTIPOLYGONM GEOMETRYCOLLECTIONM CIRCULARSTRINGM COMPOUNDCURVEM CURVEPOLYGONM  MULTICURVEM MULTISURFACEM
+%token SRID      
+%token EMPTY
+%token <value> VALUE
+%token LPAREN RPAREN COMMA EQUALS SEMICOLON
+%token  <wkb> WKB
+
+%%
+
+geometry :
+	srid  SEMICOLON  { alloc_lwgeom(srid); } geometry_int 
+	|
+	{ alloc_lwgeom(-1); } geometry_int
+
+geometry_int :
+	geom_wkb
+	|
+	geom_point
+	|
+	geom_linestring
+	|
+        geom_circularstring
+        |
+	geom_polygon
+	|
+        geom_compoundcurve
+        |
+        geom_curvepolygon
+        |
+	geom_multipoint 
+	|
+	geom_multilinestring
+        |
+        geom_multicurve
+	|
+	geom_multipolygon
+	|
+        geom_multisurface
+        |
+	geom_geometrycollection
+
+srid :
+	SRID EQUALS VALUE { set_srid($3); } 
+
+geom_wkb :
+	WKB { alloc_wkb($1); }
+
+
+/* POINT */
+
+geom_point :
+	POINT point
+	|
+	POINTM { set_zm(0, 1); } point 
+
+point :
+	empty_point
+	|
+	nonempty_point
+
+empty_point :
+	{ alloc_point(); } empty { pop(); } 
+
+nonempty_point :
+	{ alloc_point(); } point_int { pop(); } 
+
+point_int :
+	LPAREN a_point RPAREN
+
+/* MULTIPOINT */
+
+geom_multipoint :
+	MULTIPOINT { alloc_multipoint(); } multipoint  { pop(); }
+	| 
+	MULTIPOINTM { set_zm(0, 1); alloc_multipoint(); } multipoint {pop(); }
+
+multipoint :
+	empty
+	|
+	{ alloc_counter(); } LPAREN multipoint_int RPAREN { pop(); } 
+
+multipoint_int :
+	mpoint_element
+	|
+	multipoint_int COMMA mpoint_element
+
+mpoint_element :
+	nonempty_point
+	|
+	/* this is to allow MULTIPOINT(0 0, 1 1) */
+	{ alloc_point(); } a_point { pop(); }
+
+
+/* LINESTRING */
+
+geom_linestring :
+	LINESTRING linestring
+	|
+	LINESTRINGM { set_zm(0, 1); } linestring
+
+linestring :
+	empty_linestring
+	|
+	nonempty_linestring
+
+empty_linestring :
+	{ alloc_linestring(); } empty { pop(); } 
+
+nonempty_linestring :
+	{ alloc_linestring(); } linestring_1 { pop(); } 
+
+nonempty_linestring_closed :
+        { alloc_linestring_closed(); } linestring_1 { pop(); }
+
+linestring_1 :
+	{ alloc_counter(); } LPAREN linestring_int RPAREN { popc(); }
+
+linestring_int :
+	a_point
+	|
+	linestring_int COMMA a_point;
+
+/* CIRCULARSTRING */
+
+geom_circularstring :
+        CIRCULARSTRING circularstring
+        |
+        CIRCULARSTRINGM {set_zm(0, 1); } circularstring
+
+geom_circularstring_closed :
+        CIRCULARSTRING circularstring_closed
+        |
+        CIRCULARSTRINGM {set_zm(0, 1); } circularstring_closed
+
+circularstring :
+        empty_circularstring
+        |
+        nonempty_circularstring
+
+circularstring_closed :
+        empty_circularstring
+        |
+        nonempty_circularstring_closed
+
+empty_circularstring :
+        { alloc_circularstring(); } empty { pop(); }
+
+nonempty_circularstring :
+        { alloc_circularstring(); } circularstring_1 { pop(); }
+
+nonempty_circularstring_closed :
+        { alloc_circularstring_closed(); } circularstring_1 { pop(); }
+
+circularstring_1 :
+        { alloc_counter(); } LPAREN circularstring_int RPAREN { popc(); }
+
+circularstring_int :
+        a_point
+        |
+        circularstring_int COMMA a_point;
+
+/* COMPOUNDCURVE */
+
+geom_compoundcurve:
+        COMPOUNDCURVE { alloc_compoundcurve(); } compoundcurve { pop(); }
+        |
+        COMPOUNDCURVEM {set_zm(0, 1); alloc_compoundcurve(); } compoundcurve { pop(); }
+
+compoundcurve:
+        empty
+        |
+        { alloc_counter(); } LPAREN compoundcurve_int RPAREN { pop(); }
+
+compoundcurve_int:
+        nonempty_linestring
+        |
+        geom_circularstring
+        |
+        compoundcurve_int COMMA nonempty_linestring
+        |
+        compoundcurve_int COMMA geom_circularstring
+
+/* MULTILINESTRING */
+
+geom_multilinestring :
+	MULTILINESTRING { alloc_multilinestring(); }
+		multilinestring  { pop(); }
+	|
+	MULTILINESTRINGM { set_zm(0, 1); alloc_multilinestring(); }
+		multilinestring { pop(); } 
+
+multilinestring :
+	empty
+	|
+	{ alloc_counter(); } LPAREN multilinestring_int RPAREN{ pop();}
+
+multilinestring_int :
+	nonempty_linestring
+	|
+	multilinestring_int COMMA nonempty_linestring
+
+/* MULTICURVESTRING */
+
+geom_multicurve :
+        MULTICURVE { alloc_multicurve(); }
+                multicurve { pop(); }
+        |
+        MULTICURVEM { set_zm(0, 1); alloc_multicurve(); }
+                multicurve { pop(); }
+
+multicurve :
+        empty
+        |
+        { alloc_counter(); } LPAREN multicurve_int RPAREN { pop(); }
+
+multicurve_int :
+        nonempty_linestring
+        |
+        geom_circularstring
+        |
+        multicurve_int COMMA nonempty_linestring
+        |
+        multicurve_int COMMA geom_circularstring
+
+/* POLYGON */
+
+geom_polygon :
+	POLYGON polygon
+	|
+	POLYGONM { set_zm(0, 1); } polygon 
+
+polygon :
+	empty_polygon
+	|
+	nonempty_polygon
+
+empty_polygon :
+	{ alloc_polygon(); } empty  { pop(); } 
+
+nonempty_polygon :
+	{ alloc_polygon(); } polygon_1  { pop(); } 
+
+polygon_1 :
+	{ alloc_counter(); } LPAREN polygon_int RPAREN { pop();} 
+
+polygon_int :
+	linestring_1
+	|
+	polygon_int COMMA linestring_1
+
+/* CURVEPOLYGON */
+
+geom_curvepolygon :
+        CURVEPOLYGON { alloc_curvepolygon(); } curvepolygon { pop(); }
+        |
+        CURVEPOLYGONM { set_zm(0, 1); alloc_curvepolygon(); } 
+                        curvepolygon { pop(); }
+
+curvepolygon :
+        empty
+        |
+        { alloc_counter(); } LPAREN curvepolygon_int RPAREN { pop(); }
+
+curvepolygon_int :
+        nonempty_linestring_closed
+        |
+        geom_circularstring_closed
+        |
+        curvepolygon_int COMMA nonempty_linestring_closed
+        |
+        curvepolygon_int COMMA geom_circularstring_closed
+
+/* MULTIPOLYGON */
+
+geom_multipolygon :
+	MULTIPOLYGON { alloc_multipolygon(); } multipolygon { pop(); }
+	|
+	MULTIPOLYGONM { set_zm(0, 1); alloc_multipolygon(); }
+		multipolygon { pop();} 
+
+multipolygon :
+	empty
+	|
+	{ alloc_counter(); } LPAREN multipolygon_int RPAREN { pop(); }
+
+multipolygon_int :
+	nonempty_polygon
+	|
+	multipolygon_int COMMA nonempty_polygon
+
+/* MULTISURFACE */
+
+geom_multisurface :
+        MULTISURFACE {alloc_multisurface(); } multisurface { pop(); }
+        |
+        MULTISURFACEM { set_zm(0, 1); alloc_multisurface(); }
+                multisurface { pop(); }
+
+multisurface :
+        empty
+        |
+        { alloc_counter(); } LPAREN multisurface_int RPAREN { pop(); }
+
+multisurface_int :
+        nonempty_polygon
+        |
+        geom_curvepolygon
+        |
+        multisurface_int COMMA nonempty_polygon
+        |
+        multisurface_int COMMA geom_curvepolygon
+
+/* GEOMETRYCOLLECTION */
+
+geom_geometrycollection :
+	GEOMETRYCOLLECTION { alloc_geomertycollection(); }
+		geometrycollection { pop(); }
+	|
+	GEOMETRYCOLLECTIONM { set_zm(0, 1); alloc_geomertycollection(); }
+		geometrycollection { pop();}
+
+geometrycollection :
+	empty
+	|
+	{ alloc_counter(); } LPAREN geometrycollection_int RPAREN { pop(); }
+
+geometrycollection_int :
+	/* to support GEOMETRYCOLLECTION(EMPTY) for backward compatibility */
+	empty
+	|
+	geometry_int
+	|
+	geometrycollection_int COMMA geometry_int
+
+
+a_point :
+	point_2d
+	|
+	point_3d
+	|
+	point_4d 
+
+point_2d :
+	VALUE VALUE {alloc_point_2d($1,$2); }
+
+point_3d :
+	VALUE VALUE VALUE {alloc_point_3d($1,$2,$3); }
+
+point_4d :
+	VALUE VALUE VALUE VALUE {alloc_point_4d($1,$2,$3,$4); }
+
+empty :
+	EMPTY { alloc_empty(); }
+%%
+
+
+
+