exiftool_vendored 13.14.0 → 13.17.0

data/bin/lib/Image/ExifTool/Trailer.pm

@@ -0,0 +1,318 @@
+#------------------------------------------------------------------------------
+# File:         Trailer.pm
+#
+# Description:  Read JPEG trailer written by various makes of phone
+#
+# Revisions:    2025-01-27 - P. Harvey Created
+#------------------------------------------------------------------------------
+
+package Image::ExifTool::Trailer;
+
+use strict;
+use vars qw($VERSION);
+use Image::ExifTool qw(:DataAccess :Utils);
+
+$VERSION = '1.00';
+
+%Image::ExifTool::Trailer::Vivo = (
+    GROUPS => { 0 => 'Trailer', 1 => 'Vivo', 2 => 'Image' },
+    VARS => { NO_ID => 1 },
+    NOTES => 'Information written in JPEG trailer by some Vivo phones.',
+    # (don't know for sure what type of image this is, but it is in JPEG format)
+    HDRImage => {
+        Notes => 'highlights of HDR image',
+        Groups => { 2 => 'Preview' },
+        Binary => 1,
+    },
+    JSONInfo => { },
+    HiddenData => {
+        Notes => 'hidden in EXIF, not in trailer.  This data is lost if the file is edited',
+        Groups => { 0 => 'EXIF' },
+    },
+);
+
+%Image::ExifTool::Trailer::OnePlus = (
+    GROUPS => { 0 => 'Trailer', 1 => 'OnePlus', 2 => 'Image' },
+    NOTES => 'Information written in JPEG trailer by some OnePlus phones.',
+    JSONInfo => { },
+    'private.emptyspace' => { # length of the entire OnePlus trailer
+        Name => 'OnePlusTrailerLen',
+        ValueConv => 'length $val == 4 ? unpack("N", $val) : $val',
+        Unknown => 1,
+    },
+    'watermark.device' => {
+        Name => 'Device',
+        ValueConv => '"0x" . join(" ", unpack("H10Z*", $val))',
+        Format => 'string',
+    },
+);
+
+# Google and/or Android information in JPEG trailer
+%Image::ExifTool::Trailer::Google = (
+    GROUPS => { 0 => 'Trailer', 1 => 'Google', 2 => 'Image' },
+    NOTES => q{
+        Google-defined information written in the trailer of JPEG images by some
+        phones.  This information is referenced by DirectoryItem entries in the XMP.
+        Note that some of this information may also be referenced from other
+        metadata formats, and hence may be extracted twice.  For example,
+        MotionPhotoVideo may also exist within a Samsung trailer as
+        EmbbededVideoFile, or GainMapImage may also exist in an MPF trailer as
+        MPImage2.
+    },
+    MotionPhoto        => { Name => 'MotionPhotoVideo',  Groups => { 2 => 'Video' } },
+    GainMap            => { Name => 'GainMapImage',      Groups => { 2 => 'Preview' } },
+    Depth              => { Name => 'DepthMapImage',     Groups => { 2 => 'Preview' } },
+    Confidence         => { Name => 'ConfidenceMapImage',Groups => { 2 => 'Preview' } },
+    'android/depthmap' => { Name => 'DepthMapImage',     Groups => { 2 => 'Preview' } },
+    'android/confidencemap' => { Name => 'ConfidenceMapImage', Groups => { 2 => 'Preview' } },
+);
+
+#------------------------------------------------------------------------------
+# Process Vivo trailer
+# Inputs: 0) ExifTool object reference, 1) dirInfo reference
+# Returns: 1 on success, 0 on failure, -1 if we must scan for the start
+#          of the trailer to set the ExifTool TrailerStart member
+# - takes Offset as positive offset from end of trailer to end of file,
+#   and returns DataPos and DirLen, and updates OutFile when writing
+sub ProcessVivo($$)
+{
+    my ($et, $dirInfo) = @_;
+    my $raf = $$dirInfo{RAF};
+    my $buff;
+
+    # return now unless we are at a position to scan for the trailer
+    # (must scan because the trailer footer doesn't indicate the trailer length)
+    return -1 unless $$dirInfo{ScanForTrailer};
+
+    my $pos = $$et{TrailerStart} or return 0;
+    my $len = $$et{FileEnd} - $pos - $$dirInfo{Offset};
+    $raf->Seek($pos, 0) or return 0;
+    return 0 unless $len > 0 and $len < 1e7 and $raf->Read($buff, $len) == $len and
+        $buff =~ /\xff{4}\x1b\*9HWfu\x84\x93\xa2\xb1$/ and # validate footer
+        $buff =~ /(streamdata|vivo\{")/g;   # find start
+    my $start = pos($buff) - length($1);
+    if ($start) {
+        $pos += $start;
+        $len -= $start;
+        $buff = substr($buff, $start);
+    }
+    # set trailer position and length 
+    @$dirInfo{'DataPos','DirLen'} = ($pos, $len);
+
+    # let ProcessTrailers copy or delete this trailer
+    return -1 if $$dirInfo{OutFile};
+
+    $et->DumpTrailer($dirInfo) if $$et{OPTIONS}{Verbose} or $$et{HTML_DUMP};
+    my $tbl = GetTagTable('Image::ExifTool::Trailer::Vivo');
+    pos($buff) = 0; # rewind search to start of buffer
+    if ($buff =~ /^streamdata\xff\xd8\xff/ and $buff =~ /\xff\xd9stream(info|coun)/g) {
+        $et->HandleTag($tbl, HDRImage => substr($buff, 10, pos($buff)-20));
+    }
+    # continue looking for Vivo JSON data
+    if ($buff =~ /vivo\{"/g) {
+        my $jsonStart = pos($buff) - 2;
+        if ($buff =~ /\}\0/g) {
+            my $jsonLen = pos($buff) - 1 - $jsonStart;
+            $et->HandleTag($tbl, JSONInfo => substr($buff, $jsonStart, $jsonLen));
+        }
+    }
+    return 1;
+}
+
+#------------------------------------------------------------------------------
+# Process OnePlus trailer
+# Inputs: 0) ExifTool object reference, 1) dirInfo reference
+# Returns: 1 on success, 0 on failure, -1 if we must scan for the start
+#          of the trailer to set the ExifTool TrailerStart member
+# - takes Offset as positive offset from end of trailer to end of file,
+#   and returns DataPos and DirLen, and updates OutFile when writing
+sub ProcessOnePlus($$)
+{
+    my ($et, $dirInfo) = @_;
+    my $raf = $$dirInfo{RAF};
+    my ($buff, $buf2);
+
+    # return now unless we are at a position to scan for the trailer
+    # (must scan because the trailer footer doesn't indicate the entire trailer length)
+    return -1 unless $$dirInfo{ScanForTrailer};
+
+    # return -1 to let ProcessTrailers copy or delete the entire trailer
+    return -1 if $$dirInfo{OutFile};
+
+    my $start = $$et{TrailerStart} or return 0;
+    $raf->Seek(-8-$$dirInfo{Offset}, 2) and $raf->Read($buff, 8) == 8 or return 0;
+    my $end = $raf->Tell(); # (same as FileEnd - Offset)
+
+    my $dump = ($$et{OPTIONS}{Verbose} or $$et{HTML_DUMP});
+    my $tagTable = GetTagTable('Image::ExifTool::Trailer::OnePlus');
+    my $trailLen = 0;
+    if ($buff =~ /^jxrs...\0$/) {
+        my $jlen = unpack('x4V', $buff);
+        my $maxOff = 0;
+        if ($jlen < $end-$start and $jlen > 8 and $raf->Seek($end-$jlen) and
+            $raf->Read($buff, $jlen-8) == $jlen-8)
+        {
+            $buff =~ s/\0+$//;  # remove trailing null(s)
+            require Image::ExifTool::Import;
+            my $list = Image::ExifTool::Import::ReadJSONObject(undef, \$buff);
+            if (ref $list eq 'ARRAY') {
+                $$_{offset} and $$_{offset} > $maxOff and $maxOff = $$_{offset} foreach @$list;
+                $trailLen = $maxOff + $jlen;
+                if ($dump and $trailLen) {
+                    $et->DumpTrailer({
+                        RAF     => $raf,
+                        DirName => 'OnePlus',
+                        DataPos => $end-$trailLen,
+                        DirLen  => $trailLen,
+                    });
+                }
+                $et->HandleTag($tagTable, JSONInfo => $buff);
+                foreach (@$list) {
+                    my ($off, $name, $len) = @$_{qw(offset name length)};
+                    next unless $off and $name and $len;
+                    if ($raf->Seek($end-$jlen-$off) and $raf->Read($buf2, $len) == $len) {
+                        $et->HandleTag($tagTable, $name, $buf2, DataPos => $end-$jlen-$off, DataPt => \$buf2);
+                    }
+                }
+            } else {
+                $et->HandleTag($tagTable, JSONInfo => $buff);
+                $et->Warn('Error parsing OnePlus JSON information');
+            }
+        }
+    }
+    @$dirInfo{'DataPos','DirLen'} = ($end - $trailLen, $trailLen);
+
+    return 1;
+}
+
+#------------------------------------------------------------------------------
+# Process Google trailer
+# Inputs: 0) ExifTool object reference, 1) dirInfo reference
+# Returns: 1 on success, 0 on failure, -1 if we must scan for the start
+#          of the trailer to set the ExifTool TrailerStart member
+# - this trailer won't be identified when writing because XMP isn't extracted then
+sub ProcessGoogle($$)
+{
+    my ($et, $dirInfo) = @_;
+    my $raf = $$dirInfo{RAF};
+    my $info = $$et{VALUE};
+
+    my ($tag, $mime, $len, $pad) = @$info{qw(DirectoryItemSemantic DirectoryItemMime
+                                             DirectoryItemLength DirectoryItemPadding)};
+
+    unless (ref $tag eq 'ARRAY' and ref $mime eq 'ARRAY') {
+        undef $pad;
+        ($tag, $mime, $len) = @$info{qw(ContainerDirectoryItemDataURI
+            ContainerDirectoryItemMime ContainerDirectoryItemLength)};
+        unless (ref $mime eq 'ARRAY' and ref $tag eq 'ARRAY') {
+            delete $$et{ProcessGoogleTrailer};
+            return 0;
+        }
+    }
+    # we need to know TrailerStart to be able to read/write this trailer
+    return -1 unless $$dirInfo{ScanForTrailer};
+
+    delete $$et{ProcessGoogleTrailer};  # reset flag to process the Google trailer
+
+    return -1 if $$dirInfo{OutFile};
+
+    # sometimes DirectoryItemLength is missing the Primary entry
+    $len = [ $len ] unless ref $len eq 'ARRAY';
+    unshift @$len, 0 while @$len < @$mime;
+
+    my $start = $$et{TrailerStart} or return 0;
+    my $end = $$et{FileEnd}; # (ignore Offset for now because some entries may run into other trailers)
+
+    my $dump = ($$et{OPTIONS}{Verbose} or $$et{HTML_DUMP});
+    my $tagTable = GetTagTable('Image::ExifTool::Trailer::Google');
+
+    # (ignore first entry: "Primary" or "primary_image")
+    my ($i, $pos, $buff, $regex, $grp, $type);
+    for ($i=1, $pos=0; defined $$mime[$i]; ++$i) {
+        my $more = $end - $start - $pos;
+        last if $more < 16;
+        next unless $$len[$i] and defined $$tag[$i];
+        last if $$len[$i] > $more;
+        $raf->Seek($start+$pos) and $raf->Read($buff, 16) == 16 and $raf->Seek($start+$pos) or last;
+        if ($$mime[$i] eq 'image/jpeg') {
+            $regex = '\xff\xd8\xff[\xdb\xe0\xe1]';
+        } elsif ($$mime[$i] eq 'video/mp4') {
+            $regex = '\0\0\0.ftyp(mp42|isom)';
+        } else {
+            $et->Warn("Google trailer $$tag[$i] $$mime[$i] not handled");
+            next;
+        }
+        if ($buff =~ /^$regex/s) {
+            last unless $raf->Read($buff, $$len[$i]) == $$len[$i];
+        } else {
+            last if $pos; # don't skip unknown information again
+            last unless $raf->Read($buff, $more) == $more;
+            last unless $buff =~ /($regex)/sg;
+            $pos += pos($buff) - length($1);
+            $more = $end - $start - $pos;
+            last if $$len[$i] > $end - $start - $pos;
+            $buff = substr($buff, $pos, $$len[$i]);
+        }
+        unless ($$tagTable{$$tag[$i]}) {
+            my $name = $$tag[$i];
+            $name =~ s/([^A-Za-z])([a-z])/$1\u$2/g; # capitalize words
+            $name = Image::ExifTool::MakeTagName($$tag[$i]);
+            if ($$mime[$i] eq 'image/jpeg') {
+                ($type, $grp) = ('Image', 'Preview');
+            } else {
+                ($type, $grp) = ('Video', 'Video');
+            }
+            $et->VPrint(0, $$et{INDENT}, "[adding Google:$name]\n");
+            AddTagToTable($tagTable, $$tag[$i], { Name => "$name$type", Groups => { 2 => $grp } });
+        }
+        $dump and $et->DumpTrailer({
+            RAF     => $raf,
+            DirName => $$tag[$i],
+            DataPos => $start + $pos,
+            DirLen  => $$len[$i],
+        });
+        $et->HandleTag($tagTable, $$tag[$i], \$buff, { DataPos => $start + $pos, DataPt => \$buff });
+        # (haven't seen non-zero padding, but I assume this is how it works
+        $pos += $$len[$i] + (($pad and $$pad[$i]) ? $$pad[$i] : 0);
+    }
+    if (defined $$tag[$i] and defined $$mime[$i]) {
+        $et->Warn("Error reading $$tag[$i] $$mime[$i] from trailer", 1);
+    }
+    return 0 unless $pos;
+
+    @$dirInfo{'DataPos','DirLen'} = ($start, $pos);
+
+    return 1;
+}
+
+1;  # end
+
+__END__
+
+=head1 NAME
+
+Image::ExifTool::Trailer - Read JPEG trailer written by various phone makes
+
+=head1 SYNOPSIS
+
+This module is used by Image::ExifTool
+
+=head1 DESCRIPTION
+
+This module contains definitions required by Image::ExifTool to read
+metadata the trailer written by some Vivo, OnePlus and Google phones.
+
+=head1 AUTHOR
+
+Copyright 2003-2025, Phil Harvey (philharvey66 at gmail.com)
+
+This library is free software; you can redistribute it and/or modify it
+under the same terms as Perl itself.
+
+=head1 SEE ALSO
+
+L<Image::ExifTool::TagNames/Trailer Tags>,
+L<Image::ExifTool(3pm)|Image::ExifTool>
+
+=cut
+

data/bin/lib/Image/ExifTool/WriteQuickTime.pl

@@ -378,6 +378,9 @@ sub WriteNextbase($$$)
 # Write Meta Keys to add/delete entries as necessary ('mdta' handler) (ref PH)
 # Inputs: 0) ExifTool object ref, 1) dirInfo ref, 2) tag table ref
 # Returns: updated keys box data
+# Note: Residual entries may be left in the 'keys' directory when deleting tags
+#       with language codes because the language code(s) are not known until the
+#       corresponding ItemList entry(s) are processed
 sub WriteKeys($$$)
 {
     my ($et, $dirInfo, $tagTablePtr) = @_;
@@ -901,15 +904,10 @@ sub WriteQuickTime($$$)
     my $createKeys = 0;
     my ($rtnVal, $rtnErr) = $dataPt ? (undef, undef) : (1, 0);
 
-    # check for Insta360 trailer at top level
+    # check for trailer at end of file
     if ($raf) {
-        my $pos = $raf->Tell();
-        if ($raf->Seek(-40, 2) and $raf->Read($buf2, 40) == 40 and
-            substr($buf2, 8) eq '8db42d694ccc418790edff439fe026bf')
-        {
-            $trailer = [ 'Insta360', $raf->Tell() - unpack('V',$buf2) ];
-        }
-        $raf->Seek($pos, 0) or return 0;
+        $trailer = IdentifyTrailers($raf);
+        $trailer and not ref $trailer and $et->Error($trailer), return 1;
     }
     if ($dataPt) {
         $raf = File::RandomAccess->new($dataPt);
@@ -1063,6 +1061,10 @@ sub WriteQuickTime($$$)
             $et->Error("Can't yet write compressed movie metadata");
             return $rtnVal;
         } elsif ($tag eq 'wide') {
+            if ($size) {
+                $et->Warn("Incorrect size for 'wide' atom ($size bytes)");
+                $raf->Seek($size, 1) or $et->Error('Truncated wide atom');
+            }
             next;   # drop 'wide' tag
         }
 
@@ -1598,16 +1600,26 @@ sub WriteQuickTime($$$)
         if (($lastTag eq 'mdat' or $lastTag eq 'moov') and not $dataPt and (not $$tagTablePtr{$tag} or
             ref $$tagTablePtr{$tag} eq 'HASH' and $$tagTablePtr{$tag}{Unknown}))
         {
-            # identify other known trailers
+            # identify other known trailers from their first bytes
             $buf2 = '';
             $raf->Seek($lastPos,0) and $raf->Read($buf2,8);
+            my ($type, $len);
             if ($buf2 eq 'CCCCCCCC') {
-                $trailer = [ 'Kenwood', $lastPos ];
+                $type = 'Kenwood';
             } elsif ($buf2 =~ /^(gpsa|gps0|gsen|gsea)...\0/s) {
-                $trailer = [ 'RIFF', $lastPos ];
+                $type = 'RIFF';
             } else {
-                $trailer = [ 'Unknown', $lastPos ];
+                $type = 'Unknown';
             }
+            # determine length of this trailer
+            if ($trailer) {
+                $len = $$trailer[1] - $lastPos; # runs to start of next trailer
+            } else {
+                $raf->Seek(0, 2) or $et->Error('Seek error'), return $dataPt ? undef : 1;
+                $len = $raf->Tell() - $lastPos; # runs to end of file
+            }
+            # add to start of linked list of trailers
+            $trailer = [ $type, $lastPos, $len, $trailer ];
         } else {
             $et->Error($errStr);
             return $dataPt ? undef : 1;
@@ -2069,21 +2081,35 @@ sub WriteQuickTime($$$)
     # write the stuff that must come last
     Write($outfile, $writeLast) or $rtnVal = 0 if $writeLast;
 
-    # copy trailer if necessary
-    if ($rtnVal and $trailer) {
-        # are we deleting the trailer?
+    # copy trailers if necessary
+    while ($rtnVal and $trailer) {
+        # are we deleting the trailers?
         my $nvTrail = $et->GetNewValueHash($Image::ExifTool::Extra{Trailer});
-        if ($$et{DEL_GROUP}{Trailer} or ($nvTrail and not ($$nvTrail{Value} and $$nvTrail{Value}[0]))) {
+        if ($$et{DEL_GROUP}{Trailer} or $$et{DEL_GROUP}{$$trailer[0]} or
+            ($nvTrail and not ($$nvTrail{Value} and $$nvTrail{Value}[0])))
+        {
             $et->Warn("Deleted $$trailer[0] trailer", 1);
-        } elsif ($raf->Seek($$trailer[1])) {
-            $et->Warn(sprintf('Copying %s trailer from offset 0x%x', @$trailer), 1);
-            while ($raf->Read($buf2, 65536)) {
-                Write($outfile, $buf2) or $rtnVal = 0, last;
-            }
+            ++$$et{CHANGED};
+            $trailer = $$trailer[3];
+            next;
+        }
+        $raf->Seek($$trailer[1], 0) or $rtnVal = 0, last;
+        if ($$trailer[0] eq 'MIE') {
+            require Image::ExifTool::MIE;
+            my %dirInfo = ( RAF => $raf, OutFile => $outfile );
+            my $result = Image::ExifTool::MIE::ProcessMIE($et, \%dirInfo);
+            $result > 0 or $et->Error('Error writing MIE trailer'), $rtnVal = 0, last;
         } else {
-            $rtnVal = 0;
+            $et->Warn(sprintf('Copying %s trailer from offset 0x%x (%d bytes)', @$trailer[0..2]), 1);
+            my $len = $$trailer[2];
+            while ($len) {
+                my $n = $len > 65536 ? 65536 : $len;
+                $raf->Read($buf2, $n) == $n and Write($outfile, $buf2) or $rtnVal = 0, last;
+                $len -= $n;
+            }
+            $rtnVal or $et->Error("Error copying $$trailer[0] trailer"), last;
         }
-        $rtnVal or $et->Error("Error copying $$trailer[0] trailer");
+        $trailer = $$trailer[3];    # step to next trailer in linked list
     }
     return $rtnVal;
 }

data/bin/lib/Image/ExifTool/WriteRIFF.pl

@@ -324,8 +324,10 @@ sub WriteRIFF($$)
                     $raf->Read($buff, 6) == 6 or $et->Error('Truncated VP8L chunk'), return 1;
                     $outsize += 6;
                     if ($buff =~ /^\x2f/s) {
+                        my $word = Get32u(\$buff, 2);
                         $imageWidth  =  (Get16u(\$buff, 1) & 0x3fff) + 1;
-                        $imageHeight = ((Get32u(\$buff, 2) >> 6) & 0x3fff) + 1;
+                        $imageHeight = (($word >> 6) & 0x3fff) + 1;
+                        $has{ALPH} = 1 if $word & 0x100000; # set alpha flag if necessary
                     }
                     $len2 -= 6;
                 }

data/bin/lib/Image/ExifTool/Writer.pl

@@ -140,10 +140,10 @@ my @delGroups = qw(
     Adobe AFCP APP0 APP1 APP2 APP3 APP4 APP5 APP6 APP7 APP8 APP9 APP10 APP11 APP12
     APP13 APP14 APP15 AudioKeys CanonVRD CIFF Ducky EXIF ExifIFD File FlashPix
     FotoStation GlobParamIFD GPS ICC_Profile IFD0 IFD1 Insta360 InteropIFD IPTC
-    ItemList JFIF Jpeg2000 JUMBF Keys MakerNotes Meta MetaIFD Microsoft MIE MPF
-    Nextbase NikonApp NikonCapture PDF PDF-update PhotoMechanic Photoshop PNG
-    PNG-pHYs PrintIM QuickTime RMETA RSRC SEAL SubIFD Trailer UserData VideoKeys
-    Vivo XML XML-* XMP XMP-*
+    ItemList iTunes JFIF Jpeg2000 JUMBF Keys MakerNotes Meta MetaIFD Microsoft
+    MIE MPF Nextbase NikonApp NikonCapture PDF PDF-update PhotoMechanic
+    Photoshop PNG PNG-pHYs PrintIM QuickTime RMETA RSRC SEAL SubIFD Trailer
+    UserData VideoKeys Vivo XML XML-* XMP XMP-*
 );
 # family 2 group names that we can delete
 my @delGroup2 = qw(
@@ -2856,7 +2856,7 @@ sub GetAllGroups($;$)
         }
     }
     delete $allGroups{'*'};     # (not a real group)
-    return sort keys %allGroups;
+    return sort { lc $a cmp lc $b } keys %allGroups;
 }
 
 #------------------------------------------------------------------------------
@@ -2874,7 +2874,7 @@ sub GetNewGroups($)
 # Returns: List of group names (sorted alphabetically)
 sub GetDeleteGroups()
 {
-    return sort @delGroups, @delGroup2;
+    return sort { lc $a cmp lc $b } @delGroups, @delGroup2;
 }
 
 #------------------------------------------------------------------------------
@@ -3340,7 +3340,8 @@ sub InsertTagValues($$;$$$$)
                 } elsif ($tag eq 'self') {
                     $val = $et; # ("$self{var}" or "$file1:self{var}" in string)
                 } else {
-                    # get the tag value
+                    # get the tag value (note: this direct access allows excluded tags
+                    # to be accessed if the case is correct and a group name is not used)
                     $val = $et->GetValue($tag, $type);
                     unless (defined $val) {
                         # check for tag name with different case

data/bin/lib/Image/ExifTool/XMP2.pl

@@ -1995,7 +1995,8 @@ my %sACDSeeRegionStruct = (
                         Struct => {
                             STRUCT_NAME => 'DeviceItem',
                             NAMESPACE => { Item => 'http://ns.google.com/photos/dd/1.0/item/' },
-                            Mime    => { },
+                            # use this as a key to process Google trailer
+                            Mime    => { RawConv => '$$self{ProcessGoogleTrailer} = $val' },
                             Length  => { Writable => 'integer' },
                             Padding => { Writable => 'integer' },
                             DataURI => { },
@@ -2149,7 +2150,7 @@ my %sACDSeeRegionStruct = (
                     STRUCT_NAME => 'Item',
                     # (use 'GItem' to avoid conflict with Google Device Container Item)
                     NAMESPACE => { GItem => 'http://ns.google.com/photos/1.0/container/item/'},
-                    Mime     => { },
+                    Mime    => { RawConv => '$$self{ProcessGoogleTrailer} = $val' },
                     Semantic => { },
                     Length   => { Writable => 'integer' },
                     Label    => { },