comfortable_mexican_sofa 2.0.12 → 2.0.13

data/app/assets/javascripts/comfy/admin/cms/application.js.coffee

@@ -1,30 +0,0 @@
-#= require rails-ujs
-#= require jquery3
-
-#= require comfy/vendor/codemirror
-#= require comfy/vendor/codemirror/mode/css/css
-#= require comfy/vendor/codemirror/mode/htmlmixed/htmlmixed
-#= require comfy/vendor/codemirror/mode/javascript/javascript
-#= require comfy/vendor/codemirror/mode/markdown/markdown
-#= require comfy/vendor/codemirror/mode/xml/xml
-#= require comfy/vendor/codemirror/addon/edit/closetag
-#= require comfy/vendor/sortable.min
-#= require comfy/vendor/popper.min
-#= require comfy/vendor/bootstrap.min
-#= require comfy/vendor/diff/diff_match_patch.min
-#= require comfy/vendor/diff/pretty_text_diff
-#= require comfy/vendor/fontawesome
-#= require comfy/vendor/redactor
-#= require comfy/vendor/redactor/filemanager
-#= require comfy/vendor/redactor/imagemanager
-#= require comfy/vendor/redactor/definedlinks
-#= require comfy/vendor/redactor/table
-#= require comfy/vendor/redactor/video
-#= require_directory ../../vendor/redactor/i18n/
-#= require comfy/vendor/flatpickr.min
-#= require_directory ../../vendor/flatpickr/i18n/
-
-#= require comfy/admin/cms/base
-#= require comfy/admin/cms/uploader
-#= require comfy/admin/cms/files
-#= require comfy/admin/cms/custom

data/app/assets/javascripts/comfy/admin/cms/base.js.coffee

@@ -1,224 +0,0 @@
-window.CMS ||= {}
-
-window.CMS.code_mirror_instances = [ ]
-
-unless Turbolinks?.controller? # Turbolinks 5 verification
-  $ -> window.CMS.init()
-
-$(document).on 'page:load turbolinks:load', -> window.CMS.init()
-
-window.CMS.init = ->
-  window.CMS.current_path = window.location.pathname
-  CMS.set_iframe_layout()
-  CMS.slugify()
-  CMS.wysiwyg()
-  CMS.codemirror()
-  CMS.sortable_list()
-  CMS.timepicker()
-  CMS.page_fragments()
-  CMS.page_file_popovers()
-  CMS.page_update_preview()
-  CMS.categories()
-  CMS.files()
-  CMS.upload_queue()
-  CMS.diff()
-
-
-window.CMS.upload_queue = ->
-  if $("#cms-uploader").length
-    uploader_url  = $("meta[name='cms-uploader-url']").attr("content")
-    token_name    = $("meta[name='cms-uploader-token-name']").attr("content")
-    token_value   = $("meta[name='cms-uploader-token-value']").attr("content")
-    session_name  = $("meta[name='cms-uploader-session-name']").attr("content")
-    session_value = $("meta[name='cms-uploader-session-value']").attr("content")
-
-    window.CMS.uploader $("#cms-uploader"),
-      url: uploader_url,
-      multipart_params:
-        "#{token_name}": token_value,
-        "#{session_name}": session_value
-
-
-window.CMS.slugify = ->
-  slugify = (str) ->
-    # Trim string and lower case.
-    str = str.replace(/^\s+|\s+$/g, '').toLowerCase()
-
-    # Replace special chars.
-    replacements = [
-      ['à', 'a'],
-      ['á', 'a'],
-      ['ä', 'ae'],
-      ['â', 'a'],
-      ['ã', 'a'],
-      ['è', 'e'],
-      ['é', 'e'],
-      ['ë', 'e'],
-      ['ê', 'e'],
-      ['ì', 'i'],
-      ['í', 'i'],
-      ['ï', 'i'],
-      ['î', 'i'],
-      ['ò', 'o'],
-      ['ó', 'o'],
-      ['ö', 'oe'],
-      ['ô', 'o'],
-      ['õ', 'o'],
-      ['ù', 'u'],
-      ['ú', 'u'],
-      ['ü', 'ue'],
-      ['û', 'u'],
-      ['ñ', 'n'],
-      ['ç', 'c'],
-      ['ß', 'ss'],
-      ['·', '-'],
-      ['/', '-'],
-      [',', '-'],
-      [':', '-'],
-      [';', '-'],
-      ['_', '-'],
-      [' ', '-'],
-    ]
-
-    for replacement in replacements
-      str = str.replace(new RegExp(replacement[0], 'g'), replacement[1])
-
-    # Remove any other URL incompatible characters and replace multiple dashes with just a single one.
-    str = str.replace(/[^a-z0-9-]/g, '').replace(/-+/g, '-')
-
-  $('input[data-slugify=true]').bind 'keyup.cms', ->
-    $('input[data-slug=true]').val(slugify($(this).val()))
-
-
-window.CMS.wysiwyg = ->
-  csrf_token = $('meta[name=csrf-token]').attr('content')
-  csrf_param = $('meta[name=csrf-param]').attr('content')
-
-  if (csrf_param != undefined && csrf_token != undefined)
-    params = csrf_param + "=" + encodeURIComponent(csrf_token)
-
-  file_upload_path  = $("meta[name='cms-file-upload-path']").attr("content")
-  pages_path        = $("meta[name='cms-pages-path']").attr("content")
-
-  $('textarea.rich-text-editor, textarea[data-cms-rich-text]').redactor
-    minHeight:        160
-    autoresize:       true
-    imageUpload:      "#{file_upload_path}?source=redactor&type=image&#{params}"
-    imageManagerJson: "#{file_upload_path}?source=redactor&type=image"
-    fileUpload:       "#{file_upload_path}?source=redactor&type=file&#{params}"
-    fileManagerJson:  "#{file_upload_path}?source=redactor&type=file"
-    definedLinks:     "#{pages_path}?source=redactor"
-    buttonSource:     true
-    formatting:       ['p', 'h1', 'h2', 'h3', 'h4', 'h5', 'h6']
-    plugins:          ['imagemanager', 'filemanager', 'table', 'video', 'definedlinks']
-    lang:             $("meta[name='cms-locale']").attr("content")
-    convertDivs:      false
-
-
-window.CMS.codemirror = ->
-  $('textarea[data-cms-cm-mode]').each (i, element) ->
-    cm = CodeMirror.fromTextArea element,
-      mode:           $(element).data('cms-cm-mode')
-      tabSize:        2
-      lineWrapping:   true
-      autoCloseTags:  true
-      lineNumbers:    true
-      viewportMargin: Infinity
-
-    CMS.code_mirror_instances.push(cm)
-
-  $('a[data-toggle="tab"]').on 'shown.bs.tab', ->
-    for cm in CMS.code_mirror_instances
-      cm.refresh()
-
-
-window.CMS.sortable_list = ->
-  dataIdAttr = 'data-id'
-  sortableStore =
-    get: (sortable) ->
-      Array::map.call sortable.el.children, (el) -> el.getAttribute(dataIdAttr)
-    set: (sortable) ->
-      $.ajax
-        url:      "#{CMS.current_path}/reorder"
-        type:     'POST'
-        dataType: 'json'
-        data:
-          order:    sortable.toArray()
-          _method:  'PUT'
-
-  for root in document.querySelectorAll('.sortable')
-    Sortable.create root,
-      handle:     '.dragger'
-      draggable:  'li'
-      dataIdAttr: dataIdAttr
-      store:      sortableStore
-      onStart:    (evt) -> evt.from.classList.add('sortable-active')
-      onEnd:      (evt) -> evt.from.classList.remove('sortable-active')
-
-
-window.CMS.timepicker = ->
-  $('input[type=text][data-cms-datetime]').flatpickr
-    format:     'yyyy-mm-dd hh:ii'
-    enableTime: true
-    locale:     $("meta[name='cms-locale']").attr("content")
-
-  $('input[type=text][data-cms-date]').flatpickr
-    format: 'yyyy-mm-dd',
-    locale: $("meta[name='cms-locale']").attr("content")
-
-
-window.CMS.page_fragments = ->
-  $('select#fragments-toggle').bind 'change.cms', ->
-    $.ajax
-      url: $(this).data('url'),
-      data:
-        layout_id: $(this).val()
-      complete: ->
-        CMS.wysiwyg()
-        CMS.timepicker()
-        CMS.codemirror()
-        CMS.page_file_popovers()
-
-
-window.CMS.page_file_popovers = ->
-  $('[data-toggle="page-file-popover"]').popover
-    trigger:    'hover'
-    placement:  'top'
-    html:       true
-
-
-window.CMS.page_update_preview = ->
-  $('input[name=commit]').click ->
-    $(this).parents('form').attr('target', '')
-  $('input[name=preview]').click ->
-    $(this).parents('form').attr('target', 'comfy-cms-preview')
-
-
-window.CMS.categories = ->
-  $('button.toggle-cat-edit', '.categories-widget').click (event) ->
-    event.preventDefault()
-    $('.read', '.categories-widget').toggle()
-    $('.editable', '.categories-widget').toggle()
-    $('.edit', '.categories-widget').toggle()
-    $('.done', '.categories-widget').toggle()
-
-
-window.CMS.diff = ->
-  $(".revision").prettyTextDiff
-    cleanup:            true
-    originalContainer:  '.original'
-    changedContainer:   '.current'
-    diffContainer:      '.diff .content'
-
-# If we are inside an iframe remove the columns and just keep the center column content.
-# This is used for the files widget that opens in a modal window.
-window.CMS.set_iframe_layout = ->
-  in_iframe = ->
-    try
-      return window.self != window.top
-    catch e
-      return true
-
-  $('body').ready ->
-    if in_iframe()
-      $('body').addClass('in-iframe')

data/app/assets/javascripts/comfy/admin/cms/custom.js.coffee

@@ -1 +0,0 @@
-# Custom JS for the admin area

data/app/assets/javascripts/comfy/admin/cms/files.js.coffee

@@ -1,29 +0,0 @@
-(($) ->
-  window.CMS or (window.CMS = {})
-  window.CMS.files = ->
-    modal = $('.cms-files-modal')
-    $('.cms-files-open-modal').on 'click', (e) ->
-      modal.on 'show.bs.modal', ->
-        iframe    = modal.find('iframe')
-        iframeSrc = modal.data('iframe-src')
-        if iframe.attr('src') != iframeSrc
-          iframe.attr('src', iframeSrc)
-
-      modal.modal(show: true)
-      e.preventDefault()
-
-    # Make the files library modal window fill the browsers available height.
-    modal.on 'show.bs.modal', (e) ->
-      height = $(window).height() - 60
-      $(e.target).find('.modal-content').css('height', "#{height}px")
-
-    $(window).on 'resize', ->
-      height = $(window).height() - 60
-      modal.find('.modal-content').css('height', "#{height}px")
-
-    # When clicking a file path in the file list select it to make
-    # it easy to copy&paste.
-    $(document).on 'click', '.cms-uploader-filelist input[type=text]', ->
-      $(this).select()
-
-) jQuery

data/app/assets/javascripts/comfy/admin/cms/uploader.js.coffee

@@ -1,140 +0,0 @@
-# CMS Uploader using plupload http://www.plupload.com/. Code inspired by
-# plupload queue widget https://github.com/moxiecode/plupload/tree/master/js/jquery.plupload.queue
-#
-#= require comfy/vendor/moxie.min
-#= require comfy/vendor/plupload.dev
-
-(($, o) ->
-  window.CMS or (window.CMS = {})
-  window.CMS.uploader = (target, settings) ->
-
-    # Add a file to the file list.
-    addFile = (file) ->
-      fileList = $(".cms-uploader-filelist", target)
-
-      fileList.prepend("
-        <li id='#{file.id}' class='row temp'>
-          <div class='col-md-9 d-flex align-items-center'>
-            <div class='progress'>
-              <div class='progress-bar progress-bar-striped progress-bar-animated'>
-                <span>#{file.name}</span>
-              </div>
-            </div>
-          </div>
-          <div class='col-md-3 d-flex align-items-center justify-content-md-end'>
-            <a class='btn btn-sm btn-danger float-right cms-uploader-file-delete' href='#'>Delete</a>
-          </div>
-        </li>
-      ")
-
-      $("#" + file.id + " a.cms-uploader-file-delete").click (e) ->
-        uploader.removeFile(file)
-        e.preventDefault()
-
-      updateFileStatus(file)
-
-    # Remove a file from the file list.
-    removeFile = (file) ->
-      $("#" + file.id).remove()
-
-    # Update a files upload status in the file list.
-    updateFileStatus = (file) ->
-      progress_bar = $("##{file.id} .progress-bar", target)
-      if file.status == plupload.UPLOADING
-        progress_bar.css('width', "#{file.percent}%")
-      if file.status == plupload.FAILED
-        progress_bar.css('width', '100%').addClass('progress-bar-danger')
-        $('span', progress_bar).html(file.error_message)
-
-    uploader = undefined
-    id      = target.attr("id")
-
-    unless id
-      id = plupload.guid()
-      target.attr('id', id)
-
-    settings = $.extend(
-      runtimes:       "html5,browserplus,silverlight,flash,gears"
-      dragdrop:       true
-      drop_element:   "#{id}-drag-drop-target"
-      browse_button:  "#{id}-browse"
-      container:      id
-      file_data_name: "file[file]"
-    , settings)
-
-    uploader = new plupload.Uploader(settings)
-    uploader.bind "PostInit", (up) ->
-
-      # Show drag and drop info and attach events if drag and drop is
-      # supported and enabled.
-      if up.settings.dragdrop and up.features.dragdrop
-        dropElement = $(up.settings.drop_element).get(0)
-
-        # When dragging over the document add a class to the drop target
-        # that puts it ontop of every element and remove that class when
-        # dropping or leaving the drop target. Otherwise the dragleave
-        # event would fire whenever we dragging over a child element inside
-        # the drop target such as text nodes or stuff.
-        activeClass = 'cms-uploader-drag-drop-target-active'
-        document.addEventListener 'dragenter', (e) ->
-          # Only react to drag'n'drops that contain a file. See:
-          # https://developer.mozilla.org/en-US/docs/Web/API/DataTransfer/types
-          if e.dataTransfer.types.indexOf('Files') != -1
-            dropElement.classList.add(activeClass)
-        for eventName in ['drop', 'dragleave']
-          dropElement.addEventListener eventName, ->
-            dropElement.classList.remove(activeClass)
-
-      else
-        $('.cms-uploader-drag-drop-info', target).hide()
-
-    # Need to bind this before initialization to handle initialization errors too.
-    uploader.bind 'Error', (up, err) ->
-      file    = err.file
-      message = undefined
-
-      if file
-        # Get error message from the server response. Not all runtimes
-        # support this though.
-        message = err.response
-
-        # If no error message is in the server response get standard
-        # plupload error messages. This will have descriptive error message
-        # for something like file size or file format errors but for
-        # server errors it will only display a general error message.
-        unless message
-          message = err.message
-          if err.details
-            message += " (#{err.details})"
-        file.status = plupload.FAILED
-        file.error_message = message
-        updateFileStatus file
-
-      if err.code == plupload.INIT_ERROR
-        alert _('Error: Initialisation error. Reload to try again.')
-
-    uploader.init()
-    uploader.bind 'FilesAdded', (up, files) ->
-      $.each files, (i, file) ->
-        addFile file
-
-      # Auto start upload when files are added.
-      uploader.start()
-
-    uploader.bind 'UploadProgress', (up, file) ->
-      updateFileStatus(file)
-
-    uploader.bind "FileUploaded", (up, file, info) ->
-      # Replace the dummy file entry in the file list with the the entry
-      # from the server response.
-      $("li##{file.id}").replaceWith(info.response)
-
-    uploader.bind 'FilesRemoved', (up, files) ->
-      $.each files, (i, file) ->
-        removeFile file
-
-    # Call setup function
-    if settings.setup
-      settings.setup(uploader)
-
-) jQuery, plupload

data/app/views/comfy/admin/cms/files/create.js.erb

@@ -1 +0,0 @@
-$("<%= escape_javascript(render :partial => 'file', :object => @file) %>").appendTo(".cms-uploader-filelist");

data/app/views/comfy/admin/cms/files/destroy.js.coffee

@@ -1,2 +0,0 @@
-$("li[data-id=<%= @file.id %>]").fadeOut 'slow', ->
-  $(this).remove()

data/app/views/comfy/admin/cms/pages/form_fragments.js.erb

@@ -1 +0,0 @@
-$('#form-fragments').replaceWith('<%= escape_javascript(render("comfy/admin/cms/fragments/form_fragments", record: @page)) %>');

data/app/views/comfy/admin/cms/translations/form_fragments.js.erb

@@ -1 +0,0 @@
-$('#form-fragments').replaceWith('<%= escape_javascript(render("comfy/admin/cms/fragments/form_fragments", record: @translation)) %>');