breezy 0.1.4 → 0.2.0

data/lib/assets/javascripts/breezy/remote.coffee

@@ -1,136 +0,0 @@
-class Breezy.Remote
-  SUPPORTED_METHODS = ['GET', 'PUT', 'POST', 'DELETE', 'PATCH']
-  FALLBACK_LINK_METHOD = 'GET'
-  FALLBACK_FORM_METHOD = 'POST'
-
-  constructor: (target, opts={})->
-    @target = target
-    @payload = ''
-    @contentType = null
-    @setRequestType(target)
-    @async =  @getBZAttribute(target, 'bz-remote-async') || false
-    @pushState =  !(@getBZAttribute(target, 'bz-push-state') == 'false')
-    @httpUrl = target.getAttribute('href') || target.getAttribute('action')
-    @silent = @getBZAttribute(target, 'bz-silent') || false
-    @setPayload(target)
-
-  toOptions: =>
-    requestMethod: @actualRequestType
-    payload: @payload
-    contentType: @contentType
-    silent: @silent
-    target: @target
-    async: @async
-    pushState: @pushState
-
-  setRequestType: (target)=>
-    if target.tagName == 'A'
-      @httpRequestType = @getBZAttribute(target, 'bz-remote')
-      @httpRequestType ?= ''
-      @httpRequestType = @httpRequestType.toUpperCase()
-
-      if @httpRequestType not in SUPPORTED_METHODS
-        @httpRequestType = FALLBACK_LINK_METHOD
-
-    if target.tagName == 'FORM'
-      formActionMethod = target.getAttribute('method')
-      @httpRequestType = formActionMethod || @getBZAttribute(target, 'bz-remote')
-      @httpRequestType ?= ''
-      @httpRequestType = @httpRequestType.toUpperCase()
-
-      if @httpRequestType not in SUPPORTED_METHODS
-        @httpRequestType = FALLBACK_FORM_METHOD
-
-    @actualRequestType = if @httpRequestType == 'GET' then 'GET' else 'POST'
-
-  setPayload: (target)=>
-    if target.tagName == 'FORM'
-      @payload = @nativeEncodeForm(target)
-
-    if @payload not instanceof FormData
-      if @payload.indexOf("_method") == -1 && @httpRequestType && @actualRequestType != 'GET'
-        @contentType = "application/x-www-form-urlencoded; charset=UTF-8"
-        @payload = @formAppend(@payload, "_method", @httpRequestType)
-    else
-      if !target.querySelector('[name=_method]') && @httpRequestType not in ['GET', 'POST']
-        @payload.append("_method", @httpRequestType)
-
-  isValid: =>
-    @isValidLink() || @isValidForm()
-
-  isValidLink: =>
-    if @target.tagName != 'A'
-      return false
-
-    @hasBZAttribute(@target, 'bz-remote')
-
-  isValidForm: =>
-    if @target.tagName != 'FORM'
-      return false
-    @hasBZAttribute(@target, 'bz-remote') &&
-    @target.getAttribute('action')?
-
-  formAppend: (uriEncoded, key, value) ->
-    uriEncoded += "&" if uriEncoded.length
-    uriEncoded += "#{encodeURIComponent(key)}=#{encodeURIComponent(value)}"
-
-  formDataAppend: (formData, input) ->
-    if input.type == 'file'
-      for file in input.files
-        formData.append(input.name, file)
-    else
-      formData.append(input.name, input.value)
-    formData
-
-  nativeEncodeForm: (form) ->
-    formData = new FormData
-    @iterateOverFormInputs form, (input) =>
-      formData = @formDataAppend(formData, input)
-    formData
-
-  iterateOverFormInputs: (form, callback) ->
-    inputs = @enabledInputs(form)
-    for input in inputs
-      inputEnabled = !input.disabled
-      radioOrCheck = (input.type == 'checkbox' || input.type == 'radio')
-
-      if inputEnabled && input.name
-        if (radioOrCheck && input.checked) || !radioOrCheck
-          callback(input)
-
-  enabledInputs: (form) ->
-    selector = "input:not([type='reset']):not([type='button']):not([type='submit']):not([type='image']), select, textarea"
-    inputs = Array::slice.call(form.querySelectorAll(selector))
-    disabledNodes = Array::slice.call(@querySelectorAllBZAttribute(form, 'bz-remote-noserialize'))
-
-    return inputs unless disabledNodes.length
-
-    disabledInputs = disabledNodes
-    for node in disabledNodes
-      disabledInputs = disabledInputs.concat(Array::slice.call(node.querySelectorAll(selector)))
-
-    enabledInputs = []
-    for input in inputs when disabledInputs.indexOf(input) < 0
-      enabledInputs.push(input)
-    enabledInputs
-
-  bzAttribute: (attr) ->
-    bzAttr = if attr[0...3] == 'bz-'
-      "data-#{attr}"
-    else
-      "data-bz-#{attr}"
-
-  getBZAttribute: (node, attr) ->
-    bzAttr = @bzAttribute(attr)
-    (node.getAttribute(bzAttr) || node.getAttribute(attr))
-
-  querySelectorAllBZAttribute: (node, attr, value = null) ->
-    bzAttr = @bzAttribute(attr)
-    if value
-      node.querySelectorAll("[#{bzAttr}=#{value}], [#{attr}=#{value}]")
-    else
-      node.querySelectorAll("[#{bzAttr}], [#{attr}]")
-
-  hasBZAttribute: (node, attr) ->
-    bzAttr = @bzAttribute(attr)
-    node.getAttribute(bzAttr)? || node.getAttribute(attr)?

data/lib/assets/javascripts/breezy/snapshot.coffee

@@ -1,100 +0,0 @@
-#= require breezy/component_url
-#= require breezy/csrf_token
-#= require breezy/utils
-
-class Breezy.Snapshot
-  constructor: (@controller) ->
-    @pageCache = {}
-    @currentBrowserState = null
-    @pageCacheSize = 10
-    @currentPage = null
-    @loadedAssets= null
-
-  onHistoryChange: (event) =>
-    if event.state?.breezy && event.state.url != @currentBrowserState.url
-      previousUrl = new Breezy.ComponentUrl(@currentBrowserState.url)
-      newUrl = new Breezy.ComponentUrl(event.state.url)
-
-      if restorePoint = @pageCache[newUrl.absolute]
-        @cacheCurrentPage()
-        @currentPage = restorePoint
-        @controller.restore(@currentPage)
-      else
-        @controller.request event.target.location.href
-
-  constrainPageCacheTo: (limit = @pageCacheSize) =>
-    pageCacheKeys = Object.keys @pageCache
-
-    cacheTimesRecentFirst = pageCacheKeys.map (url) =>
-      @pageCache[url].cachedAt
-    .sort (a, b) -> b - a
-
-    for key in pageCacheKeys when @pageCache[key].cachedAt <= cacheTimesRecentFirst[limit]
-      delete @pageCache[key]
-
-  transitionCacheFor: (url) =>
-    return if url is @currentBrowserState.url
-    cachedPage = @pageCache[url]
-    cachedPage if cachedPage and !cachedPage.transitionCacheDisabled
-
-  pagesCached: (size = @pageCacheSize) =>
-    @pageCacheSize = parseInt(size) if /^[\d]+$/.test size
-
-  cacheCurrentPage: =>
-    return unless @currentPage
-    currentUrl = new Breezy.ComponentUrl @currentBrowserState.url
-
-    Breezy.Utils.merge @currentPage,
-      cachedAt: new Date().getTime()
-      positionY: window.pageYOffset
-      positionX: window.pageXOffset
-      url: currentUrl.relative
-      pathname: currentUrl.pathname
-      transition_cache: true
-
-    @pageCache[currentUrl.absolute] = @currentPage
-
-  rememberCurrentUrlAndState: =>
-    window.history.replaceState { breezy: true, url: document.location.href }, '', document.location.href
-    @currentBrowserState = window.history.state
-
-  removeParamFromUrl: (url, parameter) =>
-    return url
-      .replace(new RegExp('^([^#]*\?)(([^#]*)&)?' + parameter + '(\=[^&#]*)?(&|#|$)' ), '$1$3$5')
-      .replace(/^([^#]*)((\?)&|\?(#|$))/,'$1$3$4')
-
-  reflectNewUrl: (url) =>
-    if (url = new Breezy.ComponentUrl url).absolute != document.location.href
-      preservedHash = if url.hasNoHash() then document.location.hash else ''
-      fullUrl = url.absolute + preservedHash
-      fullUrl = @removeParamFromUrl(fullUrl, '_breezy_filter')
-      fullUrl = @removeParamFromUrl(fullUrl, '__')
-
-      window.history.pushState { breezy: true, url: url.absolute + preservedHash }, '', fullUrl
-
-  updateCurrentBrowserState: =>
-    @currentBrowserState = window.history.state
-
-  changePage: (nextPage, options) =>
-    if @currentPage and @assetsChanged(nextPage)
-      document.location.reload()
-      return
-
-    @currentPage = nextPage
-    @currentPage.title = options.title ? @currentPage.title
-    document.title = @currentPage.title if @currentPage.title isnt false
-
-    Breezy.CSRFToken.update @currentPage.csrf_token if @currentPage.csrf_token?
-    @updateCurrentBrowserState()
-
-  assetsChanged: (nextPage) =>
-    @loadedAssets ||= @currentPage.assets
-    fetchedAssets = nextPage.assets
-    fetchedAssets.length isnt @loadedAssets.length or Breezy.Utils.intersection(fetchedAssets, @loadedAssets).length isnt @loadedAssets.length
-
-  graftByKeypath: (keypath, node, opts={})=>
-    for k, v in @pageCache
-      @history.pageCache[k] = Breezy.Utils.graftByKeypath(keypath, node, v, opts)
-
-    @currentPage = Breezy.Utils.graftByKeypath(keypath, node, @currentPage, opts)
-    Breezy.Utils.triggerEvent Breezy.EVENTS.LOAD, @currentPage

data/lib/assets/javascripts/breezy/start.coffee

@@ -1,60 +0,0 @@
-#= require breezy/controller
-#= require breezy/remote
-#= require breezy/utils
-
-EVENTS =
-  BEFORE_CHANGE:  'breezy:click'
-  ERROR:          'breezy:request-error'
-  FETCH:          'breezy:request-start'
-  RECEIVE:        'breezy:request-end'
-  LOAD:           'breezy:load'
-  RESTORE:        'breezy:restore'
-
-controller = new Breezy.Controller
-progressBar = controller.progressBar
-
-ProgressBarAPI =
-  enable: ->
-    progressBar.install()
-  disable: ->
-    progressBar.uninstall()
-  setDelay: (value) -> progressBar.setDelay(value)
-  start: (options) -> progressBar.start(options)
-  advanceTo: (value) -> progressBar.advanceTo(value)
-  done: -> progressBar.done()
-
-remoteHandler = (ev) ->
-  target = ev.target
-  remote = new Breezy.Remote(target)
-  return unless remote.isValid()
-  ev.preventDefault()
-  controller.request remote.httpUrl, remote.toOptions()
-
-browserSupportsCustomEvents =
-  document.addEventListener and document.createEvent
-
-initializeBreezy = ->
-  ProgressBarAPI.enable()
-  window.addEventListener 'hashchange', controller.history.rememberCurrentUrlAndState, false
-  window.addEventListener 'popstate', controller.history.onHistoryChange, false
-  Breezy.Utils.documentListenerForLinks 'click', remoteHandler
-  document.addEventListener "submit", remoteHandler
-
-if Breezy.Utils.browserSupportsBreezy()
-  visit = controller.request
-  initializeBreezy()
-else
-  visit = (url = document.location.href) -> document.location.href = url
-
-Breezy.controller = controller
-Breezy.graftByKeypath = controller.history.graftByKeypath
-Breezy.visit = visit
-Breezy.replace = controller.replace
-Breezy.cache = controller.cache
-Breezy.pagesCached = controller.history.pagesCached
-Breezy.enableTransitionCache = controller.enableTransitionCache
-Breezy.disableRequestCaching = controller.disableRequestCaching
-Breezy.ProgressBar = ProgressBarAPI
-Breezy.supported = Breezy.Utils.browserSupportsBreezy()
-Breezy.EVENTS = Breezy.Utils.clone(EVENTS)
-Breezy.currentPage = controller.currentPage

data/lib/assets/javascripts/breezy/utils.coffee

@@ -1,174 +0,0 @@
-reverseMerge = (dest, obj) ->
-  for k, v of obj
-    dest[k] = v if !dest.hasOwnProperty(k)
-  dest
-
-merge = (dest, obj) ->
-  for k, v of obj
-    dest[k] = v
-  dest
-
-clone = (original) ->
-  return original if not original? or typeof original isnt 'object'
-  copy = new original.constructor()
-  copy[key] = clone value for key, value of original
-  copy
-
-withDefaults = (page, state) =>
-    currentUrl = new Breezy.ComponentUrl state.url
-
-    reverseMerge page,
-      url: currentUrl.relative
-      pathname: currentUrl.pathname
-      cachedAt: new Date().getTime()
-      assets: []
-      data: {}
-      title: ''
-      positionY: 0
-      positionX: 0
-      csrf_token: null
-
-browserIsBuggy = () ->
-# Copied from https://github.com/Modernizr/Modernizr/blob/master/feature-detects/history.js
-  ua = navigator.userAgent
-  (ua.indexOf('Android 2.') != -1 or ua.indexOf('Android 4.0') != -1) and
-    ua.indexOf('Mobile Safari') != -1 and
-    ua.indexOf('Chrome') == -1 and
-    ua.indexOf('Windows Phone') == -1
-
-browserSupportsPushState = () ->
-  window.history and 'pushState' of window.history and 'state' of window.history
-
-popCookie = (name) ->
-  value = document.cookie.match(new RegExp(name+"=(\\w+)"))?[1].toUpperCase() or ''
-  document.cookie = name + '=; expires=Thu, 01-Jan-70 00:00:01 GMT; path=/'
-  value
-
-requestMethodIsSafe = -> popCookie('request_method') in ['GET','']
-
-browserSupportsBreezy = ->
-  browserSupportsPushState() and !browserIsBuggy() and requestMethodIsSafe()
-
-intersection = (a, b) ->
-  [a, b] = [b, a] if a.length > b.length
-  value for value in a when value in b
-
-
-triggerEvent = (name, data, target = document) =>
-  event = document.createEvent 'Events'
-  event.data = data if data
-  event.initEvent name, true, true
-  target.dispatchEvent event
-
-documentListenerForLinks = (eventType, handler) ->
-  document.addEventListener eventType, (ev) ->
-    target = ev.target
-    while target != document && target?
-      if target.nodeName == "A"
-        isNodeDisabled = target.getAttribute('disabled')
-        ev.preventDefault() if target.getAttribute('disabled')
-        unless isNodeDisabled
-          handler(ev)
-          return
-
-      target = target.parentNode
-
-isObject = (val) ->
-  Object.prototype.toString.call(val) is '[object Object]'
-
-isArray = (val) ->
-  Object.prototype.toString.call(val) is '[object Array]'
-
-class Breezy.Grafter
-  constructor: ->
-    @current_path = []
-
-  graftByKeypath: (path, leaf, obj, opts={}) ->
-    if typeof path is "string"
-      path = path.split('.')
-      return @graftByKeypath(path, leaf, obj, opts)
-
-    head = path[0]
-    @current_path.push(head)
-    child = obj[head] if obj?
-    remaining = path.slice(1)
-
-    if path.length is 0
-      if opts.type == 'add' and isArray(obj)
-        copy = []
-        for child in obj
-          copy.push child
-
-        copy.push leaf
-        return copy
-      else
-        return leaf
-
-    if isObject(obj)
-      copy = {}
-      found = false
-      for key, value of obj
-        if key is head
-          node = @graftByKeypath(remaining, leaf, child, opts)
-          found = true unless child is node
-          copy[key] = node
-        else
-          copy[key] = value
-
-      return if found
-        @current_path.pop()
-        copy
-      else
-        Breezy.Utils.warn "Could not find key #{head} in keypath #{@current_path.join('.')}"
-        obj
-
-    else if isArray(obj)
-      [attr, id] = head.split('=')
-      found = false
-      if id == undefined
-        index = parseInt(attr)
-        child = obj[index]
-        node = @graftByKeypath(remaining, leaf, child, opts)
-        found = true unless child is node
-
-        copy = obj.slice(0, index)
-        copy.push(node)
-        copy = copy.concat(obj.slice(index + 1, obj.length))
-      else
-        id = parseInt(id) || 0
-        copy = []
-        for child in obj
-          if child[attr] == id
-            node = @graftByKeypath(remaining, leaf, child, opts)
-            found = true unless child is node
-            copy.push node
-          else
-            copy.push child
-
-      return if found
-        @current_path.pop()
-        copy
-      else
-        Breezy.Utils.warn "Could not find key #{head} in keypath #{@current_path.join('.')}"
-        obj
-    else
-      obj
-
-
-
-@Breezy.Utils =
-  warn: ->
-    console.warn.apply(@, arguments)
-  graftByKeypath:  ->
-    grafter = new  Breezy.Grafter
-    grafter.graftByKeypath.apply(grafter, arguments)
-  documentListenerForLinks: documentListenerForLinks
-  reverseMerge: reverseMerge
-  merge: merge
-  clone: clone
-  withDefaults: withDefaults
-  browserSupportsBreezy: browserSupportsBreezy
-  intersection: intersection
-  triggerEvent: triggerEvent
-
-