cmsimple 0.2.0

data/app/assets/javascripts/cmsimple/mercury/handlers.coffee

@@ -0,0 +1,9 @@
+jQuery(window).bind 'mercury:ready', ->
+  Mercury.modalHandlers.editMetadata = ->
+    new CMSimple.Panels.PageMetadata(@element, @, 'edit')
+
+  Mercury.modalHandlers.newPage = ->
+    new CMSimple.Panels.PageMetadata(@element, @, 'new')
+
+  Mercury.modalHandlers.publish = ->
+    new CMSimple.Panels.Publish(@element, @)

data/app/assets/javascripts/cmsimple/models/image.coffee

@@ -0,0 +1,49 @@
+class CMSimple.Image extends Spine.Model
+  @configure 'Image', 'attachment', 'width', 'height', 'content_type', 'file_size', 'created_at'
+  @extend Spine.Model.Ajax
+
+  @url: '/cmsimple/images'
+
+
+  @allWithinGeometry: (query)->
+    geometry = new CMSimple.Image.Geometry(query)
+    @select (item)->
+      geometry.inRange item.width, item.height
+
+
+# 500x200
+# <800x<800
+# >100x>300
+
+class CMSimple.Image.Geometry
+  constructor: (@query)->
+    @parse()
+
+  parse: ->
+    return unless @query
+    [width, height] = @query?.split('x')
+    @widthQualifier = width?.match(/[\<|\>]/)?[0]
+    @heightQualifier = height?.match(/[\<|\>]/)?[0]
+    @width = parseInt(width?.replace(/\D/, ''), 10)
+    @height = parseInt(height?.replace(/\D/, ''), 10)
+
+  inRange: (width, height)->
+    @widthQualifies(width) and @heightQualifies(height)
+
+  widthQualifies: (width)->
+    @qualifiedDimension width, @width, @widthQualifier
+
+  heightQualifies: (height)->
+    @qualifiedDimension height, @height, @heightQualifier
+
+  qualifiedDimension: (input, dimension, qualifier)->
+    return true unless dimension
+    input = parseInt(input, 10)
+    switch qualifier
+      when '<'
+        input <= dimension
+      when '>'
+        input >= dimension
+      else
+        input is dimension
+

data/app/assets/javascripts/cmsimple/models/page.coffee

@@ -0,0 +1,106 @@
+class CMSimple.Page extends Spine.Model
+  @configure 'Page', 'template', 'title', 'parent_id', 'position', 'slug', 'is_root', 'browser_title', 'keywords', 'description', 'published', 'unpublished_changes', 'uri'
+  @extend Spine.Model.Ajax
+
+  @belongsTo 'parent', 'CMSimple.Page', 'parent_id'
+  @hasMany 'children', 'CMSimple.Page', 'parent_id'
+
+  @roots: ->
+    pages = @select (page)-> not page.parent_id
+    _(pages).sortBy (record)-> record.position
+
+  @forPath: (path)->
+    _(@select (page)-> page.path() is path).first()
+
+  @updatePositions: (ids, options={})->
+    for id in ids
+      position = ids.indexOf(id)
+      page = CMSimple.Page.find(id)
+      if page.position isnt position
+        page.updateAttributes(position: position)
+
+  snippets: ->
+    _(@content).reduce ((memo, region)-> _.extend(memo, region.snippets)), {}
+
+  sortedChildren: ->
+    _(@children().all()).sortBy (record)-> record.position
+
+  hasChildren: ->
+    @children().all().length > 0
+
+  publishedState: ->
+    if @published
+      if @unpublished_changes
+        'has-changes'
+      else
+        'published'
+    else
+      'unpublished'
+
+  versions: ->
+    CMSimple.Version.allForPage(@)
+
+  fromForm: (form)->
+    values = form.toJSON()
+    values = values.page if values.page
+    #fix for views depending on realtime change events of children
+    values.parent_id = parseInt(values.parent_id, 0) if values.parent_id
+    @load(values)
+
+  reinflate: @::reload
+
+  reload: ->
+    @constructor.fetch
+      id: @id
+      success: => @trigger 'reload'
+
+  editPath: ->
+    "/editor#{@path()}"
+
+  isRoot: ->
+    # handle the form values pre refresh from server
+    @is_root is true or @is_root is '1'
+
+  load: (values)->
+    values = @normalizeSlug(values)
+    super(values)
+
+  path: (options={})->
+    return '/' if (not options.ignoreRoot) && @isRoot()
+
+    # if we have a client side parent compute the path
+    if @parent()
+      parent_path =  @parent().path(ignoreRoot: true)
+      path = [parent_path, @slug].join('/')
+
+    # if the parent isn't loaded fall back to the uri
+    else if @parent_id
+      path = @uri
+
+    # otherwise just use the slug
+    else
+      path = "/#{@slug}"
+
+    path = path.replace(/\/+/, '/')
+    path = path.replace(/\/$/, '')
+    path
+
+  normalizeSlug: (values)->
+    return values unless values.title
+
+    if Spine.isBlank(values.slug) && Spine.isBlank(@slug)
+      values.slug = values.title
+
+    unless Spine.isBlank(values.slug)
+      values.slug = @escape(values.slug)
+
+    return values
+
+  escape: (string)->
+    return '' unless string
+    string = string.replace(/[^\x00-\x7F]+/g, '') # Remove anything non-ASCII entirely (e.g. diacritics).
+    string = string.replace(/[^\w_ \-]+/ig, '') # Remove unwanted chars.
+    string = string.replace(/[ \-]+/ig, '-') # No more than one of the separator in a row.
+    string = string.replace(/^\-|\-$/ig, '') # Remove leading/trailing separator.
+    string.toLowerCase()
+

data/app/assets/javascripts/cmsimple/models/path.coffee

@@ -0,0 +1,31 @@
+class CMSimple.Path extends Spine.Model
+  @configure 'Path', 'uri', 'redirect_uri', 'page_id', 'updated_at', 'created_at'
+  @extend Spine.Model.Ajax
+
+  @belongsTo 'page', 'CMSimple.Page', 'page_id'
+
+  @allRedirects: ->
+    results = @select (item)->
+      not (item.page() && item.page().isRoot()) && item.uri isnt item.destinationPath()
+    _(results).sortBy (item)-> item.uri
+
+  uriIsUnique: ->
+    not _(@constructor.all()).any (path)=>
+      path.uri is @uri and not @eql(path)
+
+  validate: ->
+    unless @uri
+      return "Source URL is required"
+
+    unless @uriIsUnique()
+      return "Source URL must be unique"
+
+    unless @redirect_uri || @page_id
+      return "Destination redirect URL is required"
+
+    return null
+
+  destinationPath: ->
+    if @page() then @page().path() else @redirect_uri
+
+

data/app/assets/javascripts/cmsimple/models/version.coffee

@@ -0,0 +1,29 @@
+class CMSimple.Version extends Spine.Model
+  @configure 'Version', 'template', 'content', 'published_at', 'updated_at', 'created_at'
+  @extend Spine.Model.Ajax
+
+  @belongsTo 'page', 'CMSimple.Page', 'page_id'
+
+  @fetch: (page, params={})->
+    throw 'CMSimple.Page instance required to fetch versions' unless page
+    url = page.url('versions')
+    super _.extend {url: url}, params
+
+  @allForPage: (page)->
+    results = @select (item)-> item.page().id is page.id
+    (_(results).sortBy (item)-> moment(item.published_at)).reverse()
+
+  url: (args...) ->
+    args.unshift @page().url('versions', @id)
+    args.join('/')
+
+  revertTo: ->
+    $.ajax
+      type: 'PUT'
+      url: @url('revert_to'),
+      success: =>
+        @page().reload()
+      error: ->
+        console?.log 'error', arguments
+        alert('There was an error reverting to the requested version')
+

data/app/assets/javascripts/cmsimple/panels/images/index.coffee

@@ -0,0 +1,2 @@
+#= require cmsimple/lib/namespaces
+#= require ./panel

data/app/assets/javascripts/cmsimple/panels/images/list.coffee

@@ -0,0 +1,48 @@
+#= require cmsimple/models/image
+
+#= require cmsimple/views/image_library/_item
+
+class CMSimple.Panels.ImageLibrary.List extends Spine.Controller
+  events:
+    'click .media-actions > .info' : 'toggleInfo'
+    'click .media-info > .close' : 'toggleInfo'
+    'click [data-full-url]' : 'triggerImage'
+    'click .delete' : 'deleteImage'
+
+  constructor: (el)->
+    super el: $(el)
+
+    CMSimple.Image.bind 'refresh change', => @render()
+
+  render: ->
+    @html('')
+    @addImage image for image in CMSimple.Image.all()
+
+  filterByGeometry: (geometry)->
+    @html('')
+    @addImage image for image in CMSimple.Image.allWithinGeometry(geometry)
+
+  addImage: (image)->
+    @append JST['cmsimple/views/image_library/_item'](image)
+
+  toggleInfo: (e) ->
+    e.preventDefault()
+    info = $(e.target).parents('li').first().find('.media-info')[0]
+    $(info).toggleClass('active')
+
+  triggerImage: (e)->
+    img = $(e.target)
+    image = CMSimple.Image.find(img.data('id'))
+    @trigger 'image:selected',
+        src: img.data('full-url'),
+        alt: image.title,
+        'image-id': image.id
+
+  deleteImage: (e)->
+    e.preventDefault()
+    link = $(e.target)
+    if confirm 'Are you sure you would like to delete this image?'
+      id = link.parents('[data-id]').data('id')
+      image = CMSimple.Image.find(id)
+      image.destroy()
+

data/app/assets/javascripts/cmsimple/panels/images/panel.coffee

@@ -0,0 +1,69 @@
+#= require_self
+#= require cmsimple/models/image
+#= require cmsimple/panels/images/list
+#= require cmsimple/panels/images/selection
+
+#= require cmsimple/views/image_library/list
+#= require cmsimple/views/image_library/_item
+
+class CMSimple.Panels.ImageLibrary extends Mercury.Panel
+
+  constructor: ()->
+    super(null, 'insertMedia', title: 'Image Library', appendTo: '.mercury-toolbar-container', closeButton: true)
+    @button = $('.mercury-insertMedia-button')
+    @loadContent JST['cmsimple/views/image_library/list']()
+
+    @list = new CMSimple.Panels.ImageLibrary.List($('ul.media-grid'))
+    @selection = new CMSimple.Panels.ImageLibrary.Selection()
+
+    @bindPanelEvents()
+
+
+  toggle: ->
+    super
+    if @visible
+      CMSimple.Image.fetch()
+      @resize()
+
+
+  bindPanelEvents: ->
+    $('#add_image', @element).on('click', @toggleUploader)
+    $('.image-filter', @element).on('submit', @filterImages)
+    $(window).bind 'cmsimple:images:uploaded', => @imageUploaded()
+
+    @list.bind 'image:selected', (img)=>
+      @selection.set(img)
+
+    @selection.bind 'filter', (geometry)=>
+      @list.filterByGeometry(geometry)
+      $('.filter', @element).val(geometry)
+
+
+  toggleUploader: (e) ->
+    target = $(e.target)
+    form = $('.add-image-action', @element)
+    form.toggleClass('active')
+    if form.hasClass('active')
+      target.text('Cancel')
+    else
+      target.text('Add Image')
+
+
+  imageUploaded: ->
+    CMSimple.Image.fetch()
+    @closeUploader()
+
+
+  closeUploader: ->
+    $('#add_image', @element).text('Add Image')
+    $('.add-image-action', @element).removeClass('active')
+
+
+  filterImages: (e)=>
+    e.preventDefault()
+    query = $(e.target).find('input.filter').val()
+    if Spine.isBlank(query)
+      @list.render()
+    else
+      @list.filterByGeometry(query)
+

data/app/assets/javascripts/cmsimple/panels/images/selection.coffee

@@ -0,0 +1,52 @@
+class CMSimple.Panels.ImageLibrary.Selection extends Spine.Controller
+  constructor: ->
+    super
+    @bindEvents()
+
+
+  set: (img)->
+    if @selectedImage
+      @selectedImage.attr('src', img.src)
+      @selectedImage.attr('alt', img.alt)
+      snippet = Mercury.Snippet.find @selectedImage.parents('[data-snippet]').data('snippet')
+      snippet.options.snippet[@selectedImage.data('snippet-image')] = img.src
+
+    else if @region.type() is 'full'
+      options = {value: img}
+      @region.execCommand 'insertImage', options
+
+
+  clearSelection: ->
+    if @selectedImage
+      @selectedImage.removeClass('selected-image')
+      @selectedImage = null
+      @trigger 'filter', null
+
+
+  setSelection: (el)->
+    @selectedImage?.removeClass('selected-image')
+    @selectedImage = el
+    @selectedImage.addClass('selected-image')
+    if geometry = @selectedImage.data('image-geometry')
+      @trigger 'filter', geometry
+
+
+  bindEvents: ->
+    Mercury.on 'region:focused', (event, options) =>
+      @bindRegion(options.region)
+
+
+  bindRegion: (region)->
+    _clearSelection = => @clearSelection()
+    if @region
+      # unbind current region if user selected a new region
+      @region.element.off 'click', _clearSelection
+      @region.element.find('[data-snippet-image]').off('click')
+
+    if @region = region
+      @region.element.on 'click', _clearSelection
+      @region.element.find('[data-snippet-image]').on 'click', (e)=>
+        e.stopPropagation()
+        @setSelection($(e.target))
+
+

data/app/assets/javascripts/cmsimple/panels/page_metadata.coffee

@@ -0,0 +1,42 @@
+#= require cmsimple/models/page
+
+class CMSimple.Panels.PageMetadata extends Spine.Controller
+
+  elements:
+    'form' : 'form'
+    '.mercury-modal-content' : 'content'
+
+  events:
+    'submit form' : 'submit'
+
+  constructor: (container, @modal, @action)->
+    super el: container
+    @el.off 'ajax:beforeSend'
+
+  submit: (e)->
+    e.preventDefault()
+    @page = @pageForAction().fromForm(@form)
+    @page.save
+      ajax:
+        error: @proxy @error
+      success: @proxy @success
+
+  pageForAction: ->
+    if @action is 'edit'
+      CMSimple.Editor.current_page
+    else
+      CMSimple.Page
+
+  success: ->
+    @modal.hide()
+    Mercury.silent = true
+
+    if @action is 'edit'
+      @page.reload()
+    else
+      @navigate @page.editPath()
+
+  error: (event, data)->
+    @content.html event.responseText
+    alert('Please fill in the required fields.')
+