freighthop 0.0.6 → 0.1.0

data/modules/mysql/manifests/init.pp

@@ -0,0 +1,100 @@
+#
+class mysql(
+  $basedir               = '',
+  $bind_address          = '',
+  $client_package_ensure = '',
+  $client_package_name   = '',
+  $config_file           = '',
+  $config_template       = '',
+  $datadir               = '',
+  $default_engine        = '',
+  $etc_root_password     = '',
+  $log_error             = '',
+  $manage_config_file    = '',
+  $manage_service        = '',
+  $max_allowed_packet    = '',
+  $max_connections       = '',
+  $old_root_password     = '',
+  $package_ensure        = '',
+  $php_package_name      = '',
+  $pidfile               = '',
+  $port                  = '',
+  $purge_conf_dir        = '',
+  $restart               = '',
+  $root_group            = '',
+  $root_password         = '',
+  $server_package_name   = '',
+  $service_name          = '',
+  $service_provider      = '',
+  $socket                = '',
+  $ssl                   = '',
+  $ssl_ca                = '',
+  $ssl_cert              = '',
+  $ssl_key               = '',
+  $tmpdir                = '',
+  $attempt_compatibility_mode = false,
+) {
+
+  if $attempt_compatibility_mode {
+    notify { "An attempt has been made below to automatically apply your custom
+    settings to mysql::server. Please verify this works in a safe test
+    environment.": }
+
+    $override_options = {
+      'client'                 => {
+        'port'                 => $port,
+        'socket'               => $socket
+      },
+      'mysqld_safe'            => {
+        'log_error'            => $log_error,
+        'socket'               => $socket,
+      },
+      'mysqld'               => {
+        'basedir'            => $basedir,
+        'bind_address'       => $bind_address,
+        'datadir'            => $datadir,
+        'log_error'          => $log_error,
+        'max_allowed_packet' => $max_allowed_packet,
+        'max_connections'    => $max_connections,
+        'pid_file'           => $pidfile,
+        'port'               => $port,
+        'socket'             => $socket,
+        'ssl-ca'             => $ssl_ca,
+        'ssl-cert'           => $ssl_cert,
+        'ssl-key'            => $ssl_key,
+        'tmpdir'             => $tmpdir,
+      },
+      'mysqldump'              => {
+        'max_allowed_packet'  => $max_allowed_packet,
+      },
+      'config_file'          => $config_file,
+      'etc_root_password'    => $etc_root_password,
+      'manage_config_file'   => $manage_config_file,
+      'old_root_password'    => $old_root_password,
+      'purge_conf_dir'       => $purge_conf_dir,
+      'restart'              => $restart,
+      'root_group'           => $root_group,
+      'root_password'        => $root_password,
+      'service_name'         => $service_name,
+      'ssl'                  => $ssl
+    }
+    $filtered_options = mysql_strip_hash($override_options)
+    validate_hash($filtered_options)
+    notify { $filtered_options: }
+    class { 'mysql::server':
+      override_options => $filtered_options,
+    }
+
+  } else {
+    fail("ERROR:  This class has been deprecated and the functionality moved
+    into mysql::server.  If you run mysql::server without correctly calling
+    mysql:: server with the new override_options hash syntax you will revert
+    your MySQL to the stock settings.  Do not proceed without removing this
+    class and using mysql::server correctly.
+
+    If you are brave you may set attempt_compatibility_mode in this class which
+    attempts to automap the previous settings to appropriate calls to
+    mysql::server")
+  }
+
+}

data/modules/mysql/manifests/params.pp

@@ -0,0 +1,230 @@
+# Private class: See README.md.
+class mysql::params {
+
+  $manage_config_file     = true
+  $old_root_password      = ''
+  $purge_conf_dir         = false
+  $restart                = false
+  $root_password          = 'UNSET'
+  $server_package_ensure  = 'present'
+  $server_service_manage  = true
+  $server_service_enabled = true
+  # mysql::bindings
+  $bindings_enable         = false
+  $java_package_ensure     = 'present'
+  $java_package_provider   = undef
+  $perl_package_ensure     = 'present'
+  $perl_package_provider   = undef
+  $php_package_ensure      = 'present'
+  $php_package_provider    = undef
+  $python_package_ensure   = 'present'
+  $python_package_provider = undef
+  $ruby_package_ensure     = 'present'
+  $ruby_package_provider   = undef
+
+
+  case $::osfamily {
+    'RedHat': {
+      if $::operatingsystem == 'Fedora' and (is_integer($::operatingsystemrelease) and $::operatingsystemrelease >= 19 or $::operatingsystemrelease == "Rawhide") {
+        $client_package_name = 'mariadb'
+        $server_package_name = 'mariadb-server'
+      } else {
+        $client_package_name = 'mysql'
+        $server_package_name = 'mysql-server'
+      }
+      $basedir             = '/usr'
+      $config_file         = '/etc/my.cnf'
+      $datadir             = '/var/lib/mysql'
+      $log_error           = '/var/log/mysqld.log'
+      $pidfile             = '/var/run/mysqld/mysqld.pid'
+      $root_group          = 'root'
+      $server_service_name = 'mysqld'
+      $socket              = '/var/lib/mysql/mysql.sock'
+      $ssl_ca              = '/etc/mysql/cacert.pem'
+      $ssl_cert            = '/etc/mysql/server-cert.pem'
+      $ssl_key             = '/etc/mysql/server-key.pem'
+      $tmpdir              = '/tmp'
+      # mysql::bindings
+      $java_package_name   = 'mysql-connector-java'
+      $perl_package_name   = 'perl-DBD-MySQL'
+      $php_package_name    = 'php-mysql'
+      $python_package_name = 'MySQL-python'
+      $ruby_package_name   = 'ruby-mysql'
+    }
+
+    'Suse': {
+      $client_package_name   = $::operatingsystem ? {
+        /OpenSuSE/           => 'mysql-community-server-client',
+        /(SLES|SLED)/        => 'mysql-client',
+      }
+      $server_package_name   = $::operatingsystem ? {
+        /OpenSuSE/           => 'mysql-community-server',
+        /(SLES|SLED)/        => 'mysql',
+      }
+      $basedir             = '/usr'
+      $config_file         = '/etc/my.cnf'
+      $datadir             = '/var/lib/mysql'
+      $log_error           = $::operatingsystem ? {
+        /OpenSuSE/         => '/var/log/mysql/mysqld.log',
+        /(SLES|SLED)/      => '/var/log/mysqld.log',
+      }
+      $pidfile             = $::operatingsystem ? {
+        /OpenSuSE/         => '/var/run/mysql/mysqld.pid',
+        /(SLES|SLED)/      => '/var/lib/mysql/mysqld.pid',
+      }
+      $root_group          = 'root'
+      $server_service_name = 'mysql'
+      $socket              = $::operatingsystem ? {
+        /OpenSuSE/         => '/var/run/mysql/mysql.sock',
+        /(SLES|SLED)/      => '/var/lib/mysql/mysql.sock',
+      }
+      $ssl_ca              = '/etc/mysql/cacert.pem'
+      $ssl_cert            = '/etc/mysql/server-cert.pem'
+      $ssl_key             = '/etc/mysql/server-key.pem'
+      $tmpdir              = '/tmp'
+      # mysql::bindings
+      $java_package_name   = 'mysql-connector-java'
+      $perl_package_name   = 'perl-DBD-mysql'
+      $php_package_name    = 'apache2-mod_php5'
+      $python_package_name = 'python-mysql'
+      $ruby_package_name   = $::operatingsystem ? {
+        /OpenSuSE/         => 'rubygem-mysql',
+        /(SLES|SLED)/      => 'ruby-mysql',
+      }
+    }
+
+    'Debian': {
+      $client_package_name = 'mysql-client'
+      $server_package_name = 'mysql-server'
+
+      $basedir             = '/usr'
+      $config_file         = '/etc/mysql/my.cnf'
+      $datadir             = '/var/lib/mysql'
+      $log_error           = '/var/log/mysql/error.log'
+      $pidfile             = '/var/run/mysqld/mysqld.pid'
+      $root_group          = 'root'
+      $server_service_name = 'mysql'
+      $socket              = '/var/run/mysqld/mysqld.sock'
+      $ssl_ca              = '/etc/mysql/cacert.pem'
+      $ssl_cert            = '/etc/mysql/server-cert.pem'
+      $ssl_key             = '/etc/mysql/server-key.pem'
+      $tmpdir              = '/tmp'
+      # mysql::bindings
+      $java_package_name   = 'libmysql-java'
+      $perl_package_name   = 'libdbd-mysql-perl'
+      $php_package_name    = 'php5-mysql'
+      $python_package_name = 'python-mysqldb'
+      $ruby_package_name   = 'libmysql-ruby'
+    }
+
+    'FreeBSD': {
+      $client_package_name = 'databases/mysql55-client'
+      $server_package_name = 'databases/mysql55-server'
+      $basedir             = '/usr/local'
+      $config_file         = '/var/db/mysql/my.cnf'
+      $datadir             = '/var/db/mysql'
+      $log_error           = "/var/db/mysql/${::hostname}.err"
+      $pidfile             = '/var/db/mysql/mysql.pid'
+      $root_group          = 'wheel'
+      $server_service_name = 'mysql-server'
+      $socket              = '/tmp/mysql.sock'
+      $ssl_ca              = undef
+      $ssl_cert            = undef
+      $ssl_key             = undef
+      $tmpdir              = '/tmp'
+      # mysql::bindings
+      $java_package_name   = 'databases/mysql-connector-java'
+      $perl_package_name   = 'p5-DBD-mysql'
+      $php_package_name    = 'php5-mysql'
+      $python_package_name = 'databases/py-MySQLdb'
+      $ruby_package_name   = 'databases/ruby-mysql'
+    }
+
+    default: {
+      case $::operatingsystem {
+        'Amazon': {
+          $client_package_name = 'mysql'
+          $server_package_name = 'mysql-server'
+          $basedir             = '/usr'
+          $config_file         = '/etc/my.cnf'
+          $datadir             = '/var/lib/mysql'
+          $log_error           = '/var/log/mysqld.log'
+          $pidfile             = '/var/run/mysqld/mysqld.pid'
+          $root_group          = 'root'
+          $server_service_name = 'mysqld'
+          $socket              = '/var/lib/mysql/mysql.sock'
+          $ssl_ca              = '/etc/mysql/cacert.pem'
+          $ssl_cert            = '/etc/mysql/server-cert.pem'
+          $ssl_key             = '/etc/mysql/server-key.pem'
+          $tmpdir              = '/tmp'
+          # mysql::bindings
+          $java_package_name   = 'mysql-connector-java'
+          $perl_package_name   = 'perl-DBD-MySQL'
+          $php_package_name    = 'php-mysql'
+          $python_package_name = 'MySQL-python'
+          $ruby_package_name   = 'ruby-mysql'
+        }
+
+        default: {
+          fail("Unsupported osfamily: ${::osfamily} operatingsystem: ${::operatingsystem}, module ${module_name} only support osfamily RedHat, Debian, and FreeBSD, or operatingsystem Amazon")
+        }
+      }
+    }
+  }
+
+  case $::operatingsystem {
+    'Ubuntu': {
+      $service_provider = upstart
+    }
+    default: {
+      $service_provider = undef
+    }
+  }
+
+  $default_options = {
+    'client'          => {
+      'port'          => '3306',
+      'socket'        => $mysql::params::socket,
+    },
+    'mysqld_safe'        => {
+      'nice'             => '0',
+      'log_error'        => $mysql::params::log_error,
+      'socket'           => $mysql::params::socket,
+    },
+    'mysqld'                  => {
+      'basedir'               => $mysql::params::basedir,
+      'bind_address'          => '127.0.0.1',
+      'datadir'               => $mysql::params::datadir,
+      'expire_logs_days'      => '10',
+      'key_buffer'            => '16M',
+      'log_error'             => $mysql::params::log_error,
+      'max_allowed_packet'    => '16M',
+      'max_binlog_size'       => '100M',
+      'max_connections'       => '151',
+      'myisam_recover'        => 'BACKUP',
+      'pid_file'              => $mysql::params::pidfile,
+      'port'                  => '3306',
+      'query_cache_limit'     => '1M',
+      'query_cache_size'      => '16M',
+      'skip-external-locking' => true,
+      'socket'                => $mysql::params::socket,
+      'ssl'                   => false,
+      'ssl-ca'                => $mysql::params::ssl_ca,
+      'ssl-cert'              => $mysql::params::ssl_cert,
+      'ssl-key'               => $mysql::params::ssl_key,
+      'thread_cache_size'     => '8',
+      'thread_stack'          => '256K',
+      'tmpdir'                => $mysql::params::tmpdir,
+      'user'                  => 'mysql',
+    },
+    'mysqldump'             => {
+      'max_allowed_packet'  => '16M',
+      'quick'               => true,
+      'quote-names'         => true,
+    },
+    'isamchk'      => {
+      'key_buffer' => '16M',
+    },
+  }
+
+}

data/modules/mysql/manifests/server/account_security.pp

@@ -0,0 +1,22 @@
+class mysql::server::account_security {
+  mysql_user {
+    [ "root@${::fqdn}",
+      'root@127.0.0.1',
+      'root@::1',
+      "@${::fqdn}",
+      '@localhost',
+      '@%']:
+    ensure  => 'absent',
+    require => Anchor['mysql::server::end'],
+  }
+  if ($::fqdn != $::hostname) {
+    mysql_user { ["root@${::hostname}", "@${::hostname}"]:
+      ensure  => 'absent',
+      require => Anchor['mysql::server::end'],
+    }
+  }
+  mysql_database { 'test':
+    ensure  => 'absent',
+    require => Anchor['mysql::server::end'],
+  }
+}

data/modules/mysql/manifests/server/backup.pp

@@ -0,0 +1,56 @@
+# See README.me for usage.
+class mysql::server::backup (
+  $backupuser,
+  $backuppassword,
+  $backupdir,
+  $backupcompress = true,
+  $backuprotate = 30,
+  $delete_before_dump = false,
+  $backupdatabases = [],
+  $file_per_database = false,
+  $ensure = 'present',
+  $time = ['23', '5'],
+) {
+
+  mysql_user { "${backupuser}@localhost":
+    ensure        => $ensure,
+    password_hash => mysql_password($backuppassword),
+    provider      => 'mysql',
+    require       => Class['mysql::server::config'],
+  }
+
+  mysql_grant { "${backupuser}@localhost/*.*":
+    ensure     => present,
+    user       => "${backupuser}@localhost",
+    table      => '*.*',
+    privileges => [ 'SELECT', 'RELOAD', 'LOCK TABLES', 'SHOW VIEW' ],
+    require    => Mysql_user["${backupuser}@localhost"],
+  }
+
+  cron { 'mysql-backup':
+    ensure  => $ensure,
+    command => '/usr/local/sbin/mysqlbackup.sh',
+    user    => 'root',
+    hour    => $time[0],
+    minute  => $time[1],
+    require => File['mysqlbackup.sh'],
+  }
+
+  file { 'mysqlbackup.sh':
+    ensure  => $ensure,
+    path    => '/usr/local/sbin/mysqlbackup.sh',
+    mode    => '0700',
+    owner   => 'root',
+    group   => 'root',
+    content => template('mysql/mysqlbackup.sh.erb'),
+  }
+
+  file { 'mysqlbackupdir':
+    ensure => 'directory',
+    path   => $backupdir,
+    mode   => '0700',
+    owner  => 'root',
+    group  => 'root',
+  }
+
+}

data/modules/mysql/manifests/server/config.pp

@@ -0,0 +1,31 @@
+# See README.me for options.
+class mysql::server::config {
+
+  $options = $mysql::server::options
+
+  File {
+    owner  => 'root',
+    group  => $mysql::server::root_group,
+    mode   => '0400',
+    notify => Class['mysql::server::service'],
+  }
+
+  file { '/etc/mysql':
+    ensure => directory,
+    mode   => '0755',
+  }
+
+  file { '/etc/mysql/conf.d':
+    ensure  => directory,
+    mode    => '0755',
+    recurse => $mysql::server::purge_conf_dir,
+    purge   => $mysql::server::purge_conf_dir,
+  }
+
+  if $mysql::server::manage_config_file  {
+    file { $mysql::server::config_file:
+      content => template('mysql/my.cnf.erb'),
+      mode    => '0644',
+    }
+  }
+}

data/modules/mysql/manifests/server/install.pp

@@ -0,0 +1,9 @@
+#
+class mysql::server::install {
+
+  package { 'mysql-server':
+    ensure => $mysql::server::package_ensure,
+    name   => $mysql::server::package_name,
+  }
+
+}

data/modules/mysql/manifests/server/monitor.pp

@@ -0,0 +1,24 @@
+#This is a helper class to add a monitoring user to the database
+class mysql::server::monitor (
+  $mysql_monitor_username,
+  $mysql_monitor_password,
+  $mysql_monitor_hostname
+) {
+
+  Anchor['mysql::server::end'] -> Class['mysql::server::monitor']
+
+  mysql_user { "${mysql_monitor_username}@${mysql_monitor_hostname}":
+    ensure        => present,
+    password_hash => mysql_password($mysql_monitor_password),
+    require       => Class['mysql::server::service'],
+  }
+
+  mysql_grant { "${mysql_monitor_username}@${mysql_monitor_hostname}/*.*":
+    ensure     => present,
+    user       => "${mysql_monitor_username}@${mysql_monitor_hostname}",
+    table      => '*.*',
+    privileges => [ 'PROCESS', 'SUPER' ],
+    require    => Mysql_user["${mysql_monitor_username}@${mysql_monitor_hostname}"],
+  }
+
+}

data/modules/mysql/manifests/server/mysqltuner.pp

@@ -0,0 +1,9 @@
+#
+class mysql::server::mysqltuner($ensure='present') {
+  # mysql performance tester
+  file { '/usr/local/bin/mysqltuner':
+    ensure  => $ensure,
+    mode    => '0550',
+    source  => 'puppet:///modules/mysql/mysqltuner.pl',
+  }
+}

data/modules/mysql/manifests/server/providers.pp

@@ -0,0 +1,8 @@
+# Convenience class to call each of the three providers with the corresponding
+# hashes provided in mysql::server.
+# See README.md for details.
+class mysql::server::providers {
+  create_resources('mysql_user', $mysql::server::users)
+  create_resources('mysql_grant', $mysql::server::grants)
+  create_resources('mysql_database', $mysql::server::databases)
+}

data/modules/mysql/manifests/server/root_password.pp

@@ -0,0 +1,21 @@
+#
+class mysql::server::root_password {
+
+  $options = $mysql::server::options
+
+  # manage root password if it is set
+  if $mysql::server::root_password != 'UNSET' {
+    mysql_user { 'root@localhost':
+      ensure        => present,
+      password_hash => mysql_password($mysql::server::root_password),
+    }
+
+    file { "${::root_home}/.my.cnf":
+      content => template('mysql/my.cnf.pass.erb'),
+      owner   => 'root',
+      mode    => '0600',
+      require => Mysql_user['root@localhost'],
+    }
+  }
+
+}

data/modules/mysql/manifests/server/service.pp

@@ -0,0 +1,19 @@
+#
+class mysql::server::service {
+
+  if $mysql::server::real_service_enabled {
+    $service_ensure = 'running'
+  } else {
+    $service_ensure = 'stopped'
+  }
+
+  if $mysql::server::real_service_manage {
+    service { 'mysqld':
+      ensure   => $service_ensure,
+      name     => $mysql::server::service_name,
+      enable   => $mysql::server::real_service_enabled,
+      provider => $mysql::server::service_provider,
+    }
+  }
+
+}

data/modules/mysql/manifests/server.pp

@@ -0,0 +1,69 @@
+# Class: mysql::server:  See README.md for documentation.
+class mysql::server (
+  $config_file             = $mysql::params::config_file,
+  $manage_config_file      = $mysql::params::manage_config_file,
+  $old_root_password       = $mysql::params::old_root_password,
+  $override_options        = {},
+  $package_ensure          = $mysql::params::server_package_ensure,
+  $package_name            = $mysql::params::server_package_name,
+  $purge_conf_dir          = $mysql::params::purge_conf_dir,
+  $remove_default_accounts = false,
+  $restart                 = $mysql::params::restart,
+  $root_group              = $mysql::params::root_group,
+  $root_password           = $mysql::params::root_password,
+  $service_enabled         = $mysql::params::server_service_enabled,
+  $service_manage          = $mysql::params::server_service_manage,
+  $service_name            = $mysql::params::server_service_name,
+  $service_provider        = $mysql::params::server_service_provider,
+  $users                   = {},
+  $grants                  = {},
+  $databases               = {},
+
+  # Deprecated parameters
+  $enabled                 = undef,
+  $manage_service          = undef
+) inherits mysql::params {
+
+  # Deprecated parameters.
+  if $enabled {
+    crit('This parameter has been renamed to service_enabled.')
+    $real_service_enabled = $enabled
+  } else {
+    $real_service_enabled = $service_enabled
+  }
+  if $manage_service {
+    crit('This parameter has been renamed to service_manage.')
+    $real_service_manage = $manage_service
+  } else {
+    $real_service_manage = $service_manage
+  }
+
+  # Create a merged together set of options.  Rightmost hashes win over left.
+  $options = mysql_deepmerge($mysql::params::default_options, $override_options)
+
+  Class['mysql::server::root_password'] -> Mysql::Db <| |>
+
+  include '::mysql::server::install'
+  include '::mysql::server::config'
+  include '::mysql::server::service'
+  include '::mysql::server::root_password'
+  include '::mysql::server::providers'
+
+  if $remove_default_accounts {
+    class { '::mysql::server::account_security':
+      require => Anchor['mysql::server::end'],
+    }
+  }
+
+  anchor { 'mysql::server::start': }
+  anchor { 'mysql::server::end': }
+
+  Anchor['mysql::server::start'] ->
+  Class['mysql::server::install'] ->
+  Class['mysql::server::config'] ->
+  Class['mysql::server::service'] ->
+  Class['mysql::server::root_password'] ->
+  Class['mysql::server::providers'] ->
+  Anchor['mysql::server::end']
+
+}