chosen-rails-adding 1.0.2.1

data/vendor/assets/javascripts/lib/abstract-chosen.coffee

@@ -0,0 +1,282 @@
+class AbstractChosen
+
+  constructor: (@form_field, @options={}) ->
+    return unless AbstractChosen.browser_is_supported()
+    @is_multiple = @form_field.multiple
+    this.set_default_text()
+    this.set_default_values()
+
+    this.setup()
+
+    this.set_up_html()
+    this.register_observers()
+
+  set_default_values: ->
+    @click_test_action = (evt) => this.test_active_click(evt)
+    @activate_action = (evt) => this.activate_field(evt)
+    @active_field = false
+    @mouse_on_container = false
+    @results_showing = false
+    @result_highlighted = null
+    @allow_single_deselect = if @options.allow_single_deselect? and @form_field.options[0]? and @form_field.options[0].text is "" then @options.allow_single_deselect else false
+    @disable_search_threshold = @options.disable_search_threshold || 0
+    @disable_search = @options.disable_search || false
+    @enable_split_word_search = if @options.enable_split_word_search? then @options.enable_split_word_search else true
+    @group_search = if @options.group_search? then @options.group_search else true
+    @search_contains = @options.search_contains || false
+    @single_backstroke_delete = if @options.single_backstroke_delete? then @options.single_backstroke_delete else true
+    @max_selected_options = @options.max_selected_options || Infinity
+    @inherit_select_classes = @options.inherit_select_classes || false
+    @display_selected_options = if @options.display_selected_options? then @options.display_selected_options else true
+    @display_disabled_options = if @options.display_disabled_options? then @options.display_disabled_options else true
+    @create_option = @options.create_option || false
+    @persistent_create_option = @options.persistent_create_option || false
+    @skip_no_results = @options.skip_no_results || false
+
+  set_default_text: ->
+    if @form_field.getAttribute("data-placeholder")
+      @default_text = @form_field.getAttribute("data-placeholder")
+    else if @is_multiple
+      @default_text = @options.placeholder_text_multiple || @options.placeholder_text || AbstractChosen.default_multiple_text
+    else
+      @default_text = @options.placeholder_text_single || @options.placeholder_text || AbstractChosen.default_single_text
+
+    @results_none_found = @form_field.getAttribute("data-no_results_text") || @options.no_results_text || AbstractChosen.default_no_result_text
+    @create_option_text = @form_field.getAttribute("data-create_option_text") || @options.create_option_text || AbstractChosen.default_create_option_text
+
+  mouse_enter: -> @mouse_on_container = true
+  mouse_leave: -> @mouse_on_container = false
+
+  input_focus: (evt) ->
+    if @is_multiple
+      setTimeout (=> this.container_mousedown()), 50 unless @active_field
+    else
+      @activate_field() unless @active_field
+
+  input_blur: (evt) ->
+    if not @mouse_on_container
+      @active_field = false
+      setTimeout (=> this.blur_test()), 100
+
+  results_option_build: (options) ->
+    content = ''
+    for data in @results_data
+      if data.group
+        content += this.result_add_group data
+      else
+        content += this.result_add_option data
+
+      # this select logic pins on an awkward flag
+      # we can make it better
+      if options?.first
+        if data.selected and @is_multiple
+          this.choice_build data
+        else if data.selected and not @is_multiple
+          this.single_set_selected_text(data.text)
+
+    content
+
+  result_add_option: (option) ->
+    return '' unless option.search_match
+    return '' unless this.include_option_in_results(option)
+
+    classes = []
+    classes.push "active-result" if !option.disabled and !(option.selected and @is_multiple)
+    classes.push "disabled-result" if option.disabled and !(option.selected and @is_multiple)
+    classes.push "result-selected" if option.selected
+    classes.push "group-option" if option.group_array_index?
+    classes.push option.classes if option.classes != ""
+
+    option_el = document.createElement("li")
+    option_el.className = classes.join(" ")
+    option_el.style.cssText = option.style
+    option_el.setAttribute("data-option-array-index", option.array_index)
+    option_el.innerHTML = option.search_text
+
+    this.outerHTML(option_el)
+
+  result_add_group: (group) ->
+    return '' unless group.search_match || group.group_match
+    return '' unless group.active_options > 0
+
+    group_el = document.createElement("li")
+    group_el.className = "group-result"
+    group_el.innerHTML = group.search_text
+
+    this.outerHTML(group_el)
+
+  append_option: (option) ->
+    this.select_append_option(option)
+
+  results_update_field: ->
+    this.set_default_text()
+    this.results_reset_cleanup() if not @is_multiple
+    this.result_clear_highlight()
+    this.results_build()
+    this.winnow_results() if @results_showing
+
+  reset_single_select_options: () ->
+    for result in @results_data
+      result.selected = false if result.selected
+
+  results_toggle: ->
+    if @results_showing
+      this.results_hide()
+    else
+      this.results_show()
+
+  results_search: (evt) ->
+    if @results_showing
+      this.winnow_results()
+    else
+      this.results_show()
+
+  winnow_results: ->
+    this.no_results_clear()
+
+    results = 0
+    exact_result = false
+
+    searchText = this.get_search_text()
+    escapedSearchText = searchText.replace(/[-[\]{}()*+?.,\\^$|#\s]/g, "\\$&")
+    regexAnchor = if @search_contains then "" else "^"
+    regex = new RegExp(regexAnchor + escapedSearchText, 'i')
+    zregex = new RegExp(escapedSearchText, 'i')
+    eregex = new RegExp('^' + escapedSearchText + '$', 'i')
+
+    for option in @results_data
+
+      option.search_match = false
+      results_group = null
+
+      if this.include_option_in_results(option)
+
+        if option.group
+          option.group_match = false
+          option.active_options = 0
+
+        if option.group_array_index? and @results_data[option.group_array_index]
+          results_group = @results_data[option.group_array_index]
+          results += 1 if results_group.active_options is 0 and results_group.search_match
+          results_group.active_options += 1
+                
+        unless option.group and not @group_search
+
+          option.search_text = if option.group then option.label else option.html
+          option.search_match = this.search_string_match(option.search_text, regex)
+          results += 1 if option.search_match and not option.group
+
+          exact_result = eregex.test option.html
+
+          if option.search_match
+            if searchText.length
+              startpos = option.search_text.search zregex
+              text = option.search_text.substr(0, startpos + searchText.length) + '</em>' + option.search_text.substr(startpos + searchText.length)
+              option.search_text = text.substr(0, startpos) + '<em>' + text.substr(startpos)
+
+            results_group.group_match = true if results_group?
+          
+          else if option.group_array_index? and @results_data[option.group_array_index].search_match
+            option.search_match = true
+
+    this.result_clear_highlight()
+
+    if results < 1 and searchText.length
+      this.update_results_content ""
+      this.no_results searchText unless @create_option and @skip_no_results
+    else
+      this.update_results_content this.results_option_build()
+      this.winnow_results_set_highlight()
+
+    if @create_option and (results < 1 or (!exact_result and @persistent_create_option)) and searchText.length
+      this.show_create_option( searchText )
+
+  search_string_match: (search_string, regex) ->
+    if regex.test search_string
+      return true
+    else if @enable_split_word_search and (search_string.indexOf(" ") >= 0 or search_string.indexOf("[") == 0)
+      #TODO: replace this substitution of /\[\]/ with a list of characters to skip.
+      parts = search_string.replace(/\[|\]/g, "").split(" ")
+      if parts.length
+        for part in parts
+          if regex.test part
+            return true
+
+  choices_count: ->
+    return @selected_option_count if @selected_option_count?
+
+    @selected_option_count = 0
+    for option in @form_field.options
+      @selected_option_count += 1 if option.selected
+    
+    return @selected_option_count
+
+  choices_click: (evt) ->
+    evt.preventDefault()
+    this.results_show() unless @results_showing or @is_disabled
+
+  keyup_checker: (evt) ->
+    stroke = evt.which ? evt.keyCode
+    this.search_field_scale()
+
+    switch stroke
+      when 8
+        if @is_multiple and @backstroke_length < 1 and this.choices_count() > 0
+          this.keydown_backstroke()
+        else if not @pending_backstroke
+          this.result_clear_highlight()
+          this.results_search()
+      when 13
+        evt.preventDefault()
+        this.result_select(evt) if this.results_showing
+      when 27
+        this.results_hide() if @results_showing
+        return true
+      when 9, 38, 40, 16, 91, 17
+        # don't do anything on these keys
+      else this.results_search()
+
+  container_width: ->
+    return if @options.width? then @options.width else "#{@form_field.offsetWidth}px"
+
+  include_option_in_results: (option) ->
+    return false if @is_multiple and (not @display_selected_options and option.selected)
+    return false if not @display_disabled_options and option.disabled
+    return false if option.empty
+
+    return true
+
+  search_results_touchstart: (evt) ->
+    @touch_started = true
+    this.search_results_mouseover(evt)
+
+  search_results_touchmove: (evt) ->
+    @touch_started = false
+    this.search_results_mouseout(evt)
+
+  search_results_touchend: (evt) ->
+    this.search_results_mouseup(evt) if @touch_started
+
+  outerHTML: (element) ->
+    return element.outerHTML if element.outerHTML
+    tmp = document.createElement("div")
+    tmp.appendChild(element)
+    tmp.innerHTML
+
+  # class methods and variables ============================================================ 
+
+  @browser_is_supported: ->
+    if window.navigator.appName == "Microsoft Internet Explorer"
+      return document.documentMode >= 8
+    if /iP(od|hone)/i.test(window.navigator.userAgent)
+      return false
+    if /Android/i.test(window.navigator.userAgent)
+      return false if /Mobile/i.test(window.navigator.userAgent)
+    return true
+
+  @default_multiple_text: "Select Some Options"
+  @default_single_text: "Select an Option"
+  @default_no_result_text: "No results match"
+  @default_create_option_text: "Add Option"
+
+window.AbstractChosen = AbstractChosen

data/vendor/assets/javascripts/lib/select-parser.coffee

@@ -0,0 +1,66 @@
+class SelectParser
+
+  constructor: ->
+    @options_index = 0
+    @parsed = []
+
+  add_node: (child) ->
+    if child.nodeName.toUpperCase() is "OPTGROUP"
+      this.add_group child
+    else
+      this.add_option child
+
+  add_group: (group) ->
+    group_position = @parsed.length
+    @parsed.push
+      array_index: group_position
+      group: true
+      label: this.escapeExpression(group.label)
+      children: 0
+      disabled: group.disabled
+    this.add_option( option, group_position, group.disabled ) for option in group.childNodes
+
+  add_option: (option, group_position, group_disabled) ->
+    if option.nodeName.toUpperCase() is "OPTION"
+      if option.text != ""
+        if group_position?
+          @parsed[group_position].children += 1
+        @parsed.push
+          array_index: @parsed.length
+          options_index: @options_index
+          value: option.value
+          text: option.text
+          html: option.innerHTML
+          selected: option.selected
+          disabled: if group_disabled is true then group_disabled else option.disabled
+          group_array_index: group_position
+          classes: option.className
+          style: option.style.cssText
+      else
+        @parsed.push
+          array_index: @parsed.length
+          options_index: @options_index
+          empty: true
+      @options_index += 1
+
+  escapeExpression: (text) ->
+    if not text? or text is false
+      return ""
+    unless /[\&\<\>\"\'\`]/.test(text)
+      return text
+    map =
+      "<": "&lt;"
+      ">": "&gt;"
+      '"': "&quot;"
+      "'": "&#x27;"
+      "`": "&#x60;"
+    unsafe_chars = /&(?!\w+;)|[\<\>\"\'\`]/g
+    text.replace unsafe_chars, (chr) ->
+      map[chr] || "&amp;"
+
+SelectParser.select_to_array = (select) ->
+  parser = new SelectParser()
+  parser.add_node( child ) for child in select.childNodes
+  parser.parsed
+
+window.SelectParser = SelectParser

data/vendor/assets/stylesheets/chosen.css.scss

@@ -0,0 +1,411 @@
+@import "compass/css3/box-sizing";
+@import "compass/css3/images";
+@import "compass/css3/user-interface";
+
+$chosen-sprite: image-url('chosen-sprite.png');
+$chosen-sprite-retina: image-url('chosen-sprite@2x.png');
+
+/* @group Base */
+.chosen-container {
+  position: relative;
+  display: inline-block;
+  vertical-align: middle;
+  font-size: 13px;
+  zoom: 1;
+  *display: inline;
+  @include user-select(none);
+  .chosen-drop {
+    position: absolute;
+    top: 100%;
+    left: -9999px;
+    z-index: 1010;
+    @include box-sizing(border-box);
+    width: 100%;
+    border: 1px solid #aaa;
+    border-top: 0;
+    background: #fff;
+    box-shadow: 0 4px 5px rgba(#000,.15);
+  }
+  &.chosen-with-drop .chosen-drop {
+    left: 0;
+  }
+  a{
+    cursor: pointer;
+  }
+}
+/* @end */
+
+/* @group Single Chosen */
+.chosen-container-single{
+  .chosen-single {
+    position: relative;
+    display: block;
+    overflow: hidden;
+    padding: 0 0 0 8px;
+    height: 23px;
+    border: 1px solid #aaa;
+    border-radius: 5px;
+    background-color: #fff;
+    @include background(linear-gradient(top, #fff 20%, #f6f6f6 50%, #eee 52%, #f4f4f4 100%));
+    background-clip: padding-box;
+    box-shadow: 0 0 3px #fff inset, 0 1px 1px rgba(#000,.1);
+    color: #444;
+    text-decoration: none;
+    white-space: nowrap;
+    line-height: 24px;
+  }
+  .chosen-default {
+    color: #999;
+  }
+  .chosen-single span {
+    display: block;
+    overflow: hidden;
+    margin-right: 26px;
+    text-overflow: ellipsis;
+    white-space: nowrap;
+  }
+  .chosen-single-with-deselect span {
+    margin-right: 38px;
+  }
+  .chosen-single abbr {
+    position: absolute;
+    top: 6px;
+    right: 26px;
+    display: block;
+    width: 12px;
+    height: 12px;
+    background: $chosen-sprite -42px 1px no-repeat;
+    font-size: 1px;
+    &:hover {
+      background-position: -42px -10px;
+    }
+  }
+  &.chosen-disabled .chosen-single abbr:hover {
+    background-position: -42px -10px;
+  }
+  .chosen-single div {
+    position: absolute;
+    top: 0;
+    right: 0;
+    display: block;
+    width: 18px;
+    height: 100%;
+    b {
+      display: block;
+      width: 100%;
+      height: 100%;
+      background: $chosen-sprite no-repeat 0px 2px;
+    }
+  }
+  .chosen-search {
+    position: relative;
+    z-index: 1010;
+    margin: 0;
+    padding: 3px 4px;
+    white-space: nowrap;
+    input[type="text"] {
+      @include box-sizing(border-box);
+      margin: 1px 0;
+      padding: 4px 20px 4px 5px;
+      width: 100%;
+      height: auto;
+      outline: 0;
+      border: 1px solid #aaa;
+      background: #fff $chosen-sprite no-repeat 100% -20px;
+      @include background($chosen-sprite no-repeat 100% -20px, linear-gradient(#eee 1%, #fff 15%));
+      font-size: 1em;
+      font-family: sans-serif;
+      line-height: normal;
+      border-radius: 0;
+    }
+  }
+  .chosen-drop {
+    margin-top: -1px;
+    border-radius: 0 0 4px 4px;
+    background-clip: padding-box;
+  }
+  &.chosen-container-single-nosearch .chosen-search {
+    position: absolute;
+    left: -9999px;
+  }
+}
+/* @end */
+
+/* @group Results */
+.chosen-container .chosen-results {
+  position: relative;
+  overflow-x: hidden;
+  overflow-y: auto;
+  margin: 0 4px 4px 0;
+  padding: 0 0 0 4px;
+  max-height: 240px;
+  -webkit-overflow-scrolling: touch;
+  li {
+    display: none;
+    margin: 0;
+    padding: 5px 6px;
+    list-style: none;
+    line-height: 15px;
+    -webkit-touch-callout: none;
+    &.active-result {
+      display: list-item;
+      cursor: pointer;
+    }
+    &.disabled-result {
+      display: list-item;
+      color: #ccc;
+      cursor: default;
+    }
+    &.highlighted {
+      background-color: #3875d7;
+      @include background-image(linear-gradient(#3875d7 20%, #2a62bc 90%));
+      color: #fff;
+    }
+    &.no-results {
+      display: list-item;
+      background: #f4f4f4;
+    }
+    &.group-result {
+      display: list-item;
+      font-weight: bold;
+      cursor: default;
+    }
+    &.group-option {
+      padding-left: 15px;
+    }
+    em {
+      font-style: normal;
+      text-decoration: underline;
+    }
+  }
+}
+/* @end */
+
+/* @group Multi Chosen */
+.chosen-container-multi{
+  .chosen-choices {
+    position: relative;
+    overflow: hidden;
+    @include box-sizing(border-box);
+    margin: 0;
+    padding: 0;
+    width: 100%;
+    height: auto !important;
+    height: 1%;
+    border: 1px solid #aaa;
+    background-color: #fff;
+    @include background-image(linear-gradient(#eee 1%, #fff 15%));
+    cursor: text;
+  }
+  .chosen-choices li {
+    float: left;
+    list-style: none;
+    &.search-field {
+      margin: 0;
+      padding: 0;
+      white-space: nowrap;
+      input[type="text"] {
+        margin: 1px 0;
+        padding: 5px;
+        height: 15px;
+        outline: 0;
+        border: 0 !important;
+        background: transparent !important;
+        box-shadow: none;
+        color: #666;
+        font-size: 100%;
+        font-family: sans-serif;
+        line-height: normal;
+        border-radius: 0;
+      }
+      .default {
+        color: #999;
+      }
+    }
+    &.search-choice {
+      position: relative;
+      margin: 3px 0 3px 5px;
+      padding: 3px 20px 3px 5px;
+      border: 1px solid #aaa;
+      border-radius: 3px;
+      background-color: #e4e4e4;
+      @include background-image(linear-gradient(#f4f4f4 20%, #f0f0f0 50%, #e8e8e8 52%, #eee 100%));
+      background-clip: padding-box; 
+      box-shadow: 0 0 2px #fff inset, 0 1px 0 rgba(#000,.05);
+      color: #333;
+      line-height: 13px;
+      cursor: default;
+      .search-choice-close {
+        position: absolute;
+        top: 4px;
+        right: 3px;
+        display: block;
+        width: 12px;
+        height: 12px;
+        background: $chosen-sprite -42px 1px no-repeat;
+        font-size: 1px;
+        &:hover {
+          background-position: -42px -10px;
+        }
+      }
+    }
+    &.search-choice-disabled {
+      padding-right: 5px;
+      border: 1px solid #ccc;
+      background-color: #e4e4e4;
+      @include background-image(linear-gradient(top, #f4f4f4 20%, #f0f0f0 50%, #e8e8e8 52%, #eee 100%));
+      color: #666;
+    }
+    &.search-choice-focus {
+      background: #d4d4d4;
+      .search-choice-close {
+        background-position: -42px -10px;
+      }
+    }
+  }
+  .chosen-results {
+    margin: 0;
+    padding: 0;
+  }
+  .chosen-drop .result-selected {
+    display: list-item;
+    color: #ccc;
+    cursor: default;
+  }
+}
+/* @end */
+
+/* @group Active  */
+.chosen-container-active{
+  .chosen-single {
+    border: 1px solid #5897fb;
+    box-shadow: 0 0 5px rgba(#000,.3);
+  }
+  &.chosen-with-drop{
+    .chosen-single {
+      border: 1px solid #aaa;
+      -moz-border-radius-bottomright: 0;
+      border-bottom-right-radius: 0;
+      -moz-border-radius-bottomleft: 0;
+      border-bottom-left-radius: 0;
+      @include background-image(linear-gradient(#eee 20%, #fff 80%));
+      box-shadow: 0 1px 0 #fff inset;
+    }
+    .chosen-single div {
+      border-left: none;
+      background: transparent;
+      b {
+        background-position: -18px 2px;
+      }
+    }
+  }
+  .chosen-choices {
+    border: 1px solid #5897fb;
+    box-shadow: 0 0 5px rgba(#000,.3);
+    li.search-field input[type="text"] {
+      color: #111 !important;
+    }
+  }
+}
+/* @end */
+
+/* @group Disabled Support */
+.chosen-disabled {
+  opacity: 0.5 !important;
+  cursor: default;
+  .chosen-single {
+    cursor: default;
+  }
+  .chosen-choices .search-choice .search-choice-close {
+    cursor: default;
+  }
+}
+/* @end */
+
+/* @group Right to Left */
+.chosen-rtl {
+  text-align: right;
+  .chosen-single {
+    overflow: visible;
+    padding: 0 8px 0 0;
+  }
+  .chosen-single span {
+    margin-right: 0;
+    margin-left: 26px;
+    direction: rtl;
+  }
+  .chosen-single-with-deselect span {
+    margin-left: 38px;
+  }
+  .chosen-single div {
+    right: auto;
+    left: 3px;
+  }
+  .chosen-single abbr {
+    right: auto;
+    left: 26px;
+  }
+  .chosen-choices li {
+    float: right;
+    &.search-field input[type="text"] {
+      direction: rtl;
+    }
+    &.search-choice {
+      margin: 3px 5px 3px 0;
+      padding: 3px 5px 3px 19px;
+      .search-choice-close {
+        right: auto;
+        left: 4px;
+      }
+    }
+  }
+  &.chosen-container-single-nosearch .chosen-search,
+  .chosen-drop {
+    left: 9999px;
+  }
+  &.chosen-container-single .chosen-results {
+    margin: 0 0 4px 4px;
+    padding: 0 4px 0 0;
+  }
+  .chosen-results li.group-option {
+    padding-right: 15px;
+    padding-left: 0;
+  }
+  &.chosen-container-active.chosen-with-drop .chosen-single div {
+    border-right: none;
+  }
+  .chosen-search input[type="text"] {
+    padding: 4px 5px 4px 20px;
+    background: #fff $chosen-sprite no-repeat -30px -20px;
+    @include background($chosen-sprite no-repeat -30px -20px, linear-gradient(#eee 1%, #fff 15%));
+    direction: rtl;
+  }
+  &.chosen-container-single{
+    .chosen-single div b {
+      background-position: 6px 2px;
+    }
+    &.chosen-with-drop{
+      .chosen-single div b {
+        background-position: -12px 2px;
+      }
+    }
+  }
+}
+
+/* @end */
+
+/* @group Retina compatibility */
+@media only screen and (-webkit-min-device-pixel-ratio: 2), only screen and (min-resolution: 144dpi)  {
+  .chosen-rtl .chosen-search input[type="text"],
+  .chosen-container-single .chosen-single abbr,
+  .chosen-container-single .chosen-single div b,
+  .chosen-container-single .chosen-search input[type="text"],
+  .chosen-container-multi .chosen-choices .search-choice .search-choice-close,
+  .chosen-container .chosen-results-scroll-down span,
+  .chosen-container .chosen-results-scroll-up span {
+    background-image: $chosen-sprite-retina !important;
+    background-size: 52px 37px !important;
+    background-repeat: no-repeat !important;
+  }
+}
+/* @end */