card-mod-script 0.13.1 → 0.13.2

data/assets/script/decko/filter_items.js.coffee

@@ -0,0 +1,128 @@
+# FILTERED LIST / ITEMS INTERFACE
+# (fancy pointer ui)
+
+$(window).ready ->
+# add all selected items
+  $("body").on "click", "._filter-items ._add-selected", ->
+    btn = $(this)
+    content = newFilteredListContent btn
+    btn.attr "href", addSelectedButtonUrl(btn, content)
+
+  # select all visible filtered items
+  $("body").on "click", "._select-all", ->
+    filterBox($(this)).find("._unselected input._checkbox-list-checkbox").each ->
+      selectFilteredItem $(this)
+    $(this).prop "checked", false
+    updateAfterSelection $(this)
+
+  # deselect all selected items
+  $("body").on "click", "._deselect-all", ->
+    filterBox($(this)).find("._selected input._checkbox-list-checkbox").each ->
+      $(this).slot().remove()
+    $(this).prop "checked", true
+    updateAfterSelection $(this)
+
+  $("body").on "click", "._filter-items ._unselected input._checkbox-list-checkbox", ->
+    selectFilteredItem $(this)
+    updateAfterSelection $(this)
+
+  $("body").on "click", "._filter-items ._selected input._checkbox-list-checkbox", ->
+    bin = selectedBin $(this)
+    $(this).slot().remove()
+    updateAfterSelection bin
+
+  $('body').on 'click', '._filtered-list-item-delete', ->
+    $(this).closest('li').remove()
+
+# TODO: make this object oriented!
+
+newFilteredListContent = (el) ->
+  $.map(prefilteredIds(el).concat(selectedIds el), (id) -> "~" + id).join "\n"
+
+addSelectedButtonUrl = (btn, content) ->
+  view = btn.slot().data("slot")["view"]
+  card_args = { content: content, type: "Pointer" }
+  query = { assign: true, view: view, card: card_args }
+  path_base = btn.attr("href") + "&" + $.param(query)
+  decko.slotPath path_base, btn.slot()
+
+updateAfterSelection = (el) ->
+  trackSelectedIds el
+  f = new decko.filter(filterBox(el).find('._filter-widget'))
+  f.update()
+  updateSelectedCount el
+  updateUnselectedCount el
+
+updateSelectedCount = (el) ->
+  count = selectedBin(el).children().length
+  filterBox(el).find("._selected-items").html count
+  deselectAllLink(el).attr "disabled", count == 0
+  if count > 0
+    addSelectedButton(el).removeClass("disabled")
+  else
+    addSelectedButton(el).addClass("disabled")
+
+  updateSelectedSectionVisibility el, count > 0
+
+updateSelectedSectionVisibility = (el, items_present) ->
+  box = filterBox el
+  selected_items = box.find "._selected-item-list"
+  help_text = box.find "._filter-help"
+  if items_present
+    selected_items.show()
+    help_text.hide()
+  else
+    selected_items.hide()
+    help_text.show()
+
+updateUnselectedCount = (el) ->
+  box = filterBox(el)
+  count = box.find("._search-checkbox-list").children().length
+  box.find("._unselected-items").html count
+  box.find("._select-all").attr "disabled", count > 0
+
+selectFilteredItem = (checkbox) ->
+  checkbox.prop "checked", true
+  selectedBin(checkbox).append checkbox.slot()
+
+selectedBin = (el) ->
+  filterBox(el).find "._selected-bin"
+
+filterBox = (el) ->
+  el.closest "._filter-items"
+
+# this button contains the data about the form that opened the filter-items interface.
+# the itemSelector
+addSelectedButton = (el) ->
+  filterBox(el).find("._add-selected")
+
+deselectAllLink = (el) ->
+  filterBox(el).find("._deselect-all")
+
+selectedIds = (el) ->
+  selectedData el, "cardId"
+
+prefilteredIds = (el) ->
+  prefilteredData el, "cardId"
+
+prefilteredNames = (el) ->
+  prefilteredData el, "cardName"
+
+prefilteredData = (el, field) ->
+  btn = addSelectedButton el
+  selector = btn.data "itemSelector"
+  arrayFromField btn.slot().find(selector), field
+
+selectedNames = (el) ->
+  selectedData el, "cardName"
+
+selectedData = (el, field) ->
+  arrayFromField selectedBin(el).children(), field
+
+arrayFromField = (rows, field) ->
+  rows.map( -> $(this).data field ).toArray()
+
+trackSelectedIds = (el) ->
+  ids = prefilteredIds(el).concat selectedIds(el)
+  box = filterBox el
+  box.find("._not-ids").val ids.toString()

data/assets/script/decko/filter_links.js.coffee

@@ -0,0 +1,81 @@
+decko.slotReady (slot) ->
+  slot.find("._filter-widget").each ->
+    if slot[0] == $(this).slot()[0]
+      filter = new decko.filter this
+      filter.showWithStatus "active"
+      filter.updateLastVals()
+      filter.updateQuickLinks()
+
+$(window).ready ->
+  filterFor = (el) ->
+    new decko.filter el
+
+  # sometimes this element shows up as changed and breaks the filter.
+  weirdoSelect2FilterBreaker = (el) ->
+    $(el).hasClass "select2-search__field"
+
+  filterableData = (filterable) ->
+    f = $(filterable)
+    f.data("filter") || f.find("._filterable").data("filter")
+
+  targetFilter = (filterable) ->
+    selector = $(filterable).closest("._filtering").data("filter-selector")
+    filterFor (selector || this)
+
+  # Add Filter
+  $("body").on "click", "._filter-category-select", (e) ->
+    e.preventDefault()
+    # e.stopPropagation()
+    f = filterFor(this)
+    category = $(this).data("category")
+    f.activate category
+    f.updateIfPresent category
+
+  # Update filter results based on filter value changes
+  onchangers =
+    "._filter-input input:not(.simple-text), ._filter-input select, ._filter-sort"
+  $("body").on "change", onchangers, ->
+    return if weirdoSelect2FilterBreaker this
+    filterFor(this).update()
+
+  # update filter result after typing in text box
+  keyupTimeout = null
+  $("body").on "keyup", "._filter-input input.simple-text", ->
+    clearTimeout keyupTimeout
+    filter = filterFor this
+    keyupTimeout = setTimeout ( -> filter.updateIfChanged() ), 333
+
+  # remove filter
+  $("body").on "click", "._delete-filter-input", ->
+    filter = filterFor this
+    filter.removeField $(this).closest("._filter-input").data("category")
+    filter.update()
+
+  # reset all filters
+  $('body').on 'click', '._reset-filter', () ->
+    f = filterFor(this)
+    f.reset()
+    f.update()
+
+  $('body').on 'click', '._filtering ._filterable', (e) ->
+    f = targetFilter this
+    if f.widget.length
+      f.restrict filterableData(this)
+    e.preventDefault()
+    e.stopPropagation()
+
+  $('body').on 'click', '._filter-link', (e) ->
+    f = filterFor this
+    link = $(this)
+    filter_data = link.data "filter"
+    if inactiveQuickfilter link
+      f.removeRestrictions filter_data
+    else
+      f.addRestrictions filter_data
+
+    e.preventDefault()
+    e.stopPropagation()
+
+  inactiveQuickfilter = (link) ->
+    !link.hasClass("active") && link.closest(".quick-filter").length > 0
+

data/assets/script/decko/follow.js.coffee

@@ -0,0 +1,22 @@
+$(window).ready ->
+  $('body').on 'click', '.btn-item', ->
+    $(this).find('i').html('hourglass_full')
+
+  $('body').on 'mouseenter', '.btn-item-delete', ->
+    $(this).find('i').html('remove')
+    $(this).addClass("btn-danger").removeClass("btn-primary")
+
+  $('body').on 'mouseleave', '.btn-item-delete', ->
+    $(this).find('i').html('check')
+    $(this).addClass("btn-primary").removeClass("btn-danger")
+
+  $('body').on 'click', '.follow-updater', ->
+    $(this).closest('form').find('#card_update_all_users').val 'true'
+
+  $('body').on 'submit', '.edit-view.SELF-Xfollow_default .card-form', ->
+    confirmer = $(this).find '.confirm_update_all-view'
+    if confirmer.is ':hidden'
+      $(this).find('.follow-updater').show()
+
+      confirmer.show 'blind'
+      false

data/assets/script/decko/layout.js.coffee

@@ -0,0 +1,76 @@
+wrapDeckoLayout = ->
+  $footer  = $('body > footer').first()
+  $('body > article, body > aside').wrapAll("<div class='#{containerClass()}'/>")
+  $('body > div > article, body > div > aside')
+    .wrapAll('<div class="row row-offcanvas">')
+  if $footer
+    $('body').append $footer
+
+wrapSidebarToggle = (toggle, flex) ->
+  "<div class='container'><div class='row #{flex}'>#{toggle}</div></div>"
+
+containerClass = ->
+  if $('body').hasClass('fluid') then "container-fluid" else "container"
+
+toggleButton = (side) ->
+  icon_dir = if side == 'left' then 'right' else 'left'
+  "<button class='offcanvas-toggle btn btn-secondary "+
+    "d-sm-none' data-toggle='offcanvas-#{side}'>" +
+    "<i class='material-icons'>chevron_#{icon_dir}</i></button>"
+
+sidebarToggle = (side) ->
+  if side == "both"
+    wrapSidebarToggle(toggleButton("left") + toggleButton("right"), "flex-row justify-content-between")
+  else if side == "left"
+    wrapSidebarToggle(toggleButton("left"), "flex-row")
+  else
+    wrapSidebarToggle(toggleButton("right"), "flex-row-reverse")
+
+singleSidebar = (side) ->
+  $article = $('body > article').first()
+  $aside   = $('body > aside').first()
+  $article.addClass("col-xs-12 col-sm-9")
+  $aside.addClass(
+    "col-xs-6 col-sm-3 sidebar-offcanvas sidebar-offcanvas-#{side}"
+  )
+  if side == 'left'
+    $('body').append($aside).append($article)
+  else
+    $('body').append($article).append($aside)
+  wrapDeckoLayout()
+  $article.prepend(sidebarToggle(side))
+
+doubleSidebar = ->
+  $article    = $('body > article').first()
+  $asideLeft  = $('body > aside').first()
+  $asideRight = $($('body > aside')[1])
+  $article.addClass("col-xs-12 col-sm-6")
+  sideClass = "col-xs-6 col-sm-3 sidebar-offcanvas"
+  $asideLeft.addClass("#{sideClass} sidebar-offcanvas-left")
+  $asideRight.addClass("#{sideClass} sidebar-offcanvas-right")
+  $('body').append($asideLeft).append($article).append($asideRight)
+  wrapDeckoLayout()
+  toggles = sidebarToggle('both')
+  $article.prepend(toggles)
+
+$.fn.extend toggleText: (a, b) ->
+  @text(if @text() == b then a else b)
+
+  this
+$(window).ready ->
+  switch
+    when $('body').hasClass('right-sidebar')
+      singleSidebar('right')
+    when $('body').hasClass('left-sidebar')
+      singleSidebar('left')
+    when $('body').hasClass('two-sidebar')
+      doubleSidebar()
+
+  $('[data-toggle="offcanvas-left"]').click ->
+    $('.row-offcanvas').removeClass('right-active').toggleClass('left-active')
+    $(this).find('i.material-icons')
+      .toggleText('chevron_left', 'chevron_right')
+  $('[data-toggle="offcanvas-right"]').click ->
+    $('.row-offcanvas').removeClass('left-active').toggleClass('right-active')
+    $(this).find('i.material-icons')
+      .toggleText('chevron_left', 'chevron_right')

data/assets/script/decko/link_editor.js.coffee

@@ -0,0 +1,61 @@
+$(document).ready ->
+  $('body').on 'click', 'button._link-apply', () ->
+    link.applyLink($(this).data("tinymce-id"), $(this).data("tm-snippet-start"), $(this).data("tm-snippet-size"))
+
+window.link ||= {}
+
+$(document).ready ->
+  $('body').on 'click', '._link-field-toggle', () ->
+    if $(this).is(':checked')
+      link.addPlus()
+    else
+      link.removePlus()
+
+  $('body').on 'input', 'input._link-target', (event) ->
+    link.targetChanged()
+
+  $('body').on 'input', 'input._link-title', (event) ->
+    link.titleChanged()
+
+$.extend link,
+  # called by TinyMCE
+  openLinkEditor: (tm) ->
+    params = nest.editParams(tm, "[[", "]]") unless params?
+    nest.openEditorForTm(tm, params, "link_editor", "modal_link_editor")
+
+  applyLink: (tinymce_id, link_start, link_size) ->
+    nest.applySnippet("link", tinymce_id, link_start, link_size)
+
+  target: () ->
+    link.evalFieldOption $('input._link-target').val()
+
+  title: () ->
+    $('input._link-title').val()
+
+  titleChanged: () ->
+    new_val = $("._link-preview").val().replace(/^\[\[[^\]]*/, "[[" + link.target() + "|" + link.title())
+    link.updatePreview new_val
+
+  targetChanged: () ->
+    new_val = $("._link-preview").val().replace(/^\[\[[^\]|]*/, "[[" + link.target())
+    link.updatePreview new_val
+
+  evalFieldOption: (name) ->
+    if link.isField() then "+#{name}" else name
+
+  isField: ->
+    $('._link-field-toggle').is(":checked")
+
+  addPlus: () ->
+    new_val = $("._link-preview").val().replace(/^\[\[\+?/, "[[+")
+    link.updatePreview new_val
+    $(".input-group.hide-prefix").removeClass("hide-prefix").addClass("show-prefix")
+
+  removePlus: () ->
+    new_val = $("._link-preview").val().replace(/^\[\[\+?/, "[[")
+    link.updatePreview new_val
+    $(".input-group.show-prefix").removeClass("show-prefix").addClass("hide-prefix")
+
+  updatePreview: (new_val) ->
+    new_val = "[[#{link.target()}|#{link.title()}]]" unless new_val?
+    $("._link-preview").val new_val

data/assets/script/decko/mod.js.coffee

@@ -0,0 +1,85 @@
+
+window.decko ||= {} #needed to run w/o *head.  eg. jasmine
+
+# $.extend decko,
+# Can't get this to work yet.  Intent was to tighten up head tag.
+#  initGoogleAnalytics: (key) ->
+#    window._gaq.push ['_setAccount', key]
+#    window._gaq.push ['_trackPageview']
+#
+#    initfunc = ()->
+#      ga = document.createElement 'script'
+#      ga.type = 'text/javascript'
+#      ga.async = true
+#      ga.src = `('https:' == document.location.protocol ? 'https://ssl' : 'http://www') + '.google-analytics.com/ga.js'`
+#      s = document.getElementsByTagName('script')[0]
+#      s.parentNode.insertBefore ga, s
+#  initfunc()
+
+$(window).ready ->
+  $('body').on 'click', '._stop_propagation', (event)->
+    event.stopPropagation()
+
+  $('body').on 'click', '._prevent_default', (event)->
+    event.preventDefault()
+
+  $('body').on 'mouseenter', 'a[data-hover-text]', ->
+    text = $(this).text()
+    $(this).data("original-text", text)
+    $(this).text($(this).data("hover-text"))
+
+  $('body').on 'mouseleave', 'a[data-hover-text]', ->
+    $(this).text($(this).data("original-text"))
+
+  #decko_org mod (for now)
+  $('body').on 'click', '.shade-view h1', ->
+    toggleThis = $(this).slot().find('.shade-content').is ':hidden'
+    decko.toggleShade $(this).closest('.pointer-list').find('.shade-content:visible').parent()
+    if toggleThis
+      decko.toggleShade $(this).slot()
+
+  if firstShade = $('.shade-view h1')[0]
+    $(firstShade).trigger 'click'
+
+  # performance log mod
+  $('body').on 'click', '.open-slow-items', ->
+    panel = $(this).closest('.panel-group')
+    panel.find('.open-slow-items').removeClass('open-slow-items').addClass('close-slow-items')
+    panel.find('.toggle-fast-items').text("show < 100ms")
+    panel.find('.duration-ok').hide()
+    panel.find('.panel-danger > .panel-collapse').collapse('show').find('a > span').addClass('show-fast-items')
+
+  $('body').on 'click', '.close-slow-items', ->
+    panel = $(this).closest('.panel-group')
+    panel.find('.close-slow-items').removeClass('close-slow-items').addClass('open-slow-items')
+    panel.find('.toggle-fast-items').text("hide < 100ms")
+    panel.find('.panel-danger > .panel-collapse').collapse('hide').removeClass('show-fast-items')
+    panel.find('.duration-ok').show()
+
+  $('body').on 'click', '.toggle-fast-items', ->
+    panel = $(this).closest('.panel-group')
+    if $(this).text() == 'hide < 100ms'
+      panel.find('.duration-ok').hide()
+      $(this).text("show < 100ms")
+    else
+      panel.find('.duration-ok').show()
+      $(this).text("hide < 100ms")
+
+  $('body').on 'click', '.show-fast-items', (event) ->
+    $(this).removeClass('show-fast-items')
+    panel = $(this).closest('.panel-group')
+    panel.find('.duration-ok').show()
+    panel.find('.show-fast-items').removeClass('show-fast-items')
+    panel.find('.panel-collapse').collapse('show')
+    event.stopPropagation()
+
+$.extend decko,
+  toggleShade: (shadeSlot) ->
+    shadeSlot.find('.shade-content').slideToggle 1000
+    shadeSlot.find('.glyphicon').toggleClass 'glyphicon-triangle-right glpyphicon-triangle-bottom'
+
+
+
+
+
+