card-mod-script 0.13.0 → 0.13.4

data/assets/script/decko/filter_links.js.coffee

@@ -0,0 +1,81 @@
+decko.slotReady (slot) ->
+  slot.find("._filter-widget").each ->
+    if slot[0] == $(this).slot()[0]
+      filter = new decko.filter this
+      filter.showWithStatus "active"
+      filter.updateLastVals()
+      filter.updateQuickLinks()
+
+$(window).ready ->
+  filterFor = (el) ->
+    new decko.filter el
+
+  # sometimes this element shows up as changed and breaks the filter.
+  weirdoSelect2FilterBreaker = (el) ->
+    $(el).hasClass "select2-search__field"
+
+  filterableData = (filterable) ->
+    f = $(filterable)
+    f.data("filter") || f.find("._filterable").data("filter")
+
+  targetFilter = (filterable) ->
+    selector = $(filterable).closest("._filtering").data("filter-selector")
+    filterFor (selector || this)
+
+  # Add Filter
+  $("body").on "click", "._filter-category-select", (e) ->
+    e.preventDefault()
+    # e.stopPropagation()
+    f = filterFor(this)
+    category = $(this).data("category")
+    f.activate category
+    f.updateIfPresent category
+
+  # Update filter results based on filter value changes
+  onchangers =
+    "._filter-input input:not(.simple-text), ._filter-input select, ._filter-sort"
+  $("body").on "change", onchangers, ->
+    return if weirdoSelect2FilterBreaker this
+    filterFor(this).update()
+
+  # update filter result after typing in text box
+  keyupTimeout = null
+  $("body").on "keyup", "._filter-input input.simple-text", ->
+    clearTimeout keyupTimeout
+    filter = filterFor this
+    keyupTimeout = setTimeout ( -> filter.updateIfChanged() ), 333
+
+  # remove filter
+  $("body").on "click", "._delete-filter-input", ->
+    filter = filterFor this
+    filter.removeField $(this).closest("._filter-input").data("category")
+    filter.update()
+
+  # reset all filters
+  $('body').on 'click', '._reset-filter', () ->
+    f = filterFor(this)
+    f.reset()
+    f.update()
+
+  $('body').on 'click', '._filtering ._filterable', (e) ->
+    f = targetFilter this
+    if f.widget.length
+      f.restrict filterableData(this)
+      e.preventDefault()
+      e.stopPropagation()
+
+  $('body').on 'click', '._filter-link', (e) ->
+    f = filterFor this
+    link = $(this)
+    filter_data = link.data "filter"
+    if inactiveQuickfilter link
+      f.removeRestrictions filter_data
+    else
+      f.addRestrictions filter_data
+
+    e.preventDefault()
+    e.stopPropagation()
+
+  inactiveQuickfilter = (link) ->
+    !link.hasClass("active") && link.closest(".quick-filter").length > 0
+

data/assets/script/decko/follow.js.coffee

@@ -0,0 +1,22 @@
+$(window).ready ->
+  $('body').on 'click', '.btn-item', ->
+    $(this).find('i').html('hourglass_full')
+
+  $('body').on 'mouseenter', '.btn-item-delete', ->
+    $(this).find('i').html('remove')
+    $(this).addClass("btn-danger").removeClass("btn-primary")
+
+  $('body').on 'mouseleave', '.btn-item-delete', ->
+    $(this).find('i').html('check')
+    $(this).addClass("btn-primary").removeClass("btn-danger")
+
+  $('body').on 'click', '.follow-updater', ->
+    $(this).closest('form').find('#card_update_all_users').val 'true'
+
+  $('body').on 'submit', '.edit-view.SELF-Xfollow_default .card-form', ->
+    confirmer = $(this).find '.confirm_update_all-view'
+    if confirmer.is ':hidden'
+      $(this).find('.follow-updater').show()
+
+      confirmer.show 'blind'
+      false

data/assets/script/decko/layout.js.coffee

@@ -0,0 +1,76 @@
+wrapDeckoLayout = ->
+  $footer  = $('body > footer').first()
+  $('body > article, body > aside').wrapAll("<div class='#{containerClass()}'/>")
+  $('body > div > article, body > div > aside')
+    .wrapAll('<div class="row row-offcanvas">')
+  if $footer
+    $('body').append $footer
+
+wrapSidebarToggle = (toggle, flex) ->
+  "<div class='container'><div class='row #{flex}'>#{toggle}</div></div>"
+
+containerClass = ->
+  if $('body').hasClass('fluid') then "container-fluid" else "container"
+
+toggleButton = (side) ->
+  icon_dir = if side == 'left' then 'right' else 'left'
+  "<button class='offcanvas-toggle btn btn-secondary "+
+    "d-sm-none' data-toggle='offcanvas-#{side}'>" +
+    "<i class='material-icons'>chevron_#{icon_dir}</i></button>"
+
+sidebarToggle = (side) ->
+  if side == "both"
+    wrapSidebarToggle(toggleButton("left") + toggleButton("right"), "flex-row justify-content-between")
+  else if side == "left"
+    wrapSidebarToggle(toggleButton("left"), "flex-row")
+  else
+    wrapSidebarToggle(toggleButton("right"), "flex-row-reverse")
+
+singleSidebar = (side) ->
+  $article = $('body > article').first()
+  $aside   = $('body > aside').first()
+  $article.addClass("col-xs-12 col-sm-9")
+  $aside.addClass(
+    "col-xs-6 col-sm-3 sidebar-offcanvas sidebar-offcanvas-#{side}"
+  )
+  if side == 'left'
+    $('body').append($aside).append($article)
+  else
+    $('body').append($article).append($aside)
+  wrapDeckoLayout()
+  $article.prepend(sidebarToggle(side))
+
+doubleSidebar = ->
+  $article    = $('body > article').first()
+  $asideLeft  = $('body > aside').first()
+  $asideRight = $($('body > aside')[1])
+  $article.addClass("col-xs-12 col-sm-6")
+  sideClass = "col-xs-6 col-sm-3 sidebar-offcanvas"
+  $asideLeft.addClass("#{sideClass} sidebar-offcanvas-left")
+  $asideRight.addClass("#{sideClass} sidebar-offcanvas-right")
+  $('body').append($asideLeft).append($article).append($asideRight)
+  wrapDeckoLayout()
+  toggles = sidebarToggle('both')
+  $article.prepend(toggles)
+
+$.fn.extend toggleText: (a, b) ->
+  @text(if @text() == b then a else b)
+
+  this
+$(window).ready ->
+  switch
+    when $('body').hasClass('right-sidebar')
+      singleSidebar('right')
+    when $('body').hasClass('left-sidebar')
+      singleSidebar('left')
+    when $('body').hasClass('two-sidebar')
+      doubleSidebar()
+
+  $('[data-toggle="offcanvas-left"]').click ->
+    $('.row-offcanvas').removeClass('right-active').toggleClass('left-active')
+    $(this).find('i.material-icons')
+      .toggleText('chevron_left', 'chevron_right')
+  $('[data-toggle="offcanvas-right"]').click ->
+    $('.row-offcanvas').removeClass('left-active').toggleClass('right-active')
+    $(this).find('i.material-icons')
+      .toggleText('chevron_left', 'chevron_right')

data/assets/script/decko/link_editor.js.coffee

@@ -0,0 +1,61 @@
+$(document).ready ->
+  $('body').on 'click', 'button._link-apply', () ->
+    link.applyLink($(this).data("tinymce-id"), $(this).data("tm-snippet-start"), $(this).data("tm-snippet-size"))
+
+window.link ||= {}
+
+$(document).ready ->
+  $('body').on 'click', '._link-field-toggle', () ->
+    if $(this).is(':checked')
+      link.addPlus()
+    else
+      link.removePlus()
+
+  $('body').on 'input', 'input._link-target', (event) ->
+    link.targetChanged()
+
+  $('body').on 'input', 'input._link-title', (event) ->
+    link.titleChanged()
+
+$.extend link,
+  # called by TinyMCE
+  openLinkEditor: (tm) ->
+    params = nest.editParams(tm, "[[", "]]") unless params?
+    nest.openEditorForTm(tm, params, "link_editor", "modal_link_editor")
+
+  applyLink: (tinymce_id, link_start, link_size) ->
+    nest.applySnippet("link", tinymce_id, link_start, link_size)
+
+  target: () ->
+    link.evalFieldOption $('input._link-target').val()
+
+  title: () ->
+    $('input._link-title').val()
+
+  titleChanged: () ->
+    new_val = $("._link-preview").val().replace(/^\[\[[^\]]*/, "[[" + link.target() + "|" + link.title())
+    link.updatePreview new_val
+
+  targetChanged: () ->
+    new_val = $("._link-preview").val().replace(/^\[\[[^\]|]*/, "[[" + link.target())
+    link.updatePreview new_val
+
+  evalFieldOption: (name) ->
+    if link.isField() then "+#{name}" else name
+
+  isField: ->
+    $('._link-field-toggle').is(":checked")
+
+  addPlus: () ->
+    new_val = $("._link-preview").val().replace(/^\[\[\+?/, "[[+")
+    link.updatePreview new_val
+    $(".input-group.hide-prefix").removeClass("hide-prefix").addClass("show-prefix")
+
+  removePlus: () ->
+    new_val = $("._link-preview").val().replace(/^\[\[\+?/, "[[")
+    link.updatePreview new_val
+    $(".input-group.show-prefix").removeClass("show-prefix").addClass("hide-prefix")
+
+  updatePreview: (new_val) ->
+    new_val = "[[#{link.target()}|#{link.title()}]]" unless new_val?
+    $("._link-preview").val new_val

data/assets/script/decko/mod.js.coffee

@@ -0,0 +1,85 @@
+
+window.decko ||= {} #needed to run w/o *head.  eg. jasmine
+
+# $.extend decko,
+# Can't get this to work yet.  Intent was to tighten up head tag.
+#  initGoogleAnalytics: (key) ->
+#    window._gaq.push ['_setAccount', key]
+#    window._gaq.push ['_trackPageview']
+#
+#    initfunc = ()->
+#      ga = document.createElement 'script'
+#      ga.type = 'text/javascript'
+#      ga.async = true
+#      ga.src = `('https:' == document.location.protocol ? 'https://ssl' : 'http://www') + '.google-analytics.com/ga.js'`
+#      s = document.getElementsByTagName('script')[0]
+#      s.parentNode.insertBefore ga, s
+#  initfunc()
+
+$(window).ready ->
+  $('body').on 'click', '._stop_propagation', (event)->
+    event.stopPropagation()
+
+  $('body').on 'click', '._prevent_default', (event)->
+    event.preventDefault()
+
+  $('body').on 'mouseenter', 'a[data-hover-text]', ->
+    text = $(this).text()
+    $(this).data("original-text", text)
+    $(this).text($(this).data("hover-text"))
+
+  $('body').on 'mouseleave', 'a[data-hover-text]', ->
+    $(this).text($(this).data("original-text"))
+
+  #decko_org mod (for now)
+  $('body').on 'click', '.shade-view h1', ->
+    toggleThis = $(this).slot().find('.shade-content').is ':hidden'
+    decko.toggleShade $(this).closest('.pointer-list').find('.shade-content:visible').parent()
+    if toggleThis
+      decko.toggleShade $(this).slot()
+
+  if firstShade = $('.shade-view h1')[0]
+    $(firstShade).trigger 'click'
+
+  # performance log mod
+  $('body').on 'click', '.open-slow-items', ->
+    panel = $(this).closest('.panel-group')
+    panel.find('.open-slow-items').removeClass('open-slow-items').addClass('close-slow-items')
+    panel.find('.toggle-fast-items').text("show < 100ms")
+    panel.find('.duration-ok').hide()
+    panel.find('.panel-danger > .panel-collapse').collapse('show').find('a > span').addClass('show-fast-items')
+
+  $('body').on 'click', '.close-slow-items', ->
+    panel = $(this).closest('.panel-group')
+    panel.find('.close-slow-items').removeClass('close-slow-items').addClass('open-slow-items')
+    panel.find('.toggle-fast-items').text("hide < 100ms")
+    panel.find('.panel-danger > .panel-collapse').collapse('hide').removeClass('show-fast-items')
+    panel.find('.duration-ok').show()
+
+  $('body').on 'click', '.toggle-fast-items', ->
+    panel = $(this).closest('.panel-group')
+    if $(this).text() == 'hide < 100ms'
+      panel.find('.duration-ok').hide()
+      $(this).text("show < 100ms")
+    else
+      panel.find('.duration-ok').show()
+      $(this).text("hide < 100ms")
+
+  $('body').on 'click', '.show-fast-items', (event) ->
+    $(this).removeClass('show-fast-items')
+    panel = $(this).closest('.panel-group')
+    panel.find('.duration-ok').show()
+    panel.find('.show-fast-items').removeClass('show-fast-items')
+    panel.find('.panel-collapse').collapse('show')
+    event.stopPropagation()
+
+$.extend decko,
+  toggleShade: (shadeSlot) ->
+    shadeSlot.find('.shade-content').slideToggle 1000
+    shadeSlot.find('.glyphicon').toggleClass 'glyphicon-triangle-right glpyphicon-triangle-bottom'
+
+
+
+
+
+

data/assets/script/decko/modal.js.coffee

@@ -0,0 +1,113 @@
+$(window).ready ->
+  $('body').on 'hidden.bs.modal', (_event) ->
+    decko.removeModal()
+
+  $('body').on "show.bs.modal", "._modal-slot", (event, slot) ->
+    link = $(event.relatedTarget)
+    addModalDialogClasses $(this), link
+    $(this).modal("handleUpdate")
+    decko.contentLoaded $(event.target), link
+
+  $('._modal-slot').each ->
+    openModalIfPresent $(this)
+    addModalDialogClasses $(this)
+
+  $('body').on 'click', '.submit-modal', ->
+    $(this).closest('.modal-content').find('form').submit()
+
+openModalIfPresent = (mslot) ->
+  modal_content = mslot.find(".modal-content")
+  if modal_content.length > 0 && modal_content.html().length > 0
+    $("#main > .card-slot").registerAsOrigin("modal", mslot)
+    mslot.modal("show")
+
+addModalDialogClasses = ($modal_slot, $link) ->
+  dialog = $modal_slot.find(".modal-dialog")
+  classes_from_link =
+    if $link? then $link.data("modal-class") else $modal_slot.data("modal-class")
+  if classes_from_link? and dialog?
+    dialog.addClass classes_from_link
+
+jQuery.fn.extend {
+  showAsModal: ($slotter) ->
+    el = @modalify($slotter) if $slotter?
+    if $("body > ._modal-slot").is(":visible")
+      @addModal el, $slotter
+    else
+      if $("body > ._modal-slot")[0]
+        $("._modal-slot").trigger "slotDestroy"
+        $("body > ._modal-slot").replaceWith el
+      else
+        $("body").append el
+
+      $slotter.registerAsOrigin("modal", el)
+      el.modal("show", $slotter)
+
+  addModal: (el, $slotter) ->
+    if $slotter.data("slotter-mode") == "modal-replace"
+      dialog = el.find(".modal-dialog")
+      el.adoptModalOrigin()
+      $("._modal-slot").trigger "slotDestroy"
+      $("body > ._modal-slot > .modal-dialog").replaceWith(dialog)
+      decko.contentLoaded(dialog, $slotter)
+    else
+      decko.pushModal el
+      $slotter.registerAsOrigin("modal", el)
+      el.modal("show", $slotter)
+
+  adoptModalOrigin: () ->
+    origin_slot_id = $("body > ._modal-slot .card-slot[data-modal-origin-slot-id]")
+                        .data("modal-origin-slot-id")
+    @find(".modal-body .card-slot").attr("data-modal-origin-slot-id", origin_slot_id)
+
+  modalOriginSlot: ()->
+
+
+  modalSlot: ->
+    slot = $("#modal-container")
+    if slot.length > 0 then slot else decko.createModalSlot()
+
+  modalify: ($slotter) ->
+    if $slotter.data("modal-body")?
+      @find(".modal-body").append($slotter.data("modal-body"))
+
+    if @hasClass("_modal-slot")
+      this
+    else
+      modalSlot = $('<div/>', id: "modal-container", class: "modal fade _modal-slot")
+      modalSlot.append(
+        $('<div/>' , class: "modal-dialog").append(
+          $('<div/>', class: "modal-content").append(this)
+        )
+      )
+      modalSlot
+}
+
+$.extend decko,
+  createModalSlot: ->
+    slot = $('<div/>', id: "modal-container", class: "modal fade _modal-slot")
+    $("body").append(slot)
+    slot
+
+  removeModal: ->
+    if $("._modal-stack")[0]
+      decko.popModal()
+    else
+      $("._modal-slot").trigger "slotDestroy"
+      $(".modal-dialog").empty()
+
+  pushModal: (el) ->
+    mslot = $("body > ._modal-slot")
+    mslot.removeAttr("id")
+    mslot.removeClass("_modal-slot").addClass("_modal-stack").removeClass("modal").addClass("background-modal")
+    el.insertBefore mslot
+    $(".modal-backdrop").removeClass("show")
+
+  popModal: ->
+    $(".modal-backdrop").addClass("show")
+    $("body > ._modal-slot").trigger "slotDestroy"
+    $("body > ._modal-slot").remove()
+    modal = $($("._modal-stack")[0])
+    modal.addClass("_modal-slot").removeClass("_modal-stack").attr("id", "modal-container").addClass("modal").removeClass("background-modal")
+    $(document.body).addClass("modal-open")
+

data/assets/script/decko/name_editor.js.coffee

@@ -0,0 +1,40 @@
+checkNameAfterTyping = null
+
+$(window).ready ->
+  $('body').on 'keyup', '.name-editor input', (event) ->
+    clearTimeout(checkNameAfterTyping) if checkNameAfterTyping
+    input = $(this)
+    if event.which == 13
+      checkName(input)
+      checkNameAfterTyping = null
+    else
+      checkNameAfterTyping = setTimeout ->
+          checkName(input)
+          checkNameAfterTyping = null
+        , 400
+
+
+checkName = (box) ->
+  name = box.val()
+  decko.pingName name, (data)->
+    return null if box.val() != name # avert race conditions
+    status = data['status']
+    if status
+      ed = box.parent()
+      leg = box.closest('fieldset').find('legend')
+      msg = leg.find '.name-messages'
+      unless msg[0]
+        msg = $('<span class="name-messages"></span>')
+        leg.append msg?
+      ed.removeClass 'real-name virtual-name known-name'
+
+      # use id to avoid warning when renaming to name variant
+      slot_id = box.slot().data 'cardId'
+      if status != 'unknown' and !(slot_id && parseInt(slot_id) == data['id'])
+        ed.addClass status + '-name known-name'
+        qualifier = if status == 'virtual' then 'in virtual' else 'already in'
+        href = decko.path(data['url_key'])
+        msg.html "\"<a href='#{href}'>#{name}</a>\" #{qualifier} use"
+      else
+        msg.html ''
+

data/assets/script/decko/navbox.js.coffee

@@ -0,0 +1,74 @@
+$(window).ready ->
+  navbox = $('._navbox')
+  navbox.select2
+    placeholder: navbox.attr("placeholder")
+    escapeMarkup: (markup) ->
+      markup
+    minimumInputLength: 1
+    maximumSelectionSize: 1
+    ajax:
+      delay: 200
+      url: decko.path ':search.json'
+      data: (params) ->
+        query: { keyword: params.term }
+        view: "complete"
+      processResults: (data) ->
+        results: navboxize(data)
+      cache: true
+    templateResult: formatNavboxItem
+    templateSelection: formatNavboxSelectedItem
+    multiple: true
+    containerCssClass: 'select2-navbox-autocomplete'
+    dropdownCssClass: 'select2-navbox-dropdown'
+    width: "100%!important"
+
+  navbox.on "select2:select", (e) ->
+    navboxSelect(e)
+
+formatNavboxItem = (i) ->
+  if i.loading
+    return i.text
+  '<i class="material-icons">' + i.icon + '</i>' +
+  '<span class="navbox-item-label">' + i.prefix + ':</span> ' +
+  '<span class="navbox-item-value">' + i.label + '</span>'
+
+formatNavboxSelectedItem = (i) ->
+  unless i.icon
+    return i.text
+  '<i class="material-icons">' + i.icon + '</i>' +
+  '<span class="navbox-item-value">' + i.label + '</span>'
+
+navboxize = (results) ->
+  items = []
+  term = results.term
+  if results["search"]
+    # id is what the form sends
+    items.push navboxItem(prefix: "search", id: term, text: term)
+
+  $.each ['add', 'new'], (index, key) ->
+    if val = results[key]
+      items.push navboxItem(prefix: key, icon: "add", text: val[0], href: val[1])
+
+  $.each results['goto'], (index, val) ->
+    i = navboxItem(
+      prefix: "go to", id: index, icon: "arrow_forward",
+      text: val[0], href: val[1], label: val[2]
+    )
+    items.push i
+
+  items
+
+navboxItem = (data) ->
+  data.id ||= data.prefix
+  data.icon ||= data.prefix
+  data.label ||= '<strong class="highlight">' + data.text + '</strong>'
+  data
+
+navboxSelect = (event) ->
+  item = event.params.data
+  if item.href
+    window.location = decko.path(item.href)
+  else
+    $(event.target).closest('form').submit()
+
+  $(event.target).attr('disabled', 'disabled')