card-mod-script 0.13.1 → 0.14.0

data/assets/script/decko/nest_editor.js.coffee

@@ -0,0 +1,166 @@
+$(document).ready ->
+  $('body').on 'click', 'button._nest-apply', () ->
+    if $(this).data("index")?
+      nest.applyNestToNestListEditor($(this).data("index"))
+    else
+      nest.applyNestToTinymceEditor($(this).data("tinymce-id"), $(this).data("tm-snippet-start"), $(this).data("tm-snippet-size"))
+
+  $('body').on 'click', 'button._change-create-to-update', () ->
+    tm_id = $(this).closest("form").find("#success_tinymce_id").val()
+    nest.changeCreateToUpdate(tm_id)
+
+  $('body').on 'click', 'button._open-nest-editor', () ->
+    form = $(this).closest("._nest-form")
+    reference = form.find("._reference").val()
+    nest_options = form.find("._nest-options").val()
+    encoded_nest = encodeURIComponent "{{#{reference}|#{nest_options}}}"
+    nest.openNestEditorForSlot(
+      $(this).closest(".card-slot"),
+      $(this).closest(".slotter"),
+      "index=#{form.data('index')}&tm_snippet_raw=#{encoded_nest}"
+    )
+
+
+window.nest ||= {}
+
+$.extend nest,
+  # called by TinyMCE
+  openNestEditor: (tm, params) ->
+    params = nest.editParams(tm) unless params?
+    this.openEditorForTm(tm, params, "nest_editor", "modal_nest_editor")
+
+  openNestEditorForSlot: (slot, slotter, params) ->
+    card = if slot[0] then $(slot[0]).attr('data-card-name') else ":update"
+    nest.request(card, "nest_editor", "modal_nest_editor", slotter, params)
+
+  openEditorForTm: (tm, params, overlay_view, modal_view) ->
+    params += "&tinymce_id=#{tm.id}"
+    slot = $("##{tm.id}").closest(".card-slot")
+    slotter = $("##{tm.id}")
+    card = if slot[0] then $(slot[0]).attr('data-card-name') else ":update"
+    nest.request(card, overlay_view, modal_view, slotter, params)
+
+  # called by TinyMCE
+  openImageEditor: (tm) ->
+    params = nest.editParams(tm, "{{", "}}", false) unless params?
+    this.openEditorForTm(tm, params,"nest_image", "modal_nest_image")
+
+  changeCreateToUpdate: (tm_id) ->
+    form = $("##{tm_id}").closest("form")
+    new_action = form.attr("action").replace("card/create", "card/update")
+    form.attr("action", new_action)
+
+  insertNest: (tm, nest_string) ->
+    tm.insertContent(nest_string)
+    # insertIndex = nest.offsetAfterInsert(tm, nest_string)
+    # params = nest.paramsStr(insertIndex, nest_string)
+    # nest.openNestEditor(etm, params)
+
+
+  request: (card, overlay_view, modal_view, slotter, params) ->
+    slot = $(".bridge-sidebar > ._overlay-container-placeholder > .card-slot")
+
+    if slot[0]
+      view = overlay_view
+      mode = "overlay"
+    else
+      slot = $($(".card-slot")[0])
+      view = modal_view
+      mode = "modal"
+
+    nest.sendRequest(slotter, slot, mode, card, view, params)
+
+  sendRequest: (slotter, slot, mode, card, view, params) ->
+      params = "" unless params?
+      url = "/#{card}?view=#{view}&#{params}"
+      $.ajax
+        url: url
+        type: 'GET'
+        success: (html) ->
+          slot.setSlotContent html, mode, slotter
+
+  editParams: (tm, prefix="{{", postfix="}}", edit=true) ->
+    sel = tm.selection.getSel()
+    return nest.paramsStr(0) unless sel? and sel.anchorNode?
+
+    text = sel.anchorNode.data
+    return nest.paramsStr(sel.anchorOffset) unless text
+
+    offset = sel.anchorOffset
+    before = text.substr(0, offset)
+    after =  text.substr(offset)
+    index = {
+      before: {
+        close: before.lastIndexOf(postfix)
+        open: before.lastIndexOf(prefix)
+      },
+      after: {
+        close: after.indexOf(postfix)
+        open: after.indexOf(prefix)
+      }
+    }
+    if index.before.open > index.before.close &&
+       index.after.close != -1 &&
+       (index.after.open == -1 || index.after.close < index.after.open)
+      nest_start = index.before.open
+      unless name?
+        nest_size = index.after.close + offset + 2 - nest_start
+        name = text.substr(nest_start, nest_size)
+      if edit
+        nest.paramsStr(nest_start, name)
+      else
+        nest.paramsStr(nest_start + nest_size)
+    else
+      nest.paramsStr(offset)
+
+  paramsStr: (start, name) ->
+    params = ""
+    if start?
+      params += "&tm_snippet_start=#{start}"
+    if name? and name.length > 0
+      params += "&tm_snippet_raw=#{encodeURIComponent(name)}"
+
+    params
+
+  offsetAfterInsert: (editor, content) ->
+    offset = editor.selection.getSel().anchorOffset
+    offset - content.lengthr
+
+  applyNestToTinymceEditor: (tinymce_id, nest_start, nest_size) ->
+    nest.applySnippet("nest", tinymce_id, nest_start, nest_size)
+
+  applyNestToNestListEditor: (index) ->
+    row = $("._nest-form[data-index='#{index}']")
+    row.find("._reference").val(nest.name())
+    row.find("._nest-options").val(nest.options())
+    decko.updateAddItemButton(row)
+
+
+  applySnippet: (snippet_type, tinymce_id, start, size) ->
+    content = $("._#{snippet_type}-preview").val()
+    editor = tinymce.get(tinymce_id)
+    if start?
+      nest.replaceSnippet(editor, start, size, content)
+    else
+      editor.insertContent content
+      offset = nest.offsetAfterInsert(editor, content)
+      $("button._#{snippet_type}-apply").attr("data-tm-snippet-start", offset)
+
+    $("button._#{snippet_type}-apply").attr("data-tm-snippet-size", content.length)
+
+  replaceSnippet: (editor, start, size, content) ->
+    sel = editor.selection.getSel()
+    if sel? and sel.anchorNode? and sel.anchorNode.data?
+      text = sel.anchorNode.data
+      size = 0 unless size?
+      text = "#{text.substr(0, start)}#{content}#{text.substr(start + size)}"
+      sel.anchorNode.data = text
+    else
+      editor.insertContent content
+
+  updatePreview: (new_val) ->
+    new_val = "{{#{nest.name()}|#{nest.options()}}}" unless new_val?
+    preview = $("._nest-preview")
+    preview.val new_val
+    preview.data("nest-options", nest.options())
+    preview.data("reference", nest.name())

data/assets/script/decko/nest_editor_name.js.coffee

@@ -0,0 +1,102 @@
+nestNameTimeout = null
+
+$(document).ready ->
+  $('body').on 'click', '._nest-field-toggle', () ->
+    if $(this).is(':checked')
+      nest.addPlus()
+    else
+      nest.removePlus()
+
+  $('body').on 'input', 'input._nest-name', (event) ->
+    nest.nameChanged()
+
+    unless event.which == 13
+      clearTimeout(nestNameTimeout) if nestNameTimeout
+      nestNameTimeout = setTimeout (-> nest.updateNameRelatedTabs()), 700
+
+  $('body').on 'keydown', 'input._nest-name', (event) ->
+    if event.which == 13
+      clearTimeout(nestNameTimeout) if nestNameTimeout
+      nest.updateNameRelatedTabs()
+
+$.extend nest,
+  name: () ->
+    nest.evalFieldOption $('input._nest-name').val()
+
+  nameChanged: () ->
+    new_val = $("._nest-preview").val().replace(/^\{\{[^}|]*/, "{{" + nest.name())
+    nest.updatePreview new_val
+
+  evalFieldOption: (name) ->
+    if nest.isField() then "+#{name}" else name
+
+  isField: ->
+    $('._nest-field-toggle').is(":checked")
+
+  addPlus: () ->
+    new_val = $("._nest-preview").val().replace(/^\{\{\+?/, "{{+")
+    nest.updatePreview new_val
+    $(".input-group.hide-prefix").removeClass("hide-prefix").addClass("show-prefix")
+
+  removePlus: () ->
+    new_val = $("._nest-preview").val().replace(/^\{\{\+?/, "{{")
+    nest.updatePreview new_val
+    $(".input-group.show-prefix").removeClass("show-prefix").addClass("hide-prefix")
+
+  rulesTabSlot: () ->
+    $("._nest-editor .tab-pane-rules > .card-slot")
+
+  contentTabSlot: () ->
+    $("._nest-editor .tab-pane-content > .card-slot")
+
+  emptyNameAlert: (show) ->
+    if show
+      $("._empty-nest-name-alert").removeClass("d-none")
+    else
+      $("._empty-nest-name-alert:not(.d-none)").addClass("d-none")
+
+  updateNameRelatedTabs: () ->
+    nest.updateRulesTab()
+    nest.updateContentTab()
+
+  updateContentTab: () ->
+    $contentTab = nest.contentTabSlot()
+    if $contentTab.length > 0
+      url = decko.path "#{nest.fullName()}?view=nest_content"
+      nest.updateNameDependentSlot($contentTab, url)
+
+  updateRulesTab: () ->
+    $rulesTab = nest.rulesTabSlot()
+    url = decko.path "#{nest.setNameForRules()}?view=nest_rules"
+    nest.updateNameDependentSlot($rulesTab, url)
+
+  updateNameDependentSlot: ($slot, url) ->
+    name = $("input._nest-name").val()
+    if name? && name.length > 0
+      nest.emptyNameAlert(false)
+      $slot.reloadSlot url
+    else
+      $slot.clearSlot()
+      nest.emptyNameAlert(true)
+
+  fullName: () ->
+    input = $('input._nest-name')
+    nest_name = input.val()
+    if nest.isField() and input.attr("data-left-name")
+      "#{input.attr("data-left-name")}+#{nest_name}"
+    else
+      nest_name
+
+#  set in the sense of card set
+  setNameForRules: () ->
+    input = $('input._nest-name')
+    nest_name = input.val()
+    if nest.isField()
+      if input.attr("data-left-type")
+        "#{input.attr("data-left-type")}+#{nest_name}+*type plus right"
+      else
+        "#{nest_name}+*right"
+    else
+      return  "#{nest_name}+*self"
+
+

data/assets/script/decko/nest_editor_options.js.coffee

@@ -0,0 +1,93 @@
+$(document).ready ->
+  $('body').on 'keyup', 'input._nest-option-value', () ->
+    nest.updatePreview()
+
+  $('body').on "select2:select", "._nest-option-name", () ->
+    nest.toggleOptionName($(this).closest("._options-select"), $(this).val(), true)
+    nest.updatePreview()
+
+  $('body').on "select2:selecting", "._nest-option-name", () ->
+    nest.toggleOptionName($(this).closest("._options-select"), $(this).val(), false)
+
+  $('body').on "select2:select", "._nest-option-name._new-row", () ->
+    $(this).closest(".input-group").find(".input-group-prepend").removeClass("d-none")
+    row =  $(this).closest("._nest-option-row")
+    row.find("._nest-option-value").removeAttr("disabled")
+    template = row.parent().find("._nest-option-row._template")
+    $(this).removeClass("_new-row")
+    nest.addRow(template)
+
+  $('body').on "click", "._configure-items-button", () ->
+    nest.addItemsOptions($(this))
+
+  $('body').on 'click', 'button._nest-delete-option', () ->
+    nest.removeRow $(this).closest("._nest-option-row")
+
+$.extend nest,
+  showTemplate: (elem) ->
+    elem.removeClass("_template") #.removeClass("_#{name}-template").addClass("_#{name}")
+
+  addRow: (template) ->
+    select_tag = template.find("select")
+    select_tag.select2("destroy")
+    select_tag.removeAttr("data-select2-id")
+    double = template.clone()
+    #double = template.cloneSelect2(true, true)
+    decko.initSelect2(select_tag)
+    nest.showTemplate template
+    template.after(double)
+    decko.initSelect2(double.find("select"))
+
+  removeRow: (row) ->
+    name = row.find("._nest-option-name").val()
+    nest.toggleOptionName(row.closest("._options-select"), name,false)
+    row.remove()
+    nest.updatePreview()
+
+  addItemsOptions: (button) ->
+    container = button.closest("._configure-items")
+    next = container.cloneSelect2(true)
+    title = button.text()
+    button.replaceWith($("<h6>#{title.substr(9)}<h6>"))
+    nest.showTemplate container.find("._options-select._template")
+    next.find("._configure-items-button").text(title.replace("items", "subitems"))
+    container.after(next)
+    nest.updatePreview()
+
+  options: () ->
+    options = []
+    for ele in $("._options-select:not(._template")
+      options.push nest.extractOptions($(ele))
+
+    level_options = options.map (opts) ->
+                      nest.toNestSyntax(opts)
+    level_options.join "|"
+
+  # extract options for one item level
+  extractOptions: (ele) ->
+    options = {}
+    nest.addOption(options, $(row)) for row in ele.find("._nest-option-row:not(.template)")
+    options
+
+  addOption: (options, row) ->
+    val = row.find("._nest-option-value").val()
+    return unless val? && val.length > 0
+
+    name = row.find("._nest-option-name").val()
+    if options[name]?
+      options[name].push val
+    else
+      options[name] = [val]
+
+  toggleOptionName: (container, name, active) ->
+    return true if name == "show" || name == "hide"
+    for sel in container.find("._nest-option-name")
+      if $(sel).val() != name
+        $(sel).find("option[value=#{name}]").attr "disabled", active
+      # $(sel).find("option[value=#{val}]").removeAttr "disabled"
+      decko.initSelect2($(sel))
+
+  toNestSyntax: (opts) ->
+    str = []
+    str.push "#{name}: #{values.join ', '}" for name, values of opts
+    str.join "; "

data/assets/script/decko/nest_editor_rules.js.coffee

@@ -0,0 +1,3 @@
+
+
+

data/assets/script/decko/overlay.js.coffee

@@ -0,0 +1,54 @@
+jQuery.fn.extend
+  overlaySlot: ->
+    oslot = @closest(".card-slot._overlay")
+    return oslot if oslot[0]?
+    oslot = @closest(".overlay-container").find("._overlay")
+    oslot[0]? && $(oslot[0])
+
+  addOverlay: (overlay, $slotter) ->
+    if @parent().hasClass("overlay-container")
+      if $(overlay).hasClass("_stack-overlay")
+        @before overlay
+      else
+        $("._overlay-origin").removeClass("_overlay-origin")
+        @replaceOverlay(overlay)
+    else
+      if @parent().hasClass("_overlay-container-placeholder")
+        @parent().addClass("overlay-container")
+      else
+        @wrapAll('<div class="overlay-container">')
+      @addClass("_bottomlay-slot")
+      @before overlay
+
+    $slotter.registerAsOrigin("overlay", overlay)
+    decko.contentLoaded(overlay, $slotter)
+
+  replaceOverlay: (overlay) ->
+    @overlaySlot().trigger "slotDestroy"
+    @overlaySlot().replaceWith overlay
+    $(".bridge-sidebar .tab-pane:not(.active) .bridge-pills > .nav-item > .nav-link.active").removeClass("active")
+
+  isInOverlay: ->
+    return @closest(".card-slot._overlay").length
+
+  removeOverlay: () ->
+      slot = @overlaySlot()
+      if slot
+        slot.removeOverlaySlot()
+
+  removeOverlaySlot: () ->
+    @trigger "slotDestroy"
+    if @siblings().length == 1
+      bottomlay = $(@siblings()[0])
+      if bottomlay.hasClass("_bottomlay-slot")
+        if bottomlay.parent().hasClass("_overlay-container-placeholder")
+          bottomlay.parent().removeClass("overlay-container")
+        else
+          bottomlay.unwrap()
+        bottomlay.removeClass("_bottomlay-slot").updateBridge(true, bottomlay)
+
+        #bottomlay.find(".tinymce-textarea").each ->
+        #  tinymce.EditorManager.execCommand('mceAddControl',true, editor_id);
+        #  decko.initTinyMCE($(this).attr("id"))
+
+    @remove()

data/assets/script/decko/pointer_config.js.coffee

@@ -0,0 +1,79 @@
+$.extend decko.editorContentFunctionMap,
+    'select.pointer-select': ->
+      pointerContent @val()
+    'select.pointer-multiselect': ->
+      pointerContent @val()
+    '.pointer-radio-list': ->
+      pointerContent @find('input:checked').val()
+    '.pointer-list-ul': ->
+      pointerContent @find('input').map( -> $(this).val() )
+    '.pointer-link-list-ul': ->
+      decko.linkListContent @find('.input-group')
+    '._nest-list-ul': ->
+      decko.nestListContent @find('.input-group')
+    '.pointer-checkbox-list': ->
+      pointerContent @find('input:checked').map( -> $(this).val() )
+    '.pointer-select-list': ->
+      pointerContent @find('.pointer-select select').map( -> $(this).val() )
+    '._pointer-filtered-list': ->
+      pointerContent @find('._filtered-list-item').map( -> $(this).data('cardName') )
+    '._pointer-list': ->
+      pointerContent @find('._pointer-item').map( -> $(this).val() )
+    # can't find evidence that the following is in use: #efm
+    # '.pointer-mixed': ->
+    #   element = '.pointer-checkbox-sublist input:checked,\
+    #             .pointer-sublist-ul input'
+    #   pointerContent @find(element).map( -> $(this).val() )
+    # must happen after pointer-list-ul, I think
+    '.perm-editor': -> permissionsContent this
+
+decko.editorInitFunctionMap['.pointer-list-editor'] = ->
+  @sortable({handle: '.handle', cancel: ''})
+  decko.initPointerList @find('input')
+
+decko.editorInitFunctionMap['._pointer-filtered-list'] = ->
+  @sortable({handle: '._handle', cancel: ''})
+
+$.extend decko,
+  initPointerList: (input) ->
+    decko.initAutoCardPlete input
+
+  initAutoCardPlete: (input) ->
+    optionsCard = input.data 'options-card'
+    return unless !!optionsCard
+    path = optionsCard + '.json?view=name_match'
+    input.autocomplete { source: decko.slotPath(path) }
+
+  pointerContent: (vals) ->
+    $.makeArray(vals).join "\n"
+
+  linkListContent: (input_groups) ->
+    vals = input_groups.map( ->
+      v = $(this).find('input._reference').val()
+      title = $(this).find('input._title').val()
+      v += "|#{title}" if title.length > 0
+      v
+    )
+    list = $.map $.makeArray(vals), (v) -> if v then '[[' + v + ']]'
+    $.makeArray(list).join "\n"
+
+  nestListContent: (input_groups) ->
+    vals = input_groups.map( ->
+      v = $(this).find('input._reference').val()
+      options = $(this).find('input._nest-options').val()
+      v += "|#{options}" if options.length > 0
+      v
+    )
+    list = $.map $.makeArray(vals), (v) -> if v then '{{' + v + '}}'
+    $.makeArray(list).join "\n"
+
+
+pointerContent = (vals) ->
+  decko.pointerContent vals
+  # deprecated. backwards compatibility
+
+permissionsContent = (ed) ->
+  return '_left' if ed.find('#inherit').is(':checked')
+  groups = ed.find('.perm-group input:checked').map( -> $(this).val() )
+  indivs = ed.find('.perm-indiv input'        ).map( -> $(this).val() )
+  pointerContent $.makeArray(groups).concat($.makeArray(indivs))

data/assets/script/decko/pointer_list_editor.js.coffee

@@ -0,0 +1,67 @@
+$(window).ready ->
+  # add pointer item when clicking on "add another" button
+  $('body').on 'click', '._pointer-item-add', (event)->
+    decko.addPointerItem this
+    event.preventDefault() # Prevent link from following its href
+
+  # add pointer item when you hit enter in an item
+  $('body').on 'keydown', '.pointer-item-text', (event)->
+    if event.key == 'Enter'
+      decko.addPointerItem this
+      event.preventDefault() # was triggering extra item in unrelated pointer
+
+  # enable/disable add
+  $('body').on 'keyup', '.pointer-item-text', (_event)->
+    decko.updateAddItemButton this
+
+  $('body').on 'click', '.pointer-item-delete', ->
+    item = $(this).closest 'li'
+    list =  item.closest('ul')
+    if list.find('.pointer-li').length > 1
+      item.remove()
+    else
+      item.find('input').val ''
+    decko.updateAddItemButton(list)
+
+decko.slotReady (slot) ->
+  slot.find('.pointer-list-editor').each ->
+    decko.updateAddItemButton this
+
+$.extend decko,
+  addPointerItem: (el) ->
+    slot = $(el).slot()
+    slot.trigger "slotDestroy"
+    # why is this necessary?
+    # this can have a lot of side effects in a multi-card form.
+
+    newInput = decko.nextPointerInput decko.lastPointerItem(el)
+    newInput.val ''
+
+    slot.trigger "slotReady"
+    decko.initializeEditors slot
+    # should be (but is not) handled by slotReady
+    # without this, "add another" was breaking tinymce editors in same slot
+
+    newInput.first().focus()
+    decko.updateAddItemButton el
+    decko.initPointerList newInput
+
+  nextPointerInput: (lastItem)->
+    lastInputs = lastItem.find 'input'
+    all_empty = true
+    for input in lastInputs
+        all_empty  = all_empty and $(input).val() == ''
+    return lastInputs if all_empty
+
+    newItem = lastItem.clone()
+    lastItem.after newItem
+    newItem.attr("data-index", parseInt(lastItem.attr("data-index") + 1))
+    newItem.find 'input'
+
+  lastPointerItem: (el)->
+    $(el).closest('.content-editor').find '.pointer-li:last'
+
+  updateAddItemButton: (el)->
+    button = $(el).closest('.content-editor').find '._pointer-item-add'
+    disabled = decko.lastPointerItem(el).find('input').val() == ''
+    button.prop 'disabled', disabled

data/assets/script/decko/recaptcha.js.coffee

@@ -0,0 +1,19 @@
+jQuery.fn.extend {
+  updateRecaptchaToken: (event) ->
+    recaptcha = @find("input._recaptcha-token")
+
+    if !recaptcha[0]?
+      recaptcha.val "recaptcha-token-field-missing"
+    else if !grecaptcha?
+      recaptcha.val("grecaptcha-undefined")
+    else
+      $slotter = $(this)
+      event.stopPropagation() if event
+      grecaptcha.execute(recaptcha.data("site-key"), action: recaptcha.data("action"))
+        .then (token) ->
+          recaptcha.val(token)
+          recaptcha.addClass("_token-updated")
+          if event
+            $slotter.submit()
+      false
+  }

data/assets/script/decko/selectable_filtered_content.js.coffee

@@ -0,0 +1,12 @@
+$(window).ready ->
+
+  # TODO: generalize so this works with item views other than bar
+  $("body").on "click", "._selectable-filtered-content .bar-body", (e) ->
+    item = $(this)
+    name = item.slot().data("card-name")
+    container = item.closest("._selectable-filtered-content")
+    input = $(container.data("input-selector"))
+    input.val name
+    item.closest('.modal').modal('hide')
+    e.preventDefault()
+    e.stopPropagation()