cfacter 3.11.0.rc.20180314

data/ext/facter/leatherman/cmake/GetGitRevisionDescription.cmake

@@ -0,0 +1,130 @@
+# - Returns a version string from Git
+#
+# These functions force a re-configure on each git commit so that you can
+# trust the values of the variables in your build system.
+#
+#  get_git_head_revision(<refspecvar> <hashvar> [<additional arguments to git describe> ...])
+#
+# Returns the refspec and sha hash of the current head revision
+#
+#  git_describe(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe on the source tree, and adjusting
+# the output so that it tests false if an error occurs.
+#
+#  git_get_exact_tag(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe --exact-match on the source tree,
+# and adjusting the output so that it tests false if there was no exact
+# matching tag.
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+if(__get_git_revision_description)
+	return()
+endif()
+set(__get_git_revision_description YES)
+
+# We must run the following at "include" time, not at function call time,
+# to find the path to this module rather than the path to a calling list file
+get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
+
+function(get_git_head_revision _refspecvar _hashvar)
+	set(GIT_PARENT_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
+	set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+	while(NOT EXISTS "${GIT_DIR}")	# .git dir not found, search parent directories
+		set(GIT_PREVIOUS_PARENT "${GIT_PARENT_DIR}")
+		get_filename_component(GIT_PARENT_DIR ${GIT_PARENT_DIR} PATH)
+		if(GIT_PARENT_DIR STREQUAL GIT_PREVIOUS_PARENT)
+			# We have reached the root directory, we are not in git
+			set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+			set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+			return()
+		endif()
+		set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+	endwhile()
+	# check if this is a submodule
+	if(NOT IS_DIRECTORY ${GIT_DIR})
+		file(READ ${GIT_DIR} submodule)
+		string(REGEX REPLACE "gitdir: (.*)\n$" "\\1" GIT_DIR_RELATIVE ${submodule})
+		get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
+		get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE} ABSOLUTE)
+	endif()
+	set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
+	if(NOT EXISTS "${GIT_DATA}")
+		file(MAKE_DIRECTORY "${GIT_DATA}")
+	endif()
+
+	if(NOT EXISTS "${GIT_DIR}/HEAD")
+		return()
+	endif()
+	set(HEAD_FILE "${GIT_DATA}/HEAD")
+	configure_file("${GIT_DIR}/HEAD" "${HEAD_FILE}" COPYONLY)
+
+	configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
+		"${GIT_DATA}/grabRef.cmake"
+		@ONLY)
+	include("${GIT_DATA}/grabRef.cmake")
+
+	set(${_refspecvar} "${HEAD_REF}" PARENT_SCOPE)
+	set(${_hashvar} "${HEAD_HASH}" PARENT_SCOPE)
+endfunction()
+
+function(git_describe _var)
+	if(NOT GIT_FOUND)
+		find_package(Git QUIET)
+	endif()
+	get_git_head_revision(refspec hash)
+	if(NOT GIT_FOUND)
+		set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
+		return()
+	endif()
+	if(NOT hash)
+		set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
+		return()
+	endif()
+
+	# TODO sanitize
+	#if((${ARGN}" MATCHES "&&") OR
+	#	(ARGN MATCHES "||") OR
+	#	(ARGN MATCHES "\\;"))
+	#	message("Please report the following error to the project!")
+	#	message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
+	#endif()
+
+	#message(STATUS "Arguments to execute_process: ${ARGN}")
+
+	execute_process(COMMAND
+		"${GIT_EXECUTABLE}"
+		describe
+		${hash}
+		${ARGN}
+		WORKING_DIRECTORY
+		"${CMAKE_SOURCE_DIR}"
+		RESULT_VARIABLE
+		res
+		OUTPUT_VARIABLE
+		out
+		ERROR_QUIET
+		OUTPUT_STRIP_TRAILING_WHITESPACE)
+	if(NOT res EQUAL 0)
+		set(out "${out}-${res}-NOTFOUND")
+	endif()
+
+	set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
+
+function(git_get_exact_tag _var)
+	git_describe(out --exact-match ${ARGN})
+	set(${_var} "${out}" PARENT_SCOPE)
+endfunction()

data/ext/facter/leatherman/cmake/GetGitRevisionDescription.cmake.in

@@ -0,0 +1,38 @@
+# 
+# Internal file for GetGitRevisionDescription.cmake
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+set(HEAD_HASH)
+
+file(READ "@HEAD_FILE@" HEAD_CONTENTS LIMIT 1024)
+
+string(STRIP "${HEAD_CONTENTS}" HEAD_CONTENTS)
+if(HEAD_CONTENTS MATCHES "ref")
+	# named branch
+	string(REPLACE "ref: " "" HEAD_REF "${HEAD_CONTENTS}")
+	if(EXISTS "@GIT_DIR@/${HEAD_REF}")
+		configure_file("@GIT_DIR@/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+	elseif(EXISTS "@GIT_DIR@/logs/${HEAD_REF}")
+		configure_file("@GIT_DIR@/logs/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+		set(HEAD_HASH "${HEAD_REF}")
+	endif()
+else()
+	# detached HEAD
+	configure_file("@GIT_DIR@/HEAD" "@GIT_DATA@/head-ref" COPYONLY)
+endif()
+
+if(NOT HEAD_HASH)
+	file(READ "@GIT_DATA@/head-ref" HEAD_HASH LIMIT 1024)
+	string(STRIP "${HEAD_HASH}" HEAD_HASH)
+endif()

data/ext/facter/leatherman/cmake/cflags.cmake

@@ -0,0 +1,110 @@
+# Set compiler-specific flags
+# Each of our project dirs sets CMAKE_CXX_FLAGS based on these. We do
+# not set CMAKE_CXX_FLAGS globally because gtest is not warning-clean.
+if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "\\w*Clang")
+    set(LEATHERMAN_CXX_FLAGS "-std=c++11 -Wall -Wextra -Werror -Wno-unused-parameter -Wno-tautological-constant-out-of-range-compare ${CMAKE_CXX_FLAGS}")
+
+    # Clang warns that 'register' is deprecated; 'register' is used throughout boost, so it can't be an error yet.
+    # The warning flag is different on different clang versions so we need to extract the clang version.
+    # And the Mavericks version of clang report its version in its own special way (at least on 10.9.5) - yay
+    EXECUTE_PROCESS( COMMAND ${CMAKE_CXX_COMPILER} --version OUTPUT_VARIABLE clang_full_version_string )
+    if ("${CMAKE_SYSTEM_NAME}" MATCHES "Darwin")
+        string (REGEX REPLACE ".*based on LLVM ([0-9]+\\.[0-9]+).*" "\\1" CLANG_VERSION_STRING ${clang_full_version_string})
+        # Clang's output changed in Xcode 7.
+        if (NOT ${clang_full_version_string})
+            string(REGEX REPLACE "Apple LLVM version ([0-9]+\\.[0-9]+).*" "\\1" CLANG_VERSION_STRING ${clang_full_version_string})
+        endif()
+    else()
+        string (REGEX REPLACE ".*clang version ([0-9]+\\.[0-9]+).*" "\\1" CLANG_VERSION_STRING ${clang_full_version_string})
+    endif()
+    MESSAGE( STATUS "CLANG_VERSION_STRING:         " ${CLANG_VERSION_STRING} )
+
+    # Now based on clang version set the appropriate warning flag
+    if ("${CLANG_VERSION_STRING}" VERSION_GREATER "3.4")
+        set(LEATHERMAN_CXX_FLAGS "-Wno-deprecated-register ${LEATHERMAN_CXX_FLAGS}")
+    else()
+        set(LEATHERMAN_CXX_FLAGS "-Wno-deprecated ${LEATHERMAN_CXX_FLAGS}")
+    endif()
+
+    if ("${CLANG_VERSION_STRING}" VERSION_GREATER "6.9")
+        set(LEATHERMAN_CXX_FLAGS "-Wno-unused-local-typedef ${LEATHERMAN_CXX_FLAGS}")
+    endif()
+
+    # FreeBSD needs -fPIC
+    if(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
+        set(LEATHERMAN_LIBRARY_FLAGS "-fPIC")
+    endif()
+
+elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
+    # maybe-uninitialized is a relatively new GCC warning that Boost 1.57 violates; disable it for now until it's available in Clang as well
+    # it's also sometimes wrong
+    set(CMAKE_CXX_FLAGS "-Wno-maybe-uninitialized ${CMAKE_CXX_FLAGS}")
+
+    # missing-field-initializers is disabled because GCC can't make up their mind how to treat C++11 initializers
+    set(LEATHERMAN_CXX_FLAGS "-std=c++11 -Wall -Werror -Wno-unused-parameter -Wno-unused-local-typedefs -Wno-unknown-pragmas -Wno-missing-field-initializers ${CMAKE_CXX_FLAGS}")
+    if (NOT "${CMAKE_SYSTEM_NAME}" MATCHES "SunOS")
+        set(LEATHERMAN_CXX_FLAGS "-Wextra ${LEATHERMAN_CXX_FLAGS}")
+    endif()
+
+    # On Windows with GCC 5.2.0, disable deprecated declarations because it causes warnings with Boost's use of auto_ptr
+    if (WIN32)
+        set(LEATHERMAN_CXX_FLAGS "-Wno-deprecated-declarations ${LEATHERMAN_CXX_FLAGS}")
+    endif()
+
+    # On unix systems we want to be sure to specify -fPIC for libraries
+    if (NOT WIN32)
+        set(LEATHERMAN_LIBRARY_FLAGS "-fPIC -nostdlib -nodefaultlibs")
+    endif()
+elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Intel")
+elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")
+    #set(LEATHERMAN_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Wall")
+endif()
+
+# Add code coverage
+if (COVERALLS)
+    set(LEATHERMAN_CXX_FLAGS "-fprofile-arcs -ftest-coverage ${LEATHERMAN_CXX_FLAGS}")
+    set(CMAKE_SHARED_LINKER_FLAGS "--coverage ${CMAKE_SHARED_LINKER_FLAGS}")
+    set(CMAKE_EXE_LINKER_FLAGS "--coverage ${CMAKE_EXE_LINKER_FLAGS}")
+endif()
+
+if (WIN32)
+    # Update standard link libraries to explicitly exclude kernel32. It isn't necessary, and when compiling with
+    # MinGW makes the executable unusable on Microsoft Nano Server due to including __C_specific_handler.
+    SET(CMAKE_C_STANDARD_LIBRARIES "-luser32 -lgdi32 -lwinspool -lshell32 -lole32 -loleaut32 -luuid -lcomdlg32 -ladvapi32"
+        CACHE STRING "Standard C link libraries." FORCE)
+    SET(CMAKE_CXX_STANDARD_LIBRARIES "-luser32 -lgdi32 -lwinspool -lshell32 -lole32 -loleaut32 -luuid -lcomdlg32 -ladvapi32"
+        CACHE STRING "Standard C++ link libraries." FORCE)
+
+    # We currently support Windows Vista and later APIs, see
+    # http://msdn.microsoft.com/en-us/library/windows/desktop/aa383745(v=vs.85).aspx for version strings.
+    list(APPEND LEATHERMAN_DEFINITIONS -DWINVER=0x0600 -D_WIN32_WINNT=0x0600)
+
+    # The GetUserNameEx function requires the application have a defined security level.
+    # We define security sufficient to get the current user's info.
+    # Also force use of UNICODE APIs, following the pattern outlined at http://utf8everywhere.org/.
+    list(APPEND LEATHERMAN_DEFINITIONS -DUNICODE -D_UNICODE -DSECURITY_WIN32)
+endif()
+
+# Enforce UTF-8 in Leatherman.Logging; disable deprecated names in Boost.System to avoid warnings on Windows.
+list(APPEND LEATHERMAN_DEFINITIONS -DBOOST_LOG_WITHOUT_WCHAR_T -DBOOST_SYSTEM_NO_DEPRECATED)
+
+# Set project name for locale customization. Also set build directory for testing.
+list(APPEND LEATHERMAN_DEFINITIONS -DPROJECT_NAME="${CMAKE_PROJECT_NAME}" -DPROJECT_DIR="${PROJECT_BINARY_DIR}")
+
+if (NOT BOOST_STATIC)
+    # Boost.Log requires that BOOST_LOG_DYN_LINK is set when using dynamic linking. We set ALL for consistency.
+    list(APPEND LEATHERMAN_DEFINITIONS -DBOOST_ALL_DYN_LINK)
+endif()
+
+set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
+if (WIN32)
+    # On Windows, DLL paths aren't hardcoded in the executable. We place all the executables and libraries
+    # in the same directory to avoid having to setup the DLL search path in the dev environment.
+    set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
+else()
+    set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
+endif()
+
+if ((LEATHERMAN_TOPLEVEL OR LEATHERMAN_HAVE_LOCALES) AND LEATHERMAN_USE_LOCALES)
+    list(APPEND LEATHERMAN_DEFINITIONS -DLEATHERMAN_USE_LOCALES)
+endif()

data/ext/facter/leatherman/cmake/generate_translations.cmake

@@ -0,0 +1,17 @@
+# Generates or updates translation files from a pot file using msginit or msgmerge.
+#
+# Usage:
+#   cmake -DPOT_FILE=<pot_file_name> \
+#         -DLANG_FILE=<lang_file_name> \
+#         -DLANG=<language> \
+#         -DMSGMERGE_EXE=<path_to_msgmerge> \
+#         -DMSGINIT_EXE=<path_to_msginit> \
+#         -P generate_translations.cmake
+
+if (EXISTS ${LANG_FILE})
+    message(STATUS "Updating ${LANG_FILE}")
+    execute_process(COMMAND ${MSGMERGE_EXE} -U ${LANG_FILE} ${POT_FILE})
+else()
+    execute_process(COMMAND ${MSGINIT_EXE} --no-translator -l ${LANG}.UTF-8 -o ${LANG_FILE} -i ${POT_FILE})
+endif()
+

data/ext/facter/leatherman/cmake/internal.cmake

@@ -0,0 +1,241 @@
+# This file contains the macros used to add and manage leatherman
+# libraries. If you are adding a new library to leatherman, this is
+# probably the place to go for documentation. If you're just using
+# Leatherman, you should check out the README for information on its
+# interface.
+
+include(leatherman) # contains some helpers we use
+
+####
+# Macros for use by leatherman libraries
+#
+# These are the API that libraries use to build themselves as
+# "standard" leatherman components"
+####
+
+# Usage: add_leatherman_deps(${DEP1_LIB} ${DEP2_LIB})
+#
+# Append to the LEATHERMAN_<LIBRARY>_DEPS variable.
+macro(add_leatherman_deps)
+    list(APPEND ${deps_var} ${ARGV})
+    export_var(${deps_var})
+endmacro()
+
+# Usage: add_leatherman_includes(${DIR1} ${DIR2})
+#
+# Append to the LEATHERMAN_<LIBRARY>_INCLUDE variable
+macro(add_leatherman_includes)
+    list(APPEND ${include_var} ${ARGV})
+    list(REMOVE_DUPLICATES ${include_var})
+    export_var(${include_var})
+endmacro()
+
+# Usage: leatherman_dependency("libname")
+#
+# Automatically handle include directories and library linking for the
+# given leatherman library.
+#
+# Will throw a fatal error if the dependency cannot be found.
+macro(leatherman_dependency library)
+    string(MAKE_C_IDENTIFIER "${library}" id)
+    string(TOUPPER "${id}" name)
+    set(option "LEATHERMAN_USE_${name}")
+    set(dep_lib "LEATHERMAN_${name}_LIB")
+    set(dep_deps "LEATHERMAN_${name}_DEPS")
+    set(dep_include "LEATHERMAN_${name}_INCLUDE")
+
+    if(${${option}})
+        debug("Found ${library} as ${name}, using it in current context")
+        if ((NOT "" STREQUAL "${${dep_deps}}") AND (NOT LEATHERMAN_SHARED))
+            debug("Adding ${${dep_deps}} to deps for ${dirname}")
+            append_new(${deps_var} ${${dep_deps}})
+            export_var(${deps_var})
+        endif()
+        if (NOT "" STREQUAL "${${dep_lib}}")
+            debug("Adding ${${dep_lib}} to deps for ${dirname}")
+            list(FIND ${deps_var} ${${dep_lib}} found)
+            if (${found} EQUAL -1)
+                list(APPEND ${deps_var} ${${dep_lib}})
+            endif()
+            export_var(${deps_var})
+        endif()
+        if (NOT "" STREQUAL "${${dep_include}}")
+            debug("Adding ${${dep_include}} to include directories for ${dirname}")
+            list(APPEND ${include_var} ${${dep_include}})
+            list(REMOVE_DUPLICATES ${include_var})
+            export_var(${include_var})
+        endif()
+    else()
+        message(FATAL_ERROR "${library} not found as a dependency for ${dirname}")
+    endif()
+endmacro()
+
+# Usage: add_leatherman_library(${SOURCES} [OPTS] [EXPORTS HEADER])
+#
+# Creates a static CMake library built from the provided sources. Sets
+# LEATHERMAN_<LIBRARY>_LIB to the name of this library.
+#
+# This macro directly calls add_library, so any add_library options
+# can be passed along with the sources.
+#
+# If the EXPORTS keyword is given, the string following it describes
+# the location to put an export header using the symbol_exports
+# helper.
+#
+# This macro cannot be invoked multiple times
+macro(add_leatherman_library)
+    include_directories(BEFORE ${${include_var}})
+
+    set(LIBRARY_ARGS ${ARGV})
+    list(FIND LIBRARY_ARGS EXPORTS EXPORTS_IDX)
+    if (NOT ${EXPORTS_IDX} EQUAL -1)
+        list(REMOVE_AT LIBRARY_ARGS ${EXPORTS_IDX})
+        list(GET LIBRARY_ARGS ${EXPORTS_IDX} EXPORT_HEADER)
+        list(REMOVE_AT LIBRARY_ARGS ${EXPORTS_IDX})
+    endif()
+
+    if(LEATHERMAN_SHARED)
+        add_library(${libname} SHARED ${LIBRARY_ARGS})
+        target_link_libraries(${libname} PRIVATE ${${deps_var}})
+    else()
+        add_library(${libname} STATIC ${LIBRARY_ARGS})
+    endif()
+    set_target_properties(${libname} PROPERTIES COMPILE_FLAGS "${LEATHERMAN_CXX_FLAGS} ${LEATHERMAN_LIBRARY_FLAGS}" VERSION ${PROJECT_VERSION})
+    if(LEATHERMAN_INSTALL)
+        leatherman_install(${libname} EXPORT LeathermanLibraries)
+    endif()
+
+    if (EXPORT_HEADER)
+        symbol_exports(${libname} ${EXPORT_HEADER})
+    endif()
+    set(${lib_var} "${libname}" PARENT_SCOPE)
+endmacro()
+
+# Usage: add_leatherman_test(${SOURCES} [OPTS])
+#
+# Adds the listed files to the set which will be built for the
+# leatherman unit test executable.
+macro(add_leatherman_test)
+    foreach(FILE ${ARGV})
+        if (IS_ABSOLUTE FILE)
+            list(APPEND LEATHERMAN_TEST_SRCS "${FILE}")
+        else()
+            list(APPEND LEATHERMAN_TEST_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/${FILE}")
+        endif()
+    endforeach()
+    export_var(LEATHERMAN_TEST_SRCS)
+endmacro()
+
+
+# Usage: add_leatherman_headers(${DIRECTORIES})
+#
+# Adds the listed directories to the set which will be installed to
+# $PREFIX/include
+macro(add_leatherman_headers)
+    if(LEATHERMAN_INSTALL)
+        foreach(DIR ${ARGV})
+            install(DIRECTORY "${DIR}" DESTINATION include)
+        endforeach()
+    endif()
+endmacro()
+
+# Usage: add_leatherman_vendored("pkg.zip" "abcdef..." "include" [SOURCE_DIR])
+#
+# Unpacks a vendored package and installs the headers to include/leatherman/vendor
+# Optionally, a variable can be passed as the last argument that's set to the
+# unpacked location, in case it's needed for compiling a simple library.
+macro(add_leatherman_vendored pkg md5 header_path)
+    unpack_vendored(${pkg} ${md5} SOURCE_DIR)
+
+    set(include_dir "${SOURCE_DIR}/${header_path}")
+    add_leatherman_includes(${include_dir})
+
+    if (LEATHERMAN_INSTALL)
+        install(DIRECTORY "${include_dir}/" DESTINATION "include/leatherman/vendor")
+    endif()
+
+    add_custom_target(${dirname} DEPENDS ${pkg})
+
+    if (ARGV4)
+        set(${ARGV4} ${SOURCE_DIR})
+    endif()
+endmacro()
+
+####
+# Macros for use in the top-level leatherman CMakeLists.txt
+#
+# These macros are used to build up the variables which are passed
+# into whatever project is including leatherman
+####
+
+# Usage: add_leatherman_dir(subdir [EXCLUDE_FROM_VARS])
+#
+# Creates all of the CMake variables intended to be used by consumers
+# of leatherman, including the ENABLE flag.
+#
+# If the enable flag is set, also sets up the variables used by the
+# library API macros and adds the named subdirectory to the CMake
+# project.
+#
+# If EXCLUDE_FROM_VARS is present, this library will not be added to
+# the LEATHERMAN_LIBRARIES and LEATHERMAN_INCLUDE variables. The
+# LEATHERMAN_<LIBRARY>_<FIELD> variables will still be set.
+macro(add_leatherman_dir dir)
+    debug("Setting up leatherman library for ${dir}")
+    string(MAKE_C_IDENTIFIER "${dir}" id)
+    string(TOUPPER "${id}" id_upper)
+    set(dirname "${dir}") # Used by other macros to know our human-readable name
+    set(option "LEATHERMAN_USE_${id_upper}")
+    set(include_dir "${CMAKE_CURRENT_SOURCE_DIR}/${dir}/inc")
+    set(libname "leatherman_${id}")
+
+    defoption(${option} "Should ${dir} be built and used?" ${LEATHERMAN_DEFAULT_ENABLE})
+    if (${${option}})
+        set(include_var "LEATHERMAN_${id_upper}_INCLUDE")
+        set(lib_var "LEATHERMAN_${id_upper}_LIB")
+        set(deps_var "LEATHERMAN_${id_upper}_DEPS")
+ 
+        set(${include_var} ${include_dir})
+        set(${lib_var} "") # if library is built, this will be set automatically
+
+        # By adding the subdirectory after setting all variables, but
+        # before exporting, we give the library an opportunity to
+        # munge them (for example, to add vendor dirs)
+        add_subdirectory("${dir}")
+
+        if (LEATHERMAN_INSTALL)
+            if ("${ARGV1}" STREQUAL EXCLUDE_FROM_VARS)
+                set(COMPONENT_STRING "leatherman_component(${id} EXCLUDE_FROM_VARS)")
+            else()
+                set(COMPONENT_STRING "leatherman_component(${id})")
+            endif()
+            install(FILES "${dir}/CMakeLists.txt" DESTINATION "lib${LIB_SUFFIX}/cmake/leatherman" RENAME "${id}.cmake")
+            set(LEATHERMAN_COMPONENTS "${LEATHERMAN_COMPONENTS}\n${COMPONENT_STRING}")
+        endif()
+
+        # We set this one afterwards because it doesn't need
+        # overriding
+        set(libs_var "LEATHERMAN_${id_upper}_LIBS")
+        set(${libs_var} ${${lib_var}} ${${deps_var}})
+
+        if(NOT "${ARGV1}" STREQUAL EXCLUDE_FROM_VARS)
+            debug("Appending values for ${id_upper} to common vars")
+            list(APPEND LEATHERMAN_INCLUDE_DIRS ${${include_var}})
+            if (NOT "" STREQUAL "${${lib_var}}")
+                # Prepend leatherman libraries, as later libs may depend on earlier libs.
+                list(INSERT LEATHERMAN_LIBS 0 ${${lib_var}})
+            endif()
+            append_new(LEATHERMAN_DEPS ${${deps_var}})
+        else()
+            debug("Excluding values for ${id_upper} from common vars")
+        endif()
+
+        export_var(${include_var})
+        export_var(${lib_var})
+        export_var(${libs_var})
+        export_var(${deps_var})
+
+        # Enable cppcheck on this library
+        list(APPEND LEATHERMAN_CPPCHECK_DIRS "${CMAKE_SOURCE_DIR}/${dir}")
+    endif()
+endmacro(add_leatherman_dir)