ecrire 0.20.0

data/lib/ecrire/app/assets/javascripts/admin/editor/extensions/clipboard.coffee

@@ -0,0 +1,98 @@
+Editor.Extensions.push class ClipBoard
+  constructor: (editor) ->
+    @editor = editor
+    @editor.on 'paste', @paste
+
+  paste: (e) =>
+    e.preventDefault()
+    e.stopPropagation()
+
+    data = e.clipboardData.getData('text/plain')
+
+    texts = data.split('\n').map (text) ->
+      document.createTextNode(text)
+    return unless texts.length > 0
+
+    _sel = window.getSelection()
+    sel = {
+      type: _sel.type
+    }
+    position = _sel.anchorNode.compareDocumentPosition(_sel.extentNode)
+    if _sel.anchorOffset <= _sel.extentOffset || position == document.DOCUMENT_POSITION_PRECEDING
+      sel.anchorNode = _sel.anchorNode
+      sel.anchorOffset = _sel.anchorOffset
+      sel.extentNode = _sel.extentNode
+      sel.extentOffset = _sel.extentOffset
+    else
+      sel.anchorNode = _sel.extentNode
+      sel.anchorOffset = _sel.extentOffset
+      sel.extentNode = _sel.anchorNode
+      sel.extentOffset = _sel.anchorOffset
+
+    if sel.anchorNode == @editor.element()
+      line = @editor.line()
+      @editor.element().appendChild(line)
+      sel.anchorNode = sel.extentNode = line
+
+    @editor.observer.hold =>
+      if sel.type == 'Range'
+        @replace(texts, sel)
+      else
+        @insert(texts, sel)
+
+
+  replace: (texts, sel) =>
+    
+    node = sel.extentNode
+    line = node
+    nodes = [node]
+
+    while line.parentElement != @editor.element()
+      line = line.parentElement
+
+    offsets = {
+      start: sel.anchorOffset
+      end: sel.extentOffset
+    }
+
+    offsets.start = @editor.lineOffset(line, sel.anchorNode, offsets.start)
+    offsets.end = @editor.lineOffset(line, sel.extentNode, offsets.end)
+
+    text = texts.map((t) ->
+      t.textContent
+    ).join()
+
+    
+    line.textContent = line.textContent.substr(0, offsets.start) + text + line.textContent.substr(offsets.end)
+
+    fragment = @editor.parse(@editor.cloneNodesFrom(line))
+
+    @editor.updateDOM(line, fragment)
+
+    @editor.setCursorAt(line, offsets.start + text.length)
+
+
+  insert: (texts, sel) =>
+
+    node = sel.anchorNode
+    str = node.textContent
+    text = texts.map((t) ->
+      t.textContent
+    ).join("\n")
+
+    node.textContent = str.substr(0, sel.anchorOffset)
+    node.textContent += text
+    node.textContent += str.substr(sel.anchorOffset)
+
+    offset = sel.anchorOffset + text.length
+    
+    while node.parentElement != @editor.element()
+      node = node.parentElement
+
+    fragment = @editor.parse(@editor.cloneNodesFrom(node))
+
+    lines = @editor.updateDOM(node, fragment)
+
+    @editor.setCursorAt(lines[0], offset)
+
+

data/lib/ecrire/app/assets/javascripts/admin/editor/extensions/image.coffee

@@ -0,0 +1,19 @@
+Joint.bind 'Editor.Image', class
+  loaded: =>
+    @element().addEventListener 'dragover', @over
+    @element().addEventListener 'dragleave', @cancel
+    @element().addEventListener 'drop', @drop
+
+  over: (e) =>
+    e.preventDefault()
+    @element().classList.add 'dropping'
+
+  cancel: (e) =>
+    e.preventDefault()
+    @element().classList.remove 'dropping'
+
+  drop: (e) =>
+    e.preventDefault()
+    @element().classList.remove 'dropping'
+
+

data/lib/ecrire/app/assets/javascripts/admin/editor/navigation/delete.js.coffee

@@ -0,0 +1,11 @@
+Joint.bind 'Post.Delete', class
+  loaded: =>
+    @on 'change', @element().querySelector('input[type=checkbox]'), @toggle
+
+  toggle: (e) =>
+    button = e.target.parentElement
+    if e.target.checked
+      button.removeAttribute('disabled')
+    else
+      button.setAttribute('disabled', 'disabled')
+

data/lib/ecrire/app/assets/javascripts/admin/editor/navigation/draft.js.coffee

@@ -0,0 +1,42 @@
+Joint.bind 'Editor.Draft', class
+  resetInterval: 4000
+  loaded: =>
+    @on 'Editor:updated', document, @update
+    @on 'change', @element().querySelector('input[type=checkbox]'), @toggle
+
+  toggle: (e) =>
+    if e.target.checked
+      @show()
+    else
+      @hide()
+
+  show: =>
+    el = @element().firstElementChild
+    el.style.marginLeft = "-#{el.getBoundingClientRect().width}px"
+    el.style.opacity = 0
+    @element().querySelector('form.destroy').classList.remove('hide')
+    @timerID = setTimeout @reset, @resetInterval
+
+  hide: =>
+    if @timerID?
+      clearTimeout(@timerID)
+      @timerID = null
+
+    el = @element().firstElementChild
+    el.style.marginLeft = ''
+    el.style.opacity = 1
+    @element().querySelector('form.destroy').classList.add('hide')
+
+
+  reset: =>
+    checkbox = @element().querySelector('input[type=checkbox]')
+    if checkbox.checked
+      checkbox.checked = false
+      @hide()
+
+  update: (e) =>
+    unless @cached?
+      @cached = e.target.textContent
+      return
+
+

data/lib/ecrire/app/assets/javascripts/admin/editor/navigation/help.js.coffee

@@ -0,0 +1,6 @@
+Joint.bind 'Post.Documentation', class
+  loaded: =>
+    @on 'posts:help', @show
+
+  show: (e) =>
+    document.body.appendChild e.HTML

data/lib/ecrire/app/assets/javascripts/admin/editor/navigation/save.js.coffee

@@ -0,0 +1,61 @@
+Joint.bind 'Editor.Save', class
+  loaded: =>
+    @button = @element().querySelector('button')
+    @time = @element().querySelector('div.update > p')
+
+    @on 'Editor:loaded', document, @cache
+    @on 'Editor:updated', document, @update
+    @on 'posts:update', document, @saved
+    @on 'click', @button, @save
+    @on 'beforeunload', window, @confirm
+
+    @button.innerText = @button.getAttribute('persisted')
+    @refresh()
+    @cache()
+    @interval = setInterval(@refresh, 1000)
+
+  refresh: () =>
+    @time.textContent = moment(@time.getAttribute('time')).fromNow()
+
+  confirm: (e) =>
+    if @cache() != PostBody.instance.toString()
+      e.returnValue = "You have unsaved changed."
+      return e.returnValue
+
+  cache: =>
+    cache = PostBody.instance.toString()
+    @cache = (refresh) ->
+      if refresh
+        cache = PostBody.instance.toString()
+        @button.setAttribute('disabled', 'disabled')
+        @button.innerText = @button.getAttribute('persisted')
+      cache
+    @cache()
+
+  save: (e) =>
+    e.preventDefault()
+    e.stopPropagation()
+
+    xhr = new Joint.XHR(e.target.form)
+    xhr.data.set('post[content]', PostBody.instance.toString())
+    xhr.data.set('context', 'content')
+    xhr.send()
+
+  saved: (e) =>
+    if e.MessageHTML
+      event = new CustomEvent('Editor:message', { bubbles: true})
+      event.MessageHTML = e.MessageHTML
+      @element().dispatchEvent(event)
+      @time.setAttribute('time', e.UpdatedAtTime)
+      @refresh()
+      @cache(true)
+
+  update: (e) =>
+    return unless @cache()?
+    if @cache() != PostBody.instance.toString()
+      @button.removeAttribute('disabled')
+      @button.innerText = @button.getAttribute('dirty')
+    else
+      @button.setAttribute('disabled', 'disabled')
+      @button.innerText = @button.getAttribute('persisted')
+

data/lib/ecrire/app/assets/javascripts/admin/editor/navigation/sticky.js.coffee

@@ -0,0 +1,11 @@
+Joint.bind 'Post.Sticky', class
+  loaded: =>
+    @on 'scroll', document, @scrolled
+
+  scrolled: (e) =>
+    top = @element().getBoundingClientRect().top
+    if top < 0
+      @element().style.paddingTop = "#{Math.abs(top)}px"
+    else
+      @element().style.paddingTop = ''
+

data/lib/ecrire/app/assets/javascripts/admin/editor/navigation/toggle.js.coffee

@@ -0,0 +1,10 @@
+Joint.bind 'Navigation.Toggle', class
+  loaded: =>
+    @on 'click', @toggle
+
+  toggle: (e) =>
+    if @element().classList.toggle('active')
+      Menu.style.marginTop = '0'
+    else
+      Menu.style.marginTop = ''
+

data/lib/ecrire/app/assets/javascripts/admin/editor/parsers/code.coffee

@@ -0,0 +1,39 @@
+Editor.Parsers.push class
+  rule: /^((~{3,})([a-z]+)?$)(.+)?(~{3,}$)?/mi
+
+  constructor: (node) ->
+    @nodes = [node]
+    @tildeCount = 0
+
+  isMatched: =>
+    @match = @rule.exec(@nodes[0].textContent)
+    if @match? && @match[0]?
+      @tildeCount = @match[2].length
+      @collectSiblingsUntilMatched(@tildeCount, @nodes[0])
+
+  collectSiblingsUntilMatched: (count, node) =>
+    node = node.nextSibling
+    while node
+      @nodes.push node
+      nextNode = node.nextSibling
+      node.remove()
+
+      match = @rule.exec(node.textContent)
+
+      if match? && match[2]? && match[2].length == count
+        break
+
+      node = nextNode
+
+
+  render: =>
+    pre = "<pre>".toHTML()
+    code = "<code>".toHTML()
+    if @match[3]?
+      code.classList.add("language-#{@match[3]}")
+    texts = @nodes.map (n) -> n.textContent
+    code.textContent = texts.join("\n")
+    Prism.highlightElement(code)
+    pre.appendChild(code)
+    pre
+

data/lib/ecrire/app/assets/javascripts/admin/editor/parsers/heading.coffee

@@ -0,0 +1,19 @@
+Editor.Parsers.push class
+  rule: /^(#{1,6}) /i
+
+  constructor: (node) ->
+    @node = node
+
+  isMatched: =>
+    @match = @rule.exec(@node.textContent)
+    @match?
+
+  render: =>
+    header = "<h#{@match[1].length}>".toHTML()
+
+    if header.nodeName == @node.nodeName
+      return @node
+    else
+      header.appendChild(node.cloneNode(true)) for node in Array.prototype.slice.call(@node.childNodes)
+      return header
+

data/lib/ecrire/app/assets/javascripts/admin/editor/parsers/image.coffee

@@ -0,0 +1,129 @@
+Editor.Parsers.push class
+  rule: /^(!{1}\[([^\]]+)\])(\(([^\s]+)?\))$/i
+
+  constructor: (node) ->
+    @walker = document.createTreeWalker(node, NodeFilter.SHOW_TEXT)
+
+  isMatched: =>
+    @match = @rule.exec(@walker.root.textContent)
+    @match?
+
+  render: =>
+    @container = new Container()
+
+    @uploader = new Editor.ImageUploader(@show)
+
+
+    @picture = "<picture as='Editor.Image'>".toHTML()
+
+    @title = "<em></em>".toHTML()
+    @title.appendChild document.createTextNode(@match[1])
+    @title.appendChild document.createTextNode(@match[3])
+    if @match[4]?
+      @title.setAttribute('name', @match[4])
+
+    @picture.appendChild @container.toHTML(@match[4])
+    @picture.appendChild @title
+
+    @container.input.addEventListener 'change', @update
+    @picture.addEventListener 'drop', @drop
+
+    return @picture
+
+  show: (e, url) =>
+    @container.image(url)
+    @title.lastChild.textContent = "(#{url})"
+
+  update: (e) =>
+    unless e.file?
+      e.file = e.target.files[0]
+    @container.loading()
+    @uploader.send(e)
+
+  drop: (e) =>
+    e.preventDefault()
+    e.file = e.dataTransfer.files[0]
+    @update(e)
+
+
+class Container
+  constructor: ->
+    @el = "<div contenteditable=false></div>".toHTML()
+    @el.addEventListener 'click', @open
+
+    if !(@input = @el.querySelector('input'))?
+      @input = "<input type='file'>".toHTML()
+
+    @el.appendChild(@input)
+
+  image: (url) =>
+    @el.style.backgroundImage = "url(#{url})"
+    @el.innerHTML = ''
+    @el.classList.remove 'loading'
+
+  loading: =>
+    @loading = =>
+      @el.classList.add 'loading'
+      @el.innerHTML = ''
+
+    @loading()
+
+  placeholder: =>
+    el = "<p>Drop an image or click here to upload a picture.</p>".toHTML()
+    @placeholder = =>
+      @el.innerHTML = ''
+      @el.appendChild(el)
+
+    @placeholder()
+
+  open: (e) =>
+    @input.click()
+
+  toHTML: (url) =>
+    if url?
+      @image(url)
+    else if @el.classList.contains('loading')
+      @loading()
+    else
+      @placeholder()
+
+    @el
+
+
+class Editor.ImageUploader
+  constructor: (@callback) ->
+
+  uploaded: (e) =>
+    xml = new DOMParser().parseFromString(e.target.response, 'text/xml')
+    url = xml.querySelector('Location').textContent
+    @callback(e, url)
+
+  send: (e) =>
+    id = PostBody.getAttribute('postid')
+    policy = PostBody.getAttribute('policy')
+    signature = PostBody.getAttribute('signature')
+    bucket = PostBody.getAttribute('bucket')
+    namespace = PostBody.getAttribute('namespace')
+    access_key = PostBody.getAttribute('access_key')
+
+    url = "https://s3.amazonaws.com/#{bucket}/"
+    dir = [id]
+    if namespace?
+      dir.splice(0,0, namespace)
+
+    dir = dir.join '/'
+
+    data = new FormData()
+    data.append 'AWSAccessKeyId', access_key
+    data.append 'success_action_status', 201
+    data.append 'acl', 'private'
+    data.append 'policy', policy
+    data.append 'signature', signature
+    data.append 'key', "#{dir}/#{e.file.name}"
+    data.append 'Content-Type', e.file.type
+    data.append 'file', e.file
+
+    xhr = new XMLHttpRequest()
+    xhr.open('POST', url, true)
+    xhr.onload = @uploaded
+    xhr.send(data)

data/lib/ecrire/app/assets/javascripts/admin/editor/parsers/link.coffee

@@ -0,0 +1,44 @@
+Editor.Parsers.push class
+  rule: /!{0}(\[([^\]]+)\])(\(([^\)]+)\))/gi
+
+  constructor: (node, el) ->
+    @walker = document.createTreeWalker(node, NodeFilter.SHOW_TEXT)
+
+  isMatched: =>
+    @matches().length > 0
+
+  matches: () =>
+    matches = []
+    while node = @walker.nextNode()
+      while (m = @rule.exec(node.textContent))?
+        matches.push m
+        if m.index > 0 || m[0].length < node.length
+          node = node.splitText(m.index)
+          node.splitText(m[0].length)
+
+        m.node = node
+        @walker.currentNode = node
+
+    @matches = ->
+      matches
+    @matches()
+
+  render: =>
+
+    for match in @matches()
+      if match.node.parentElement.nodeName == 'A'
+        continue
+
+      node = match.node
+      el = "<a>".toHTML()
+      el.href = match[4]
+
+      name = "<strong>".toHTML()
+      url = node.splitText(match[1].length)
+      name.textContent = match[1]
+      el.appendChild(name)
+      el.appendChild(url)
+      node.parentElement.replaceChild(el, node)
+
+    @walker.root
+

data/lib/ecrire/app/assets/javascripts/admin/editor/parsers/lists.coffee

@@ -0,0 +1,48 @@
+Editor.Parsers.push class
+  rules: [
+    {
+      type: 'ul'
+      regex: /^(-\s)(.+)?$/i
+    },
+    {
+      type: 'ol'
+      regex: /^(\d+\.)(.+)?$/i
+    }
+  ]
+
+  constructor: (node) ->
+    @nodes = [node]
+    for rule in @rules
+      m = rule.regex.exec(@nodes[0].textContent)
+      if m?
+        @match = m
+        @type = rule.type
+        @rule = rule.regex 
+
+  isMatched: =>
+    if @match?
+      @collectMatchingSiblings(@nodes[0])
+
+    @match?
+
+  collectMatchingSiblings: (root) =>
+    node = root.nextElementSibling
+    while node
+      sibling = node.nextElementSibling
+      m = @rule.exec(node.textContent)
+      if m?
+        @nodes.push node
+        node.remove()
+        node = sibling
+        continue
+      break
+
+
+  render: =>
+    list = "<#{@type}>".toHTML()
+    for node in @nodes
+      li = '<li>'.toHTML()
+      li.textContent = node.textContent
+      list.appendChild(li)
+    list
+

data/lib/ecrire/app/assets/javascripts/admin/editor/parsers/word.coffee

@@ -0,0 +1,56 @@
+Editor.Parsers.push class
+  rule: /((\*{1,2})[^\*]+(\*{1,2}))/gi
+
+  constructor: (node, el) ->
+    @walker = document.createTreeWalker(node, NodeFilter.SHOW_TEXT)
+
+  isMatched: =>
+    @matches().length > 0
+
+  matches: () =>
+    matches = []
+    while node = @walker.nextNode()
+      while (m = @rule.exec(node.textContent))?
+        matches.push m
+        if m.index > 0 || m[0].length < node.length
+          node = node.splitText(m.index)
+          node.splitText(m[0].length)
+
+        m.node = node
+        @walker.currentNode = node
+
+    @matches = ->
+      matches
+    @matches()
+
+  render: =>
+    if @matches().length == 0
+      return @walker.root
+
+    for match in @matches()
+      if match[match.length - 1].length == match[match.length - 2].length
+        if match[match.length - 1].length == 2
+          @bold(match)
+        else
+          @italic(match)
+
+    @walker.root
+      
+  bold: (match) =>
+    if match.node.parentElement.nodeName == 'STRONG'
+      return
+    node = match.node
+    el = "<strong>".toHTML()
+    node.parentElement.replaceChild(el, node)
+    el.appendChild(node)
+    el
+
+  italic: (match) =>
+    if match.node.parentElement.nodeName == 'EM'
+      return
+    node = match.node
+    el = "<em>".toHTML()
+    node.parentElement.replaceChild(el, node)
+    el.appendChild(node)
+    el
+

data/lib/ecrire/app/assets/javascripts/admin/posts/header.coffee

@@ -0,0 +1,69 @@
+Joint.bind 'Post.Header', class
+  loaded: =>
+    @on 'dragover', @over
+    @on 'dragleave', @cancel
+    @on 'drop', @drop
+    @on 'click', @element().querySelector('div'), @open
+    @on 'submit', @element().querySelector('form.clear'), @loading
+    input = @element().querySelector('input[type=file]')
+    @on 'change', input, @submit
+
+    @on 'images:update', @update
+    @on 'images:destroy', @clear
+    @refresh()
+
+  open: (e) =>
+    @element().querySelector('input[type=file]').click()
+
+  over: (e) =>
+    e.preventDefault()
+    @element().classList.add 'dropping'
+
+  cancel: (e) =>
+    e.preventDefault()
+    @element().classList.remove 'dropping'
+
+  drop: (e) =>
+    @element().classList.remove 'dropping'
+    @loading()
+    e.preventDefault()
+    form = @element().querySelector('form.update')
+    xhr = new Joint.XHR(form)
+    xhr.data.set 'image[file]', e.dataTransfer.files[0]
+    xhr.send()
+
+  submit: (e) =>
+    @loading()
+    Joint.XHR.send(e.target.form)
+
+  loading: =>
+    @element().classList.add 'loading'
+
+  clear: (e) =>
+    @element().style.backgroundImage = null
+    @element().classList.remove 'loading'
+    @refresh()
+
+  update: (e) =>
+    @element().classList.remove 'loading'
+
+    if e.ErrorHTML
+      document.body.appendChild(e.ErrorHTML)
+      return
+
+    @element().style.backgroundImage = "url(#{e.headerURL})"
+    @refresh()
+
+
+  refresh: =>
+    clearForm = @element().querySelector('form.clear')
+    p = @element().querySelector('p')
+    @refresh = =>
+      if @element().style.backgroundImage.length > 0
+        p.style.visibility = 'hidden'
+        clearForm.style.visibility = 'visible'
+      else
+        clearForm.style.visibility = 'hidden'
+        p.style.visibility = 'visible'
+
+    @refresh()

data/lib/ecrire/app/assets/javascripts/admin/posts/new.js.coffee

@@ -0,0 +1,7 @@
+Joint.bind 'Posts.New', class
+  loaded: =>
+    for el in @element().querySelectorAll('.transparent')
+      el.classList.remove('transparent')
+
+    @element().querySelector('input[type=text]').focus()
+