exiftool_vendored 10.65.0 → 11.41.0

data/bin/lib/Image/ExifTool/FITS.pm

@@ -0,0 +1,148 @@
+#------------------------------------------------------------------------------
+# File:         FITS.pm
+#
+# Description:  Read Flexible Image Transport System metadata
+#
+# Revisions:    2018/03/07 - P. Harvey Created
+#
+# References:   1) https://fits.gsfc.nasa.gov/fits_standard.html
+#------------------------------------------------------------------------------
+
+package Image::ExifTool::FITS;
+
+use strict;
+use vars qw($VERSION);
+use Image::ExifTool qw(:DataAccess :Utils);
+
+$VERSION = '1.00';
+
+# FITS tags (ref 1)
+%Image::ExifTool::FITS::Main = (
+    GROUPS => { 2 => 'Image' },
+    NOTES => q{
+        This table lists some standard Flexible Image Transport System (FITS) tags,
+        but ExifTool will extract any other tags found.  See
+        L<https://fits.gsfc.nasa.gov/fits_standard.html> for the specification.
+    },
+    TELESCOP => 'Telescope',
+    BACKGRND => 'Background',
+    INSTRUME => 'Instrument',
+    OBJECT   => 'Object',
+    OBSERVER => 'Observer',
+    DATE     => { Name => 'CreateDate', Groups => { 2 => 'Time' } },
+    AUTHOR   => { Name => 'Author',     Groups => { 2 => 'Author' } },
+    REFERENC => 'Reference',
+   'DATE-OBS'=> { Name => 'ObservationDate',    Groups => { 2 => 'Time' } },
+   'TIME-OBS'=> { Name => 'ObservationTime',    Groups => { 2 => 'Time' } },
+   'DATE-END'=> { Name => 'ObservationDateEnd', Groups => { 2 => 'Time' } },
+   'TIME-END'=> { Name => 'ObservationTimeEnd', Groups => { 2 => 'Time' } },
+);
+
+#------------------------------------------------------------------------------
+# Read information in a FITS document
+# Inputs: 0) ExifTool ref, 1) dirInfo ref
+# Returns: 1 on success, 0 if this wasn't a valid FITS file
+sub ProcessFITS($$)
+{
+    my ($et, $dirInfo) = @_;
+    my $raf = $$dirInfo{RAF};
+    my ($buff, $tag, $continue);
+
+    return 0 unless $raf->Read($buff, 80) == 80 and $buff =~ /^SIMPLE  = {20}T/;
+    $et->SetFileType();
+    my $tagTablePtr = GetTagTable('Image::ExifTool::FITS::Main');
+
+    for (;;) {
+        $raf->Read($buff, 80) == 80 or $et->Warn('Truncated FITS header'), last;
+        my $key = substr($buff, 0, 8);
+        $key =~ s/ +$//;    # remove trailing space from key
+        if ($key eq 'CONTINUE') {
+            defined $continue or $et->WarnOnce('Unexpected FITS CONTINUE keyword'), next;
+        } else {
+            if (defined $continue) {
+                # the previous value wasn't continued, so store with the trailing '&'
+                $et->HandleTag($tagTablePtr, $tag, $continue . '&');
+                undef $continue;
+            }
+            last if $key eq 'END';
+            # make sure the key is valid
+            $key =~ /^[-_A-Z0-9]*$/ or $et->Warn('Format error in FITS header'), last;
+            next unless substr($buff,8,2) eq '= ';  # ignore comment lines
+            # save tag name (avoiding potential conflict with ExifTool variables)
+            $tag = $Image::ExifTool::specialTags{$key} ? "_$key" : $key;
+            # add to tag table if necessary
+            unless ($$tagTablePtr{$tag}) {
+                my $name = ucfirst lc $tag; # make tag name lower case with leading capital
+                $name =~ s/_(.)/\U$1/g;     # remove all '_' and capitalize subsquent letter
+                AddTagToTable($tagTablePtr, $tag, { Name => $name });
+            }
+        }
+        my $val = substr($buff, 10);
+        # parse quoted values
+        if ($val =~ /^'(.*?)'(.*)/) {
+            ($val, $buff) = ($1, $2);
+            while ($buff =~ /^('.*?)'(.*)/) {   # handle escaped quotes
+                $val .= $1;
+                $buff = $2;
+            }
+            $val =~ s/ +$//;            # remove trailing spaces
+            if (defined $continue) {
+                $val = $continue . $val;
+                undef $continue;
+            }
+            # check for possible continuation, removing trailing '&'
+            $val =~ s/\&$// and $continue = $val, next;
+        } elsif (defined $continue) {
+            $et->WarnOnce('Invalid FITS CONTINUE value');
+            next;
+        } else {
+            $val =~ s/ *(\/.*)?$//;     # remove trailing spaces and comment
+            next unless length $val;    # ignore undefined values
+            $val =~ s/^ +//;            # remove leading spaces
+            # re-format floating-point values to use 'e'
+            $val =~ tr/DE/e/ if $val =~ /^[+-]?(?=\d|\.\d)\d*(\.\d*)?([ED]([+-]?\d+))?$/;
+        }
+        $et->HandleTag($tagTablePtr, $tag, $val);
+    }
+    return 1;
+}
+
+1;  # end
+
+__END__
+
+=head1 NAME
+
+Image::ExifTool::FITS - Read Flexible Image Transport System metadata
+
+=head1 SYNOPSIS
+
+This module is used by Image::ExifTool
+
+=head1 DESCRIPTION
+
+This module contains definitions required by Image::ExifTool to read meta
+information from FITS (Flexible Image Transport System) images.
+
+=head1 AUTHOR
+
+Copyright 2003-2019, Phil Harvey (phil at owl.phy.queensu.ca)
+
+This library is free software; you can redistribute it and/or modify it
+under the same terms as Perl itself.
+
+=head1 REFERENCES
+
+=over 4
+
+=item L<https://fits.gsfc.nasa.gov/fits_standard.html>
+
+=back
+
+=head1 SEE ALSO
+
+L<Image::ExifTool::TagNames/FITS Tags>,
+L<Image::ExifTool(3pm)|Image::ExifTool>
+
+=cut
+

data/bin/lib/Image/ExifTool/FLAC.pm

@@ -155,7 +155,7 @@ sub ProcessBitStream($$$)
     my $tag;
 
     if ($verbose) {
-        $et->VPrint(0, "  + [BitStream directory, $dirLen bytes, '$byteOrder' order]\n");
+        $et->VPrint(0, "  + [BitStream directory, $dirLen bytes, '${byteOrder}' order]\n");
     }
     foreach $tag (sort keys %$tagTablePtr) {
         next unless $tag =~ /^Bit(\d+)-?(\d+)?/;
@@ -284,7 +284,7 @@ information from Free Lossless Audio Codec (FLAC) audio files.
 
 =head1 AUTHOR
 
-Copyright 2003-2017, Phil Harvey (phil at owl.phy.queensu.ca)
+Copyright 2003-2019, Phil Harvey (phil at owl.phy.queensu.ca)
 
 This library is free software; you can redistribute it and/or modify it
 under the same terms as Perl itself.

data/bin/lib/Image/ExifTool/FLIF.pm

@@ -329,7 +329,7 @@ meta information in FLIF (Free Lossless Image Format) images.
 
 =head1 AUTHOR
 
-Copyright 2003-2017, Phil Harvey (phil at owl.phy.queensu.ca)
+Copyright 2003-2019, Phil Harvey (phil at owl.phy.queensu.ca)
 
 This library is free software; you can redistribute it and/or modify it
 under the same terms as Perl itself.

data/bin/lib/Image/ExifTool/FLIR.pm

@@ -24,7 +24,7 @@ use Image::ExifTool qw(:DataAccess :Utils);
 use Image::ExifTool::Exif;
 use Image::ExifTool::GPS;
 
-$VERSION = '1.16';
+$VERSION = '1.18';
 
 sub ProcessFLIR($$;$);
 sub ProcessFLIRText($$$);
@@ -97,7 +97,7 @@ my %float8g = ( Format => 'float', PrintConv => 'sprintf("%.8g",$val)' );
     PROCESS_PROC => \&ProcessFLIR,
     VARS => { ALPHA_FIRST => 1 },
     NOTES => q{
-        Information extracted from FLIR FFF images and the FLIR APP1 segment of JPEG
+        Information extracted from FLIR FFF images and the APP1 FLIR segment of JPEG
         images.  These tags may also be extracted from the first frame of an FLIR
         SEQ file.
     },
@@ -165,7 +165,10 @@ my %float8g = ( Format => 'float', PrintConv => 'sprintf("%.8g",$val)' );
     },
     0x2b => {
         Name => 'GPSInfo',
-        SubDirectory => { TagTable => 'Image::ExifTool::FLIR::GPSInfo' },
+        SubDirectory => {
+            TagTable => 'Image::ExifTool::FLIR::GPSInfo',
+            ByteOrder => 'LittleEndian',
+        },
     },
     0x2c => {
         Name => 'MeterLink',
@@ -443,6 +446,8 @@ my %float8g = ( Format => 'float', PrintConv => 'sprintf("%.8g",$val)' );
     0x21c => { Name => 'FilterSerialNumber',Format => 'string[32]' },
     0x308 => { Name => 'PlanckO',           Format => 'int32s' }, #1
     0x30c => { Name => 'PlanckR2',          %float8g }, #1
+    0x310 => { Name => 'RawValueRangeMin',  Format => 'int16u', Groups => { 2 => 'Image' } }, #forum10060
+    0x312 => { Name => 'RawValueRangeMax',  Format => 'int16u', Groups => { 2 => 'Image' } }, #forum10060
     0x338 => { Name => 'RawValueMedian',    Format => 'int16u', Groups => { 2 => 'Image' } },
     0x33c => { Name => 'RawValueRange',     Format => 'int16u', Groups => { 2 => 'Image' } },
     0x384 => {
@@ -602,15 +607,111 @@ my %float8g = ( Format => 'float', PrintConv => 'sprintf("%.8g",$val)' );
     7 => { Name => 'PiPY2', Description => 'PiP Y2' },
 );
 
-# FLIR GPS record (ref PH/JD)
+# FLIR GPS record (ref PH/JD/forum9615)
 %Image::ExifTool::FLIR::GPSInfo = (
-    GROUPS => { 0 => 'APP1', 2 => 'Image' },
+    GROUPS => { 0 => 'APP1', 2 => 'Location' },
     PROCESS_PROC => \&Image::ExifTool::ProcessBinaryData,
     FIRST_ENTRY => 0,
+    0x00 => {
+        Name => 'GPSValid',
+        Format => 'int32u',
+        RawConv => '$$self{GPSValid} = $val',
+        PrintConv => { 0 => 'No', 1 => 'Yes' },
+    },
+    0x04 => {
+        Name => 'GPSVersionID',
+        Format => 'undef[4]',
+        RawConv => '$val eq "\0\0\0\0" ? undef : $val',
+        PrintConv => 'join ".", split //, $val',
+    },
+    0x08 => {
+        Name => 'GPSLatitudeRef',
+        Format => 'string[2]',
+        RawConv => 'length($val) ? $val : undef',
+        PrintConv => {
+            N => 'North',
+            S => 'South',
+        },
+    },
+    0x0a => {
+        Name => 'GPSLongitudeRef',
+        Format => 'string[2]',
+        RawConv => 'length($val) ? $val : undef',
+        PrintConv => {
+            E => 'East',
+            W => 'West',
+        },
+    },
+  # 0x0c - 4 unknown bytes
+    0x10 => {
+        Name => 'GPSLatitude',
+        Condition => '$$self{GPSValid}',    # valid only if GPSValid is 1
+        Format => 'double', # (signed)
+        PrintConv => 'Image::ExifTool::GPS::ToDMS($self, $val, 1, "N")',
+    },
+    0x18 => {
+        Name => 'GPSLongitude',
+        Condition => '$$self{GPSValid}',    # valid only if GPSValid is 1
+        Format => 'double', # (signed)
+        PrintConv => 'Image::ExifTool::GPS::ToDMS($self, $val, 1, "E")',
+    },
+    0x20 => {
+        Name => 'GPSAltitude',
+        Condition => '$$self{GPSValid}',    # valid only if GPSValid is 1
+        Format => 'float',
+        # (have seen likely invalid value of -1 when GPSValid is 1)
+        PrintConv => 'sprintf("%.2f m", $val)',
+    },
+  # 0x24 - 28 unknown bytes:
+  # 0x28 - int8u: seen 0,49,51,55,57 (ASCII "1","3","7","9")
+  # 0x29 - int8u: seen 0,48 (ASCII "0")
+    0x40 => {
+        Name => 'GPSDOP',
+        Description => 'GPS Dilution Of Precision',
+        Format => 'float',
+        RawConv => '$val > 0 ? $val : undef', # (have also seen likely invalid value of 1)
+        PrintConv => 'sprintf("%.2f", $val)',
+    },
+    0x44 => {
+        Name => 'GPSSpeedRef',
+        Format => 'string[2]',
+        RawConv => 'length($val) ? $val : undef',
+        PrintConv => {
+            K => 'km/h',
+            M => 'mph',
+            N => 'knots',
+        },
+    },
+    0x46 => {
+        Name => 'GPSTrackRef',
+        Format => 'string[2]',
+        RawConv => 'length($val) ? $val : undef',
+        PrintConv => {
+            M => 'Magnetic North',
+            T => 'True North',
+        },
+    },
+  # 0x48 - int32u: seen 0,77
+    0x4c => {
+        Name => 'GPSSpeed',
+        %float2f,
+        RawConv => '$val < 0 ? undef : $val',
+    },
+    0x50 => {
+        Name => 'GPSTrack',
+        %float2f,
+        RawConv => '$val < 0 ? undef : $val',
+    },
+  # 0x54 - float: seen 0,-1
     0x58 => {
         Name => 'GPSMapDatum',
         Format => 'string[16]',
+        RawConv => 'length($val) ? $val : undef',
     },
+  # 0xa4 - string[6]: seen 000208,081210,020409,000608,010408,020808,091011
+  # 0x78 - double[2]: seen "-1 -1","0 0"
+  # 0x78 - float[2]: seen "-1 -1","0 0"
+  # 0xb2 - string[2]?: seen "5\0"
 );
 
 # humidity meter information
@@ -1311,10 +1412,7 @@ sub ProcessMeasInfo($$$)
         last if $recLen < 0x28 or $pos + $recLen > $dirEnd;
         my $pre = 'Meas' . $i;
         $et->VerboseDir("MeasInfo $i", undef, $recLen);
-        if ($verbose > 2) {
-            HexDump($dataPt, $recLen,
-                Start=>$pos, Prefix=>$$et{INDENT}, DataPos=>$dataPos);
-        }
+        $et->VerboseDump($dataPt, Len => $recLen, Start=>$pos, DataPos=>$dataPos);
         my $coordLen = Get16u($dataPt, $pos+4);
         # generate tag table entries for this tool if necessary
         foreach $t ('Type', 'Params', 'Label') {
@@ -1448,9 +1546,7 @@ sub ProcessFLIR($$;$)
                 Size    => $recLen,
             );
         } elsif ($verbose > 2) {
-            my %parms = ( DataPos => $recPos, Prefix => $$et{INDENT} );
-            $parms{MaxLen} = 96 if $verbose < 4;
-            HexDump(\$rec, $recLen, %parms);
+            $et->VerboseDump(\$rec, Len => $recLen, DataPos => $recPos);
         }
     }
     delete $$et{SET_GROUP0};
@@ -1499,7 +1595,7 @@ Systems Inc. thermal image files (FFF, FPF and JPEG format).
 
 =head1 AUTHOR
 
-Copyright 2003-2017, Phil Harvey (phil at owl.phy.queensu.ca)
+Copyright 2003-2019, Phil Harvey (phil at owl.phy.queensu.ca)
 
 This library is free software; you can redistribute it and/or modify it
 under the same terms as Perl itself.

data/bin/lib/Image/ExifTool/Fixup.pm

@@ -354,7 +354,7 @@ linear list when ApplyFixups() is called.
 
 =head1 AUTHOR
 
-Copyright 2003-2017, Phil Harvey (phil at owl.phy.queensu.ca)
+Copyright 2003-2019, Phil Harvey (phil at owl.phy.queensu.ca)
 
 This library is free software; you can redistribute it and/or modify it
 under the same terms as Perl itself.

data/bin/lib/Image/ExifTool/Flash.pm

@@ -363,7 +363,7 @@ Record: for ($rec=0; ; ++$rec) {
                 $pos += 2 + $len;
                 # first string of a typed object is the object name
                 if ($getName) {
-                    $et->VPrint(1,"  | (object name '$tag')\n");
+                    $et->VPrint(1,"  | (object name '${tag}')\n");
                     undef $getName;
                     next; # (ignore name for now)
                 }
@@ -454,7 +454,7 @@ Record: for ($rec=0; ; ++$rec) {
             } else {
                 # give verbose indication if we ignore a lone value
                 my $t = $amfType[$type] || sprintf('type 0x%x',$type);
-                $et->VPrint(1, "  | (ignored lone $t value '$val')\n");
+                $et->VPrint(1, "  | (ignored lone $t value '${val}')\n");
             }
         }
     }
@@ -721,7 +721,7 @@ will add AMF3 support.
 
 =head1 AUTHOR
 
-Copyright 2003-2017, Phil Harvey (phil at owl.phy.queensu.ca)
+Copyright 2003-2019, Phil Harvey (phil at owl.phy.queensu.ca)
 
 This library is free software; you can redistribute it and/or modify it
 under the same terms as Perl itself.

data/bin/lib/Image/ExifTool/FlashPix.pm

@@ -9,6 +9,8 @@
 #               2) http://www.graphcomp.com/info/specs/livepicture/fpx.pdf
 #               3) http://search.cpan.org/~jdb/libwin32/
 #               4) http://msdn.microsoft.com/en-us/library/aa380374.aspx
+#               5) http://www.cpan.org/modules/by-authors/id/H/HC/HCARVEY/File-MSWord-0.1.zip
+#               6) https://msdn.microsoft.com/en-us/library/cc313153(v=office.12).aspx
 #------------------------------------------------------------------------------
 
 package Image::ExifTool::FlashPix;
@@ -19,7 +21,7 @@ use Image::ExifTool qw(:DataAccess :Utils);
 use Image::ExifTool::Exif;
 use Image::ExifTool::ASF;   # for GetGUID()
 
-$VERSION = '1.29';
+$VERSION = '1.36';
 
 sub ProcessFPX($$);
 sub ProcessFPXR($$$);
@@ -27,7 +29,12 @@ sub ProcessProperties($$$);
 sub ReadFPXValue($$$$$;$$);
 sub ProcessHyperlinks($$);
 sub ProcessContents($$$);
+sub ProcessWordDocument($$$);
+sub ProcessDocumentTable($);
+sub ProcessCommentBy($$$);
+sub ProcessLastSavedBy($$$);
 sub SetDocNum($$;$$$);
+sub ConvertDTTM($);
 
 # sector type constants
 sub HDR_SIZE           () { 512; }
@@ -425,6 +432,21 @@ my %fpxFileType = (
             return substr($val, 8 + $pos, $len);
         },
     },
+    'WordDocument' => {
+        Name => 'WordDocument',
+        SubDirectory => { TagTable => 'Image::ExifTool::FlashPix::WordDocument' },
+    },
+    # save these tables until after the WordDocument was processed
+    '0Table' => {
+        Name => 'Table0',
+        Hidden => 1, # (used only as temporary storage until table is processed)
+        Binary => 1,
+    },
+    '1Table' => {
+        Name => 'Table1',
+        Hidden => 1, # (used only as temporary storage until table is processed)
+        Binary => 1,
+    },
     Preview => {
         Name => 'PreviewImage',
         Groups => { 2 => 'Preview' },
@@ -1031,6 +1053,216 @@ my %fpxFileType = (
     },
 );
 
+# decode Word document FIB header (ref [MS-DOC].pdf)
+%Image::ExifTool::FlashPix::WordDocument = (
+    PROCESS_PROC => \&ProcessWordDocument,
+    GROUPS => { 2 => 'Other' },
+    FORMAT => 'int16u',
+    NOTES => 'Tags extracted from the Microsoft Word document stream.',
+    0 => {
+        Name => 'Identification',
+        PrintHex => 1,
+        PrintConv => {
+            0x6a62 => 'MS Word 97',
+            0x626a => 'Word 98 Mac',
+            0xa5dc => 'Word 6.0/7.0',
+            0xa5ec => 'Word 8.0',
+        },
+    },
+    3 => {
+        Name => 'LanguageCode',
+        PrintHex => 1,
+        PrintConv => {
+            0x0400 => 'None',
+            0x0401 => 'Arabic',
+            0x0402 => 'Bulgarian',
+            0x0403 => 'Catalan',
+            0x0404 => 'Traditional Chinese',
+            0x0804 => 'Simplified Chinese',
+            0x0405 => 'Czech',
+            0x0406 => 'Danish',
+            0x0407 => 'German',
+            0x0807 => 'German (Swiss)',
+            0x0408 => 'Greek',
+            0x0409 => 'English (US)',
+            0x0809 => 'English (British)',		
+            0x0c09 => 'English (Australian)',
+            0x040a => 'Spanish (Castilian)',
+            0x080a => 'Spanish (Mexican)',
+            0x040b => 'Finnish',
+            0x040c => 'French',
+            0x080c => 'French (Belgian)',
+            0x0c0c => 'French (Canadian)',
+            0x100c => 'French (Swiss)',
+            0x040d => 'Hebrew',
+            0x040e => 'Hungarian',
+            0x040f => 'Icelandic',
+            0x0410 => 'Italian',
+            0x0810 => 'Italian (Swiss)',
+            0x0411 => 'Japanese',
+            0x0412 => 'Korean',
+            0x0413 => 'Dutch',
+            0x0813 => 'Dutch (Belgian)',
+            0x0414 => 'Norwegian (Bokmal)',
+            0x0814 => 'Norwegian (Nynorsk)',
+            0x0415 => 'Polish',
+            0x0416 => 'Portuguese (Brazilian)',
+            0x0816 => 'Portuguese',
+            0x0417 => 'Rhaeto-Romanic',	
+            0x0418 => 'Romanian',
+            0x0419 => 'Russian',
+            0x041a => 'Croato-Serbian (Latin)',
+            0x081a => 'Serbo-Croatian (Cyrillic)',
+            0x041b => 'Slovak',
+            0x041c => 'Albanian',
+            0x041d => 'Swedish',
+            0x041e => 'Thai',
+            0x041f => 'Turkish',
+            0x0420 => 'Urdu',
+            0x0421 => 'Bahasa',
+            0x0422 => 'Ukrainian',
+            0x0423 => 'Byelorussian',
+            0x0424 => 'Slovenian',
+            0x0425 => 'Estonian',
+            0x0426 => 'Latvian',
+            0x0427 => 'Lithuanian',
+            0x0429 => 'Farsi',
+            0x042d => 'Basque',
+            0x042f => 'Macedonian',
+            0x0436 => 'Afrikaans',
+            0x043e => 'Malaysian',
+        },
+    },
+    5 => {
+        Name => 'DocFlags',
+        Mask => 0xff0f, # ignore save count
+        RawConv => '$$self{DocFlags} = $val',
+        PrintConv => { BITMASK => {
+            0 => 'Template',
+            1 => 'AutoText only',
+            2 => 'Complex',
+            3 => 'Has picture',
+            # 4-7 = number of incremental saves
+            8 => 'Encrypted',
+            9 => '1Table',
+            10 => 'Read only',
+            11 => 'Passworded',
+            12 => 'ExtChar',
+            13 => 'Load override',
+            14 => 'Far east',
+            15 => 'Obfuscated',
+        }},
+    },
+    9.1 => {
+        Name => 'System',
+        Mask => 0x0001,
+        PrintConv => {
+            0x0000 => 'Windows',
+            0x0001 => 'Macintosh',
+        },
+    },
+    9.2 => {
+        Name => 'Word97',
+        Mask => 0x0010,
+        PrintConv => { 0 => 'No', 1 => 'Yes' },
+    },
+);
+
+# tags decoded from Word document table
+%Image::ExifTool::FlashPix::DocTable = (
+    GROUPS => { 1 => 'MS-DOC', 2 => 'Document' },
+    NOTES => 'Tags extracted from the Microsoft Word document table.',
+    VARS => { NO_ID => 1 },
+    CommentBy => {
+        Groups => { 2 => 'Author' },
+        Notes => 'enable Duplicates option to extract all entries',
+    },
+    LastSavedBy => {
+        Groups => { 2 => 'Author' },
+        Notes => 'enable Duplicates option to extract history of up to 10 entries',
+    },
+    DOP => { SubDirectory => { TagTable => 'Image::ExifTool::FlashPix::DOP' } },
+    ModifyDate => {
+        Groups => { 2 => 'Time' },
+        Format => 'int64u',
+        Priority => 0,
+        RawConv => q{
+            $val = $val * 1e-7 - 11644473600;   # convert to seconds since 1970
+            return $val > 0 ? $val : undef;
+        },
+        ValueConv => 'ConvertUnixTime($val)',
+        PrintConv => '$self->ConvertDateTime($val)',
+    },
+#
+# tags below are used internally in intermediate steps to extract the tags above
+#
+    TableOffsets => { Hidden => 1 }, # stores offsets to extract data from document table
+    CommentByBlock => {   # entire block of CommentBy entries
+        SubDirectory => {
+            TagTable => 'Image::ExifTool::FlashPix::DocTable',
+            ProcessProc => \&ProcessCommentBy,
+        },
+        Hidden => 1,
+    },
+    LastSavedByBlock => {   # entire block of LastSavedBy entries
+        SubDirectory => {
+            TagTable => 'Image::ExifTool::FlashPix::DocTable',
+            ProcessProc => \&ProcessLastSavedBy,
+        },
+        Hidden => 1,
+    },
+);
+
+# Microsoft Office Document Properties (ref [MS-DOC].pdf)
+%Image::ExifTool::FlashPix::DOP = (
+    PROCESS_PROC => \&Image::ExifTool::ProcessBinaryData,
+    GROUPS => { 1 => 'MS-DOC', 2 => 'Document' },
+    NOTES => 'Microsoft office document properties.',
+    20 => {
+        Name => 'CreateDate',
+        Format => 'int32u',
+        Groups => { 2 => 'Time' },
+        Priority => 0,
+        RawConv => \&ConvertDTTM,
+        PrintConv => '$self->ConvertDateTime($val)',
+    },
+    24 => {
+        Name => 'ModifyDate',
+        Format => 'int32u',
+        Groups => { 2 => 'Time' },
+        Priority => 0,
+        RawConv => \&ConvertDTTM,
+        PrintConv => '$self->ConvertDateTime($val)',
+    },
+    28 => {
+        Name => 'LastPrinted',
+        Format => 'int32u',
+        Groups => { 2 => 'Time' },
+        RawConv => \&ConvertDTTM,
+        PrintConv => '$self->ConvertDateTime($val)',
+    },
+    32 => { Name => 'RevisionNumber', Format => 'int16u' },
+    34 => {
+        Name => 'TotalEditTime',
+        Format => 'int32u',
+        PrintConv => 'ConvertTimeSpan($val,60)',
+    },
+    # (according to the MS-DOC specification, the following are accurate only if
+    # flag 'X' is set, and flag 'u' specifies whether the main or subdoc tags are
+    # used, but in my tests it seems that both are filled in with reasonable values,
+    # so just extract the main counts and ignore the subdoc counts for now - PH)
+    38 => { Name => 'Words',      Format => 'int32u' },
+    42 => { Name => 'Characters', Format => 'int32u' },
+    46 => { Name => 'Pages',      Format => 'int16u' },
+    48 => { Name => 'Paragraphs', Format => 'int32u' },
+    56 => { Name => 'Lines',      Format => 'int32u' },
+    #60 => { Name => 'WordsWithSubdocs',      Format => 'int32u' },
+    #64 => { Name => 'CharactersWithSubdocs', Format => 'int32u' },
+    #68 => { Name => 'PagesWithSubdocs',      Format => 'int16u' },
+    #70 => { Name => 'ParagraphsWithSubdocs', Format => 'int32u' },
+    #74 => { Name => 'LinesWithSubdocs',      Format => 'int32u' },
+);
+
 # FujiFilm "Property" information (ref PH)
 %Image::ExifTool::FlashPix::PreviewInfo = (
     PROCESS_PROC => \&Image::ExifTool::ProcessBinaryData,
@@ -1072,6 +1304,22 @@ my %fpxFileType = (
 # add our composite tags
 Image::ExifTool::AddCompositeTags('Image::ExifTool::FlashPix');
 
+#------------------------------------------------------------------------------
+# Convert Microsoft DTTM structure to date/time
+# Inputs: 0) DTTM value
+# Returns: EXIF-format date/time string ("0000:00:00 00:00:00" for zero date/time)
+sub ConvertDTTM($)
+{
+    my $val = shift;
+    my $yr  = ($val >> 20) & 0x1ff;
+    my $mon = ($val >> 16) & 0x0f;
+    my $day = ($val >> 11) & 0x1f;
+    my $hr  = ($val >> 6)  & 0x1f;
+    my $min = ($val & 0x3f);
+    $yr += 1900 if $val;
+    return sprintf("%.4d:%.2d:%.2d %.2d:%.2d:00%s",$yr,$mon,$day,$hr,$min,$val ? 'Z' : '');
+}
+
 #------------------------------------------------------------------------------
 # Process hyperlinks from PID_HYPERLINKS array
 # (ref http://msdn.microsoft.com/archive/default.asp?url=/archive/en-us/dnaro97ta/html/msdn_hyper97.asp)
@@ -1263,6 +1511,181 @@ sub ProcessContents($$$)
     return 1;
 }
 
+#------------------------------------------------------------------------------
+# Process WordDocument stream of MSWord doc file (ref 6)
+# Inputs: 0) ExifTool object ref, 1) dirInfo ref, 2) tag table ref
+# Returns: 1 on success
+sub ProcessWordDocument($$$)
+{
+    my ($et, $dirInfo, $tagTablePtr) = @_;
+    my $dataPt = $$dirInfo{DataPt} or return 0;
+    my $dirLen = length $$dataPt;
+    # validate the FIB signature
+    unless ($dirLen > 2 and Get16u($dataPt,0) == 0xa5ec) {
+        $et->WarnOnce('Invalid FIB signature', 1);
+        return 0;
+    }
+    $et->ProcessBinaryData($dirInfo, $tagTablePtr); # process FIB
+    # continue parsing the WordDocument stream until we find the FibRgFcLcb
+    my $pos = 32;
+    return 0 if $pos + 2 > $dirLen;
+    my $n = Get16u($dataPt, $pos);  # read csw
+    $pos += 2 + $n * 2;             # skip fibRgW
+    return 0 if $pos + 2 > $dirLen;
+    $n = Get16u($dataPt, $pos);     # read cslw
+    $pos += 2 + $n * 4;             # skip fibRgLw
+    return 0 if $pos + 2 > $dirLen;
+    $n = Get16u($dataPt, $pos);     # read cbRgFcLcb
+    $pos += 2;  # point to start of fibRgFcLcbBlob
+    return 0 if $pos + $n * 8 > $dirLen;
+    my ($off, @tableOffsets);
+    # save necessary entries for later processing of document table
+    # (DOP, CommentBy, LastSavedBy)
+    foreach $off (0xf8, 0x120, 0x238) {
+        last if $off + 8 > $n * 8;
+        push @tableOffsets, Get32u($dataPt, $pos + $off);
+        push @tableOffsets, Get32u($dataPt, $pos + $off + 4);
+    }
+    my $tbl = GetTagTable('Image::ExifTool::FlashPix::DocTable');
+    # extract ModifyDate if it exists
+    $et->HandleTag($tbl, 'ModifyDate', undef,
+        DataPt => $dataPt,
+        Start  => $pos + 0x2b8,
+        Size   => 8,
+    );
+    $et->HandleTag($tbl, TableOffsets => \@tableOffsets);   # save for later
+    # $pos += $n * 8;                 # skip fibRgFcLcbBlob
+    # return 0 if $pos + 2 > $dirLen;
+    # $n = Get16u($dataPt, $pos);     # read cswNew
+    # return 0 if $pos + 2 + $n * 2 > $dirLen;
+    # my $nFib = Get16u($dataPt, 2 + ($n ? $pos : 0));
+    # $pos += 2 + $n * 2;             # skip fibRgCswNew
+    return 1;
+}
+
+#------------------------------------------------------------------------------
+# Process Microsoft Word Document Table
+# Inputs: 0) ExifTool object ref
+sub ProcessDocumentTable($)
+{
+    my $et = shift;
+    my $value = $$et{VALUE};
+    my $extra = $$et{TAG_EXTRA};
+    my ($i, $j, $tag);
+    # loop through TableOffsets for each sub-document
+    for ($i=0; ; ++$i) {
+        my $key = 'TableOffsets' . ($i ? " ($i)" : '');
+        my $offsets = $$value{$key};
+        last unless defined $offsets;
+        my $doc = $$extra{$key}{G3} if $$extra{$key};
+        $doc = '' unless $doc;
+        # get DocFlags for this sub-document
+        my ($docFlags, $docTable);
+        for ($j=0; ; ++$j) {
+            my $key = 'DocFlags' . ($j ? " ($j)" : '');
+            last unless defined $$value{$key};
+            my $tmp = $$extra{$key}{G3} if $$extra{$key};
+            $tmp = '' unless $tmp;
+            if ($tmp eq $doc) {
+                $docFlags = $$value{$key};
+                last;
+            }
+        }
+        next unless defined $docFlags;
+        $tag = $docFlags & 0x200 ? 'Table1' : 'Table0';
+        # get table for this sub-document
+        for ($j=0; ; ++$j) {
+            my $key = $tag . ($j ? " ($j)" : '');
+            last unless defined $$value{$key};
+            my $tmp = $$extra{$key}{G3} if $$extra{$key};
+            $tmp = '' unless $tmp;
+            if ($tmp eq $doc) {
+                $docTable = \$$value{$key};
+                last;
+            }
+        }
+        next unless defined $docTable;
+        # extract DOP and LastSavedBy information from document table
+        $$et{DOC_NUM} = $doc;   # use same document number
+        my $tagTablePtr = GetTagTable('Image::ExifTool::FlashPix::DocTable');
+        foreach $tag (qw(DOP CommentByBlock LastSavedByBlock)) {
+            last unless @$offsets;
+            my $off = shift @$offsets;
+            my $len = shift @$offsets;
+            next unless $len and $off + $len <= length $$docTable;
+            $et->HandleTag($tagTablePtr, $tag, undef,
+                DataPt => $docTable,
+                Start  => $off,
+                Size   => $len,
+            );
+        }
+        delete $$et{DOC_NUM};
+    }
+    # delete intermediate tags
+    foreach $tag (qw(TableOffsets Table0 Table1)) {
+        for ($i=0; ; ++$i) {
+            my $key = $tag . ($i ? " ($i)" : '');
+            last unless defined $$value{$key};
+            $et->DeleteTag($key);
+        }
+    }
+}
+
+#------------------------------------------------------------------------------
+# Extract names of comment authors (ref 6)
+# Inputs: 0) ExifTool object ref, 1) dirInfo ref, 2) tag table ref
+# Returns: 1 on success
+sub ProcessCommentBy($$$)
+{
+    my ($et, $dirInfo, $tagTablePtr) = @_;
+    my $dataPt = $$dirInfo{DataPt};
+    my $pos = $$dirInfo{DirStart};
+    my $end = $$dirInfo{DirLen} + $pos;
+    $et->VerboseDir($$dirInfo{DirName});
+	while ($pos + 2 < $end) {
+		my $len = Get16u($dataPt, $pos);
+		$pos += 2;
+	    last if $pos + $len * 2 > $end;
+		my $author = $et->Decode(substr($$dataPt, $pos, $len*2), 'UCS2');
+		$pos += $len * 2;
+		$et->HandleTag($tagTablePtr, CommentBy => $author);
+	}
+    return 1;
+}
+
+#------------------------------------------------------------------------------
+# Extract last-saved-by names (ref 5)
+# Inputs: 0) ExifTool object ref, 1) dirInfo ref, 2) tag table ref
+# Returns: 1 on success
+sub ProcessLastSavedBy($$$)
+{
+    my ($et, $dirInfo, $tagTablePtr) = @_;
+    my $dataPt = $$dirInfo{DataPt};
+    my $pos = $$dirInfo{DirStart};
+    my $end = $$dirInfo{DirLen} + $pos;
+    return 0 if $pos + 6 > $end;
+    $et->VerboseDir($$dirInfo{DirName});
+	my $num = Get16u($dataPt, $pos+2);
+	$pos += 6;
+	while ($num >= 2) {
+	    last if $pos + 2 > $end;
+		my $len = Get16u($dataPt, $pos);
+		$pos += 2;
+	    last if $pos + $len * 2 > $end;
+		my $author = $et->Decode(substr($$dataPt, $pos, $len*2), 'UCS2');
+		$pos += $len * 2;
+	    last if $pos + 2 > $end;
+		$len = Get16u($dataPt, $pos);
+		$pos += 2;
+	    last if $pos + $len * 2 > $end;
+		my $path = $et->Decode(substr($$dataPt, $pos, $len*2), 'UCS2');
+		$pos += $len * 2;
+		$et->HandleTag($tagTablePtr, LastSavedBy => "$author ($path)");
+		$num -= 2;
+	}
+    return 1;
+}
+
 #------------------------------------------------------------------------------
 # Check FPX byte order mark (BOM) and set byte order appropriately
 # Inputs: 0) data ref, 1) offset to BOM
@@ -1482,7 +1905,7 @@ sub ProcessFPXR($$$)
             my $name = Image::ExifTool::Decode(undef, $1, 'UCS2', 'II', 'Latin');
             if ($verbose) {
                 my $psize = ($size == 0xffffffff) ? 'storage' : "$size bytes";
-                $et->VPrint(0,"  |  $entry) Name: '$name' [$psize]\n");
+                $et->VPrint(0,"  |  $entry) Name: '${name}' [$psize]\n");
             }
             # remove directory specification
             $name =~ s{.*/}{}s;
@@ -1637,7 +2060,7 @@ sub ProcessFPX($$)
 {
     my ($et, $dirInfo) = @_;
     my $raf = $$dirInfo{RAF};
-    my ($buff, $out, %dumpParms, $oldIndent, $miniStreamBuff);
+    my ($buff, $out, $oldIndent, $miniStreamBuff);
     my ($tag, %hier, %objIndex, %loadedDifSect);
 
     # read header
@@ -1667,8 +2090,6 @@ sub ProcessFPX($$)
 
     if ($verbose) {
         $out = $et->Options('TextOut');
-        $dumpParms{Out} = $out;
-        $dumpParms{MaxLen} = 96 if $verbose == 3;
         print $out "  Sector size=$sectSize\n  FAT: Count=$fatCount\n";
         print $out "  DIR: Start=$dirStart\n";
         print $out "  MiniFAT: Mini-sector size=$miniSize Start=$miniStart Count=$miniCount Cutoff=$miniCutoff\n";
@@ -1736,11 +2157,11 @@ sub ProcessFPX($$)
     }
     if ($verbose) {
         print $out "  FAT [",length($fat)," bytes]:\n";
-        HexDump(\$fat, undef, %dumpParms) if $verbose > 2;
+        $et->VerboseDump(\$fat);
         print $out "  Mini-FAT [",length($miniFat)," bytes]:\n";
-        HexDump(\$miniFat, undef, %dumpParms) if $verbose > 2;
+        $et->VerboseDump(\$miniFat);
         print $out "  Directory [",length($dir)," bytes]:\n";
-        HexDump(\$dir, undef, %dumpParms) if $verbose > 2;
+        $et->VerboseDump(\$dir);
     }
 #
 # process the directory
@@ -1919,6 +2340,9 @@ sub ProcessFPX($$)
             }
         }
     }
+    # process Word document table
+    ProcessDocumentTable($et);
+
     return 1;
 }
 
@@ -1942,7 +2366,7 @@ JPEG images.
 
 =head1 AUTHOR
 
-Copyright 2003-2017, Phil Harvey (phil at owl.phy.queensu.ca)
+Copyright 2003-2019, Phil Harvey (phil at owl.phy.queensu.ca)
 
 This library is free software; you can redistribute it and/or modify it
 under the same terms as Perl itself.