copy_tuner_client 0.3.5 → 0.4.0

data/src/copyray.coffee

@@ -0,0 +1,354 @@
+window.Copyray ?= {}
+
+# Max CSS z-index. The overlay and copyray bar use this.
+MAX_ZINDEX = 2147483647
+HIDDEN_CLASS = 'copy-tuner-hidden'
+
+isMac = navigator.platform.toUpperCase().indexOf('MAC') isnt -1
+
+isVisible = (element) ->
+  !!(element.offsetWidth || element.offsetHeight || element.getClientRects().length)
+
+getOffset = (elment) ->
+  box = elment.getBoundingClientRect()
+  {
+    top: box.top + window.pageYOffset - document.documentElement.clientTop,
+    left: box.left + window.pageXOffset - document.documentElement.clientLeft
+  }
+
+# Returns all currently created Copyray.Specimen objects.
+Copyray.specimens = ->
+  Copyray.BlurbSpecimen.all
+
+# Looks up the stored constructor info
+Copyray.constructorInfo = (constructor) ->
+  if window.CopyrayPaths
+    for own info, func of window.CopyrayPaths
+      return JSON.parse(info) if func == constructor
+  null
+
+getAllComments = (rootElement) ->
+  filterNone = ->
+    NodeFilter.FILTER_ACCEPT
+
+  comments = []
+  iterator = document.createNodeIterator(rootElement, NodeFilter.SHOW_COMMENT, filterNone, false)
+  while (curNode = iterator.nextNode())
+    comments.push(curNode)
+  comments
+
+# Scans the document for blurbs, creating Copyray.BlurbSpecimen for them.
+Copyray.findBlurbs = -> util.bm 'findBlurbs', ->
+  # Find all <!-- COPYRAY START ... --> comments
+  comments = getAllComments(document.body).filter((comment) ->
+    comment.nodeValue.startsWith('COPYRAY START')
+  )
+
+  comments.forEach((comment) ->
+    [_, id, path, url] = comment.nodeValue.match(/^COPYRAY START (\d+) (\S*) (\S*)/)
+    blurbElement = null
+    el = comment.nextSibling
+    until !el or (el.nodeType == Node.COMMENT_NODE and el.data == "COPYRAY END #{id}")
+      if el.nodeType == Node.ELEMENT_NODE and el.tagName != 'SCRIPT'
+        blurbElement = el
+        break
+      el = el.nextSibling
+
+    # Remove COPYRAY template comments from the DOM.
+    el.parentNode.removeChild(el) if el?.nodeType == Node.COMMENT_NODE
+    comment.parentNode.removeChild(comment)
+
+    if blurbElement
+      # Add the template specimen
+      Copyray.BlurbSpecimen.add blurbElement,
+        name: path.split('/').slice(-1)[0]
+        path: path
+        url: url
+  )
+
+# Open the given filesystem path by calling out to Copyray's server.
+Copyray.open = (url) ->
+  window.open(url, null, 'width=700, height=600')
+
+# Show the Copyray overlay
+Copyray.show = (type = null) ->
+  Copyray.Overlay.instance().show(type)
+  Copyray.showBar()
+
+# Hide the Copyray overlay
+Copyray.hide = ->
+  Copyray.Overlay.instance().hide()
+  Copyray.hideBar()
+
+Copyray.addToggleButton = ->
+  element = document.createElement('a')
+  element.addEventListener('click', () ->
+    Copyray.show()
+  )
+  element.classList.add('copyray-toggle-button')
+  element.textContent = 'Open CopyTuner'
+  document.body.appendChild(element)
+
+# Wraps a DOM element that Copyray is tracking. This is subclassed by
+# Copyray.Blurbsspecimen
+class Copyray.Specimen
+  @add: (el, info = {}) ->
+    @all.push new this(el, info)
+
+  @remove: (el) ->
+    @find(el)?.remove()
+
+  @find: (el) ->
+    for specimen in @all
+      return specimen if specimen.el == el
+    null
+
+  @reset: ->
+    @all = []
+
+  constructor: (el, info = {}) ->
+    @el = el
+    @name = info.name
+    @path = info.path
+    @url = info.url
+
+  remove: ->
+    idx = @constructor.all.indexOf(this)
+    @constructor.all.splice(idx, 1) unless idx == -1
+
+  makeBox: ->
+    @bounds = util.computeBoundingBox([@el])
+    @box = document.createElement('div')
+    @box.classList.add('copyray-specimen')
+    @box.classList.add(@constructor.name)
+    for key, value of @bounds
+      @box.style[key] = "#{value}px"
+
+    # If the element is fixed, override the computed position with the fixed one.
+    if getComputedStyle(@el).position == 'fixed'
+      @box.css
+        position : 'fixed'
+        top      : getComputedStyle(@el).top
+        left     : getComputedStyle(@el).left
+
+    @box.addEventListener('click', =>
+      Copyray.open "#{@url}/blurbs/#{@path}/edit"
+    )
+
+    @box.appendChild(@makeLabel())
+
+  makeLabel: =>
+    div = document.createElement('div')
+    div.classList.add('copyray-specimen-handle')
+    div.classList.add(@constructor.name)
+    div.textContent = @name
+    div
+
+# copy-tuner blurbs
+class Copyray.BlurbSpecimen extends Copyray.Specimen
+  @all = []
+
+# Singleton class for the Copyray "overlay" invoked by the keyboard shortcut
+class Copyray.Overlay
+  @instance: ->
+    @singletonInstance ||= new this
+
+  constructor: ->
+    Copyray.Overlay.singletonInstance = this
+    @overlay = document.createElement('div')
+    @overlay.setAttribute('id', 'copyray-overlay')
+    @shownBoxes = []
+    @overlay.addEventListener('click', () =>
+      @hide()
+    )
+
+  show: (type = null) ->
+    @reset()
+    Copyray.isShowing = true
+    util.bm 'show', =>
+      unless document.body.contains(@overlay)
+        document.body.appendChild(@overlay)
+        Copyray.findBlurbs()
+        specimens = Copyray.specimens()
+
+      for element in specimens
+        element.makeBox()
+        # A cheap way to "order" the boxes, where boxes positioned closer to the
+        # bottom right of the document have a higher z-index.
+        element.box.style.zIndex = Math.ceil(MAX_ZINDEX*0.9 + element.bounds.top + element.bounds.left)
+        @shownBoxes.push element.box
+        document.body.appendChild(element.box)
+
+  reset: ->
+    $box.remove() for $box in @shownBoxes
+    @shownBoxes = []
+
+  hide: ->
+    Copyray.isShowing = false
+    @overlay.remove()
+    @reset()
+    Copyray.hideBar()
+
+# Utility methods.
+util =
+  # Benchmark a piece of code
+  bm: (name, fn) ->
+    time = new Date
+    result = fn()
+    # console.log "#{name} : #{new Date() - time}ms"
+    result
+
+  # elements with no parent in the set.
+  computeBoundingBox: (elements) ->
+    # Edge case: the container may not physically wrap its children, for
+    # example if they are floated and no clearfix is present.
+    if elements.length == 1 and elements[0].clientHeight
+      return util.computeBoundingBox(elements[0].children)
+
+    boxFrame =
+      top    : Number.POSITIVE_INFINITY
+      left   : Number.POSITIVE_INFINITY
+      right  : Number.NEGATIVE_INFINITY
+      bottom : Number.NEGATIVE_INFINITY
+
+    elements.forEach((element) ->
+      return unless isVisible(element)
+      frame = getOffset(element)
+      frame.right  = frame.left + element.offsetWidth
+      frame.bottom = frame.top + element.offsetHeight
+      boxFrame.top    = frame.top if frame.top < boxFrame.top
+      boxFrame.left   = frame.left if frame.left < boxFrame.left
+      boxFrame.right  = frame.right if frame.right > boxFrame.right
+      boxFrame.bottom = frame.bottom if frame.bottom > boxFrame.bottom
+    )
+
+    return {
+      left   : boxFrame.left
+      top    : boxFrame.top
+      width  : boxFrame.right - boxFrame.left
+      height : boxFrame.bottom - boxFrame.top
+    }
+
+Copyray.showBar = ->
+  document.getElementById('copy-tuner-bar').classList.remove(HIDDEN_CLASS)
+  document.querySelector('.copyray-toggle-button').classList.add(HIDDEN_CLASS)
+  Copyray.focusSearchBox()
+
+Copyray.hideBar = ->
+  document.getElementById('copy-tuner-bar').classList.add(HIDDEN_CLASS)
+  document.querySelector('.copyray-toggle-button').classList.remove(HIDDEN_CLASS)
+  document.querySelector('.js-copy-tuner-bar-log-menu').classList.add(HIDDEN_CLASS)
+
+Copyray.createLogMenu = ->
+  tbody = document.querySelector('.js-copy-tuner-bar-log-menu__tbody.is-not-initialized')
+  return unless tbody
+
+  tbody.classList.remove('is-not-initialized')
+  baseUrl = document.getElementById('copy-tuner-data').dataset.copyTunerUrl
+  log = JSON.parse(document.getElementById('copy-tuner-data').dataset.copyTunerTranslationLog)
+
+  Object.keys(log).sort().forEach((key) ->
+    value = log[key]
+    return if value == ''
+
+    url = "#{baseUrl}/blurbs/#{key}/edit"
+
+    td1 = document.createElement('td')
+    td1.textContent = key
+
+    td2 = document.createElement('td')
+    td2.textContent = value
+
+    tr = document.createElement('tr')
+    tr.classList.add('copy-tuner-bar-log-menu__row')
+    tr.classList.add('js-copy-tuner-blurb-row')
+    tr.dataset.url = url
+
+    tr.addEventListener('click', ({currentTarget}) ->
+      Copyray.open(currentTarget.dataset.url)
+    )
+
+    tr.appendChild(td1)
+    tr.appendChild(td2)
+    tbody.appendChild(tr)
+  )
+
+Copyray.focusSearchBox = ->
+  document.querySelector('.js-copy-tuner-bar-search').focus()
+
+Copyray.toggleLogMenu = ->
+  Copyray.createLogMenu()
+  document.getElementById('copy-tuner-bar-log-menu').classList.toggle(HIDDEN_CLASS)
+
+Copyray.setupLogMenu = ->
+  element = document.querySelector('.js-copy-tuner-bar-open-log')
+  element.addEventListener('click', (event) ->
+    event.preventDefault()
+    Copyray.toggleLogMenu()
+  )
+
+Copyray.setupSearchBar = ->
+  timer = null
+  lastKeyword = ''
+  barElement = document.querySelector('.js-copy-tuner-bar-search')
+
+  barElement.addEventListener('focus', ({target}) ->
+    lastKeyword = target.value
+  )
+
+  barElement.addEventListener('keyup', ({target}) ->
+    keyword = target.value.trim()
+    if lastKeyword != keyword
+      Copyray.toggleLogMenu() if !isVisible(document.getElementById('copy-tuner-bar-log-menu'))
+      clearTimeout(timer)
+      timer = setTimeout ->
+        rows = Array.from(document.getElementsByClassName('js-copy-tuner-blurb-row'))
+        if keyword == ''
+          rows.forEach((row) ->
+            row.classList.remove(HIDDEN_CLASS)
+          )
+        else
+          rows.forEach((row) ->
+            row.classList.add(HIDDEN_CLASS)
+          )
+
+          rows.filter((row) ->
+            Array.from(row.getElementsByTagName('td')).some((td) ->
+              td.textContent.includes(keyword)
+            )
+          ).forEach((row) ->
+            row.classList.remove(HIDDEN_CLASS)
+          )
+      , 500
+      lastKeyword = keyword
+  )
+
+init = ->
+  return if Copyray.initialized
+  Copyray.initialized = true
+
+  # Register keyboard shortcuts
+  document.addEventListener('keydown', (event) ->
+    # cmd + shift + k
+    if (isMac and event.metaKey or !isMac and event.ctrlKey) and event.shiftKey and event.keyCode is 75
+      if Copyray.isShowing then Copyray.hide() else Copyray.show()
+    if Copyray.isShowing and event.keyCode is 27 # esc
+      Copyray.hide()
+  )
+
+  # Instantiate the overlay singleton.
+  new Copyray.Overlay
+  # Go ahead and do a pass on the DOM to find templates.
+  Copyray.findBlurbs()
+
+  Copyray.addToggleButton()
+  Copyray.setupSearchBar()
+  Copyray.setupLogMenu()
+
+  # Ready to rock.
+  console?.log "Ready to Copyray. Press #{if isMac then 'cmd+shift+k' else 'ctrl+shift+k'} to scan your UI."
+
+if document.readyState == 'complete' || document.readyState != 'loading'
+  init()
+else
+  document.addEventListener('DOMContentLoaded', init)

metadata

@@ -1,14 +1,14 @@
 --- !ruby/object:Gem::Specification
 name: copy_tuner_client
 version: !ruby/object:Gem::Version
-  version: 0.3.5
+  version: 0.4.0
 platform: ruby
 authors:
 - SonicGarden
 autorequire: 
 bindir: bin
 cert_chain: []
-date: 2017-06-09 00:00:00.000000000 Z
+date: 2017-06-23 00:00:00.000000000 Z
 dependencies:
 - !ruby/object:Gem::Dependency
   name: i18n
@@ -236,9 +236,10 @@ files:
 - Gemfile.lock
 - README.md
 - Rakefile
-- app/assets/javascripts/copyray.js.coffee
+- app/assets/javascripts/copyray.js
 - app/assets/stylesheets/copyray.css
 - app/views/_copy_tuner_bar.html.erb
+- coffeelint.json
 - copy_tuner_client.gemspec
 - features/rails.feature
 - features/step_definitions/copycopter_server_steps.rb
@@ -267,6 +268,8 @@ files:
 - lib/copy_tuner_client/translation_log.rb
 - lib/copy_tuner_client/version.rb
 - lib/tasks/copy_tuner_client_tasks.rake
+- package-lock.json
+- package.json
 - spec/copy_tuner_client/cache_spec.rb
 - spec/copy_tuner_client/client_spec.rb
 - spec/copy_tuner_client/configuration_spec.rb
@@ -288,6 +291,7 @@ files:
 - spec/support/fake_unicorn.rb
 - spec/support/middleware_stack.rb
 - spec/support/writing_cache.rb
+- src/copyray.coffee
 - ui/views/copytuner/index.html.erb
 - ui/views/layouts/copytuner_default.html.erb
 homepage: https://github.com/SonicGarden/copy-tuner-ruby-client

data/app/assets/javascripts/copyray.js.coffee

@@ -1,282 +0,0 @@
-window.Copyray = {}
-return unless $ = window.jQuery
-
-# Max CSS z-index. The overlay and copyray bar use this.
-MAX_ZINDEX = 2147483647
-
-# Initialize Copyray. Called immediately, but some setup is deferred until DOM ready.
-Copyray.init = do ->
-  return if Copyray.initialized
-  Copyray.initialized = true
-
-  is_mac = navigator.platform.toUpperCase().indexOf('MAC') isnt -1
-
-  # Register keyboard shortcuts
-  $(document).keydown (e) ->
-    # cmd + shift + k
-    if (is_mac and e.metaKey or !is_mac and e.ctrlKey) and e.shiftKey and e.keyCode is 75
-      if Copyray.isShowing then Copyray.hide() else Copyray.show()
-    if Copyray.isShowing and e.keyCode is 27 # esc
-      Copyray.hide()
-
-  $ ->
-    # Instantiate the overlay singleton.
-    new Copyray.Overlay
-    # Go ahead and do a pass on the DOM to find templates.
-    Copyray.findBlurbs()
-
-    Copyray.addToggleButton()
-
-    # Ready to rock.
-    console?.log "Ready to Copyray. Press #{if is_mac then 'cmd+shift+k' else 'ctrl+shift+k'} to scan your UI."
-
-# Returns all currently created Copyray.Specimen objects.
-Copyray.specimens = ->
-  Copyray.BlurbSpecimen.all
-
-# Looks up the stored constructor info
-Copyray.constructorInfo = (constructor) ->
-  if window.CopyrayPaths
-    for own info, func of window.CopyrayPaths
-      return JSON.parse(info) if func == constructor
-  null
-
-# Scans the document for blurbs, creating Copyray.BlurbSpecimen for them.
-Copyray.findBlurbs = -> util.bm 'findBlurbs', ->
-  # Find all <!-- COPYRAY START ... --> comments
-  comments = $('*:not(iframe,script)').contents().filter ->
-    this.nodeType == 8 and this.data[0..12] == "COPYRAY START"
-
-  # Find the <!-- COPYRAY END ... --> comment for each. Everything between the
-  for comment in comments
-    [_, id, path, url] = comment.data.match(/^COPYRAY START (\d+) (\S*) (\S*)/)
-    $blurbContents = new jQuery
-    el = comment.nextSibling
-    until !el or (el.nodeType == 8 and el.data == "COPYRAY END #{id}")
-      if el.nodeType == 1 and el.tagName != 'SCRIPT'
-        $blurbContents.push el
-      el = el.nextSibling
-    # Remove COPYRAY template comments from the DOM.
-    el.parentNode.removeChild(el) if el?.nodeType == 8
-    comment.parentNode.removeChild(comment)
-    # Add the template specimen
-    Copyray.BlurbSpecimen.add $blurbContents,
-      name: path.split('/').slice(-1)[0]
-      path: path
-      url: url
-
-# Open the given filesystem path by calling out to Copyray's server.
-Copyray.open = (url) ->
-  window.open(url, null, 'width=700, height=600')
-
-# Show the Copyray overlay
-Copyray.show = (type = null) ->
-  Copyray.Overlay.instance().show(type)
-  Copyray.showBar()
-
-# Hide the Copyray overlay
-Copyray.hide = ->
-  Copyray.Overlay.instance().hide()
-  Copyray.hideBar()
-
-Copyray.toggleSettings = ->
-  Copyray.Overlay.instance().settings.toggle()
-
-Copyray.addToggleButton = ->
-  $('body').append("<a href='javascript:Copyray.show()' class='copyray-toggle-button'>Open CopyTuner</a>")
-
-# Wraps a DOM element that Copyray is tracking. This is subclassed by
-# Copyray.Blurbsspecimen
-class Copyray.Specimen
-  @add: (el, info = {}) ->
-    @all.push new this(el, info)
-
-  @remove: (el) ->
-    @find(el)?.remove()
-
-  @find: (el) ->
-    el = el[0] if el instanceof jQuery
-    for specimen in @all
-      return specimen if specimen.el == el
-    null
-
-  @reset: ->
-    @all = []
-
-  constructor: (contents, info = {}) ->
-    @el = if contents instanceof jQuery then contents[0] else contents
-    @$contents = $(contents)
-    @name = info.name
-    @path = info.path
-    @url = info.url
-
-  remove: ->
-    idx = @constructor.all.indexOf(this)
-    @constructor.all.splice(idx, 1) unless idx == -1
-
-  isVisible: ->
-    @$contents.length
-
-  makeBox: ->
-    @bounds = util.computeBoundingBox(@$contents)
-    @$box = $("<div class='copyray-specimen #{@constructor.name}'>").css(@bounds)
-
-    # If the element is fixed, override the computed position with the fixed one.
-    if @$contents.css('position') == 'fixed'
-      @$box.css
-        position : 'fixed'
-        top      : @$contents.css('top')
-        left     : @$contents.css('left')
-
-    @$box.click => Copyray.open @url + '/blurbs/' + @path + '/edit'
-    @$box.append @makeLabel
-
-  makeLabel: =>
-    $("<div class='copyray-specimen-handle #{@constructor.name}'>").append(@name)
-
-# copy-tuner blurbs
-class Copyray.BlurbSpecimen extends Copyray.Specimen
-  @all = []
-
-# Singleton class for the Copyray "overlay" invoked by the keyboard shortcut
-class Copyray.Overlay
-  @instance: ->
-    @singletonInstance ||= new this
-
-  constructor: ->
-    Copyray.Overlay.singletonInstance = this
-    @$overlay = $('<div id="copyray-overlay">')
-    @shownBoxes = []
-    @$overlay.click => @hide()
-
-  show: (type = null) ->
-    @reset()
-    Copyray.isShowing = true
-    util.bm 'show', =>
-      unless @$overlay.is(':visible')
-        $('body').append @$overlay
-        Copyray.findBlurbs()
-        specimens = Copyray.specimens()
-      for element in specimens
-        continue unless element.isVisible()
-        element.makeBox()
-        # A cheap way to "order" the boxes, where boxes positioned closer to the
-        # bottom right of the document have a higher z-index.
-        element.$box.css
-          zIndex: Math.ceil(MAX_ZINDEX*0.9 + element.bounds.top + element.bounds.left)
-        @shownBoxes.push element.$box
-        $('body').append element.$box
-
-  reset: ->
-    $box.remove() for $box in @shownBoxes
-    @shownBoxes = []
-
-  hide: ->
-    Copyray.isShowing = false
-    @$overlay.detach()
-    @reset()
-    Copyray.hideBar()
-
-# Utility methods.
-util =
-  # Benchmark a piece of code
-  bm: (name, fn) ->
-    time = new Date
-    result = fn()
-    # console.log "#{name} : #{new Date() - time}ms"
-    result
-
-  # Computes the bounding box of a jQuery set, which may be many sibling
-  # elements with no parent in the set.
-  computeBoundingBox: ($contents) ->
-    # Edge case: the container may not physically wrap its children, for
-    # example if they are floated and no clearfix is present.
-    if $contents.length == 1 and $contents.height() <= 0
-      return util.computeBoundingBox($contents.children())
-
-    boxFrame =
-      top    : Number.POSITIVE_INFINITY
-      left   : Number.POSITIVE_INFINITY
-      right  : Number.NEGATIVE_INFINITY
-      bottom : Number.NEGATIVE_INFINITY
-
-    for el in $contents
-      $el = $(el)
-      continue unless $el.is(':visible')
-      frame = $el.offset()
-      frame.right  = frame.left + $el.outerWidth()
-      frame.bottom = frame.top + $el.outerHeight()
-      boxFrame.top    = frame.top if frame.top < boxFrame.top
-      boxFrame.left   = frame.left if frame.left < boxFrame.left
-      boxFrame.right  = frame.right if frame.right > boxFrame.right
-      boxFrame.bottom = frame.bottom if frame.bottom > boxFrame.bottom
-
-    return {
-      left   : boxFrame.left
-      top    : boxFrame.top
-      width  : boxFrame.right - boxFrame.left
-      height : boxFrame.bottom - boxFrame.top
-    }
-
-Copyray.showBar = ->
-  $('#copy-tuner-bar').show()
-  $('.copyray-toggle-button').hide()
-  Copyray.focusSearchBox()
-
-Copyray.hideBar = ->
-  $('#copy-tuner-bar').hide()
-  $('.copyray-toggle-button').show()
-  $('.js-copy-tuner-bar-log-menu').hide()
-
-Copyray.createLogMenu = ->
-  $tbody = $('.js-copy-tuner-bar-log-menu__tbody.is-not-initialized')
-  return if $tbody.length == 0
-  $tbody.removeClass('is-not-initialized')
-  baseUrl = $('[data-copy-tuner-url]').data('copy-tuner-url')
-  log = $('[data-copy-tuner-translation-log').data('copy-tuner-translation-log')
-  keys = Object.keys(log).sort()
-  $.each keys, (_, k) ->
-    v = log[k]
-    if v != ''
-      url = "#{baseUrl}/blurbs/#{k}/edit"
-      $a = $("<a href='#{url}' class='js-copy-tuner-blurb-link'>").text k
-      $td1 = $('<td>').append $a
-      $td2 = $('<td>').text v
-      $tr = $("<tr class='copy-tuner-bar-log-menu__row js-copy-tuner-blurb-row'>")
-      $tr.append $td1, $td2
-      $tbody.append $tr
-  $tbody.on 'click', '.js-copy-tuner-blurb-link', (e) ->
-    e.preventDefault()
-  $tbody.on 'click', '.js-copy-tuner-blurb-row', ->
-    Copyray.open $(@).find('a').attr('href')
-
-Copyray.focusSearchBox = ->
-  $('.js-copy-tuner-bar-search').focus()
-
-Copyray.toggleLogMenu = ->
-  Copyray.createLogMenu()
-  $('.js-copy-tuner-bar-log-menu').toggle()
-
-$(document).on 'click', '.js-copy-tuner-bar-open-log', (e) ->
-  e.preventDefault()
-  Copyray.toggleLogMenu()
-
-do ->
-  timer = null
-  lastKeyword = ''
-  $(document).on 'focus', '.js-copy-tuner-bar-search', ->
-    lastKeyword = $(@).val()
-  $(document).on 'keyup', '.js-copy-tuner-bar-search', ->
-    keyword = $.trim($(@).val())
-    if lastKeyword != keyword
-      Copyray.toggleLogMenu() if !$('.js-copy-tuner-bar-log-menu').is(':visible')
-      clearTimeout(timer)
-      timer = setTimeout ->
-        if keyword == ''
-          $('.js-copy-tuner-blurb-row').show()
-        else
-          $('.js-copy-tuner-blurb-row').hide()
-          $(".js-copy-tuner-blurb-row td:contains(#{keyword})").closest('.js-copy-tuner-blurb-row').show()
-      , 500
-      lastKeyword = keyword
-