exiftool_vendored 12.18.0 → 12.33.0

data/bin/lib/Image/ExifTool/Jpeg2000.pm

@@ -16,9 +16,10 @@ use strict;
 use vars qw($VERSION);
 use Image::ExifTool qw(:DataAccess :Utils);
 
-$VERSION = '1.27';
+$VERSION = '1.31';
 
 sub ProcessJpeg2000Box($$$);
+sub ProcessJUMD($$$);
 
 my %resolutionUnit = (
     -3 => 'km',
@@ -54,6 +55,22 @@ my %jp2Map = (
     MakerNotes   => 'ExifIFD',
 );
 
+# map of where information is written in a JXL image
+my %jxlMap = (
+    IFD0         => 'Exif',
+    XMP          => 'XML',
+   'Exif'        => 'JP2',
+    IFD1         => 'IFD0',
+    EXIF         => 'IFD0', # to write EXIF as a block
+    ExifIFD      => 'IFD0',
+    GPS          => 'IFD0',
+    SubIFD       => 'IFD0',
+    GlobParamIFD => 'IFD0',
+    PrintIM      => 'IFD0',
+    InteropIFD   => 'ExifIFD',
+    MakerNotes   => 'ExifIFD',
+);
+
 # UUID's for writable UUID directories (by tag name)
 my %uuid = (
     'UUID-EXIF'   => 'JpgTiffExif->JP2',
@@ -107,9 +124,13 @@ my %j2cMarker = (
     WRITE_PROC => \&ProcessJpeg2000Box,
     PREFERRED => 1, # always add these tags when writing
     NOTES => q{
-        The tags below are extracted from JPEG 2000 images, however ExifTool
-        currently writes only EXIF, IPTC and XMP tags in these images.
+        The tags below are found in JPEG 2000 images and the JUMBF metadata in JPEG
+        images, but not all of these are extracted.  Note that ExifTool currently
+        writes only EXIF, IPTC and XMP tags in Jpeg2000 images.
     },
+#
+# NOTE: ONLY TAGS WITH "Format" DEFINED ARE EXTRACTED!
+#
    'jP  ' => 'JP2Signature', # (ref 1)
    "jP\x1a\x1a" => 'JP2Signature', # (ref 2)
     prfl => 'Profile',
@@ -199,13 +220,22 @@ my %j2cMarker = (
     chck => 'DigitalSignature',
     mp7b => 'MPEG7Binary',
     free => 'Free',
-    jp2c => 'ContiguousCodestream',
+    jp2c => [{
+        Name => 'ContiguousCodestream',
+        Condition => 'not $$self{jumd_level}',
+    },{
+        Name => 'PreviewImage',
+        Groups => { 2 => 'Preview' },
+        Format => 'undef',
+        Binary => 1,
+    }],
     jp2i => {
         Name => 'IntellectualProperty',
         SubDirectory => { TagTable => 'Image::ExifTool::XMP::Main' },
     },
-   'xml '=> {
+   'xml '=> [{
         Name => 'XML',
+        Condition => 'not $$self{IsJXL}',
         Writable => 'undef',
         Flags => [ 'Binary', 'Protected', 'BlockExtract' ],
         List => 1,
@@ -213,12 +243,18 @@ my %j2cMarker = (
             by default, the XML data in this tag is parsed using the ExifTool XMP module
             to to allow individual tags to be accessed when reading, but it may also be
             extracted as a block via the "XML" tag, which is also how this tag is
-            written and copied.  This is a List-type tag because multiple XML blocks may
-            exist
+            written and copied.  It may also be extracted as a block by setting the API
+            BlockExtract option.  This is a List-type tag because multiple XML blocks
+            may exist
         },
         # (note: extracting as a block was broken in 11.04, and finally fixed in 12.14)
         SubDirectory => { TagTable => 'Image::ExifTool::XMP::XML' },
-    },
+    },{
+        Name => 'XMP',
+        Notes => 'used for XMP in JPEG XL files',
+        # NOTE: the hacked code relies on this being at index 1 of the tagInfo list!
+        SubDirectory => { TagTable => 'Image::ExifTool::XMP::Main' },
+    }],
     uuid => [
         {
             Name => 'UUID-EXIF',
@@ -302,6 +338,22 @@ my %j2cMarker = (
                 Start => '$valuePtr + 16',
             },
         },
+        {
+            Name => 'UUID-Signature',  # (seen in JUMB data of JPEG images)
+            # (may be able to remove this when JUMBF specification is finalized)
+            Condition => '$$valPt=~/^casg\x00\x11\x00\x10\x80\x00\x00\xaa\x00\x38\x9b\x71/',
+            Format => 'undef',
+            ValueConv => 'substr($val,16)',
+        },
+        {
+            Name => 'UUID-C2PAClaimSignature',  # (seen in incorrectly-formatted JUMB data of JPEG images)
+            # (may be able to remove this when JUMBF specification is finalized)
+            Condition => '$$valPt=~/^c2cs\x00\x11\x00\x10\x80\x00\x00\xaa\x00\x38\x9b\x71/',
+            SubDirectory => {
+                TagTable => 'Image::ExifTool::CBOR::Main',
+                Start => '$valuePtr + 16',
+            },
+        },
         {
             Name => 'UUID-Unknown',
         },
@@ -321,6 +373,73 @@ my %j2cMarker = (
             Name => 'URL',
             Format => 'string',
         },
+    # JUMBF boxes (ref https://github.com/thorfdbg/codestream-parser)
+    jumd => {
+        Name => 'JUMBFDescr',
+        SubDirectory => { TagTable => 'Image::ExifTool::Jpeg2000::JUMD' },
+    },
+    jumb => {
+        Name => 'JUMBFBox',
+        SubDirectory => {
+            TagTable => 'Image::ExifTool::Jpeg2000::Main',
+            ProcessProc => \&ProcessJUMB,
+        },
+    },
+    json => {
+        Name => 'JSONData',
+        Flags => [ 'Binary', 'Protected', 'BlockExtract' ],
+        Notes => q{
+            by default, data in this tag is parsed using the ExifTool JSON module to to
+            allow individual tags to be accessed when reading, but it may also be
+            extracted as a block via the "JSONData" tag or by setting the API
+            BlockExtract option
+        },
+        SubDirectory => { TagTable => 'Image::ExifTool::JSON::Main' },
+    },
+    cbor => {
+        Name => 'CBORData',
+        Flags => [ 'Binary', 'Protected' ],
+        SubDirectory => { TagTable => 'Image::ExifTool::CBOR::Main' },
+    },
+    bfdb => { # used in JUMBF (see  # (used when tag is renamed according to JUMDLabel)
+        Name => 'BinaryDataType',
+        Notes => 'JUMBF, MIME type and optional file name',
+        Format => 'undef',
+        # (ignore "toggles" byte and just extract MIME type and file name)
+        ValueConv => '$_=substr($val,1); s/\0+$//; s/\0/, /; $_',
+        JUMBF_Suffix => 'Type', # (used when tag is renamed according to JUMDLabel)
+    },
+    bidb => { # used in JUMBF
+        Name => 'BinaryData',
+        Notes => 'JUMBF',
+        Groups => { 2 => 'Preview' },
+        Format => 'undef',
+        Binary => 1,
+        JUMBF_Suffix => 'Data', # (used when tag is renamed according to JUMDLabel)
+    },
+#
+# stuff seen in JPEG XL images:
+#
+  # jbrd - JPEG Bitstream Reconstruction Data (allows lossless conversion back to original JPG)
+    jxlc => {
+        Name => 'JXLCodestream',
+        Format => 'undef',
+        Notes => q{
+            Codestream in JPEG XL image.  Currently processed only to determine
+            ImageSize
+        },
+        RawConv => 'Image::ExifTool::Jpeg2000::ProcessJXLCodestream($self,\$val); undef',
+    },
+    Exif => {
+        Name => 'EXIF',
+        SubDirectory => {
+            TagTable => 'Image::ExifTool::Exif::Main',
+            ProcessProc => \&Image::ExifTool::ProcessTIFF,
+            WriteProc => \&Image::ExifTool::WriteTIFF,
+            DirName => 'EXIF',
+            Start => '$valuePtr + 4',
+        },
+    },
 );
 
 %Image::ExifTool::Jpeg2000::ImageHeader = (
@@ -375,6 +494,7 @@ my %j2cMarker = (
             'jp2 ' => 'JPEG 2000 Image (.JP2)',           # image/jp2
             'jpm ' => 'JPEG 2000 Compound Image (.JPM)',  # image/jpm
             'jpx ' => 'JPEG 2000 with extensions (.JPX)', # image/jpx
+            'jxl ' => 'JPEG XL Image (.JXL)',             # image/jxl
         },
     },
     1 => {
@@ -513,6 +633,114 @@ my %j2cMarker = (
     ],
 );
 
+# JUMBF description box
+%Image::ExifTool::Jpeg2000::JUMD = (
+    PROCESS_PROC => \&ProcessJUMD,
+    GROUPS => { 0 => 'JUMBF', 1 => 'JUMBF', 2 => 'Image' },
+    NOTES => 'Information extracted from the JUMBF description box.',
+    'type' => {
+        Name => 'JUMDType',
+        ValueConv => 'unpack "H*", $val',
+        PrintConv => q{
+            my @a = $val =~ /^(\w{8})(\w{4})(\w{4})(\w{16})$/;
+            return $val unless @a;
+            my $ascii = pack 'H*', $a[0];
+            $a[0] = "($ascii)" if $ascii =~ /^[a-zA-Z0-9]{4}$/;
+            return join '-', @a;
+        },
+        # seen:
+        # cacb/cast/caas/cacl/casg/json-00110010800000aa00389b71
+        # 6579d6fbdba2446bb2ac1b82feeb89d1 - JPEG image
+    },
+    'label' => { Name => 'JUMDLabel' },
+    'toggles' => {
+        Name => 'JUMDToggles',
+        Unknown => 1,
+        PrintConv => { BITMASK => {
+            0 => 'Requestable',
+            1 => 'Label',
+            2 => 'ID',
+            3 => 'Signature',
+        }},
+    },
+    'id'    => { Name => 'JUMDID', Description => 'JUMD ID' },
+    'sig'   => { Name => 'JUMDSignature', PrintConv => 'unpack "H*", $val' },
+);
+
+#------------------------------------------------------------------------------
+# Read JUMBF box to keep track of sub-document numbers
+# Inputs: 0) ExifTool ref, 1) dirInfo ref, 2) tag table ref
+# Returns: 1 on success
+sub ProcessJUMB($$$)
+{
+    my ($et, $dirInfo, $tagTablePtr) = @_;
+    if ($$et{jumd_level}) {
+        ++$$et{jumd_level}[-1]; # increment current sub-document number
+    } else {
+        $$et{jumd_level} = [ ++$$et{DOC_COUNT} ]; # new top-level sub-document
+        $$et{SET_GROUP0} = 'JUMBF';
+    }
+    $$et{DOC_NUM} = join '-', @{$$et{jumd_level}};
+    push @{$$et{jumd_level}}, 0;
+    ProcessJpeg2000Box($et, $dirInfo, $tagTablePtr);
+    delete $$et{DOC_NUM};
+    delete $$et{JUMBFLabel};
+    pop @{$$et{jumd_level}};
+    if (@{$$et{jumd_level}} < 2) {
+        delete $$et{jumd_level};
+        delete $$et{SET_GROUP0};
+    }
+    return 1;
+}
+
+#------------------------------------------------------------------------------
+# Read JUMBF description box (ref https://github.com/thorfdbg/codestream-parser)
+# Inputs: 0) ExifTool ref, 1) dirInfo ref, 2) tag table ref
+# Returns: 1 on success
+sub ProcessJUMD($$$)
+{
+    my ($et, $dirInfo, $tagTablePtr) = @_;
+    my $dataPt = $$dirInfo{DataPt};
+    my $pos    = $$dirInfo{DirStart};
+    my $end    = $pos + $$dirInfo{DirLen};
+    $et->VerboseDir('JUMD', 0, $end-$pos);
+    delete $$et{JUMBFLabel};
+    $$dirInfo{DirLen} < 17 and $et->Warn('Truncated JUMD directory'), return 0;
+    my $type = substr($$dataPt, $pos, 4);
+    $et->HandleTag($tagTablePtr, 'type', substr($$dataPt, $pos, 16));
+    $pos += 16;
+    my $flags = Get8u($dataPt, $pos++);
+    $et->HandleTag($tagTablePtr, 'toggles', $flags);
+    if ($flags & 0x02) {    # label exists?
+        pos($$dataPt) = $pos;
+        $$dataPt =~ /\0/g or $et->Warn('Missing JUMD label terminator'), return 0;
+        my $len = pos($$dataPt) - $pos;
+        my $name = substr($$dataPt, $pos, $len);
+        $et->HandleTag($tagTablePtr, 'label', $name);
+        $pos += $len;
+        if ($len) {
+            $name =~ s/[^-_a-zA-Z0-9]([a-z])/\U$1/g; # capitalize characters after illegal characters
+            $name =~ tr/-_a-zA-Z0-9//dc;    # remove other illegal characters
+            $name =~ s/__/_/;               # collapse double underlines
+            $name = ucfirst $name;          # capitalize first letter
+            $name = "Tag$name" if length($name) < 2; # must at least 2 characters long
+            $$et{JUMBFLabel} = $name;
+        }
+    }
+    if ($flags & 0x04) {    # ID exists?
+        $pos + 4 > $end and $et->Warn('Missing JUMD ID'), return 0;
+        $et->HandleTag($tagTablePtr, 'id', Get32u($dataPt, $pos));
+        $pos += 4;
+    }
+    if ($flags & 0x08) {    # signature exists?
+        $pos + 32 > $end and $et->Warn('Missing JUMD signature'), return 0;
+        $et->HandleTag($tagTablePtr, 'sig', substr($$dataPt, $pos, 32));
+        $pos += 32;
+    }
+    $pos == $end or $et->Warn('Extra data in JUMD box'." $pos $end", 1);
+    return 1;
+}
+
 #------------------------------------------------------------------------------
 # Create new JPEG 2000 boxes when writing
 # (Currently only supports adding top-level Writable JPEG2000 tags and certain UUID boxes)
@@ -542,8 +770,29 @@ sub CreateNewBoxes($$)
             $et->VerboseValue("+ Jpeg2000:$$tagInfo{Name}", $val);
         }
     }
-    # add UUID boxes
+    # add UUID boxes (and/or JXL Exif/XML boxes)
     foreach $dirName (sort keys %$addDirs) {
+        # handle JPEG XL XMP and EXIF
+        if ($dirName eq 'XML' or $dirName eq 'Exif') {
+            my ($tag, $dir) = $dirName eq 'XML' ? ('xml ', 'XMP') : ('Exif', 'EXIF');
+            my $tagInfo = $Image::ExifTool::Jpeg2000::Main{$tag};
+            $tagInfo = $$tagInfo[1] if ref $tagInfo eq 'ARRAY'; # (hack for stupid JXL XMP)
+            my $subdir = $$tagInfo{SubDirectory};
+            my $tagTable = GetTagTable($$subdir{TagTable});
+            $tagTable = GetTagTable('Image::ExifTool::XMP::Main') if $dir eq 'XMP';
+            my %dirInfo = (
+                DirName => $dir,
+                Parent => 'JP2',
+            );
+            my $newdir = $et->WriteDirectory(\%dirInfo, $tagTable, $$subdir{WriteProc});
+            if (defined $newdir and length $newdir) {
+                # not sure why, but EXIF box is padded with leading 0's in my sample
+                my $pad = $dirName eq 'Exif' ? "\0\0\0\0" : '';
+                my $boxhdr = pack('N', length($newdir) + length($pad) + 8) . $tag;
+                Write($outfile, $boxhdr, $pad, $newdir) or return 0;
+                next;
+            }
+        }
         next unless $uuid{$dirName};
         my $tagInfo;
         foreach $tagInfo (@{$Image::ExifTool::Jpeg2000::Main{uuid}}) {
@@ -715,6 +964,14 @@ sub ProcessJpeg2000Box($$$)
                 }
             }
         }
+        # create new tag for JUMBF data values with name corresponding to JUMBFLabel
+        if ($tagInfo and $$et{JUMBFLabel} and (not $$tagInfo{SubDirectory} or $$tagInfo{BlockExtract})) {
+            $tagInfo = { %$tagInfo, Name => $$et{JUMBFLabel} . ($$tagInfo{JUMBF_Suffix} || '') };
+            delete $$tagInfo{Description};
+            AddTagToTable($tagTablePtr, '_JUMBF_' . $$et{JUMBFLabel}, $tagInfo);
+            delete $$tagInfo{Protected}; # (must do this so -j -b returns JUMBF binary data)
+            $$tagInfo{TagID} = $boxID;
+        }
         if ($verbose) {
             $et->VerboseInfo($boxID, $tagInfo,
                 Table  => $tagTablePtr,
@@ -752,8 +1009,8 @@ sub ProcessJpeg2000Box($$$)
                 # remove this directory from our create list
                 delete $$et{AddJp2Dirs}{$$tagInfo{Name}};
                 my $newdir;
-                # only edit writable UUID boxes
-                if ($uuid) {
+                # only edit writable UUID and Exif boxes
+                if ($uuid or $boxID eq 'Exif' or ($boxID eq 'xml ' and $$et{IsJXL})) {
                     $newdir = $et->WriteDirectory(\%subdirInfo, $subTable, $$subdir{WriteProc});
                     next if defined $newdir and not length $newdir; # next if deleting the box
                 } elsif (defined $uuid) {
@@ -803,6 +1060,68 @@ sub ProcessJpeg2000Box($$$)
     return 1;
 }
 
+#------------------------------------------------------------------------------
+# Return bits from a bitstream object
+# Inputs: 0) array ref, 1) number of bits
+# Returns: specified number of bits as an integer, and shifts input bitstream
+sub GetBits($$)
+{
+    my ($a, $n) = @_;
+    my $v = 0;
+    my $bit = 1;
+    my $i;
+    while ($n--) {
+        for ($i=0; $i<@$a; ++$i) {
+            # consume bits LSB first
+            my $set = $$a[$i] & 1;
+            $$a[$i] >>= 1;
+            if ($i) {
+                $$a[$i-1] |= 0x80 if $set;
+            } else {
+                $v |= $bit if $set;
+                $bit <<= 1;
+            }
+        }
+    }
+    return $v;
+}
+
+#------------------------------------------------------------------------------
+# Extract parameters from JPEG XL codestream [unverified!]
+# Inputs: 0) ExifTool ref, 1) codestream ref
+# Returns: 1
+sub ProcessJXLCodestream($$)
+{
+    my ($et, $dataPt) = @_;
+    # add padding if necessary to avoid unpacking past end of data
+    if (length $$dataPt < 14) {
+        my $tmp = $$dataPt . ("\0" x 14);
+        $dataPt = \$tmp;
+    }
+    my @a = unpack 'x2C12', $$dataPt;
+    my ($x, $y);
+    my $small = GetBits(\@a, 1);
+    if ($small) {
+        $y = (GetBits(\@a, 5) + 1) * 8;
+    } else {
+        $y = GetBits(\@a, [9, 13, 18, 30]->[GetBits(\@a, 2)]) + 1;
+    }
+    my $ratio = GetBits(\@a, 3);
+    if ($ratio == 0) {
+        if ($small) {
+            $x = (GetBits(\@a, 5) + 1) * 8;;
+        } else {
+            $x = GetBits(\@a, [9, 13, 18, 30]->[GetBits(\@a, 2)]) + 1;
+        }
+    } else {
+        my $r = [[1,1],[12,10],[4,3],[3,2],[16,9],[5,4],[2,1]]->[$ratio-1];
+        $x = int($y * $$r[0] / $$r[1]);
+    }
+    $et->FoundTag(ImageWidth => $x);
+    $et->FoundTag(ImageHeight => $y);
+    return 1;
+}
+
 #------------------------------------------------------------------------------
 # Read/write meta information from a JPEG 2000 image
 # Inputs: 0) ExifTool object reference, 1) dirInfo reference
@@ -817,8 +1136,9 @@ sub ProcessJP2($$)
 
     # check to be sure this is a valid JPG2000 file
     return 0 unless $raf->Read($hdr,12) == 12;
-    unless ($hdr eq "\x00\x00\x00\x0cjP  \x0d\x0a\x87\x0a" or     # (ref 1)
-            $hdr eq "\x00\x00\x00\x0cjP\x1a\x1a\x0d\x0a\x87\x0a") # (ref 2)
+    unless ($hdr eq "\0\0\0\x0cjP  \x0d\x0a\x87\x0a" or     # (ref 1)
+            $hdr eq "\0\0\0\x0cjP\x1a\x1a\x0d\x0a\x87\x0a" or # (ref 2)
+            $$et{IsJXL})
     {
         return 0 unless $hdr =~ /^\xff\x4f\xff\x51\0/;  # check for JP2 codestream format
         if ($outfile) {
@@ -835,17 +1155,23 @@ sub ProcessJP2($$)
     }
     if ($outfile) {
         Write($outfile, $hdr) or return -1;
-        $et->InitWriteDirs(\%jp2Map);
+        if ($$et{IsJXL}) {
+            $et->InitWriteDirs(\%jxlMap);
+            $$et{AddJp2Tags} = { }; # (don't add JP2 tags in JXL files)
+        } else {
+            $et->InitWriteDirs(\%jp2Map);
+            $$et{AddJp2Tags} = $et->GetNewTagInfoHash(\%Image::ExifTool::Jpeg2000::Main);
+        }
         # save list of directories to create
-        my %addDirs = %{$$et{ADD_DIRS}};
+        my %addDirs = %{$$et{ADD_DIRS}}; # (make a copy)
         $$et{AddJp2Dirs} = \%addDirs;
-        $$et{AddJp2Tags} = $et->GetNewTagInfoHash(\%Image::ExifTool::Jpeg2000::Main);
     } else {
         my ($buff, $fileType);
         # recognize JPX and JPM as unique types of JP2
         if ($raf->Read($buff, 12) == 12 and $buff =~ /^.{4}ftyp(.{4})/s) {
             $fileType = 'JPX' if $1 eq 'jpx ';
             $fileType = 'JPM' if $1 eq 'jpm ';
+            $fileType = 'JXL' if $1 eq 'jxl ';
         }
         $raf->Seek(-length($buff), 1) if defined $buff;
         $et->SetFileType($fileType);
@@ -860,6 +1186,59 @@ sub ProcessJP2($$)
     return $et->ProcessDirectory(\%dirInfo, $tagTablePtr);
 }
 
+#------------------------------------------------------------------------------
+# Read meta information from a JPEG XL image
+# Inputs: 0) ExifTool object reference, 1) dirInfo reference
+# Returns: 1 on success, 0 if this wasn't a valid JPEG XL file, -1 on write error
+sub ProcessJXL($$)
+{
+    my ($et, $dirInfo) = @_;
+    my $raf = $$dirInfo{RAF};
+    my $outfile = $$dirInfo{OutFile};
+    my ($hdr, $buff);
+
+    return 0 unless $raf->Read($hdr,12) == 12;
+    if ($hdr eq "\0\0\0\x0cJXL \x0d\x0a\x87\x0a") {
+        # JPEG XL in ISO BMFF container
+        $$et{IsJXL} = 1;
+    } elsif ($hdr =~ /^\xff\x0a/) {
+        # JPEG XL codestream
+        if ($outfile) {
+            if ($$et{OPTIONS}{IgnoreMinorErrors}) {
+                $et->Warn('Wrapped JXL codestream in ISO BMFF container');
+            } else {
+                $et->Error('Will wrap JXL codestream in ISO BMFF container for writing',1);
+                return 0;
+            }
+            $$et{IsJXL} = 2;
+            my $buff = "\0\0\0\x0cJXL \x0d\x0a\x87\x0a\0\0\0\x14ftypjxl \0\0\0\0jxl ";
+            # add metadata to empty ISO BMFF container
+            $$dirInfo{RAF} = new File::RandomAccess(\$buff);
+        } else {
+            $et->SetFileType('JXL Codestream','image/jxl', 'jxl');
+            return ProcessJXLCodestream($et, \$hdr);
+        }
+    } else {
+        return 0;
+    }
+    $raf->Seek(0,0) or $et->Error('Seek error'), return 0;
+
+    my $success = ProcessJP2($et, $dirInfo);
+
+    if ($outfile and $success > 0 and $$et{IsJXL} == 2) {
+        # attach the JXL codestream box to the ISO BMFF file
+        $raf->Seek(0,2) or return -1;
+        my $size = $raf->Tell();
+        $raf->Seek(0,0) or return -1;
+        SetByteOrder('MM');
+        Write($outfile, Set32u($size + 8), 'jxlc') or return -1;
+        while ($raf->Read($buff, 65536)) {
+            Write($outfile, $buff) or return -1;
+        }
+    }
+    return $success;
+}
+
 1;  # end
 
 __END__

data/bin/lib/Image/ExifTool/LIF.pm

@@ -0,0 +1,153 @@
+#------------------------------------------------------------------------------
+# File:         LIF.pm
+#
+# Description:  Read LIF (Leica Image File) files
+#
+# Revisions:    2021-06-21 - P. Harvey Created
+#------------------------------------------------------------------------------
+
+package Image::ExifTool::LIF;
+
+use strict;
+use vars qw($VERSION);
+use Image::ExifTool qw(:DataAccess :Utils);
+use Image::ExifTool::XMP;
+
+$VERSION = '1.00';
+
+%Image::ExifTool::LIF::Main = (
+    GROUPS => { 0 => 'XML', 1 => 'XML', 2 => 'Image' },
+    PROCESS_PROC => \&Image::ExifTool::XMP::ProcessXMP,
+    VARS => { NO_ID => 1 },
+    NOTES => q{
+        Tags extracted from Leica Image Format (LIF) imaging files.  As well as the
+        tags listed below, all available information is extracted from the
+        XML-format metadata in the LIF header.
+    },
+    TimeStampList => {
+        Groups => { 2 => 'Time' },
+        ValueConv => q{
+            my $unixTimeZero = 134774 * 24 * 3600;
+            my @vals = split ' ', $val;
+            foreach (@vals) {
+                $_ = 1e-7 * hex($_);
+                # shift from Jan 1, 1601 to Jan 1, 1970
+                $_ = Image::ExifTool::ConvertUnixTime($_ - $unixTimeZero);
+            }
+            return \@vals;
+        },
+    },
+);
+
+#------------------------------------------------------------------------------
+# Shorten obscenely long LIF tag names
+# Inputs: Tag name
+# Returns: Shortened tag name
+sub ShortenTagNames($)
+{
+    local $_;
+    $_ = shift;
+    s/DescriptionDimensionsDimensionDescription/Dimensions/;
+    s/DescriptionChannelsChannelDescription/Channel/;
+    s/ShutterListShutter/Shutter/;
+    s/SettingDefinition/Setting/;
+    s/AdditionalZPositionListAdditionalZPosition/AdditionalZPosition/;
+    s/LMSDataContainerHeader//g;
+    s/FilterWheelWheel/FilterWheel/;
+    s/FilterWheelFilter/FilterWheel/;
+    s/DetectorListDetector/Detector/;
+    s/OnlineDyeSeparationOnlineDyeSeparation/OnlineDyeSeparation/;
+    s/AotfListAotf/Aotf/;
+    s/SettingAotfLaserLineSetting/SettingAotfLaser/;
+    s/DataROISetROISet/DataROISet/;
+    s/AdditionalZPosition/AddZPos/;
+    s/FRAPplusBlock_FRAPBlock_FRAP_PrePost_Info/FRAP_/;
+    s/FRAPplusBlock_FRAPBlock_FRAP_(Master)?/FRAP_/;
+    s/LDM_Block_SequentialLDM_Block_Sequential_/LDM_/;
+    s/ATLConfocalSetting/ATLConfocal/;
+    s/LaserArrayLaser/Laser/;
+    s/LDM_Master/LDM_/;
+    s/(List)?ATLConfocal/ATL_/;
+    s/Separation/Sep/;
+    s/BleachPointsElement/BleachPoint/;
+    s/BeamPositionBeamPosition/BeamPosition/;
+    s/DataROISetPossible(ROI)?/DataROISet/;
+    s/RoiElementChildrenElementDataROISingle(Roi)?/Roi/;
+    s/InfoLaserLineSettingArrayLaserLineSetting/LastLineSetting/;
+    s/FilterWheelWheelNameFilterName/FilterWheelFilterName/;
+    s/LUT_ListLut/Lut/;
+    s/ROI_ListRoiRoidata/ROI_/;
+    s/LaserLineSettingArrayLaserLineSetting/LaserLineSetting/;
+    return $_;
+}
+
+#------------------------------------------------------------------------------
+# Extract metadata from a LIF image
+# Inputs: 0) ExifTool object reference, 1) dirInfo reference
+# Returns: 1 on success, 0 if this wasn't a valid LIF file
+sub ProcessLIF($$)
+{
+    my ($et, $dirInfo) = @_;
+    my $raf = $$dirInfo{RAF};
+    my $buff;
+
+    # verify this is a valid LIF file
+    return 0 unless $raf->Read($buff, 15) == 15 and $buff =~ /^\x70\0{3}.{4}\x2a.{4}<\0/s;
+
+    $et->SetFileType();
+    SetByteOrder('II');
+
+    my $size = Get32u(\$buff, 4);       # XML chunk size
+    my $len = Get32u(\$buff, 9) * 2;    # XML data length
+
+    $size < $len and $et->Error('Corrupted LIF XML block'), return 1;
+    $size > 100000000 and $et->Error('LIF XML block too large'), return 1;
+
+    $raf->Seek(-2, 1) and $raf->Read($buff, $len) == $len or $et->Error('Truncated LIF XML block'), return 1;
+
+    my $tagTablePtr = GetTagTable('Image::ExifTool::LIF::Main');
+
+    # convert from UCS2 to UTF8
+    my $xml = Image::ExifTool::Decode($et, $buff, 'UCS2', 'II', 'UTF8');
+
+    my %dirInfo = ( DataPt => \$xml );
+
+    $$et{XmpIgnoreProps} = [ 'LMSDataContainerHeader', 'Element', 'Children', 'Data', 'Image', 'Attachment' ];
+    $$et{ShortenXmpTags} = \&ShortenTagNames;
+
+    $et->ProcessDirectory(\%dirInfo, $tagTablePtr);
+
+    return 1;
+}
+
+1;  # end
+
+__END__
+
+=head1 NAME
+
+Image::ExifTool::LIF - Read LIF meta information
+
+=head1 SYNOPSIS
+
+This module is used by Image::ExifTool
+
+=head1 DESCRIPTION
+
+This module contains definitions required by Image::ExifTool to read
+metadata from Leica Image File (LIF) images.
+
+=head1 AUTHOR
+
+Copyright 2003-2021, Phil Harvey (philharvey66 at gmail.com)
+
+This library is free software; you can redistribute it and/or modify it
+under the same terms as Perl itself.
+
+=head1 SEE ALSO
+
+L<Image::ExifTool::TagNames/LIF Tags>,
+L<Image::ExifTool(3pm)|Image::ExifTool>
+
+=cut
+