bone_tree 0.5.6 → 0.9.2

data/source/javascripts/bone_tree/models/_directory.js.coffee

@@ -1,63 +0,0 @@
-#= require ./_nodes
-
-BoneTree.namespace "BoneTree.Models", (Models) ->
-  class Models.Directory extends Models.Node
-    ###
-    Public: Object representing a directory.
-
-    * defaults
-      * name         - A String naming the directory (default: "New Directory").
-      * sortPriority - A String representing the priority with which the
-                       node is sorted. Directories have sortPriority "0"
-                       allowing them to be sorted before Files which have
-                       sortPriority "1".
-      * nodeType     - A String denoting what type of node this object is.
-                       The two types are "file" and "directory".
-      * open         - The state of the directory. Controls whether or not
-                       to display files and directories contained within this
-                       Directory (default: false).
-
-    ###
-    defaults:
-      name: "New Directory"
-      open: false
-      sortPriority: "0"
-      nodeType: "directory"
-
-    toggleOpen: =>
-      ###
-      Public: Toggle the open state of this Directory.
-
-      Examples
-
-          dir = new BoneTree.Models.Directory
-
-          dir.get('open')
-          # => false
-
-          dir.toggleOpen()
-          dir.get('open')
-          # => true
-
-      Returns this Directory.
-      ###
-      currentState = @get 'open'
-
-      @set {open: not currentState}
-
-  Models.Directory.find = (currentDirectory, name) ->
-    ###
-    Internal: Check to see if there is a directory with the matching name
-              contained within currentDirectory.
-
-    * currentDirectory - A Directory object to search for the matching directory name.
-
-    * name             - A String name used to check for matching directory
-                         names in currentDirectory.
-
-    Returns The Directory object with the matching name if it exists and undefined otherwise.
-    ###
-    currentDirectory.collection.find (dir) ->
-      dir.get('name') is name
-
-

data/source/javascripts/bone_tree/models/_file.js.coffee

@@ -1,55 +0,0 @@
-#= require ./_nodes
-
-BoneTree.namespace "BoneTree.Models", (Models) ->
-  class Models.File extends Models.Node
-    ###
-    Public: Object representing file data in the tree.
-
-    * defaults
-      * name         - A String naming the file (default: "New File").
-      * sortPriority - A String representing the priority with which the
-                       node is sorted. Directories have sortPriority "0"
-                       allowing them to be sorted before Files which have
-                       sortPriority "1".
-      * nodeType     - A String denoting what type of node this object is.
-                       The two types are "file" and "directory".
-
-    ###
-    defaults:
-      name: "New File"
-      sortPriority: "1"
-      nodeType: "file"
-
-  Models.File.createFromFileName = (fileName, fileData) ->
-    ###
-    Public: Class method to create a new File object based on the fileName
-            and fileData passed in.
-
-    * fileName - A String representing the name of the file to be created.
-                 files with '.' in the name will be parsed out and only the
-                 string after the final '.' will be considered the extension.
-
-    * fileData - An Object of attributes to associate with the file.
-
-    Examples
-
-        data = {
-          contents: alert 'this is the code in the file'
-          createdAt: 1330846900589
-          language: 'CoffeeScript'
-        }
-
-        BoneTree.Models.File.createFromFileName('example.coffee', data)
-        # => <File>
-
-    Returns the File object just created.
-    ###
-
-    # Make sure that files like jquery.min.js work
-    [names..., extension] = fileName.split "."
-    name = names.join('.')
-
-    data = _.extend({}, fileData, {name: name, extension: extension})
-
-    return new Models.File(data)
-

data/source/javascripts/bone_tree/models/_nodes.js.coffee

@@ -1,117 +0,0 @@
-BoneTree.namespace "BoneTree.Models", (Models) ->
-  class Models.Node extends Backbone.Model
-    ###
-    Internal: An abstract super class for File and Directory objects to inherit from.
-
-    ###
-    initialize: ->
-      ###
-      Internal: Initialize a new Node object. Set it up to contain a collection of
-                children nodes.
-
-      ###
-      @collection = new Models.Nodes
-
-    constantize: =>
-      ###
-      Public: Returns a String with the nodeType capitalized so that it may be used
-              to instatiate the appropriate view type
-
-      Examples
-
-          file = new BoneTree.Models.File
-          directory = new BoneTree.Models.Directory
-
-          file.constantize()
-          # => 'File'
-
-          directory.constantize()
-          # => 'Directory'
-
-          # use it to create a new view of the appropriate type
-          view = new BoneTree.Views[file.constantize()]
-
-      Returns a String of the nodeType with the first letter capitalized.
-      ###
-      nodeType = @get('nodeType')
-
-      nodeType[0].toUpperCase() + nodeType.substring(1)
-
-    nameWithExtension: =>
-      ###
-      Public: Returns the node name with the extension if it has
-              one and just the node name if there is no extension.
-
-      Examples
-
-          file = new BoneTree.Models.File
-            name: "file"
-            extension: "coffee"
-
-          noExt = new BoneTree.Models.File
-            name: "file2"
-
-          directory = new BoneTree.Model.Directory
-            name: "source"
-
-          file.nameWithExtension()
-          # => "file.coffee"
-
-          noExt.nameWithExtension()
-          # => "file2"
-
-          directory.nameWithExtension()
-          # => "source"
-
-      Returns a String. If the extension exists then the node name plus the extension
-      are returned. If there is no extension, then just the node name is returned.
-      ###
-      {extension, name} = @attributes
-
-      extension ||= ""
-
-      if extension isnt ""
-        extension = "." + extension
-
-      return name + extension
-
-  class Models.Nodes extends Backbone.Collection
-    ###
-    Internal: A collection of node models. Since Node is an abstract super
-              class, in practice this collection will hold File objects
-              and Directory objects.
-
-    ###
-    comparator: (node) ->
-      ###
-      Internal: Function that determines how the file tree is sorted. Directories
-                are sorted before files. After node type sort
-                priority, nodes are sorted by name.
-
-      Examples
-
-          tree.addFile('/source/file1.coffee')
-          tree.addFile('/source/file2.coffee')
-          tree.addFile('main.coffee')
-
-          tree.render()
-
-          # even though 'main' comes before 'source' alphabetically it is placed
-          # after the 'source' directory due to the sortPriority of the Directory object.
-          tree.toAscii()
-          # => "
-            -source
-             -file1.coffee
-             -file2.coffee
-            -main.coffee
-          "
-
-      ###
-      {name, sortPriority} = node.attributes
-
-      return sortPriority + name
-
-    model: Models.Node
-
-
-

data/source/javascripts/bone_tree/models/_settings.js.coffee

@@ -1,25 +0,0 @@
-BoneTree.namespace "BoneTree.Models", (Models) ->
-  class Models.Settings extends Backbone.Model
-    ###
-    Internal: A configuration object. Consumers of the API don't need to
-              worry about this. It is used internally to manage the options
-              passed into the file tree.
-
-    * defaults
-      * beforeAdd      - A Function that is invoked before each file is added to the tree.
-                         It is passed the raw file attributes and should return true if
-                         that file should be added to the tree and false if not. The
-                         default implementation is to return true.
-      * confirmDeletes - A Boolean. If true, the tree will prompt the user, making
-                         sure they want to delete the file (default: false).
-      * showExtensions - A Boolean. If true, files display their extensions. Internally,
-                         extensions are always kept track of but by default they are
-                         hidden (default: false).
-      * viewCache      - An Object that stores views when they are created and is used
-                         to look them up to prevent extra views from being created.
-    ###
-    defaults:
-      confirmDeletes: false
-      showExtensions: false
-      viewCache: {}
-

data/source/javascripts/bone_tree/views/_directory.js.coffee

@@ -1,73 +0,0 @@
-BoneTree.namespace "BoneTree.Views", (Views) ->
-  class Views.Directory extends Backbone.View
-    ###
-    Internal: View that renders a Directory node and controls its behavior (class: 'directory', tag: 'ul').
-
-    ###
-    className: 'directory'
-    tagName: 'ul'
-
-    initialize: (options) ->
-      ###
-      Internal: Initialize a new directory node. Adds associated model cid to the
-                view element. Binds change handler to the `change:open` event that
-                toggles the display of directory contents. Binds change handler to
-                the `change:name` event that re-renders a sorted file tree.
-
-      * options - Passes in settings object, which is used for access to the
-                  tree view root in order to proxy events to it.
-
-      ###
-      @settings = options.settings
-
-      @$el.attr 'data-cid', @model.cid
-
-      @model.bind 'change:open', (model, open) =>
-        @displayChildren(open)
-
-      @model.bind 'change:name', (model, name) =>
-        treeView = @settings.get 'treeView'
-        treeView.render().trigger 'rename', model, name
-
-      @model.collection.bind 'add', @render
-
-      @model.collection.bind 'remove', (model, collection) =>
-        @settings.get('treeView').trigger 'remove', model
-        @render()
-
-      @displayChildren(@model.get('open'))
-
-    appendView: (node) =>
-      ###
-      Internal: Appends a view based on the underlying node model to this view.
-
-      node - A Node model. Either a File or a Directory. This is the model the
-             created view will be associated with.
-
-      ###
-      view = @settings.get('treeView').findOrCreateView(node)
-
-      @$el.append view.render().$el
-
-    render: =>
-      ###
-      Internal: Set the text of the view element based on the underlying model name.
-
-      Returns `this` view.
-      ###
-      @$el.text @model.get('name')
-
-      @model.collection.sort().each @appendView
-
-      return @
-
-    displayChildren: (open) =>
-      ###
-      Internal: Toggles display of the children Files or Diretories of this view.
-
-      ###
-      fileDirChildren = @$el.children('.directory, .file')
-
-      @$el.toggleClass('open', open)
-      fileDirChildren.toggle(open)
-

data/source/javascripts/bone_tree/views/_file.js.coffee

@@ -1,51 +0,0 @@
-BoneTree.namespace "BoneTree.Views", (Views) ->
-  class Views.File extends Backbone.View
-    ###
-    Internal: View that renders a File node and controls its behavior (class: 'file', tag: 'li').
-
-    ###
-    className: 'file'
-    tagName: 'li'
-
-    initialize: (options) ->
-      ###
-      Internal: Initialize a new file node. Adds associated model cid to the
-                view element. Binds change handlers to the `change:name` and
-                `change:extension` events. These take care of resorting the file
-                nodes.
-
-      * options - Passes in settings object, which is used to control
-                  whether or not file extensions are shown.
-
-      ###
-      @settings = options.settings
-
-      @$el.attr('data-cid', @model.cid).addClass(@model.get('extension'))
-
-      @model.bind 'change:name', (model, name) =>
-        treeView = @settings.get('treeView')
-        treeView.render().trigger 'rename', model, model.nameWithExtension()
-
-      @model.bind 'change:extension', (model, extension) =>
-        @$el.attr('class', "file #{extension}")
-
-        treeView = @settings.get('treeView')
-        treeView.render().trigger 'rename', model, model.nameWithExtension()
-
-    render: =>
-      ###
-      Internal: Sets the text of the file node according to the underlying model
-                name. If the 'showExtensions' setting is set, renders the
-                full file name with extension, otherwise renders just the file
-                name attribute.
-
-      ###
-      return "" if @model.get('hidden')
-
-      if @settings.get('showExtensions')
-        @$el.text @model.nameWithExtension()
-      else
-        @$el.text @model.get('name')
-
-      return @
-

data/source/javascripts/bone_tree/views/_menu.js.coffee

@@ -1,97 +0,0 @@
-BoneTree.namespace "BoneTree.Views", (Views) ->
-  class Views.Menu extends Backbone.View
-    ###
-    Internal: View that controls the context menu (class: 'filetree\_context\_menu').
-
-    Events
-
-    * contextMenu   - Prevents the standard browser context menu from appearing
-                      when right clicking within the file tree context menu.
-
-    * click .rename - Prompts the user to rename a file.
-
-    * click .delete - Deletes a node from the file tree.
-
-    ###
-    className: 'filetree_context_menu'
-
-    events:
-      'contextmenu': 'contextMenu'
-      'click .rename': 'rename'
-      'click .delete': 'delete'
-
-    initialize: (options) ->
-      ###
-      Internal: Initialize a new menu widget.
-
-      * options - An Object. Internally used to pass the settings configuration
-                  into the menu. This controls whether or not the user is
-                  prompted to confirm deleting a file.
-
-      ###
-      @settings = options.settings
-
-    contextMenu: (e) =>
-      ###
-      Internal: Kill the default browser behavior for the contextmenu event.
-
-      ###
-      e.preventDefault()
-      e.stopPropagation()
-
-    delete: (e) =>
-      ###
-      Internal: Deletes a node from the file tree. If the confirmDeletes setting
-                is set, prompts the user for delete confirmation.
-
-      ###
-      if @settings.get('confirmDeletes')
-        if confirm "Are you sure you want to delete '#{@model.nameWithExtension()}'?"
-          @model.destroy()
-      else
-        @model.destroy()
-
-      @$el.hide()
-
-    rename: (e) =>
-      ###
-      Internal: Prompts the user to rename a File or Directory.
-
-      ###
-      if newName = prompt "New Name", @model.nameWithExtension()
-        [fileName, extension] = newName.split "."
-
-        extension ?= ""
-
-        @model.set
-          name: fileName
-          extension: extension
-
-      @$el.hide()
-
-    render: =>
-      ###
-      Internal: Renders the <ul> that contains the context menu choices
-                'Rename' and 'Delete'.
-
-      Returns `this`, the menu view.
-      ###
-
-      @$el.html @template()
-
-      return @
-
-    template: ->
-      ###
-      Internal: html template for the context menu.
-
-      ###
-      """
-        <ul>
-          <li class='rename'>Rename</li>
-          <hr/>
-          <li class='delete'>Delete</li>
-        </ul>
-      """
-
-