flexPartyPlayer 0.0.1

data/src/cc/varga/utils/URLHelper.as

@@ -0,0 +1,52 @@
+//!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
+//
+//Authors: Franics Varga
+//eMail: fv@varga-multimedia.com
+//homepage: http://www.varga-multimedia.com
+//
+//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+//<a href='http://creativecommons.org/licenses/by-nc-sa/3.0/'>Creative Commons License<a\>
+//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+//
+//You are free:
+//
+//to Share — to copy, distribute and transmit the work
+//to Remix — to adapt the work
+//Under the following conditions:
+//
+//Attribution — You must attribute the work in the manner specified by the author or licensor 
+//(but not in any way that suggests that they endorse you or your use of the work).
+//
+//Noncommercial — You may not use this work for commercial purposes.
+//
+//Share Alike — If you alter, transform, or build upon this work, you may distribute the resulting work only under the same or similar license to this one.
+//
+//With the understanding that:
+//
+//Waiver — Any of the above conditions can be waived if you get permission from the copyright holder.
+//Public Domain — Where the work or any of its elements is in the public domain under applicable law, that status is in no way affected by the license.
+//Other Rights — In no way are any of the following rights affected by the license:
+//
+//Your fair dealing or fair use rights, or other applicable copyright exceptions and limitations; The author's moral rights;
+//
+//Rights other persons may have either in the work itself or in how the work is used, such as publicity or privacy rights.
+//Notice — For any reuse or distribution, you must make clear to others the license terms of this work. 
+//The best way to do this is with a link to this web page.																	
+//
+//!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
+package cc.varga.utils
+{
+	public class URLHelper
+	{
+		public function URLHelper()
+		{
+		}
+		
+		public static function getFileURL(host:String, docID:String):String{
+			return host + "" + docID;
+		}
+		
+		public function toString():String{ return "cc.varga.utils.logging.URLHelper"}
+	}
+	
+}

data/src/cc/varga/utils/logging/Logger.as

@@ -0,0 +1,94 @@
+//!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
+//
+//Authors: Franics Varga
+//eMail: fv@varga-multimedia.com
+//homepage: http://www.varga-multimedia.com
+//
+//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+//<a href='http://creativecommons.org/licenses/by-nc-sa/3.0/'>Creative Commons License<a\>
+//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
+//
+//You are free:
+//
+//to Share — to copy, distribute and transmit the work
+//to Remix — to adapt the work
+//Under the following conditions:
+//
+//Attribution — You must attribute the work in the manner specified by the author or licensor 
+//(but not in any way that suggests that they endorse you or your use of the work).
+//
+//Noncommercial — You may not use this work for commercial purposes.
+//
+//Share Alike — If you alter, transform, or build upon this work, you may distribute the resulting work only under the same or similar license to this one.
+//
+//With the understanding that:
+//
+//Waiver — Any of the above conditions can be waived if you get permission from the copyright holder.
+//Public Domain — Where the work or any of its elements is in the public domain under applicable law, that status is in no way affected by the license.
+//Other Rights — In no way are any of the following rights affected by the license:
+//
+//Your fair dealing or fair use rights, or other applicable copyright exceptions and limitations; The author's moral rights;
+//
+//Rights other persons may have either in the work itself or in how the work is used, such as publicity or privacy rights.
+//Notice — For any reuse or distribution, you must make clear to others the license terms of this work. 
+//The best way to do this is with a link to this web page.																	
+//
+//!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
+package cc.varga.utils.logging
+{
+//	import flash.filesystem.File;
+//	import flash.filesystem.FileMode;
+//	import flash.filesystem.FileStream;
+	import cc.varga.mvc.ApplicationContext;
+	
+	import flash.utils.getTimer;
+
+	public class Logger
+	{
+		
+		private static var traceingStr : String = "";
+		//private static var tracingFile : File = new File(File.applicationDirectory.resolvePath("libs/logs/trace.log").toString());
+		
+		private static var errorStr : String = "";
+		//private static var errorFile : File = new File(File.applicationDirectory.resolvePath("libs/logs/error.log").toString());
+		
+		private static var debugStr : String = "";
+		//private static var debugFile : File = new File(File.applicationDirectory.resolvePath("libs/logs/debug.log").toString());
+		
+		public function Logger(){}
+		
+		public static function tracing(message:String, classpath : String):void{
+			traceingStr = "["+getTimer()+"].[TRACING].["+classpath+"] --> " + message;
+			trace(traceingStr);
+			(ApplicationContext.INSTANCE.contextView as FlexPlayer).debug.text += traceingStr + "\n";
+			//writeToFile(tracingFile, traceingStr);
+		}
+		
+		public static function errorTracing(message:String, classpath : String):void{
+			errorStr = "["+getTimer()+"].[ERROR].["+classpath+"]--> " + message;
+			trace(errorStr);
+			(ApplicationContext.INSTANCE.contextView as FlexPlayer).debug.text += traceingStr + "\n";
+			//writeToFile(errorFile, errorStr);
+		}
+		
+		public static function debugTracing(message:String, classpath : String):void{
+			debugStr= "["+getTimer()+"].[DEBUG].["+classpath+"]--> " + message;	
+			trace(debugStr);
+			(ApplicationContext.INSTANCE.contextView as FlexPlayer).debug.text += traceingStr + "\n";
+			//writeToFile(debugFile, debugStr);
+		}
+		
+		/*
+		private static function writeToFile(type:File, message:String):void{
+			
+			var fileStream : FileStream = new FileStream();
+			fileStream.openAsync(type, FileMode.WRITE);
+			fileStream.writeUTFBytes(message);
+			fileStream.close();
+			
+		}
+		*/
+		public function toString():String{ return "cc.varga.utils.logging.Logger"}
+	}
+	
+}

data/src/com/automatastudios/audio/audiodecoder/AudioDecoder.as

@@ -0,0 +1,84 @@
+package com.automatastudios.audio.audiodecoder {
+	import com.automatastudios.audio.audiodecoder.decoders.AudioInfo;
+	import com.automatastudios.audio.audiodecoder.decoders.IDecoder;
+	
+	import flash.events.EventDispatcher;
+	import flash.events.Event;
+	import flash.events.IOErrorEvent;
+	import flash.events.ProgressEvent;
+	import flash.errors.EOFError;
+	import flash.net.URLStream;
+	import flash.utils.ByteArray;
+	import flash.utils.Endian;
+	import flash.utils.IDataInput;
+	import flash.media.Sound;
+	import flash.media.SoundChannel;
+	import flash.net.Socket;
+	
+	public class AudioDecoder extends EventDispatcher {
+		private var _decoder:IDecoder;
+		private var _sound:Sound;
+		private var _soundChannel:SoundChannel;
+		
+		public function AudioDecoder():void {
+			_sound = new Sound();
+		}
+		
+		public function load(data:IDataInput, decoder:Class, bufferSize:uint = 1000, progressEventName:String = null):void {
+			if (progressEventName == null) {
+				if (data is URLStream) {
+					progressEventName = ProgressEvent.PROGRESS;
+				} else if (data is Socket) {
+					progressEventName = ProgressEvent.SOCKET_DATA;
+				}
+			}
+			
+			_sound.addEventListener("sampleData", onSamplesRequest);
+			
+			_decoder = (new decoder() as IDecoder);
+			_decoder.addEventListener(Event.INIT, onDecoderInit);
+			_decoder.addEventListener(Event.COMPLETE, onDecoderComplete);
+			_decoder.addEventListener(IOErrorEvent.IO_ERROR, onDecoderIOError);
+			
+			_decoder.init(data, bufferSize, progressEventName);
+		}
+
+		public function play():SoundChannel {
+			_soundChannel = _sound.play();
+			return _soundChannel;
+		}
+		
+		public function get sound():Sound {
+			return _sound;
+		}
+
+		public function get audioInfo():AudioInfo {
+			return _decoder.getAudioInfo();
+		}
+
+		public function getTotalTime():Number {
+			return _decoder.getTotalTime();
+		}
+		
+		public function getPosition():Number {
+			return _decoder.getPosition();
+		}
+
+		private function onDecoderInit(event:Event):void {
+			dispatchEvent(event);
+		}
+		
+		private function onDecoderComplete(event:Event):void {
+			dispatchEvent(event);
+		}
+		
+		private function onDecoderIOError(event:IOErrorEvent):void {
+			dispatchEvent(event);
+		}
+		
+		private function onSamplesRequest(event:*):void {
+			_decoder.getSamples(event.position, 4096, event.data); 
+		}
+
+	}
+}

data/src/com/automatastudios/audio/audiodecoder/decoders/AudioInfo.as

@@ -0,0 +1,52 @@
+package com.automatastudios.audio.audiodecoder.decoders {
+	public class AudioInfo {
+		
+		public var decoder:String;
+		public var format:String;
+		public var channels:uint;
+		public var sampleRate:uint;
+		public var bitRateUpper:uint;
+		public var bitRateLower:uint;
+		public var bitRateNominal:uint;
+		public var blockAlign:uint;
+		public var bitsPerSample:uint;
+		public var sampleMultiplier:uint;
+		public var commentList:Array;
+		public var commentTable:Object;
+		
+		public function AudioInfo():void {
+			commentList = new Array();
+			commentTable = new Object();
+		}
+		
+		public function toString():String {
+			var result:String = "";
+			var i:uint;
+			var p:String;
+			var max:uint = commentList.length;
+			
+			result += "decoder: " + decoder + "\n";
+			result += "format: " + format + "\n";
+			result += "channels: " + channels + "\n";
+			result += "sampleRate: " + sampleRate + "\n";
+			result += "bitRateUpper: " + bitRateUpper + "\n";
+			result += "bitRateLower: " + bitRateLower + "\n";
+			result += "bitRateNominal: " + bitRateNominal + "\n";
+			result += "blockAlign: " + blockAlign + "\n";
+			result += "bitsPerSample: " + bitsPerSample + "\n";
+			result += "sampleMultiplier: " + sampleMultiplier + "\n";
+			
+			result += "commentList: \n";
+			for (i=0; i<max; ++i) {
+				result += "\t" + i + ": " + commentList[i] + "\n";
+			}
+			
+			result += "commentTable: \n";
+			for (p in commentTable) {
+				result += "\t" + p + ": " + commentTable[p] + "\n";
+			}
+			
+			return result;
+		}
+	}
+}

data/src/com/automatastudios/audio/audiodecoder/decoders/IDecoder.as

@@ -0,0 +1,13 @@
+package com.automatastudios.audio.audiodecoder.decoders {
+	import flash.events.IEventDispatcher;
+	import flash.utils.IDataInput;
+	import flash.utils.ByteArray;
+	
+	public interface IDecoder extends IEventDispatcher {
+		function init(data:IDataInput, buffer:uint, progressEventName:String):void;
+		function getSamples(position:Number, numSamples:uint, sampleData:ByteArray):void;
+		function getAudioInfo():AudioInfo;
+		function getTotalTime():Number;
+		function getPosition():Number;
+	}
+}

data/src/com/automatastudios/audio/audiodecoder/decoders/OggVorbisDecoder.as

@@ -0,0 +1,221 @@
+package com.automatastudios.audio.audiodecoder.decoders {
+	import cmodule.oggvorbis.CLibInit;	
+
+	import flash.errors.EOFError;
+	import flash.events.EventDispatcher;
+	import flash.events.Event;
+	import flash.events.IOErrorEvent;
+	import flash.events.ProgressEvent;
+	import flash.errors.EOFError;
+	import flash.net.URLStream;
+	import flash.utils.ByteArray;
+	import flash.utils.Endian;
+	import flash.utils.IDataInput;		
+	
+	public class OggVorbisDecoder extends EventDispatcher implements IDecoder{
+		private static const READ_ERROR:int = -128;
+		private static const READ_NOT_VORBIS:int = -132;
+		private static const READ_VERSION:int = -134;
+		private static const READ_BAD_HEADER:int = -133;
+		private static const READ_FAULT:int = -129;
+		
+		private static var decoder:*;
+		private var _rawData:IDataInput;
+		private var _data:ByteArray;
+		private var _bufferSize:uint;
+		private var _vorbisFileId:int;
+		
+		private var _position:uint
+		private var _bytesTotal:uint;
+		
+		private var _audioInfo:AudioInfo;
+		private var _convertMethod:Function;
+		
+		private var _nextMethod:Function;
+		
+		public function OggVorbisDecoder():void {
+			// do nothing, wait for init
+		}
+		
+		public function init(data:IDataInput, bufferSize:uint, progressEventName:String):void {
+			var libInit:CLibInit;
+			
+			_nextMethod = setupDecoder;
+			
+			_rawData = data;
+			_data = new ByteArray();
+			_bufferSize = bufferSize;
+			
+			if (decoder == null) {
+				libInit = new CLibInit();
+				decoder = libInit.init();			
+			}
+			
+				
+			if (_rawData is ByteArray) {
+				_bytesTotal = (_rawData as ByteArray).length;
+				_data.length = _bytesTotal;
+			}
+				
+			if (progressEventName != null) {
+				(data as EventDispatcher).addEventListener(progressEventName, onDataProgress);
+			} else {
+				_nextMethod();
+			}			
+		}
+			
+		public function getSamples(position:Number, numSamples:uint, sampleData:ByteArray):void {
+			var numBytes:uint = numSamples * _audioInfo.blockAlign / _audioInfo.sampleMultiplier;
+			var dataReadSize:int;
+			var sampleReadSize:int;
+			var rawSampleData:ByteArray = new ByteArray();
+			var i:uint;
+			
+			rawSampleData.endian = Endian.LITTLE_ENDIAN;
+			
+			dataReadSize = decoder.getSampleData(_vorbisFileId, numBytes, rawSampleData);
+			
+			sampleReadSize = dataReadSize/_audioInfo.blockAlign;
+			
+			if (dataReadSize == -1) {
+				dispatchEvent(new Event(Event.COMPLETE));
+			} else {
+				_position += dataReadSize;
+				rawSampleData.position = 0;
+
+				_convertMethod(sampleReadSize, rawSampleData, sampleData);
+				// pad with extra 0s as needed
+				for (i=sampleReadSize * _audioInfo.sampleMultiplier; i<numSamples; ++i) {
+					sampleData.writeFloat(0);
+					sampleData.writeFloat(0);
+				}
+			}
+		}
+		
+		public function getAudioInfo():AudioInfo {
+			return _audioInfo; 
+		}
+		
+		public function getTotalTime():Number {
+			return decoder.getLength(_vorbisFileId);
+		}
+		
+		public function getPosition():Number {
+			return decoder.getPosition(_vorbisFileId);
+		}
+		
+		private function onDataProgress(event:ProgressEvent):void {
+			var size:uint
+			
+			// need to move the data into a proper ByteArray
+			// FlaCC only works with ByteArrays at this timessss
+			_rawData.readBytes(_data, _data.length, _rawData.bytesAvailable);
+			
+			_bytesTotal = event.bytesTotal;
+
+			_position += size;
+			
+			if (_nextMethod != null) {
+				if (_bytesTotal > 0 && _data.bytesAvailable >= _bufferSize || _data.length == _bytesTotal) {
+					
+					_nextMethod();
+				}
+			}
+		}
+		
+		private function setupDecoder():void {
+			var result:int
+			
+			result = decoder.setupDecoder(_data, _bytesTotal);
+						
+			if (result > 0) {
+				_vorbisFileId = result;
+				_nextMethod = getHeaders;
+				_nextMethod();
+			} else {
+				_nextMethod = null;
+				dispatchEvent(new IOErrorEvent(IOErrorEvent.IO_ERROR, false, false, "Bad audio format"));	
+			}
+		}
+		
+		private function getHeaders():void {
+			var infoObj:Object = decoder.getHeader(_vorbisFileId);
+			var p:String;
+			var i:uint;
+			var max:uint = infoObj.commentList.length;
+			var comment:String;
+			var equalIndex:int;
+			
+			_audioInfo = new AudioInfo();
+			_audioInfo.decoder = "com.automatastudios.audio.audiodecoder.decoders.OggVorbisDecoder";
+			_audioInfo.format = "PCM";
+			_audioInfo.channels = infoObj.channels;
+			_audioInfo.sampleRate = infoObj.sampleRate;
+			_audioInfo.sampleMultiplier = 44100 / infoObj.sampleRate;
+			_audioInfo.bitRateUpper = infoObj.bitRateUpper;
+			_audioInfo.bitRateLower = infoObj.bitRateLower;
+			_audioInfo.bitRateNominal = infoObj.bitRateNominal;
+			_audioInfo.bitsPerSample = 16;
+			
+			for (i=0; i<max; ++i) {
+				comment = infoObj.commentList[i];
+				_audioInfo.commentList.push(comment);
+				
+				equalIndex = comment.indexOf("=");
+				if (equalIndex > -1) {
+					_audioInfo.commentTable[comment.substring(0, equalIndex)] = comment.substring(equalIndex + 1);
+				}
+			}
+			
+			// hardcode 2 bytes-per-sample
+			_audioInfo.blockAlign = _audioInfo.channels * 2;
+			
+			_nextMethod = null;
+			
+			if (_audioInfo.sampleRate != 44100 && _audioInfo.sampleRate != 22050 && _audioInfo.sampleRate != 11025) {
+				dispatchEvent(new IOErrorEvent(IOErrorEvent.IO_ERROR, false, false, "Bad sample rate"));
+			} else {
+				
+				if (_audioInfo.channels == 1) {
+					_convertMethod = convertMono;
+				} else {
+					_convertMethod = convertStereo;
+				}
+				
+				dispatchEvent(new Event(Event.INIT));
+			}
+		}
+		
+		private function convertMono(numSamples:uint, inputData:ByteArray, outputData:ByteArray):void {
+			var i:uint;
+			var j:uint;
+			var sample:Number;
+			
+			for (i=0; i<numSamples; ++i) {
+				sample = inputData.readShort() / 32767;
+				for (j=0; j< _audioInfo.sampleMultiplier; ++j) {
+					outputData.writeFloat(sample);
+					outputData.writeFloat(sample);
+				}
+			}		
+		}
+		
+		private function convertStereo(numSamples:uint, inputData:ByteArray, outputData:ByteArray):void {
+			var i:uint;
+			var j:uint;
+			var sample:Number;
+			
+			for (i=0; i<numSamples; ++i) {
+				sample = inputData.readShort() / 32767;
+				for (j=0; j< _audioInfo.sampleMultiplier; ++j) {
+					outputData.writeFloat(sample);
+				}
+				
+				sample = inputData.readShort() / 32767;
+				for (j=0; j< _audioInfo.sampleMultiplier; ++j) {
+					outputData.writeFloat(sample);
+				}
+			}
+		}	
+	}
+}