fustrate-rails 0.3.3

data/vendor/assets/javascripts/fustrate/components/pagination.coffee

@@ -0,0 +1,84 @@
+class Fustrate.Components.Pagination extends Fustrate.Components.Base
+  constructor: ({@current_page, @total_pages, @total_entries, @per_page}) ->
+    @base = @constructor._getPreppedPaginationURL()
+
+  link: (text, page, options = {}) =>
+    Fustrate.linkTo(text, "#{@base}page=#{page}", options)
+
+  previousLink: =>
+    if @current_page > 1
+      return "
+        <li class=\"previous_page\">
+          #{@link('← Previous', @current_page - 1, rel: 'prev')}
+        </li>"
+
+    '<li class="previous_page unavailable"><a href="#">← Previous</a></li>'
+
+  nextLink: =>
+    if @current_page < @total_pages
+      return "
+        <li class=\"next_page\">
+          #{@link('Next →', @current_page + 1, rel: 'next')}
+        </li>"
+
+    '<li class="next_page unavailable"><a href="#">Next →</a></li>'
+
+  generate: =>
+    pages = []
+
+    if @total_pages > 1
+      pages = for i in @windowedPageNumbers()
+        if i == @current_page
+          "<li class=\"current\">#{Fustrate.linkTo(i, '#')}</li>"
+        else if i == 'gap'
+          '<li class="unavailable"><span class="gap">…</span></li>'
+        else
+          "<li>#{@link i, i}</li>"
+
+      pages.unshift @previousLink()
+      pages.push @nextLink()
+
+    $('<ul class="pagination">').html pages.join(' ')
+
+  windowedPageNumbers: =>
+    window_from = @current_page - 4
+    window_to = @current_page + 4
+
+    if window_to > @total_pages
+      window_from -= window_to - @total_pages
+      window_to = @total_pages
+
+    if window_from < 1
+      window_to += 1 - window_from
+      window_from = 1
+      window_to = @total_pages if window_to > @total_pages
+
+    middle = [window_from..window_to]
+
+    left = if 4 < middle[0] then [1, 2, 'gap'] else [1...middle[0]]
+
+    if @total_pages - 3 > middle.last()
+      right = [(@total_pages - 1)..@total_pages]
+      right.unshift 'gap'
+    else if middle.last() + 1 <= @total_pages
+      right = [(middle.last() + 1)..@total_pages]
+    else
+      right = []
+
+    left.concat middle, right
+
+  @getCurrentPage: ->
+    window.location.search.match(/[?&]page=(\d+)/)?[1] ? 1
+
+  # Just add 'page='
+  @_getPreppedPaginationURL: ->
+    search = window.location.search.replace(/[?&]page=\d+/, '')
+
+    search = if search[0] == '?'
+               "#{search}&"
+             else if search[0] == '&'
+               "?#{search[1...search.length]}&"
+             else
+               '?'
+
+    "#{window.location.pathname}#{search}"

data/vendor/assets/javascripts/fustrate/components/tabs.coffee

@@ -0,0 +1,28 @@
+class Fustrate.Components.Tabs extends Fustrate.Components.Base
+  constructor: (@tabs) ->
+    @tabs.on 'click', 'li > a', (e) =>
+      @activateTab $(e.currentTarget)
+
+      false
+
+    if window.location.hash
+      @activateTab $("li > a[href='#{window.location.hash}']", @tabs).first()
+    else if $('li > a.active', @tabs).length > 0
+      @activateTab $('li > a.active', @tabs).first()
+    else
+      @activateTab $('li > a', @tabs).first()
+
+  activateTab: (tab) =>
+    return unless tab
+
+    $('.active', @tabs).removeClass 'active'
+    tab.addClass 'active'
+
+    $("##{tab.attr('href').split('#')[1]}")
+      .addClass 'active'
+      .siblings()
+      .removeClass 'active'
+
+  @initialize: =>
+    $('ul.tabs').each (index, elem) =>
+      new @($ elem)

data/vendor/assets/javascripts/fustrate/components/tooltip.coffee

@@ -0,0 +1,72 @@
+class Fustrate.Components.Tooltip extends Fustrate.Components.Base
+  @fadeSpeed: 100
+
+  constructor: (element, title) ->
+    @element = $ element
+    @active = false
+
+    @addEventListeners()
+
+    @element.attr('title', title) if title
+
+  addEventListeners: =>
+    @element
+      .off '.tooltip'
+      .on 'mouseenter.tooltip', @_show
+      .on 'mousemove.tooltip', @_move
+      .on 'mouseleave.tooltip', @_hide
+
+  setTitle: (title) ->
+    if @active
+      @tooltip.text title
+    else
+      @element.prop('title', title)
+
+  _move: (e) =>
+    @tooltip.css @_tooltipPosition(e) if @active
+
+    false
+
+  _show: (e) =>
+    return false if @active
+
+    title = @element.prop('title') ? ''
+
+    return false unless title.length > 0
+
+    @tooltip ?= $('<span class="tooltip">').hide()
+
+    @element.attr('title', '').removeAttr('title')
+
+    @active = true
+
+    @tooltip
+      .text title
+      .appendTo $('body')
+      .css @_tooltipPosition(e)
+      .fadeIn @constructor.fadeSpeed
+
+    false
+
+  _hide: (e) =>
+    # No use hiding something that doesn't exist.
+    if @tooltip
+      @element.attr 'title', @tooltip.text()
+      @active = false
+
+      @tooltip.fadeOut @constructor.fadeSpeed, @tooltip.detach
+
+    false
+
+  _tooltipPosition: (e) ->
+    top: "#{e.pageY + 15}px"
+    left: "#{e.pageX - 10}px"
+
+  @initialize: ->
+    $('[data-tooltip]').each (index, elem) ->
+      new Fustrate.Components.Tooltip elem
+
+$.fn.extend
+  tooltip: (options) ->
+    @each (index, element) ->
+      new Fustrate.Components.Tooltip element

data/vendor/assets/javascripts/fustrate/generic_form.coffee

@@ -0,0 +1,31 @@
+#= require './generic_page'
+
+class Fustrate.GenericForm extends Fustrate.GenericPage
+  addEventListeners: =>
+    super
+
+    @root.on 'submit', @onSubmit
+
+  _reloadUIElements: =>
+    super
+
+    for domObject in $('[name][id]', @root)
+      element = $ domObject
+      name = element.prop 'name'
+
+      if captures = name.match /\[([a-z_]+)\]$/
+        @fields[captures[1]] = element
+      else
+        @fields[name] = element
+
+  validate: -> true
+
+  onSubmit: (e) =>
+    e.preventDefault()
+
+    unless @validate()
+      setTimeout (=> $.rails.enableFormElements(@root)), 100
+
+      return false
+
+    true

data/vendor/assets/javascripts/fustrate/generic_page.coffee

@@ -0,0 +1,40 @@
+class Fustrate.GenericPage
+  constructor: (@root) ->
+    @_reloadUIElements()
+    @addEventListeners()
+    @initialize()
+
+  addEventListeners: ->
+
+  # Once the interface is loaded and the event listeners are active, run any
+  # other tasks.
+  initialize: ->
+
+  _reloadUIElements: =>
+    @fields = {}
+    @buttons = {}
+
+    $('[data-field]', @root).each (index, element) =>
+      field = $ element
+      @fields[field.data('field')] = field
+
+    $('[data-button]', @root).each (index, element) =>
+      button = $ element
+      @buttons[button.data('button')] = button
+
+  flashSuccess: (message, {icon} = {}) ->
+    new Fustrate.Components.Flash.Success(message, icon: icon)
+
+  flashError: (message, {icon} = {}) ->
+    new Fustrate.Components.Flash.Error(message, icon: icon)
+
+  flashInfo: (message, {icon} = {}) ->
+    new Fustrate.Components.Flash.Info(message, icon: icon)
+
+  setHeader: (text) ->
+    $('.header > span', @root).text text
+
+  # Calls all methods matching /refresh.+/
+  refresh: =>
+    for own name, func of @
+      func() if name.indexOf('refresh') == 0 && name != 'refresh'

data/vendor/assets/javascripts/fustrate/generic_table.coffee

@@ -0,0 +1,57 @@
+class Fustrate.GenericTable extends Fustrate.GenericPage
+  @blankRow: null
+  table: null
+
+  initialize: =>
+    super
+
+    @reloadTable()
+
+  reloadTable: ->
+
+  sortRows: (rows, sortFunction = ->) ->
+    sorted = ([sortFunction(row), row] for row in rows)
+    sorted.sort (x, y) ->
+      if x[0] == y[0] then 0 else if x[0] > y[0] then 1 else -1
+    sorted.map (row) -> row[1]
+
+  createRow: (item) =>
+    @updateRow @constructor.blankRow.clone(), item
+
+  updateRow: (row, item) ->
+    row
+
+  reloadRows: (rows, {sort} = { sort: null }) =>
+    tbody = $ 'tbody', @table
+
+    $('tr.loading', tbody).hide()
+
+    if rows
+      $('tr:not(.no-records):not(.loading)', tbody).remove()
+
+      tbody.append if sort then @sortRows(rows, sort) else rows
+
+    @updated()
+
+  addRow: (row) =>
+    $('tbody', @table).append row
+    @updated()
+
+  removeRow: (row) =>
+    row.fadeOut =>
+      row.remove()
+      @updated()
+
+  updated: =>
+    $('tbody tr.no-records', @table)
+      .toggle $('tbody tr:not(.no-records):not(.loading)', @table).length < 1
+
+  getCheckedIds: =>
+    (item.value for item in $('td:first-child input:checked', @table))
+
+  # This should be fed a response from a JSON request for a paginated
+  # collection.
+  updatePagination: (response) =>
+    @pagination = new Fustrate.Components.Pagination response
+
+    $('.pagination', @root).replaceWith @pagination.generate()

data/vendor/assets/javascripts/fustrate/listenable.coffee

@@ -0,0 +1,25 @@
+class Fustrate.Listenable
+  constructor: ->
+    @listeners = {}
+
+  on: (eventNames, callback) =>
+    for eventName in eventNames.split(' ')
+      @listeners[eventName] = [] unless @listeners[eventName]
+      @listeners[eventName].push callback
+
+    @
+
+  off: (eventNames) =>
+    for eventName in eventNames.split(' ')
+      @listeners[eventName] = []
+
+    @
+
+  trigger: =>
+    [name, args...] = arguments
+
+    return unless name && @listeners[name]
+
+    event.apply(@, args) for event in @listeners[name]
+
+    @

data/vendor/assets/javascripts/fustrate/object.coffee

@@ -0,0 +1,21 @@
+class Fustrate.Object extends Fustrate.Listenable
+  constructor: (data) ->
+    @extractFromData data
+
+    super
+
+  # Simple extractor to assign root keys as properties in the current object.
+  # Formats a few common attributes as dates with moment.js
+  extractFromData: (data) =>
+    @[key] = value for key, value of data
+
+    @date = moment @date if @date
+    @created_at = moment @created_at if @created_at
+    @updated_at = moment @updated_at if @updated_at
+
+  # Instantiate a new object of type klass for each item in items
+  _createList: (items, klass, additional_attributes = {}) ->
+    for item in items
+      obj = new klass(item)
+      obj[key] = value for key, value of additional_attributes
+      obj

data/vendor/assets/javascripts/fustrate/record.coffee

@@ -0,0 +1,23 @@
+class Fustrate.Record extends Fustrate.Object
+  # Rails class name
+  @class: null
+
+  constructor: (data) ->
+    super
+
+    if typeof data is 'number' or typeof data is 'string'
+      # If the parameter was a number or string, it's likely the record ID
+      @id = parseInt(data, 10)
+    else
+      # Otherwise we were probably given a hash of attributes
+      @extractFromData data
+
+  reload: ->
+
+  save: ->
+
+  toObject: -> {}
+
+  update: (data) =>
+    @extractFromData data
+    @save()

data/vendor/assets/stylesheets/_fustrate.sass

@@ -0,0 +1,7 @@
+@import "bourbon"
+@import "font-awesome"
+@import "awesomplete"
+
+@import "fustrate/colors"
+@import "fustrate/settings"
+@import "fustrate/components/components"

data/vendor/assets/stylesheets/awesomplete.sass

@@ -0,0 +1,75 @@
+/* 1795543d988d0fd9ca6237a5ac176f8e88d63990 */
+
+[hidden]
+  display: none
+
+.visually-hidden
+  position: absolute
+  clip: rect(0, 0, 0, 0)
+
+div.awesomplete
+  display: block
+  position: relative
+
+  > input
+    display: block
+
+  > ul
+    position: absolute
+    left: 0
+    z-index: 9
+    min-width: 100%
+    box-sizing: border-box
+    list-style: none
+    padding: 0
+    border-radius: .3em
+    margin: .2em 0 0
+    background: hsla(0, 0%, 100%, .9)
+    background: linear-gradient(to bottom right, white, hsla(0, 0%, 100%, .8))
+    border: 1px solid rgba(0, 0, 0, .3)
+    box-shadow: .05em .2em .6em rgba(0, 0, 0, .2)
+    text-shadow: none
+    max-height: 30vh
+    overflow-x: scroll
+
+    &[hidden],
+    &:empty
+      display: none
+
+    > li
+      position: relative
+      padding: .2em .5em
+      cursor: pointer
+
+      &:not(:last-child)
+        border-bottom: 1px solid rgba(64, 64, 64, .3)
+
+      &:hover
+        background: hsl(200, 40%, 80%)
+        color: black
+
+      &[aria-selected="true"]
+        background: hsl(205, 40%, 40%)
+        color: white
+
+  mark
+    background: hsl(65, 100%, 50%)
+
+    li:hover &
+      background: hsl(68, 100%, 41%)
+
+    li[aria-selected="true"] &
+      background: hsl(86, 100%, 21%)
+      color: inherit
+
+@supports (transform: scale(0))
+  div.awesomplete > ul
+    transition: .3s cubic-bezier(.4, .2, .5, 1.4)
+    transform-origin: 1.43em -.43em
+
+    &[hidden],
+    &:empty
+      opacity: 0
+      transform: scale(0)
+      display: block
+      transition-timing-function: ease