debugger2 1.0.0.beta1

data/emacs/rdebug-vars.el

@@ -0,0 +1,125 @@
+;;; rdebug-var.el --- Ruby debugger variables (other than regexps)
+
+;; Copyright (C) 2007 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2007 Anders Lindgren
+
+;; $Id: rdebug-vars.el 769 2008-03-17 14:29:40Z rockyb $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;; See the manual and the file `rdebug.el' for more information.
+
+;;
+;; Introduction:
+;;
+;; This is a full-blown debugger user interface to the Ruby rdebug
+;; debugger shell.
+;;
+;; Internal debug support. When `rdebug-debug-active' is non-nil,
+;; internal debug messages are placed in the buffer *Xrdebug*.
+;; Functions can be annotated with `rdebug-debug-enter' to display a
+;; call trace.
+;;
+
+;;; Code:
+
+(defvar rdebug-current-line-number 1
+  "The line number in a secondary window that you were in. We need to save
+  this value because secondary windows get recreated a lot")
+
+(defvar rdebug-debug-active nil
+  "Non-nil when rdebug should emit internal debug output to *Xrdebug*.")
+
+;; Indentation depth of `rdebug-debug-enter'.
+(defvar rdebug-debug-depth 0)
+
+(defvar rdebug-debugger-window-configuration nil
+  "The saved window layout of the debugger.")
+
+(defvar rdebug-frames-current-frame-number nil
+  "The frame number of the selected frame.")
+
+(defvar rdebug-goto-entry-acc "")
+
+(defvar rdebug-output-marker-number 0
+  "Number to be used when `rdebug-output-add-divider' is next
+  called on the secondary output buffer.")
+
+(defvar rdebug-original-window-configuration nil
+  "The window layout rdebug should restore when the debugger exits.")
+
+;; Terminology: a "secondary buffer" is the physical emacs buffer,
+;; which can be visible or invisible. A "secondary window", is a window
+;; that rdebug is reusing to display different secondary buffers.
+;;
+;; For example, the "secondary-window-help" buffer is named the way it
+;; is since it gives help on how the secondary window is used.
+(defvar rdebug-secondary-buffer nil
+  "Non-nil for rdebug secondary buffers (e.g. the breakpoints buffer).")
+
+;; Currently, this is the "output" and "info" buffers.
+(defvar rdebug-accumulative-buffer nil
+  "Non-nil for Rdebug secondary buffers that grow.")
+
+;; This is used to ensure that the original frame configuration is
+;; restored even when the user re-starts the debugger several times.
+(defvar rdebug-window-configuration-state 'original
+  "Represent the window layout that currently is in use.
+Can be `original' or `debugger'.")
+
+;; FIXME instead of just a list of commands it should a list of pairs
+;; command and lambda callback routine to call with the shell output.
+(defvar rdebug-call-queue '()
+  "List of commands queued up for results of a `rdebug-call'.
+
+Each entry is a list of the following form:
+
+   (name ... options ...)
+
+Name is the actual command string. Options are zero or more tags
+describing what should happen with the output.
+
+This is buffer local variable to the rdebug shell buffer.")
+
+;; TODO: Make this buffer-local to the shell buffer.
+(defvar rdebug-inferior-status nil
+  "The status of the Ruby program debugged under RDebug.")
+
+;; Unlike the gdb implementation, we don't have to actively update the
+;; mode line.
+(defvar rdebug-mode-line-process
+  '(:eval
+    (and (fboundp 'rdebug-display-inferior-status)
+         (rdebug-display-inferior-status)))
+  "A string representing the current debugger state, or nil.
+The mode line is displayed in all source and secondary buffers.")
+;; Needed to get :eval to work.
+(put 'rdebug-mode-line-process 'risky-local-variable t)
+
+
+;; -------------------------------------------------------------------
+;; The end.
+;;
+
+(provide 'rdebug-vars)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-vars.el ends here

data/emacs/rdebug-watch.el

@@ -0,0 +1,132 @@
+;;; rdebug-watch.el --- This file contains code dealing with the Ruby
+;;; debugger's watch (AKA display) secondary buffer.
+
+;; Copyright (C) 2008 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2008 Anders Lindgren
+
+;; $Id: rdebug-watch.el 711 2008-02-20 07:09:17Z andersl $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+;; See the manual and the file `rdebug.el' for more information.
+
+;;; Code:
+
+(require 'rdebug-dbg)
+
+(defvar rdebug-watch-mode-map
+  (let ((map (make-sparse-keymap)))
+    (suppress-keymap map)
+    (define-key map "a" 'rdebug-watch-add)
+    (define-key map "\C-d" 'rdebug-watch-delete)
+    (define-key map "d" 'rdebug-watch-delete)
+    (define-key map "e" 'rdebug-watch-edit)
+    (define-key map "\r" 'rdebug-watch-edit)
+    (rdebug-populate-digit-keys map)
+    (rdebug-populate-secondary-buffer-map map)
+
+    ;; --------------------
+    ;; The "Watch window" submenu.
+    (let ((submenu (make-sparse-keymap)))
+      (define-key-after map [menu-bar debugger watch]
+        (cons "Watch window" submenu)
+        'placeholder))
+
+    (define-key map [menu-bar debugger watch delete]
+      '(menu-item "Delete" rdebug-watch-delete
+                  :enable (eq major-mode 'rdebug-watch-mode)))
+    (define-key map [menu-bar debugger watch goto]
+      '(menu-item "Edit" rdebug-watch-edit
+                  :enable (eq major-mode 'rdebug-watch-mode)))
+    (define-key map [menu-bar debugger watch add]
+      '(menu-item "Add" rdebug-watch-add))
+
+    map)
+  "Keymap used in the watch buffer in the `rdebug' Ruby debugger.")
+
+(defun rdebug-display-watch-buffer ()
+  "Display the rdebug watch buffer."
+  (interactive)
+  (rdebug-display-secondary-buffer "watch"))
+
+(defun rdebug-watch-mode ()
+  "Major mode for displaying watched expressions in the `rdebug' Ruby debugger.
+
+\\{rdebug-watch-mode}"
+  (interactive)
+  (kill-all-local-variables)
+  (setq major-mode 'rdebug-watch-mode)
+  (setq mode-name "RDEBUG Watch")
+  (setq buffer-read-only t)
+  (setq truncate-lines t)
+  (set (make-local-variable 'rdebug-secondary-buffer) t)
+  (setq mode-line-process 'rdebug-mode-line-process)
+  (set (make-local-variable 'font-lock-defaults)
+       '(rdebug-variables-font-lock-keywords))
+  (use-local-map rdebug-watch-mode-map)
+  (run-mode-hooks 'rdebug-watch-mode-hook))
+
+(defun rdebug-setup-watch-buffer (buf comint-buffer)
+  "Set up the rdebug debugger watch secondary buffer.
+
+This buffer contains display expressions.  BUF is the buffer to set up and COMINT-BUFFER be the assocated gud process buffer."
+  (rdebug-debug-enter "rdebug-setup-watch-buffer"
+    (with-current-buffer buf
+      (rdebug-watch-mode)
+      (set (make-local-variable 'gud-comint-buffer) comint-buffer))))
+
+(defun rdebug-watch-add (expr)
+  "Add EXPR to watch in the `rdebug' Ruby debugger."
+  (interactive "sRuby expression: ")
+  (if (not (string= expr ""))
+      (gud-call (format "display %s" expr))))
+
+
+(defun rdebug-watch-delete ()
+  "Delete a display expression in the `rdebug' Ruby debugger."
+  (interactive)
+  (save-excursion
+    (beginning-of-line)
+    (if (looking-at "^\\([0-9]+\\):")
+        (gud-call (format "undisplay %s" (match-string 1))))))
+
+(defun rdebug-watch-edit (number expr)
+  "Edit a display expression in the `rdebug' Ruby debugger.
+Argument NUMBER is the display expression number.
+Argument EXPR is the expression for display number NUMBER."
+  (interactive
+   (let ((number nil)
+         (expr nil))
+     (save-excursion
+       (beginning-of-line)
+       (when (looking-at "^\\([0-9]+\\): *\\([^=]*[^= ]\\) *=")
+         (setq number (match-string 1))
+         (setq expr (match-string 2))
+         (setq expr (read-from-minibuffer "Ruby expression: " expr)))
+       (list number expr))))
+  (when expr
+    (gud-call (format "undisplay %s" number))
+    (gud-call (format "display %s" expr))))
+
+
+(provide 'rdebug-watch)
+
+;;; Local variables:
+;;; eval:(put 'rdebug-debug-enter 'lisp-indent-hook 1)
+;;; End:
+
+;;; rdebug-watch.el ends here

data/emacs/rdebug.el

@@ -0,0 +1,326 @@
+;;; rdebug.el --- Ruby debugger user interface, startup file.
+
+;; Copyright (C) 2006, 2007, 2008 Rocky Bernstein (rocky@gnu.org)
+;; Copyright (C) 2007, 2008 Anders Lindgren
+
+;; $Id: rdebug.el 409 2007-12-14 02:36:37Z rockyb $
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+;; Boston, MA 02111-1307, USA.
+
+;;; Commentary:
+
+;;
+;; Introduction:
+;;
+;; This is a full-blown debugger user interface to the Ruby rdebug
+;; debugger shell.
+;;
+;; The main features are:
+;;
+;;  * Window layout with dedicated windows for:
+;;      + Local and member variables
+;;      + Stack trace
+;;      + Display expressions
+;;      + Breakpoints
+;;      + Output
+;;      + Debugger Shell
+;;
+;;  * Source-level debugging:
+;;      + The current source file is shown and current line is marked.
+;;      + Function keys bindings for effective stepping in the source code.
+;;      + A "Debugger" menu for easy access to all features.
+;;
+;;  * A number of predefined window layouts and key bindings are
+;;    supplied, including binding that emulate Eclipse and NetBeans.
+;;    The user can easily provide their own window layout and
+;;    settings.
+;;
+;; The default window layout looks like the following:
+;;
+;; +----------------------------------------------------------------------+
+;; |                                Toolbar                               |
+;; +-----------------------------------+----------------------------------+
+;; | Debugger shell                    | Variables buffer                 |
+;; +-----------------------------------+----------------------------------+
+;; |                                   |                                  |
+;; | Source buffer                     | Output buffer                    |
+;; |                                   |                                  |
+;; +-----------------------------------+----------------------------------+
+;; | Stack buffer                      | Breakpoints buffer               |
+;; +-----------------------------------+----------------------------------+
+;;
+
+;;
+;; Installation:
+;;
+;; To use this package, place the following line in an appropriate
+;; init file (for example ~/.emacs):
+;;
+;;    (require 'rdebug)
+;;
+
+;;
+;; History and Future:
+;;
+;; The design of this debugger user interface was inspired by
+;; `gdb-ui', a similar user interface to GDB.
+;;
+;; Hopefully, rdebug, gdb-ui, and other emacs user interfaces could
+;; join forces to create a common user-level look and feel, and a
+;; battery of underlying support functions.
+;;
+
+;;
+;; This file contains only user-customizable variables and code to
+;; load the other files when needed.
+;;
+
+;;; Code:
+
+;; -------------------------------------------------------------------
+;; Consistency checks.
+;;
+
+(if (< emacs-major-version 22)
+    (error
+     "This version of rdebug.el needs at least Emacs 22 or greater - you have version %d."
+     emacs-major-version))
+
+
+;; -------------------------------------------------------------------
+;; Support functions.
+;;
+
+(defun rdebug-directory ()
+  "The directory of this file, or nil."
+  (let ((file-name (or load-file-name
+                       (symbol-file 'rdebug-directory))))
+    (if file-name
+        (file-name-directory file-name)
+      nil)))
+
+
+(defun rdebug-compare-filenames (f1 f2)
+  "Canonicalize and compare file names."
+  ;; Canonicalize by:
+  ;;  1) file-truename ensures that the file has got the correct case,
+  ;;     and that "..":s in the path are eliminated.
+  ;;  2) file-name-as-directory ensures "/foo" and "/foo/" becomes equal.
+
+  ;; Note: for some reason, when the `comp-elisp' external program is
+  ;; used, `nil' is part of `load-path'.
+  (if f1
+      (setq f1 (file-name-as-directory (file-truename f1))))
+  (if f2
+      (setq f2 (file-name-as-directory (file-truename f2))))
+  (equal f1 f2))
+
+
+;; Add the directory of `rdebug.el' to the load-path. This ensures
+;; that all the user have do to use this package is to load this file.
+(let ((dir (rdebug-directory)))
+  (if dir
+      (add-to-list 'load-path dir nil 'rdebug-compare-filenames)))
+
+
+;; -------------------------------------------------------------------
+;; Autoloads.
+;;
+
+(autoload 'rdebug "rdebug-core"
+  "Run the rdebug Ruby debugger and start the Emacs user interface.
+
+By default, the \"standard\" user window layout looks like the following:
+
++----------------------------------------------------------------------+
+|                                Toolbar                               |
++-----------------------------------+----------------------------------+
+| Debugger shell                    | Variables buffer                 |
++-----------------------------------+----------------------------------+
+|                                   |                                  |
+| Source buffer                     | Output buffer                    |
+|                                   |                                  |
++-----------------------------------+----------------------------------+
+| Stack buffer                      | Breakpoints buffer               |
++-----------------------------------+----------------------------------+
+
+The variable `rdebug-many-windows-layout-function' can be
+customized so that another layout is used. In addition to a
+number of predefined layouts it's possible to define a function
+to perform a custom layout.
+
+If `rdebug-many-windows' is nil, only a traditional debugger
+shell and source window is opened.
+
+The directory containing the debugged script becomes the initial
+working directory and source-file directory for your debugger.
+
+The custom variable `gud-rdebug-command-name' sets the command
+and options used to invoke rdebug." t)
+
+
+(autoload 'rdebug-turn-on-debugger-support "rdebug-source"
+  "Enable extra source buffer support for the `rdebug' Ruby debugger.
+
+This includes a 'Debugger' menu and special key bindings when the
+debugger is active."
+  t)
+
+
+(autoload 'rdebug-track-attach "rdebug-track"
+  "Do things to make the current process buffer work like a
+rdebug command buffer." t)
+
+(autoload 'turn-on-rdebug-track-mode "rdebug-track"
+  "Turn on rdebugtrack mode.
+
+This function is designed to be added to hooks, for example:
+  (add-hook 'comint-mode-hook 'turn-on-rdebugtrack-mode)"
+  t)
+
+
+(add-hook 'ruby-mode-hook 'rdebug-turn-on-debugger-support)
+
+;; This is needed, or at least the docstring part of it is needed to
+;; get the customization menu to work in Emacs 23.
+(defgroup rdebug nil
+  "The Ruby debugger"
+  :group 'processes
+  :group 'tools)
+
+;; -------------------------------------------------------------------
+;; User definable variables
+;;
+
+(defcustom gud-rdebug-command-name
+  "rdebug --emacs 3"
+  "File name for executing the Ruby debugger and command options.
+This should be an executable on your path, or an absolute file name."
+  :type 'string
+  :group 'gud)
+
+(defcustom rdebug-line-width 120
+  "Length of line before truncation occurs.
+This value limits output in secondary buffers."
+  :type 'integer
+  :group 'rdebug)
+
+(defcustom rdebug-many-windows t
+  "*If non-nil, use the full debugger user interface, see `rdebug'.
+
+However only set to the multi-window display if the rdebug
+command invocation has an annotate options (\"--annotate 3\")."
+  :type 'boolean
+  :group 'rdebug)
+
+(defcustom rdebug-use-separate-io-buffer t
+  "*If non-nil, output goes to a dedicated windows.
+
+This only applies when `rdebug-many-windows' is non-nil."
+  :type 'boolean
+  :group 'rdebug)
+
+(defcustom rdebug-populate-common-keys-function
+  'rdebug-populate-common-keys-standard
+  "The function to call to populate key bindings common to all rdebug windows.
+This includes the secondary windows, the debugger shell, and all
+Ruby source buffers when the debugger is active.
+
+This variable can be bound to the following:
+
+* nil -- Don't bind any keys.
+
+* `rdebug-populate-common-keys-standard' -- Bind according to a widely used
+  debugger convention:
+
+\\{rdebug-example-map-standard}
+
+* `rdebug-populate-common-keys-eclipse' -- Bind according to Eclipse.
+
+\\{rdebug-example-map-eclipse}
+
+* `rdebug-populate-common-keys-netbeans' -- Bind according to NetBeans.
+
+\\{rdebug-example-map-netbeans}
+
+* Any other value is expected to be a callable function that takes one
+  argument, the keymap, and populates it with suitable keys."
+  :type 'function
+  :group 'rdebug)
+
+(defcustom rdebug-restore-original-window-configuration :many
+  "*Control if the original window layout is restored when the debugger exits.
+The value can be t, nil, or :many.
+
+A value of t means that the original layout is always restored,
+nil means that it's never restored.
+
+:many means that the original layout is restored only when
+`rdebug-many-windows' is used."
+  :type '(choice (const :tag "Always restore" t)
+		 (const :tag "Never restore" nil)
+		 (const :tag "Restore in many windows mode" :many))
+  :group 'rdebug)
+
+(defcustom rdebug-use-separate-io-buffer t
+  "Non-nil means display output from the debugged program in a separate buffer."
+  :type 'boolean
+  :group 'gud)
+
+
+(defcustom rdebug-window-layout-function
+  'rdebug-window-layout-standard
+  "*A function that performs the window layout of `rdebug'.
+
+This is only used in `rdebug-many-windows' mode. This should be
+bound to a function that performs the actual window layout. The
+function should takes two arguments, the first is the source
+buffer and the second the name of the script to debug.
+
+Rdebug provides the following predefined layout functions:
+
+* `rdebug-window-layout-standard'         -- See `rdebug'
+
+* `rdebug-window-layout-no-shell'         -- Standard + Display, no Shell
+
+* `rdebug-window-layout-conservative'     -- Source + Shell + Output
+
+* `rdebug-window-layout-stack-of-windows' -- Extra windows to the right
+
+* `rdebug-window-layout-rocky'            -- Rocky's own layout"
+  :type
+  '(choice
+    (function :tag "Standard"         rdebug-window-layout-standard)
+    (function :tag "Conservative"     rdebug-window-layout-conservative)
+    (function :tag "Stack of windows" rdebug-window-layout-stack-of-windows)
+    (function :tag "Rocky's own"      rdebug-window-layout-rocky)
+    (function :tag "Rocky's II"       rdebug-window-layout-rocky2)
+    (function :tag "Other"            function))
+  :group 'rdebug)
+
+(defcustom rdebug-source-location-ring-size 150
+  "Size of rdebug position history ring."
+  :type 'integer
+  :group 'rdebug)
+
+
+;; -------------------------------------------------------------------
+;; The end.
+;;
+
+(provide 'rdebug)
+
+;;; rdebug.el ends here