chosen-awesome-rails 1.0.0

data/vendor/assets/javascripts/chosen/multiple.js.coffee

@@ -0,0 +1,136 @@
+$ = jQuery
+
+class Chosen.Multiple extends Chosen
+  constructor: ->
+    super
+
+    @pending_option = null
+
+  bind_option_events: (option) ->
+    option.$choice.find("a").unbind().
+      bind("mousedown", -> false).
+      bind("click", (evt) => @deselect_choice(evt))
+    return
+
+  set_default_value: ->
+    @$container.$search[0].value = ""
+    return
+
+  dropdown_mousedown: ->
+    @reset_pending_option()
+    super
+    return
+
+  keydown: (evt) ->
+    code = evt.which ? evt.keyCode
+
+    unless code is 8
+      @reset_pending_option()
+
+    switch code
+      when 8
+        @set_pending_option(true) if @pending_option
+      else
+        super
+
+    return
+
+  keyup: (evt) ->
+    code = evt.which ? evt.keyCode
+
+    if code is 8
+      @set_pending_option(false)
+    else
+      @reset_pending_option()
+
+    super
+
+  set_pending_option: (do_deselect) ->
+    if @pending_option and do_deselect
+      @deselect(@pending_option)
+      @reset_pending_option()
+
+    return if @get_caret_position() > 0 and @$container.$search[0].value.length
+
+    choise = @$container.$choices.find("li.chosen-option").last()[0]
+    option = @parser.find_by_element(choise)
+    return unless option
+
+    unless @pending_option
+      option.$choice.addClass("active")
+      @pending_option = option
+
+    return
+
+  reset_pending_option: ->
+    if @pending_option
+      @pending_option.$choice.removeClass("active")
+      @pending_option = null
+
+    return
+
+  deselect_choice: (evt) ->
+    option = @parser.find_by_element(evt.target.parentNode)
+
+    $choice = $(evt.target.parentNode)
+    $next = $choice.next("li.chosen-option")
+    $prev = $choice.prev("li.chosen-option")
+    $sibling = if $next.length then $next else if $prev.length then $prev else null
+
+    @deselect(option) if option
+
+    if $sibling and not @activated
+      $sibling.find("a").trigger("focus")
+    else
+      @activate()
+
+    evt.preventDefault()
+    evt.stopPropagation()
+
+    return @
+
+  deselect: (option) ->
+    @parser.deselect(option)
+
+    option.$choice.remove()
+    @update_dropdown_position()
+
+    @$target.trigger("change")
+    return @
+
+  select: (option) ->
+    return @ if not option or option.disabled or option.selected
+
+    @parser.select(option)
+    @$container.$search_container.before(option.$choice)
+
+    @$container.$search[0].value = ""
+
+    @bind_option_events(option)
+    @close()
+
+    @$target.trigger("change")
+    return @
+
+  deselect_all: ->
+    for option in @parser.selected()
+      @deselect(option)
+
+    return @
+
+  select_all: ->
+    for option in @parser.not_selected()
+      @select(option)
+
+    return @
+
+  load: ->
+    for option in @parser.selected()
+      @bind_option_events(option)
+      @$container.$search_container.before(option.$choice)
+
+    return @
+
+  @defaults:
+    is_multiple: true
+    placeholder: "Select some options"

data/vendor/assets/javascripts/chosen/parser.js.coffee

@@ -0,0 +1,293 @@
+$ = jQuery
+
+class Chosen.Parser
+  constructor: (@chosen)->
+    @all_options = []
+    @available_options = []
+    @selected_options = []
+    @selectable_options = []
+
+    @parse()
+
+  destroy: ->
+    delete @all_options
+    delete @available_options
+    delete @selected_options
+    delete @selectable_options
+    delete @chosen
+    return
+
+  parse: (selected_options = []) ->
+    formatter = @chosen.option_formatter || @default_formatter
+    current_group_label = null
+    group = null
+
+    @all_options = []
+    @selected_options = []
+    @selectable_options = []
+
+    $reset_link = @build_reset_link()
+
+    @chosen.$target.find("option").each (index, option) =>
+      if option.parentNode.nodeName is "OPTGROUP"
+        if current_group_label != option.parentNode.label
+          current_group_label = option.parentNode.label
+          group = $("<li />", class: "chosen-group", text: current_group_label)
+      else
+        group = null
+
+      classes = "chosen-option"
+      classes += " group" if group
+      classes += " selected" if option.selected
+      classes += " disabled" if option.disabled
+
+      $option = $(option)
+      selected = $.grep(selected_options, (o) => o.value is option.value and o.label is option.label)[0]
+      text = formatter($option)
+
+      option_obj =
+        $group: group
+        $listed: (selected and selected.$listed) or $("<li />", class: classes, html: text[0])
+        $choice: (selected and selected.$choice) or $("<li />", class: classes, html: [$reset_link.clone(), text[1]])
+        $option: (selected and selected.$option) or $option
+        blank: option.value is "" and index is 0
+        index: index
+        score: index * -1
+        label: option.text
+        value: option.value
+        selected: option.selected
+        disabled: option.disabled
+        match_type: null
+
+      @all_options.push option_obj
+
+      unless option_obj.blank
+        @selected_options.push option_obj if option.selected
+        @selectable_options.push option_obj unless option.selected
+
+    @order()
+    return @
+
+  update: (data) ->
+    parser = @chosen.option_parser || @default_parser
+    selected_options = []
+
+    for option in @all_options
+      if option.selected or option.blank
+        selected_options.push(option)
+      else
+        option.$option.remove()
+
+    for attrs in data
+      parsed = parser(attrs)
+      unless $.grep(selected_options, (o) => o.value is parsed.value.toString() and o.label == parsed.text.toString() ).length
+        @chosen.$target.append($("<option />", parsed))
+
+    @parse(selected_options)
+    return @
+
+  insert: (data) ->
+    formatter = @chosen.option_formatter || @default_formatter
+    classes = "chosen-option"
+    $option = $("<option />", value: data.value, text: data.label)
+    $reset_link = @build_reset_link()
+    text = formatter($option)
+
+    @chosen.$target.append($option)
+
+    option_obj =
+      $group: null
+      $listed: $("<li />", class: classes, html: text[0])
+      $choice: $("<li />", class: classes, html: [$reset_link, text[1]])
+      $option: $option
+      blank: false
+      index: 0
+      score: 0
+      label: $option[0].text
+      value: $option[0].value
+      selected: false
+      disabled: false
+      match_type: 0
+
+    @all_options.unshift option_obj
+    @available_options.unshift option_obj
+    @selectable_options.unshift option_obj
+
+    option_obj
+
+  restore: (option) ->
+    @select(option)
+
+    unless $.grep(@all_options, (o) => option.label is o.label).length
+      @chosen.$target.append(option.$option)
+
+      @all_options.unshift option
+      @available_options.unshift option
+      @selectable_options.unshift option
+
+    @parse()
+
+  remove: (option) ->
+    return if option.selected
+
+    option.$listed.remove()
+    option.$choice.remove()
+    option.$option.remove()
+
+    for collection in [@all_options, @available_options, @selected_options, @selectable_options]
+      index = collection.indexOf(option)
+      collection.splice(index, 1) if index > -1
+
+  to_html: ->
+    last_group = null
+    list = []
+
+    for option in @available_options
+      if option.$group
+        if not last_group or (last_group and last_group.text() isnt option.$group.text())
+          last_group = option.$group.clone()
+          list.push last_group
+      else
+        last_group = null
+
+      list.push option.$listed
+
+    list
+
+  find_by_element: (element) ->
+    for option in @all_options
+      if option.$listed[0] is element or option.$choice[0] is element
+        return option
+
+    return null
+
+  index_of: (option) ->
+    if option then @available_options.indexOf(option) else 0
+
+  select: (option) ->
+    return @ unless option
+
+    option.$option.prop(selected: true)
+    option.$listed.addClass("selected")
+    option.$choice.addClass("selected")
+    option.selected = true
+
+    index = @selectable_options.indexOf(option)
+    @selectable_options.splice(index, 1) unless index is -1
+    @selected_options.push(option)
+
+    return @
+
+  deselect: (option) ->
+    return @ unless option
+
+    option.$option.prop(selected: false)
+    option.$listed.removeClass("selected")
+    option.$choice.removeClass("selected")
+    option.selected = false
+
+    index = @selected_options.indexOf(option)
+    @selected_options.splice(index, 1) unless index is -1
+    @selectable_options.push(option)
+
+    return @
+
+  selected: ->
+    $.grep @available_options, (option) ->
+      option.selected
+
+  not_selected: ->
+    $.grep @available_options, (option) ->
+      not option.selected
+
+  exact_matches: ->
+    $.grep @available_options, (option) ->
+      option.match_type is 0
+
+  includes_blank: ->
+    not not @blank_option()
+
+  blank_option: ->
+    for option in @all_options
+      return option if option.blank
+
+    return null
+
+  apply_filter: (value) ->
+    @reset_filter()
+
+    if (value = $.trim(value))
+      scores = [
+        @all_options.length * 12, @all_options.length * 9
+        @all_options.length * 6, @all_options.length * 3
+        @all_options.length
+      ]
+
+      exact_query = value.toLowerCase()
+      query = exact_query.replace(Parser.escape_exp, "\\$&").split(" ")
+
+      expressions_collection = $.map(query, (word, index) ->
+        return [[
+          new RegExp("^#{word}$", "i"), new RegExp("^#{word}", "i")
+          new RegExp("#{word}$", "i"), new RegExp(word, "i")
+        ]]
+      )
+
+      for option in @all_options
+        if option.label.toLowerCase() is exact_query
+          option.match_type = 0
+        else
+          option.match_type = null
+
+        words = option.label.split(" ")
+
+        for word in words
+          for expressions in expressions_collection
+            for expression, index in expressions
+              if word.match(expression)
+                if option.match_type is null
+                  option.match_type = index + 1
+
+                option.score += scores[option.match_type]
+                break
+              else if index is expressions.length - 1
+                option.score -= 1
+
+    @order()
+    return @
+
+  reset_filter: ->
+    option.score = option.index * -1 for option in @all_options
+    return @
+
+  order: ->
+    @all_options = @all_options.sort (a, b) ->
+      if a.score > b.score then -1 else if a.score < b.score then 1 else 0
+
+    @available_options = []
+
+    for option in @all_options
+      if not option.blank
+        @available_options.push(option)
+
+    return @
+
+  default_parser: (attrs) ->
+    value: attrs.value
+    text: attrs.label
+    data: { source: attrs }
+
+  default_formatter: ($option) ->
+    value = $option.contents().text()
+    [value, value]
+
+  build_reset_link: ->
+    $("<a />",
+      text: "×"
+      href: "javascript:void(0)"
+      class: "chosen-delete"
+      tabindex: @chosen.$target[0].tabindex || "0"
+    )
+
+
+  @escape_exp: /[\-\[\]\/\{\}\(\)\*\+\?\.\\\^\$\|]/g

data/vendor/assets/javascripts/chosen/single.js.coffee

@@ -0,0 +1,93 @@
+$ = jQuery
+
+class Chosen.Single extends Chosen
+  build: ->
+    super
+
+    if @allow_deselect
+      @$container.$reset = @parser.build_reset_link()
+      @$container.append(@$container.$reset)
+
+    return
+
+  bind_events: ->
+    super
+
+    if @allow_deselect
+      @$container.$reset.bind "mousedown", (evt) ->
+        evt.stopImmediatePropagation()
+        evt.preventDefault()
+
+      @$container.$reset.bind "click", (evt) =>
+        @deselect()
+        @load()
+        @activate()
+        evt.stopImmediatePropagation()
+
+    return
+
+  unbind_events: ->
+    super
+
+    if @allow_deselect
+      @$container.$reset.unbind()
+
+    return
+
+  open: ->
+    return @ if @opened
+
+    selected = @parser.selected()[0]
+
+    if selected and @$container.$search[0].value is selected.label
+      @$container.$search[0].value = ""
+
+    super
+
+  set_default_value: ->
+    selected = @parser.selected()[0]
+    @$container.$search[0].value = if selected then selected.label else ""
+    @$container.$search[0].defaultValue = @$container.$search[0].value
+
+    if selected and not selected.blank
+      @$container.removeClass("placeholder")
+    else
+      @$container.addClass("placeholder")
+
+    return
+
+  deselect: (option) ->
+    @parser.deselect(option || @parser.selected()[0])
+
+    @set_default_value()
+    @close()
+
+    @$target.trigger("change")
+    return @
+
+  select: (option) ->
+    return @ if not option or option.disabled or option.selected
+
+    @parser.deselect(@parser.selected()[0])
+    @parser.select(option)
+
+    @set_default_value()
+    @close()
+
+    @$target.trigger("change")
+    return @
+
+  deselect_all: ->
+    @deselect()
+    return @
+
+  select_all: ->
+    return @
+
+  load: ->
+    @set_default_value()
+    return @
+
+  @defaults:
+    is_multiple: false
+    placeholder: "Select an option"