fondant-rails 0.2.2

data/.gitignore

@@ -0,0 +1,17 @@
+*.gem
+*.rbc
+.bundle
+.config
+.yardoc
+Gemfile.lock
+InstalledFiles
+_yardoc
+coverage
+doc/
+lib/bundler/man
+pkg
+rdoc
+spec/reports
+test/tmp
+test/version_tmp
+tmp

data/Gemfile

@@ -0,0 +1,4 @@
+source 'https://rubygems.org'
+
+# Specify your gem's dependencies in fondant-rails.gemspec
+gemspec

data/LICENSE.txt

@@ -0,0 +1,22 @@
+Copyright (c) 2013 Oven Bits
+
+MIT License
+
+Permission is hereby granted, free of charge, to any person obtaining
+a copy of this software and associated documentation files (the
+"Software"), to deal in the Software without restriction, including
+without limitation the rights to use, copy, modify, merge, publish,
+distribute, sublicense, and/or sell copies of the Software, and to
+permit persons to whom the Software is furnished to do so, subject to
+the following conditions:
+
+The above copyright notice and this permission notice shall be
+included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

data/README.md

@@ -0,0 +1,17 @@
+# Fondant for Rails' Asset Pipeline
+
+Use [fondant](https://github.com/ovenbits-ingredients/fondant) in Rails' asset pipeline.
+
+## Installation
+
+Add this line to your application's Gemfile:
+
+    gem 'fondant-rails', '~> 0.2.1', github: 'ovenbits-ingredients/fondant-rails'
+
+## Contributing
+
+1. Fork it
+2. Create your feature branch (`git checkout -b my-new-feature`)
+3. Commit your changes (`git commit -am 'Add some feature'`)
+4. Push to the branch (`git push origin my-new-feature`)
+5. Create new Pull Request

data/Rakefile

@@ -0,0 +1,10 @@
+require "bundler/gem_tasks"
+require File.expand_path('../lib/fondant-rails/source_file', __FILE__)
+
+desc "Update with latest source version"
+task :update do
+  files = SourceFile.new
+  files.fetch
+  files.cleanup
+end
+

data/fondant-rails.gemspec

@@ -0,0 +1,21 @@
+# -*- encoding: utf-8 -*-
+lib = File.expand_path('../lib', __FILE__)
+$LOAD_PATH.unshift(lib) unless $LOAD_PATH.include?(lib)
+require 'fondant-rails/version'
+
+Gem::Specification.new do |gem|
+  gem.name          = "fondant-rails"
+  gem.version       = Fondant::Rails::VERSION
+  gem.authors       = ["Phillip Ridlen"]
+  gem.email         = ["phillip@ovenbits.com"]
+  gem.description   = %q{Use fondant in Rails' asset pipeline}
+  gem.summary       = gem.description
+  gem.homepage      = "https://github.com/ovenbits-ingredients/fondant-rails"
+
+  gem.add_dependency 'railties', '>= 3.1'
+
+  gem.add_development_dependency 'thor', '~> 0.17'
+
+  gem.files         = `git ls-files`.split($/)
+  gem.require_paths = ["lib"]
+end

data/lib/fondant-rails.rb

@@ -0,0 +1,8 @@
+require "fondant-rails/version"
+
+module Fondant
+  module Rails
+    class Engine < ::Rails::Engine
+    end
+  end
+end

data/lib/fondant-rails/source_file.rb

@@ -0,0 +1,33 @@
+require 'thor'
+
+class SourceFile < Thor
+  include Thor::Actions
+
+  desc 'fetch source files', 'fetch source files from GitHub'
+  def fetch
+    self.destination_root = 'vendor/assets'
+    remote = 'https://raw.github.com/ovenbits-ingredients/fondant/master'
+    get "#{remote}/fondant.coffee", 'javascripts/fondant.coffee'
+    get "#{remote}/fondant.scss", 'stylesheets/fondant.scss'
+    get "#{remote}/VERSION", 'VERSION'
+
+    bump_version
+  end
+
+  desc 'clean up source files', 'remove source files no longer needed'
+  def cleanup
+    self.destination_root = 'vendor/assets'
+    remove_file 'VERSION'
+  end
+
+  protected
+
+  def bump_version
+    inside destination_root do
+      version = File.read('VERSION').sub("\n", '')
+      gsub_file '../../lib/fondant-rails/version.rb', /VERSION\s=\s'(\d|\.)+'$/ do |match|
+        %Q{VERSION = '#{version}'}
+      end
+    end
+  end
+end

data/lib/fondant-rails/version.rb

@@ -0,0 +1,5 @@
+module Fondant
+  module Rails
+    VERSION = '0.2.2'
+  end
+end

data/vendor/assets/javascripts/fondant.coffee

@@ -0,0 +1,441 @@
+# ## Fondant v0.2.2
+#
+# The icing on the cake for user input. A simple jQuery HTML5 WYSIWYG editor
+# using `contenteditable`.
+#
+#
+# © 2013 [Phillip Ridlen][1] & [Oven Bits, LLC][2]
+#
+#   [1]: http://phillipridlen.com
+#   [2]: http://ovenbits.com
+
+# ## Requirements
+#
+# * jQuery (tested with 1.9.1)
+# * A modern-ish browser (IE9+)
+#
+# ## Usage
+#
+# ### Instantiation
+#
+# To launch the editor on a specific element:
+#
+#     $('div.editable').fondant();
+#
+# You can also use it on a `<textarea>` and it will convert it to a `<div>`
+# while the editor is on:
+#
+#     $('form#content textarea.wysiwyg').fondant();
+#
+# ### Options Reference
+#
+# * `prefix` - prefix for all css classes and ids added to elements
+#   generated by Fondant (default: `fondant`)
+#
+# * `toolbar` - If set to `true`, Fondant will generate a toolbar. Otherwise you are responsible for
+#   hooking up all your toolbar buttons to call `$('selector').fondant('bold')`, etc.
+#   (default: `true`)
+#
+
+
+$ = jQuery
+
+$ ->
+
+  # ## Class Definition
+  #
+  # Defines the `Fondant` class that will be instantiated when `$.fn.fondant`
+  # is called.
+  #
+  class Fondant
+
+    # ## Methods
+
+    constructor: (element, options) ->
+      @init('fondant', element, options)
+
+    # ### init( type, element, options )
+    #
+    # Initializes the Fondant editor.
+    #
+    # Parameters:
+    #
+    # * `type` - should always be 'fondant' (see constructor above)
+    # * `element` - enable the Fondant editor for this element
+    # * `options` - overrides for the default options
+    # * `toolbar` -
+    #
+    init: (type, element, options) ->
+      @id = new Date().getTime()
+      @type = type
+      @$element = $(element)
+      @options = @getOptions(options)
+
+      @templates.fondant = this
+
+      if ( @$element.prop('tagName').toLowerCase() == 'textarea' )
+        @textarea = @$element
+        @replaceTextareaWithDiv()
+
+      @makeEditable()
+      @insertToolbar()
+      @bindToolbar()
+
+    # ### destroy( save = true )
+    #
+    # Destroy the Fondant editor and any elements created by it
+    #
+    destroy: ( keep_changes = true ) ->
+      @unbindToolbar()
+      @removeToolbar()
+      @makeUneditable()
+      @replaceDivWithTextarea(keep_changes) if @textarea
+      @$element.removeData(@type)
+
+    # ### focus()
+    #
+    # Focus the editor
+    #
+    focus: ->
+      @$element.find('.' + @templates.editorContentClass()).focus()
+
+    # ### insertToolbar()
+    #
+    # Add the formatting toolbar and bind the editor functions
+    #
+    insertToolbar: ->
+      @$element.prepend(@templates.toolbar()) if @options.toolbar
+
+    # ### bindToolbar()
+    #
+    # Bind toolbar click events to their respective actions
+    #
+    bindToolbar: ->
+      for action in @actions
+        $("[data-action='#{ @type }-#{ action }']").on 'click.fondant',
+          $.proxy(@[action], this)
+
+    # ### unbindToolbar()
+    #
+    # Remove all toolbar events. If the default Fondant toolbar was generated,
+    # this is not needed since the DOM elements will be destroyed
+    #
+    unbindToolbar: ->
+      $("[data-action^='#{ @type }-']").off('.fondant') unless @options.toolbar
+
+    # ### removeToolbar()
+    #
+    # Remove the formatting toolbar and unbind the editor functions.
+    #
+    removeToolbar: ->
+      @$element.find(@options.prefix + "-toolbar").remove() if @options.toolbar
+
+    # ### getElement()
+    #
+    # Get the actual underlying DOM (not jQuery) element
+    #
+    getElement: ->
+      @$element.get(0)
+
+    # ### getOptions( options )
+    #
+    # Get the options from the defaults, options passed to the constructor, and
+    # the options set in the element's `data` attribute
+    #
+    getOptions: ( options ) ->
+      options = $.extend {},
+        $.fn[@type].defaults,  # default options
+        options,               # options passed in to the constructor
+        @$element.data()       # options set in the element's `data` attribute
+
+    # ### value( html )
+    #
+    # Get the html from the editor, or if a value is passed in, set the html for the editor
+    #
+    value: ( html ) ->
+      if html == undefined
+        @$element.find('.' + @templates.editorContentClass()).html()
+      else
+        @$element.find('.' + @templates.editorContentClass()).html(html).html()
+
+    # ### makeEditable()
+    #
+    # Make the element editable. If it is a `<textarea>`, convert it to a
+    # `<div>` first.
+    #
+    makeEditable: ->
+      @$element.attr 'contenteditable', 'true'
+      @$element = @wrapEditorContent()
+
+    # ### makeUneditable()
+    #
+    # Turns off `contenteditable` for this editor. If this editor was
+    # originally a `<textarea>`, convert it back.
+    #
+    makeUneditable: ->
+      @$element = @unwrapEditorContent()
+      @$element.attr 'contenteditable', 'false'
+
+    # ### replaceElement( $old, fresh )
+    #
+    # Replace a jQuery element with a new one from a string. Returns the new
+    # jQuery element.
+    #
+    replaceElement: ( $old, fresh ) ->
+      $old.replaceWith($fresh = $(fresh))
+      $fresh
+
+    # ### replaceDivWithTextarea( keep_changes = true )
+    #
+    # Swaps out the the `<div>` for a `<textarea>`, returning the original's
+    # attributes. If keep_changes is false, put the original content back in.
+    # Essentially reverses the process of `replaceTextareaWithDiv`.
+    #
+    replaceDivWithTextarea: ( keep_changes = true ) ->
+      html = @$element.html()
+
+      @$element = @replaceElement(@$element, @textarea)
+      @$element.data(@type, this)
+      @$element.val(html) if keep_changes
+
+      @$element
+
+    # ### replaceTextareaWithDiv()
+    #
+    # Swaps out the `<textarea>` with a `<div>` so we can use contenteditable.
+    # Saves the `<textarea>`'s value and attributes so it can be restored when
+    # the editor gets canceled/destroyed.
+    #
+    replaceTextareaWithDiv: ->
+      if @textarea
+        @$element = @replaceElement @$element, @templates.editorContent()
+        @$element.data @type, this
+        @$element.addClass(@textarea.attr('class'))
+        @$element.html @textarea.val()
+
+      @$element
+
+    # ### unwrapEditorContent()
+    #
+    # Undoes what happens in `wrapEditorContent()`.
+    #
+    unwrapEditorContent: ->
+      $wrap = @$element
+      @$element = @replaceElement @$element, @$element.find(".#{ @templates.editorContentClass() }")
+      @$element.data @type, this
+      @$element.addClass @templates.editorClass()
+      $wrap.remove()
+
+      if @textarea
+        @$element.addClass(@textarea.attr 'class')
+
+      @$element
+
+    # ### wrapEditorContent()
+    #
+    # Wraps the current `@$element` with another, outer `<div>` so we can insert the toolbar
+    #
+    wrapEditorContent: ->
+      $original_element = @$element
+      @$element = @$element.wrap(@templates.editor()).parent()
+      @$element.data @type, this
+      @$element.addClass($original_element.attr 'class').removeClass(@templates.editorContentClass())
+
+      $original_element.removeClass @templates.editorClass()
+      $original_element.removeData @type
+
+      if @textarea
+        $original_element.removeClass(@textarea.attr 'class')
+
+      @$element
+
+    # ### applyFormat( command, value )
+    #
+    # Applies a rich text editor command to selection or block. Available
+    # commands are [listed on the MDN website][1].
+    #
+    #   [1]: https://developer.mozilla.org/en-US/docs/Rich-Text_Editing_in_Mozilla
+    #
+    applyFormat: ( command, value ) ->
+      document.execCommand command, false, value
+
+    # ## Formatting Functions
+    #
+    # This is where the magic happens.
+
+    # ### actions
+    #
+    # Array of all the possible formatting actions to take
+    #
+    actions: [
+      'remove', 'custom', 'undo', 'redo',
+      'bold', 'italic',
+      'p', 'h1', 'h2', 'h3', 'h4', 'blockquote',
+      'ol', 'ul', 'indent', 'outdent',
+      'link', 'unlink'
+    ]
+
+    # ### remove()
+    #
+    # Remove all formatting for selection
+    #
+    remove: -> @applyFormat 'removeFormat'
+
+    # ### custom( html )
+    #
+    # For hooking in custom actions.
+    #
+    custom: (html) ->
+      if navigator.appName == "Microsoft Internet Explorer"
+        console.log "Custom HTML not yet implemented"
+      else
+        @applyFormat 'insertHTML', html
+
+    # ### Text Styles
+    #
+    # * `bold()`
+    # * `italic()`
+    bold:   -> @applyFormat 'bold'
+    italic: -> @applyFormat 'italic'
+
+    # ### Block Formats
+    #
+    # Wraps the selected element in a block element:
+    #
+    # * `p()`
+    # * `h1()`
+    # * `h2()`
+    # * `h3()`
+    # * `h4()`
+    # * `blockquote()`
+    #
+    p:  -> @applyFormat 'formatBlock', '<p>'
+    h1: -> @applyFormat 'formatBlock', '<h1>'
+    h2: -> @applyFormat 'formatBlock', '<h2>'
+    h3: -> @applyFormat 'formatBlock', '<h3>'
+    h4: -> @applyFormat 'formatBlock', '<h4>'
+    blockquote: -> @applyFormat 'formatBlock', '<blockquote>'
+
+    # ### Lists and Indentation
+    #
+    # * `ol()`
+    # * `ul()`
+    # * `indent()`
+    # * `outdent()`
+    #
+    ol:       -> @applyFormat 'insertOrderedList'
+    ul:       -> @applyFormat 'insertUnorderedList'
+    indent:   -> @applyFormat 'indent'
+    outdent:  -> @applyFormat 'outdent'
+
+    # ### Links
+    #
+    # * `link( url )`
+    # * `unlink()`
+    link:   (url) -> @applyFormat 'link', url
+    unlink:       -> @applyFormat 'unlink'
+
+    # ## HTML Templates
+    #
+    # Templates for inserted html elements
+    templates:
+
+      editorClass: ->
+        "#{ @fondant.options.prefix }-editor"
+      editorContentClass: ->
+        "#{ @editorClass() }-content"
+      toolbarClass: ->
+        "#{ @fondant.options.prefix }-toolbar"
+
+      # ### templates.editor()
+      #
+      # Outer element to wrap the `contenteditable` region so we can insert the toolbar.
+      #
+      editor: ->
+        id = "#{ @fondant.options.prefix }-#{ @fondant.id }"
+
+        """
+        <div class="#{ @editorClass() }" id="#{ id }">
+        </div>
+        """
+
+      # ### templates.editorContent()
+      #
+      # If a `<textarea>` is being swapped out for a `<div>`, this is the
+      # function we'll use to generate the editor.
+      #
+      editorContent: ->
+        """
+        <div class="#{ @editorClass()} #{ @editorContentClass() }">
+        </div>
+        """
+
+      # ### templates.toolbar()
+      #
+      toolbar: ->
+        group = @toolbarClass() + '-button-group'
+        button = @toolbarClass() + '-button'
+        """
+        <ul class="#{ @toolbarClass() }">
+          <li class="#{ group }-label">Text Styles</li>
+          <ul class="#{ group }">
+            <li class="#{ button } #{ button }-bold"><a href="#" data-action="#{ @fondant.type }-bold">B</a></li>
+            <li class="#{ button } #{ button }-italic"><a href="#" data-action="#{ @fondant.type }-italic">I</a></li>
+          </ul>
+          <li class="#{ group }-label">Block Styles</li>
+          <ul class="#{ group }">
+            <li class="#{ button } #{ button }-p"><a href="#" data-action="#{ @fondant.type }-p">P</a></li>
+            <li class="#{ button } #{ button }-h1"><a href="#" data-action="#{ @fondant.type }-h1">H1</a></li>
+            <li class="#{ button } #{ button }-h2"><a href="#" data-action="#{ @fondant.type }-h2">H2</a></li>
+            <li class="#{ button } #{ button }-h3"><a href="#" data-action="#{ @fondant.type }-h3">H3</a></li>
+            <li class="#{ button } #{ button }-h4"><a href="#" data-action="#{ @fondant.type }-h4">H4</a></li>
+            <li class="#{ button } #{ button }-blockquote"><a href="#" data-action="#{ @fondant.type }-blockquote">Quote</a></li>
+          </ul>
+          <li class="#{ group }-label">Lists</li>
+          <ul class="#{ group }">
+            <li class="#{ button } #{ button }-ol"><a href="#" data-action="#{ @fondant.type }-ol">Numbers</a></li>
+            <li class="#{ button } #{ button }-ul"><a href="#" data-action="#{ @fondant.type }-ul">Bullets</a></li>
+            <li class="#{ button } #{ button }-indent"><a href="#" data-action="#{ @fondant.type }-indent">Increase Indent</a></li>
+            <li class="#{ button } #{ button }-outdent"><a href="#" data-action="#{ @fondant.type }-outdent">Decrease Indent</a></li>
+          </ul>
+        </ul>
+        """
+
+
+  # ## Plugin Setup
+  #
+  # ### jQuery function property
+  #
+  # Builds a fondant editor for each matched element.
+  #
+  $.fn.fondant = () ->
+    option = arguments[0]
+    args = Array.prototype.slice.call(arguments)[1..]
+
+    if (typeof option == 'string' && args.length < 1)
+
+      if option in ['getElement', 'value']
+        instance = $(this).data('fondant')
+        if instance
+          return instance[option].apply(instance, args)
+
+    @each ->
+      $this = $(this)
+      instance = $this.data('fondant')
+      options = typeof option == 'object' && option
+
+      if (!instance)
+        $this.data('fondant', (instance = new Fondant(this, options)))
+
+      if typeof option == 'string'
+        instance[option].apply(instance, args)
+
+  # ### Defaults
+  #
+  # Allows user to set their own defaults without having to pass in their
+  # overrides on every instantiation
+  #
+  $.fn.fondant.defaults =
+    prefix: 'fondant'
+    toolbar: true
+

data/vendor/assets/stylesheets/fondant.scss

@@ -0,0 +1,37 @@
+// Fondant v0.2.2
+// see http://github.com/ovenbits-ingredients/fondant for more information
+//
+.fondant-toolbar {
+  display: inline;
+  list-style: none;
+  margin: 0;
+  padding: 0;
+
+  li {
+    display: none;
+  }
+
+  ul {
+    display: inline;
+    margin: 0;
+    padding: 0;
+
+    li {
+      display: inline-block;
+
+      a {
+        background: #eee;
+        border: 1px solid #ddd;
+        border-radius: 0.3rem;
+        color: #777;
+        padding: 0.2rem 0.4rem;
+        &:hover {
+          background: #e0e0e0;
+          text-decoration: none;
+        }
+      }
+
+    }
+  }
+}
+

metadata

@@ -0,0 +1,88 @@
+--- !ruby/object:Gem::Specification
+name: fondant-rails
+version: !ruby/object:Gem::Version
+  version: 0.2.2
+  prerelease: 
+platform: ruby
+authors:
+- Phillip Ridlen
+autorequire: 
+bindir: bin
+cert_chain: []
+date: 2013-02-12 00:00:00.000000000 Z
+dependencies:
+- !ruby/object:Gem::Dependency
+  name: railties
+  requirement: !ruby/object:Gem::Requirement
+    none: false
+    requirements:
+    - - ! '>='
+      - !ruby/object:Gem::Version
+        version: '3.1'
+  type: :runtime
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    none: false
+    requirements:
+    - - ! '>='
+      - !ruby/object:Gem::Version
+        version: '3.1'
+- !ruby/object:Gem::Dependency
+  name: thor
+  requirement: !ruby/object:Gem::Requirement
+    none: false
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '0.17'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    none: false
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '0.17'
+description: Use fondant in Rails' asset pipeline
+email:
+- phillip@ovenbits.com
+executables: []
+extensions: []
+extra_rdoc_files: []
+files:
+- .gitignore
+- Gemfile
+- LICENSE.txt
+- README.md
+- Rakefile
+- fondant-rails.gemspec
+- lib/fondant-rails.rb
+- lib/fondant-rails/source_file.rb
+- lib/fondant-rails/version.rb
+- vendor/assets/javascripts/fondant.coffee
+- vendor/assets/stylesheets/fondant.scss
+homepage: https://github.com/ovenbits-ingredients/fondant-rails
+licenses: []
+post_install_message: 
+rdoc_options: []
+require_paths:
+- lib
+required_ruby_version: !ruby/object:Gem::Requirement
+  none: false
+  requirements:
+  - - ! '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+required_rubygems_version: !ruby/object:Gem::Requirement
+  none: false
+  requirements:
+  - - ! '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+requirements: []
+rubyforge_project: 
+rubygems_version: 1.8.23
+signing_key: 
+specification_version: 3
+summary: Use fondant in Rails' asset pipeline
+test_files: []