edtf 4.1.1 → 5.0.0

This diff represents the content of publicly available package versions that have been released to one of the supported registries. The information contained in this diff is provided for informational purposes only and reflects changes between package versions as they appear in their respective public registries.
data/lib/edtf/legacy.y ADDED
@@ -0,0 +1,625 @@
1
+ # -*- racc -*-
2
+ #
3
+ # The legacy grammar: the syntax of the EDTF draft.
4
+ # Legacy syntax is recorded as a deprecation (see EDTF::Parser::LEGACY).
5
+ #
6
+ # Regenerate lib/edtf/legacy.rb with `bundle exec rake racc`.
7
+
8
+ class EDTF::Legacy < EDTF::Grammar
9
+ token T Z E X U UNKNOWN OPEN LONGYEAR UNMATCHED DOTS UA
10
+
11
+ expect 0
12
+
13
+ rule
14
+
15
+ edtf
16
+ : level_0_expression
17
+ | level_1_expression
18
+ | level_2_expression
19
+ ;
20
+
21
+ # ---- Level 0 / ISO 8601 Rules ----
22
+
23
+ # NB: level 0 intervals are covered by the level 1 interval rules
24
+ level_0_expression
25
+ : date
26
+ | date_time
27
+ ;
28
+
29
+ date
30
+ : year { result = date(val[0]) }
31
+ | year_month { result = date(*val[0]) }
32
+ | year_month_day { result = date(*val[0]) }
33
+ ;
34
+
35
+ date_time
36
+ : date T time {
37
+ year, month, day = val[0][:values]
38
+ deprecate :partial_date_time if day.nil?
39
+ values = [year, month || 1, day || 1, *val[2][0, 3]]
40
+ result = { type: :date_time, values: values }
41
+ result[:offset] = val[2][3] if val[2].length > 3
42
+ }
43
+ ;
44
+
45
+ time
46
+ : base_time
47
+ | base_time zone_offset { result = val.flatten }
48
+ ;
49
+
50
+ base_time
51
+ : hour ':' minute ':' second { result = val.values_at(0, 2, 4) }
52
+ | midnight
53
+ ;
54
+
55
+ midnight
56
+ : '2' '4' ':' '0' '0' ':' '0' '0' {
57
+ deprecate :midnight
58
+ result = [24, 0, 0]
59
+ }
60
+ ;
61
+
62
+ zone_offset
63
+ : Z { result = 0 }
64
+ | '-' zone_offset_hour { result = -1 * val[1] }
65
+ | '+' positive_zone_offset { result = val[1] }
66
+ ;
67
+
68
+ positive_zone_offset
69
+ : zone_offset_hour
70
+ | '0' '0' ':' '0' '0' { result = 0 }
71
+ ;
72
+
73
+ zone_offset_hour
74
+ : d01_13 ':' minute { result = val[0] * 60 + val[2] }
75
+ | '1' '4' ':' '0' '0' { result = 840 }
76
+ | '0' '0' ':' d01_59 { result = val[3] }
77
+ ;
78
+
79
+ year
80
+ : positive_year
81
+ | '-' positive_year {
82
+ result = -val[1]
83
+ deprecate :negative_zero if result.zero?
84
+ }
85
+ ;
86
+
87
+ positive_year
88
+ : digit digit digit digit { result = number(val) }
89
+ ;
90
+
91
+ month : d01_12 ;
92
+ day : d01_31 ;
93
+
94
+ year_month
95
+ : year '-' month { result = [val[0], val[2]] }
96
+ ;
97
+
98
+ year_month_day
99
+ : year_month '-' day { result = check_day(*val[0], val[2]) }
100
+ ;
101
+
102
+ hour : d00_23 ;
103
+ minute : d00_59 ;
104
+ second : d00_59 ;
105
+
106
+ # ---- Level 1 Extension Rules ----
107
+
108
+ # NB: Uncertain/approximate Dates are covered by the Level 2 rules
109
+ level_1_expression
110
+ : unknown
111
+ | unspecified
112
+ | level_1_interval
113
+ | long_year_simple
114
+ | season
115
+ ;
116
+
117
+ unknown
118
+ : U U U U {
119
+ result = date(0, unspecified: Bitmask::XXXX)
120
+ }
121
+ ;
122
+
123
+ unspecified
124
+ : unspecified_year { result = date(val[0][0], unspecified: val[0][1]) }
125
+ | unspecified_month
126
+ | unspecified_day
127
+ | unspecified_day_and_month
128
+ ;
129
+
130
+ unspecified_year
131
+ : positive_unspecified_year
132
+ | '-' positive_unspecified_year {
133
+ result = val[1]
134
+ result[0] = -result[0]
135
+ }
136
+ ;
137
+
138
+ positive_unspecified_year
139
+ : digit digit digit U { result = [number(val[0, 3]) * 10, Bitmask::YYYX] }
140
+ | digit digit U U { result = [number(val[0, 2]) * 100, Bitmask::YYXX] }
141
+ ;
142
+
143
+ unspecified_month
144
+ : year '-' U U { result = date(val[0], 1, unspecified: Bitmask::MONTH) }
145
+ ;
146
+
147
+ unspecified_day
148
+ : year_month '-' U U {
149
+ result = date(*val[0], 1, unspecified: Bitmask::DAY)
150
+ }
151
+ ;
152
+
153
+ unspecified_day_and_month
154
+ : year '-' U U '-' U U {
155
+ result = date(val[0], 1, 1, unspecified: Bitmask::MD)
156
+ }
157
+ ;
158
+
159
+ level_1_interval
160
+ : level_1_interval_closed
161
+ | level_1_interval_open
162
+ | level_1_interval_unknown
163
+ ;
164
+
165
+ level_1_interval_closed
166
+ : level_1_start '/' level_1_end { result = interval(val[0], val[2]) }
167
+ ;
168
+
169
+ level_1_interval_open
170
+ : level_1_interval_open_start
171
+ | level_1_interval_open_end
172
+ ;
173
+
174
+ level_1_interval_open_start
175
+ : open_start_or_end '/' level_1_end { result = interval(:open, val[2]) }
176
+ ;
177
+
178
+ level_1_interval_open_end
179
+ : level_1_start '/' open_start_or_end { result = interval(val[0], :open) }
180
+ ;
181
+
182
+ open_start_or_end
183
+ : OPEN
184
+ | DOTS
185
+ ;
186
+
187
+ level_1_interval_unknown
188
+ : level_1_interval_empty_start
189
+ | level_1_interval_empty_end
190
+ | level_1_interval_unknown_start
191
+ | level_1_interval_unknown_end
192
+ ;
193
+
194
+ level_1_interval_empty_start
195
+ : '/' level_1_end { result = interval(:unknown, val[1]) }
196
+ ;
197
+
198
+ level_1_interval_empty_end
199
+ : level_1_start '/' { result = interval(val[0], :unknown) }
200
+ ;
201
+
202
+ level_1_interval_unknown_start
203
+ : UNKNOWN '/' level_1_end { result = interval(:unknown, val[2]) }
204
+ ;
205
+
206
+ level_1_interval_unknown_end
207
+ : level_1_start '/' UNKNOWN { result = interval(val[0], :unknown) }
208
+ ;
209
+
210
+ level_1_start
211
+ : date
212
+ | partial_uncertain_or_approximate
213
+ | unspecified
214
+ | partial_unspecified
215
+ ;
216
+
217
+ level_1_end : level_1_start ;
218
+
219
+ long_year_simple
220
+ : LONGYEAR long_year { result = year(val[1], 1) }
221
+ | LONGYEAR '-' long_year { result = year(-val[2], 1) }
222
+ ;
223
+
224
+ long_year
225
+ : positive_digit digit digit digit digit { result = number(val) }
226
+ | long_year digit { result = 10 * val[0] + val[1] }
227
+ ;
228
+
229
+ # Qualified seasons are an extension (season-uncertainty).
230
+ season
231
+ : year '-' season_number ua {
232
+ extension :season_uncertainty unless val[3].empty?
233
+ season = { type: :season, values: [val[0], val[2]] }
234
+ result = qualify(season, val[3], Bitmask::YM)
235
+ }
236
+ ;
237
+
238
+ season_number
239
+ : '2' '1' { result = 21 }
240
+ | '2' '2' { result = 22 }
241
+ | '2' '3' { result = 23 }
242
+ | '2' '4' { result = 24 }
243
+ ;
244
+
245
+
246
+ # ---- Level 2 Extension Rules ----
247
+
248
+ # NB: Level 2 Intervals are covered by the Level 1 Interval rules.
249
+ level_2_expression
250
+ : season_qualified
251
+ | partial_uncertain_or_approximate
252
+ | partial_unspecified
253
+ | choice_list
254
+ | inclusive_list
255
+ | masked_precision
256
+ | date_and_calendar
257
+ | long_year_scientific
258
+ ;
259
+
260
+ season_qualified
261
+ : season '^' { result = val[0]; result[:qualifier] = val[1] }
262
+ ;
263
+
264
+ long_year_scientific
265
+ : long_year_simple E integer {
266
+ result = year(exponent(val[0][:values][0], val[2]), 2)
267
+ }
268
+ | LONGYEAR int1_4 E integer {
269
+ result = year(exponent(val[1], val[3]), 2)
270
+ }
271
+ | LONGYEAR '-' int1_4 E integer {
272
+ result = year(exponent(-val[2], val[4]), 2)
273
+ }
274
+ ;
275
+
276
+ date_and_calendar
277
+ : date '^' { result = val[0]; result[:calendar] = val[1] }
278
+ ;
279
+
280
+ masked_precision
281
+ : digit digit digit X {
282
+ result = date(number(val[0, 3]) * 10, unspecified: Bitmask::YYYX)
283
+ }
284
+ | digit digit X X {
285
+ result = date(number(val[0, 2]) * 100, unspecified: Bitmask::YYXX)
286
+ }
287
+ ;
288
+
289
+ choice_list
290
+ : '[' list ']' { result = { type: :set, **val[1] } }
291
+ ;
292
+
293
+ inclusive_list
294
+ : '{' list '}' { result = { type: :list, **val[1] } }
295
+ ;
296
+
297
+ list
298
+ : earlier {
299
+ result = { values: [val[0]], earlier: true }
300
+ }
301
+ | earlier ',' list_elements ',' later {
302
+ values = [val[0], *val[2], val[4]]
303
+ result = { values: values, earlier: true, later: true }
304
+ }
305
+ | earlier ',' list_elements {
306
+ result = { values: [val[0], *val[2]], earlier: true }
307
+ }
308
+ | earlier ',' later {
309
+ result = { values: [val[0], val[2]], earlier: true, later: true }
310
+ }
311
+ | list_elements ',' later {
312
+ result = { values: [*val[0], val[2]], later: true }
313
+ }
314
+ | list_elements {
315
+ result = { values: val[0] }
316
+ }
317
+ | later {
318
+ result = { values: [val[0]], later: true }
319
+ }
320
+ ;
321
+
322
+ list_elements
323
+ : list_element { result = [val[0]] }
324
+ | list_elements ',' list_element { result = val[0] + [val[2]] }
325
+ ;
326
+
327
+ list_element
328
+ : atomic
329
+ | consecutives
330
+ ;
331
+
332
+ atomic
333
+ : date
334
+ | partial_uncertain_or_approximate
335
+ | unspecified
336
+ ;
337
+
338
+ earlier
339
+ : DOTS date { result = val[1] }
340
+ ;
341
+
342
+ later
343
+ : year_month_day DOTS { result = date(*val[0]) }
344
+ | year_month DOTS { result = date(*val[0]) }
345
+ | year DOTS { result = date(val[0]) }
346
+ ;
347
+
348
+ consecutives
349
+ : year_month_day DOTS year_month_day {
350
+ result = [date(*val[0]), date(*val[2])]
351
+ }
352
+ | year_month DOTS year_month {
353
+ result = [date(*val[0]), date(*val[2])]
354
+ }
355
+ | year DOTS year {
356
+ result = [date(val[0]), date(val[2])]
357
+ }
358
+ ;
359
+
360
+ partial_unspecified
361
+ : unspecified_year '-' month '-' day {
362
+ check_day(val[0][0], val[2], val[4])
363
+ result = date(val[0][0], val[2], val[4], unspecified: val[0][1])
364
+ }
365
+ | unspecified_year '-' month {
366
+ result = date(val[0][0], val[2], unspecified: val[0][1])
367
+ }
368
+ | unspecified_year '-' U U '-' day {
369
+ mask = val[0][1] | Bitmask::MONTH
370
+ result = date(val[0][0], 1, val[5], unspecified: mask)
371
+ }
372
+ | unspecified_year '-' U U '-' U U {
373
+ result = date(val[0][0], 1, 1, unspecified: val[0][1] | Bitmask::MD)
374
+ }
375
+ | unspecified_year '-' month '-' U U {
376
+ mask = val[0][1] | Bitmask::DAY
377
+ result = date(val[0][0], val[2], 1, unspecified: mask)
378
+ }
379
+ | year '-' U U '-' day {
380
+ result = date(val[0], 1, val[5], unspecified: Bitmask::MONTH)
381
+ }
382
+ ;
383
+
384
+ partial_uncertain_or_approximate
385
+ : pua_base
386
+ | '(' pua_base ')' UA { result = qualify(val[1], val[3]) }
387
+ ;
388
+
389
+ pua_base
390
+ : pua_year
391
+ | pua_year_month { result = val[0][0] }
392
+ | pua_year_month_day
393
+ ;
394
+
395
+ pua_year
396
+ : year UA { result = qualify(date(val[0]), val[1], :year) }
397
+ ;
398
+
399
+ pua_year_month
400
+ : pua_year '-' month ua {
401
+ result = [qualify(extend_date(val[0], val[2]), val[3], [:month, :year])]
402
+ }
403
+ | year '-' month UA {
404
+ result = [qualify(date(val[0], val[2]), val[3], [:year, :month])]
405
+ }
406
+ | year '-(' month ')' UA {
407
+ result = [qualify(date(val[0], val[2]), val[4], [:month]), true]
408
+ }
409
+ | pua_year '-(' month ')' UA {
410
+ result = [qualify(extend_date(val[0], val[2]), val[4], [:month]), true]
411
+ }
412
+ ;
413
+
414
+ pua_year_month_day
415
+ : pua_year_month '-' day ua {
416
+ parts = val[0][1] ? [:day] : nil
417
+ result = qualify(extend_date(val[0][0], val[2]), val[3], parts)
418
+ }
419
+ | pua_year_month '-(' day ')' UA {
420
+ result = qualify(extend_date(val[0][0], val[2]), val[4], [:day])
421
+ }
422
+ | year '-(' month ')' UA day ua {
423
+ result = qualify(date(val[0], val[2], val[5]), val[4], :month)
424
+ result = qualify(result, val[6], :day)
425
+ }
426
+ | year_month '-' day UA {
427
+ result = qualify(date(val[0][0], val[0][1], val[2]), val[3])
428
+ }
429
+ | year_month '-(' day ')' UA {
430
+ result = qualify(date(val[0][0], val[0][1], val[2]), val[4], [:day])
431
+ }
432
+ | year '-(' month '-' day ')' UA {
433
+ result = qualify(date(val[0], val[2], val[4]), val[6], [:month, :day])
434
+ }
435
+ | year '-(' month '-(' day ')' UA ')' UA {
436
+ result = date(val[0], val[2], val[4])
437
+ result = qualify(result, val[6], [:day])
438
+ result = qualify(result, val[8], [:month, :day])
439
+ }
440
+ | pua_year '-(' month '-' day ')' UA {
441
+ result = extend_date(val[0], val[2], val[4])
442
+ result = qualify(result, val[6], [:month, :day])
443
+ }
444
+ | pua_year '-(' month '-(' day ')' UA ')' UA {
445
+ result = extend_date(val[0], val[2], val[4])
446
+ result = qualify(result, val[6], [:day])
447
+ result = qualify(result, val[8], [:month, :day])
448
+ }
449
+ ;
450
+
451
+ ua
452
+ : /* none */ { result = [] }
453
+ | UA
454
+ ;
455
+
456
+
457
+ # ---- Auxiliary Rules ----
458
+
459
+ digit
460
+ : '0' { result = 0 }
461
+ | positive_digit
462
+ ;
463
+
464
+ positive_digit
465
+ : '1' | '2' | '3' | '4' | '5' | '6' | '7' | '8' | '9'
466
+ ;
467
+
468
+ d01_12
469
+ : '0' positive_digit { result = val[1] }
470
+ | '1' '0' { result = 10 }
471
+ | '1' '1' { result = 11 }
472
+ | '1' '2' { result = 12 }
473
+ ;
474
+
475
+ d01_13
476
+ : d01_12
477
+ | '1' '3' { result = 13 }
478
+ ;
479
+
480
+ d01_23
481
+ : '0' positive_digit { result = val[1] }
482
+ | '1' digit { result = 10 + val[1] }
483
+ | '2' '0' { result = 20 }
484
+ | '2' '1' { result = 21 }
485
+ | '2' '2' { result = 22 }
486
+ | '2' '3' { result = 23 }
487
+ ;
488
+
489
+ d00_23
490
+ : '0' '0'
491
+ | d01_23
492
+ ;
493
+
494
+ d01_29
495
+ : d01_23
496
+ | '2' '4' { result = 24 }
497
+ | '2' '5' { result = 25 }
498
+ | '2' '6' { result = 26 }
499
+ | '2' '7' { result = 27 }
500
+ | '2' '8' { result = 28 }
501
+ | '2' '9' { result = 29 }
502
+ ;
503
+
504
+ d01_30
505
+ : d01_29
506
+ | '3' '0' { result = 30 }
507
+ ;
508
+
509
+ d01_31
510
+ : d01_30
511
+ | '3' '1' { result = 31 }
512
+ ;
513
+
514
+ d01_59
515
+ : d01_29
516
+ | '3' digit { result = 30 + val[1] }
517
+ | '4' digit { result = 40 + val[1] }
518
+ | '5' digit { result = 50 + val[1] }
519
+ ;
520
+
521
+ d00_59
522
+ : '0' '0'
523
+ | d01_59
524
+ ;
525
+
526
+ int1_4
527
+ : positive_digit { result = val[0] }
528
+ | positive_digit digit { result = number(val) }
529
+ | positive_digit digit digit { result = number(val) }
530
+ | positive_digit digit digit digit { result = number(val) }
531
+ ;
532
+
533
+ integer
534
+ : positive_digit { result = val[0] }
535
+ | integer digit { result = 10 * val[0] + val[1] }
536
+ ;
537
+
538
+ end
539
+
540
+ ---- inner
541
+
542
+ def parse(input, debug: false)
543
+ @set = false
544
+ super
545
+ end
546
+
547
+ def next_token
548
+ case
549
+ when @src.eos?
550
+ nil
551
+ when @src.scan(/\(/)
552
+ deprecate :parentheses
553
+ ['(', @src.matched]
554
+ when @src.scan(/\)/)
555
+ [')', @src.matched]
556
+ when @src.scan(/[\[{]/)
557
+ @set = true
558
+ [@src.matched, @src.matched]
559
+ when @src.scan(/[\]}]/)
560
+ @set = false
561
+ [@src.matched, @src.matched]
562
+ when @src.scan(/T/)
563
+ [:T, @src.matched]
564
+ when @src.scan(/Z/)
565
+ [:Z, @src.matched]
566
+ when @src.scan(/\?~/)
567
+ deprecate :combined_qualifier
568
+ [:UA, [:uncertain, :approximate]]
569
+ when @src.scan(/%/)
570
+ [:UA, [:uncertain, :approximate]]
571
+ when @src.scan(/\?/)
572
+ [:UA, [:uncertain]]
573
+ when @src.scan(/~/)
574
+ [:UA, [:approximate]]
575
+ when @src.scan(/open/i)
576
+ deprecate :open
577
+ [:OPEN, :open]
578
+ when @src.scan(/unkn?own/i) # matches 'unkown' typo too
579
+ deprecate :unknown
580
+ [:UNKNOWN, :unknown]
581
+ when @src.scan(/u/)
582
+ deprecate :unspecified
583
+ [:U, @src.matched]
584
+ when @src.scan(/X/)
585
+ [:U, @src.matched]
586
+ when @src.scan(/x/)
587
+ deprecate :masked
588
+ [:X, @src.matched]
589
+ when @src.scan(/y/i)
590
+ deprecate :lowercase_y if @src.matched == 'y'
591
+ [:LONGYEAR, @src.matched]
592
+ when @src.scan(/e/i)
593
+ deprecate :lowercase_e if @src.matched == 'e'
594
+ [:E, @src.matched]
595
+ when @src.scan(/\+/)
596
+ ['+', @src.matched]
597
+ when @src.scan(/-\(/)
598
+ deprecate :parentheses
599
+ ['-(', @src.matched]
600
+ when @src.scan(/-/)
601
+ ['-', @src.matched]
602
+ when @src.scan(/:/)
603
+ [':', @src.matched]
604
+ when @src.scan(/\//)
605
+ ['/', @src.matched]
606
+ # Spaces around `..` and `,` are allowed in sets only.
607
+ when @set && @src.scan(/ *\.\. */)
608
+ deprecate :whitespace if @src.matched.length > 2
609
+ [:DOTS, '..']
610
+ when @set && @src.scan(/ *, */)
611
+ deprecate :whitespace if @src.matched.length > 1
612
+ [',', ',']
613
+ when @src.scan(/\.\./)
614
+ [:DOTS, '..']
615
+ when @src.scan(/,/)
616
+ [',', ',']
617
+ when @src.scan(/\^\w+/)
618
+ deprecate :caret
619
+ ['^', @src.matched[1..-1]]
620
+ when @src.scan(/\d/)
621
+ [@src.matched, @src.matched.to_i]
622
+ else @src.scan(/./)
623
+ [:UNMATCHED, @src.rest]
624
+ end
625
+ end