bebox 0.0.1

data/lib/templates/puppet/step-0/modules/rbenv/manifests/bundle.pp

@@ -0,0 +1,36 @@
+define rbenv::bundle(
+  $home,
+  $user,
+  $group   = $user,
+  $content = '',
+  $gems    = ''
+) {
+
+  if ( $gems ) {
+    $gemfile = template('rbenv/Gemfile.erb')
+  } elsif ( $content ) {
+    $gemfile = $content
+  } else {
+    fail('bundle requires either a gem list or a Gemfile')
+  }
+
+  file {"${user}/Gemfile":
+    ensure  => present,
+    path    => "${home}/Gemfile",
+    owner   => $user,
+    group   => $group,
+    content => $gemfile,
+    backup  => false,
+    require => Rbenv::Client[$user],
+  }
+
+  exec {"${user} bundle":
+    command   => "bundle --binstubs=${home}/bin --path=${home}/.bundle",
+    cwd       => $home,
+    user      => $user,
+    group     => $group,
+    path      => "${home}/bin:${home}/.rbenv/shims:/bin:/usr/bin",
+    creates   => "${home}/Gemfile.lock",
+    subscribe => File["${user}/Gemfile"],
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/client.pp

@@ -0,0 +1,48 @@
+define rbenv::client(
+  $user,
+  $home,
+  $ruby,
+  $owner,
+  $source,
+  $rc = ".profile"
+) {
+  if ! defined(Exec["rbenv::compile ${owner} ${ruby}"]) {
+    fail("Ruby version ${ruby} is not compiled for ${owner}")
+  }
+
+  file {"${user}/.rbenv":
+    ensure => link,
+    path   => "${home}/.rbenv",
+    target => "${source}/.rbenv",
+  }
+
+  file {"${user}/${rc}":
+    ensure => link,
+    path   => "${home}/${rc}",
+    target => "${source}/${rc}",
+  }
+
+  file {"${user}/.gemrc":
+    ensure => link,
+    path   => "${home}/.gemrc",
+    target => "${source}/.gemrc",
+  }
+
+  file {"${user}/.rbenv-version":
+    ensure  => present,
+    path    => "${home}/.rbenv-version",
+    content => "$ruby\n",
+  }
+
+  file {"${user}/bin":
+    ensure => directory,
+    path   => "${home}/bin",
+    owner  => $user,
+  }
+
+  file {"${user}/bin/rbenv":
+    ensure => link,
+    path   => "${home}/bin/rbenv",
+    target => "${source}/.rbenv/bin/rbenv",
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/compile.pp

@@ -0,0 +1,102 @@
+# The following part compiles and installs the chosen ruby version,
+# using the "ruby-build" rbenv plugin.
+#
+define rbenv::compile(
+  $user,
+  $ruby   = $title,
+  $group  = $user,
+  $home   = '',
+  $root   = '',
+  $source = '',
+  $global = false,
+  $configure_opts = '--disable-install-doc',
+) {
+
+  # Workaround http://projects.puppetlabs.com/issues/9848
+  $home_path = $home ? { '' => "/home/${user}", default => $home }
+  $root_path = $root ? { '' => "${home_path}/.rbenv", default => $root }
+
+  $bin         = "${root_path}/bin"
+  $shims       = "${root_path}/shims"
+  $versions    = "${root_path}/versions"
+  $global_path = "${root_path}/version"
+  $path        = [ $shims, $bin, '/bin', '/usr/bin' ]
+
+  if ! defined( Class['rbenv::dependencies'] ) {
+    require rbenv::dependencies
+  }
+
+  # If no ruby-build has been specified and the default resource hasn't been
+  # parsed
+  $custom_or_default = Rbenv::Plugin["rbenv::plugin::rubybuild::${user}"]
+  $default           = Rbenv::Plugin::Rubybuild["rbenv::rubybuild::${user}"]
+  if ! defined($custom_or_default) and ! defined($default) {
+    debug("No ruby-build found for ${user}, going to add the default one")
+    rbenv::plugin::rubybuild { "rbenv::rubybuild::${user}":
+      user   => $user,
+      group  => $group,
+      home   => $home,
+      root   => $root
+    }
+  }
+
+  if $source {
+    rbenv::definition { "rbenv::definition ${user} ${ruby}":
+      user    => $user,
+      group   => $group,
+      source  => $source,
+      ruby    => $ruby,
+      home    => $home,
+      root    => $root,
+      require => Rbenv::Plugin["rbenv::plugin::rubybuild::${user}"],
+      before  => Exec["rbenv::compile ${user} ${ruby}"]
+    }
+  }
+
+  # Set Timeout to disabled cause we need a lot of time to compile.
+  # Use HOME variable and define PATH correctly.
+  exec { "rbenv::compile ${user} ${ruby}":
+    command     => "rbenv install ${ruby} && touch ${root_path}/.rehash",
+    timeout     => 0,
+    user        => $user,
+    group       => $group,
+    cwd         => $home_path,
+    environment => [ "HOME=${home_path}", "CONFIGURE_OPTS=${configure_opts}" ],
+    creates     => "${versions}/${ruby}",
+    path        => $path,
+    require     => Rbenv::Plugin["rbenv::plugin::rubybuild::${user}"],
+    before      => Exec["rbenv::rehash ${user} ${ruby}"],
+  }
+
+  exec { "rbenv::rehash ${user} ${ruby}":
+    command     => "rbenv rehash && rm -f ${root_path}/.rehash",
+    user        => $user,
+    group       => $group,
+    cwd         => $home_path,
+    onlyif      => "[ -e '${root_path}/.rehash' ]",
+    environment => [ "HOME=${home_path}" ],
+    path        => $path,
+  }
+
+  # Install bundler
+  #
+  rbenv::gem {"rbenv::bundler ${user} ${ruby}":
+    user   => $user,
+    ruby   => $ruby,
+    gem    => 'bundler',
+    home   => $home_path,
+    root   => $root_path,
+  }
+
+  # Set default global ruby version for rbenv, if requested
+  #
+  if $global {
+    file { "rbenv::global ${user}":
+      path    => $global_path,
+      content => "$ruby\n",
+      owner   => $user,
+      group   => $group,
+      require => Exec["rbenv::compile ${user} ${ruby}"]
+    }
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/definition.pp

@@ -0,0 +1,31 @@
+define rbenv::definition(
+  $user,
+  $source,
+  $ruby  = $title,
+  $group = $user,
+  $home  = '',
+  $root  = ''
+) {
+
+  $home_path = $home ? { '' => "/home/${user}",       default => $home }
+  $root_path = $root ? { '' => "${home_path}/.rbenv", default => $root }
+
+  $destination = "${root_path}/plugins/ruby-build/share/ruby-build/${ruby}"
+
+  if $source =~ /^puppet:/ {
+    file { "rbenv::definition-file ${user} ${ruby}":
+      ensure  => file,
+      source  => $source,
+      group   => $group,
+      path    => $destination,
+      require => Exec["rbenv::plugin::checkout ${user} ruby-build"],
+    }
+  } elsif $source =~ /http(s)?:/ {
+    exec { "rbenv::definition-file ${user} ${ruby}":
+      command => "wget ${source} -O ${destination}",
+      creates => $destination,
+      user    => $user,
+      require => Exec["rbenv::plugin::checkout ${user} ruby-build"],
+    }
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/dependencies/centos.pp

@@ -0,0 +1,25 @@
+class rbenv::dependencies::centos {
+
+  # These are the "build essentials" for RHEL / CentOS
+  if ! defined(Package['autoconf'])  { package { 'autoconf':  ensure => installed } }
+  if ! defined(Package['automake'])  { package { 'automake':  ensure => installed } }
+  if ! defined(Package['binutils'])  { package { 'binutils':  ensure => installed } }
+  if ! defined(Package['bison'])     { package { 'bison':     ensure => installed } }
+  if ! defined(Package['flex'])      { package { 'flex':      ensure => installed } }
+  if ! defined(Package['gcc'])       { package { 'gcc':       ensure => installed } }
+  if ! defined(Package['gcc-c++'])   { package { 'gcc-c++':   ensure => installed } }
+  if ! defined(Package['gettext'])   { package { 'gettext':   ensure => installed } }
+  if ! defined(Package['libtool'])   { package { 'libtool':   ensure => installed } }
+  if ! defined(Package['make'])      { package { 'make':      ensure => installed } }
+  if ! defined(Package['patch'])     { package { 'patch':     ensure => installed } }
+  if ! defined(Package['pkgconfig']) { package { 'pkgconfig': ensure => installed } }
+
+  # Other packages required to build a proper Ruby
+  if ! defined(Package['readline-devel']) { package { 'readline-devel': ensure => installed } }
+  if ! defined(Package['openssl-devel'])  { package { 'openssl-devel':  ensure => installed } }
+  if ! defined(Package['zlib-devel'])     { package { 'zlib-devel':     ensure => installed } }
+
+  # Git and curl are needed for rbenv and ruby-build
+  if ! defined(Package['git'])  { package { 'git':  ensure => installed } }
+  if ! defined(Package['curl']) { package { 'curl': ensure => installed } }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/dependencies/suse.pp

@@ -0,0 +1,28 @@
+class rbenv::dependencies::suse {
+
+  # These are the "build essentials" for SuSE
+  if ! defined(Package['autoconf'])  { package { 'autoconf' : ensure => installed } }
+  if ! defined(Package['automake'])  { package { 'automake' : ensure => installed } }
+  if ! defined(Package['binutils'])  { package { 'binutils' : ensure => installed } }
+  if ! defined(Package['bison'])     { package { 'bison'    : ensure => installed } }
+  if ! defined(Package['flex'])      { package { 'flex'     : ensure => installed } }
+  if ! defined(Package['gcc'])       { package { 'gcc'      : ensure => installed } }
+  if ! defined(Package['gcc-c++'])   { package { 'gcc-c++'  : ensure => installed } }
+  if ! defined(Package['gettext'])   { package { 'gettext'  : ensure => installed, name => 'gettext-tools' } }
+  if ! defined(Package['libtool'])   { package { 'libtool'  : ensure => installed } }
+  if ! defined(Package['make'])      { package { 'make'     : ensure => installed } }
+  if ! defined(Package['patch'])     { package { 'patch'    : ensure => installed } }
+  if ! defined(Package['pkgconfig']) { package { 'pkgconfig': ensure => installed, name => 'pkg-config' } }
+
+  # Other packages required to build a proper Ruby
+  if ! defined(Package['readline-devel']) { package { 'readline-devel': ensure => installed } }
+  if ! defined(Package['openssl-devel'])  { package { 'openssl-devel' : ensure => installed, name => 'libopenssl-devel'} }
+  if ! defined(Package['zlib-devel'])     { package { 'zlib-devel'    : ensure => installed } }
+  if ! defined(Package['libyaml-devel'])  { package { 'libyaml-devel' : ensure => installed } }
+  if ! defined(Package['ncurses-devel'])  { package { 'ncurses-devel' : ensure => installed } }
+
+  # Git and curl are needed for rbenv and ruby-build
+  if ! defined(Package['git'])  { package { 'git'  : ensure => installed } }
+  if ! defined(Package['curl']) { package { 'curl' : ensure => installed } }
+
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/dependencies/ubuntu.pp

@@ -0,0 +1,17 @@
+class rbenv::dependencies::ubuntu {
+  if ! defined(Package['build-essential'])  { package { 'build-essential':  ensure => installed } }
+  if ! defined(Package['libc6-dev'])        { package { 'libc6-dev':        ensure => installed } }
+  if ! defined(Package['bison'])            { package { 'bison':            ensure => installed } }
+  if ! defined(Package['openssl'])          { package { 'openssl':          ensure => installed } }
+  if ! defined(Package['libreadline6'])     { package { 'libreadline6':     ensure => installed } }
+  if ! defined(Package['libreadline6-dev']) { package { 'libreadline6-dev': ensure => installed } }
+  if ! defined(Package['zlib1g'])           { package { 'zlib1g':           ensure => installed } }
+  if ! defined(Package['zlib1g-dev'])       { package { 'zlib1g-dev':       ensure => installed } }
+  if ! defined(Package['libssl-dev'])       { package { 'libssl-dev':       ensure => installed } }
+  if ! defined(Package['libyaml-dev'])      { package { 'libyaml-dev':      ensure => installed } }
+  if ! defined(Package['libxml2-dev'])      { package { 'libxml2-dev':      ensure => installed } }
+  if ! defined(Package['libxslt1-dev'])     { package { 'libxslt1-dev':     ensure => installed, alias =>'libxslt-dev' } }
+  if ! defined(Package['autoconf'])         { package { 'autoconf':         ensure => installed } }
+  if ! defined(Package['git'])              { package { 'git':              ensure => installed, name => 'git-core' } }
+  if ! defined(Package['curl'])             { package { 'curl':             ensure => installed } }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/dependencies.pp

@@ -0,0 +1,8 @@
+class rbenv::dependencies {
+  case $::osfamily {
+    debian  : { require rbenv::dependencies::ubuntu }
+    redhat  : { require rbenv::dependencies::centos }
+    suse    : { require rbenv::dependencies::suse   }
+    default : { notice("Could not load dependencies for ${::osfamily}") }
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/gem.pp

@@ -0,0 +1,29 @@
+# Install a gem under rbenv for a certain user's ruby version.
+# Requires rbenv::compile for the passed in user and ruby version
+#
+define rbenv::gem(
+  $user,
+  $ruby,
+  $gem    = $title,
+  $home   = '',
+  $root   = '',
+  $ensure = present
+) {
+
+  # Workaround http://projects.puppetlabs.com/issues/9848
+  $home_path = $home ? { '' => "/home/${user}", default => $home }
+  $root_path = $root ? { '' => "${home_path}/.rbenv", default => $root }
+
+  if ! defined( Exec["rbenv::compile ${user} ${ruby}"] ) {
+    fail("Rbenv-Ruby ${ruby} for user ${user} not found in catalog")
+  }
+
+  rbenvgem {"${user}/${ruby}/${gem}/${ensure}":
+    ensure  => $ensure,
+    user    => $user,
+    gemname => $gem,
+    ruby    => $ruby,
+    rbenv   => "${root_path}/versions/${ruby}",
+    require => Exec["rbenv::compile ${user} ${ruby}"],
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/install.pp

@@ -0,0 +1,55 @@
+define rbenv::install(
+  $user  = $title,
+  $group = $user,
+  $home  = '',
+  $root  = '',
+  $rc    = ".profile"
+) {
+
+  # Workaround http://projects.puppetlabs.com/issues/9848
+  $home_path = $home ? { '' => "/home/${user}", default => $home }
+  $root_path = $root ? { '' => "${home_path}/.rbenv", default => $root }
+
+  $rbenvrc = "${home_path}/.rbenvrc"
+  $shrc  = "${home_path}/${rc}"
+
+  if ! defined( Class['rbenv::dependencies'] ) {
+    require rbenv::dependencies
+  }
+
+  exec { "rbenv::checkout ${user}":
+    command => "git clone git://github.com/sstephenson/rbenv.git ${root_path}",
+    user    => $user,
+    group   => $group,
+    creates => $root_path,
+    path    => ['/usr/bin', '/usr/sbin'],
+    timeout => 100,
+    cwd => $home_path,
+    require => Package['git'],
+  }
+
+  file { "rbenv::rbenvrc ${user}":
+    path    => $rbenvrc,
+    owner   => $user,
+    group   => $group,
+    content => template('rbenv/dot.rbenvrc.erb'),
+    require => Exec["rbenv::checkout ${user}"],
+  }
+
+  exec { "rbenv::shrc ${user}":
+    command => "echo 'source ${rbenvrc}' >> ${shrc}",
+    user    => $user,
+    group   => $group,
+    unless  => "grep -q rbenvrc ${shrc}",
+    path    => ['/bin', '/usr/bin', '/usr/sbin'],
+    require => File["rbenv::rbenvrc ${user}"],
+  }
+
+  file { "rbenv::cache-dir ${user}":
+    owner   => $user,
+    group   => $group,
+    ensure  => directory,
+    path    => "${root_path}/cache",
+    require => Exec["rbenv::checkout ${user}"]
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/plugin/rbenvvars.pp

@@ -0,0 +1,16 @@
+define rbenv::plugin::rbenvvars(
+  $user   = $title,
+  $source = 'git://github.com/sstephenson/rbenv-vars.git',
+  $group  = $user,
+  $home   = '',
+  $root   = ''
+) {
+  rbenv::plugin { "rbenv::plugin::rbenvvars::${user}":
+    user        => $user,
+    source      => $source,
+    plugin_name => 'rbenv-vars',
+    group       => $group,
+    home        => $home,
+    root        => $root
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/plugin/rubybuild.pp

@@ -0,0 +1,16 @@
+define rbenv::plugin::rubybuild(
+  $user   = $title,
+  $source = 'git://github.com/sstephenson/ruby-build.git',
+  $group  = $user,
+  $home   = '',
+  $root   = ''
+) {
+  rbenv::plugin { "rbenv::plugin::rubybuild::${user}":
+    user        => $user,
+    source      => $source,
+    plugin_name => 'ruby-build',
+    group       => $group,
+    home        => $home,
+    root        => $root
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/manifests/plugin.pp

@@ -0,0 +1,40 @@
+define rbenv::plugin(
+  $user,
+  $source,
+  $plugin_name = $title,
+  $group       = $user,
+  $home        = '',
+  $root        = '',
+  $timeout     = 100
+) {
+
+  $home_path   = $home ? { '' => "/home/${user}",       default => $home }
+  $root_path   = $root ? { '' => "${home_path}/.rbenv", default => $root }
+  $plugins     = "${root_path}/plugins"
+  $destination = "${plugins}/${plugin_name}"
+
+  if $source !~ /^git:/ {
+    fail('Only git plugins are supported')
+  }
+
+  if ! defined(File["rbenv::plugins ${user}"]) {
+    file { "rbenv::plugins ${user}":
+      ensure  => directory,
+      path    => $plugins,
+      owner   => $user,
+      group   => $group,
+      require => Exec["rbenv::checkout ${user}"],
+    }
+  }
+
+  exec { "rbenv::plugin::checkout ${user} ${plugin_name}":
+    command => "git clone ${source} ${destination}",
+    user    => $user,
+    group   => $group,
+    creates => $destination,
+    path    => ['/usr/bin', '/usr/sbin'],
+    timeout => $timeout,
+    cwd => $home_path,
+    require => File["rbenv::plugins ${user}"],
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/metadata.json

@@ -0,0 +1,109 @@
+{
+  "name": "alup-rbenv",
+  "version": "1.2.0",
+  "source": "UNKNOWN",
+  "author": "alup",
+  "license": "MIT",
+  "summary": "rbenv Ruby Version Manager module",
+  "description": "Puppet module for rbenv Ruby Version Manager",
+  "project_page": "https://github.com/alup/puppet-rbenv",
+  "dependencies": [
+
+  ],
+  "types": [
+    {
+      "name": "rbenvgem",
+      "doc": "A Ruby Gem installed inside an rbenv-installed Ruby",
+      "properties": [
+        {
+          "name": "ensure",
+          "doc": "  Valid values are `present` (also called `installed`), `absent`, `latest`.  Values can match `/./`."
+        }
+      ],
+      "parameters": [
+        {
+          "name": "name",
+          "doc": "Gem qualified name within an rbenv repository"
+        },
+        {
+          "name": "gemname",
+          "doc": "The Gem name"
+        },
+        {
+          "name": "ruby",
+          "doc": "The ruby interpreter version"
+        },
+        {
+          "name": "rbenv",
+          "doc": "The rbenv root"
+        },
+        {
+          "name": "user",
+          "doc": "The rbenv owner"
+        }
+      ],
+      "providers": [
+        {
+          "name": "default",
+          "doc": "Maintains gems inside an RBenv setup\n\nRequired binaries: `su`."
+        }
+      ]
+    }
+  ],
+  "checksums": {
+    "AUTHORS": "41bce6ef435e4c4fb01a3c7662477d58",
+    "CHANGELOG.md": "d075b1f284329fff6d5175dbb3278cbc",
+    "Gemfile": "f68769c7bd5266f1a4de0607fd78d17a",
+    "Gemfile.lock": "571d1b5c4b633773b97a88c8a2974581",
+    "Modulefile": "3bb3b412457d726bb0a7318ac4562fa4",
+    "README.md": "09fcaeb15a0ad5096f1c6f1ff6e999fb",
+    "Rakefile": "7bb6178549213331858bf2512a4f6a17",
+    "TODO": "829d2a329bf2974b9d8af868cf35db94",
+    "bin/autospec": "d4fde3f4a9f1e5fd339228026654cb70",
+    "bin/facter": "54901e1d789da4ff3303d45a6d66fc03",
+    "bin/filebucket": "770eee5e0fb7f1013abce8041bc9d407",
+    "bin/hiera": "60a41938163cc8af0b56456abcbdfcd3",
+    "bin/htmldiff": "8d551a540666732a11d6caa9aa3a0e68",
+    "bin/ldiff": "3104dda81ce6a8c0bf122df6ac851365",
+    "bin/pi": "b72c410b2de13e2f58526a53cdd8c6b2",
+    "bin/puppet": "5349ed70b05332a13b83ba8077dd0043",
+    "bin/puppet-lint": "7f9089954f23d779e8ce05a4a53cf440",
+    "bin/puppet-module": "5598cb513ff52a621e80d124010ddccb",
+    "bin/puppetca": "bc1f6643a1f5752c10f9cd1d967f6339",
+    "bin/puppetd": "90205a5cf917d78fd2be85a565b7fbc5",
+    "bin/puppetdoc": "93170c3ea411bce6d11d8d6fc96bdf49",
+    "bin/puppetmasterd": "dd139c09d5e3f04c103f4ba80221432d",
+    "bin/puppetqd": "f3e6ac649b6e2b9f637dee3c7e6c8c1e",
+    "bin/puppetrun": "de8fea72006efd65a4efd0c092e6dd39",
+    "bin/rake": "d09495e1a29ed0015941718d92deb28b",
+    "bin/ralsh": "ac7d134c175adfdd682f5b73b157e81e",
+    "bin/rspec": "00ed29f02ccbfaf09483109846c4a9c3",
+    "bin/rspec-puppet-init": "6cd42b0ad1382d8a870c1f75caf67a50",
+    "lib/puppet/provider/rbenvgem/default.rb": "e4f6ccda50b6b34aa1cacbb565082fa0",
+    "lib/puppet/type/rbenvgem.rb": "a3d2f7f9e4ce273d2d58ac86a59377c5",
+    "manifests/bundle.pp": "352b95944faacc82cfb15ef3e8eadd36",
+    "manifests/client.pp": "c6be48e076e539dfb67f64fa20dc26d6",
+    "manifests/compile.pp": "050f1bedccea7e4bf060baa002bf9e93",
+    "manifests/definition.pp": "1cfd81042f40aaf34dbb32936c2a3a3a",
+    "manifests/dependencies/centos.pp": "71057409e9760e3d53ad7f2a9d862874",
+    "manifests/dependencies/suse.pp": "fe7e6bffa09f1bc30f21f77e9c911ada",
+    "manifests/dependencies/ubuntu.pp": "803d58aabe0f752e5e1182b15f1991fe",
+    "manifests/dependencies.pp": "3a23ca0524928ae39396c451d938319e",
+    "manifests/gem.pp": "d4614ec9f988e707ad7b852169cb9e20",
+    "manifests/install.pp": "93f1a0ff0cb1b2845567871299161d79",
+    "manifests/plugin/rbenvvars.pp": "e9f977b7d5f4c1af85f65b60e04bf145",
+    "manifests/plugin/rubybuild.pp": "d8f5df37e2e4f0dbd83145f7cdabf79f",
+    "manifests/plugin.pp": "cd89bbf44c3418fefb26a49117957617",
+    "spec/classes/dependencies_spec.rb": "6f39406d29bb15e4e2b9155ae09f0daf",
+    "spec/defines/rbenv__compile_spec.rb": "b9e07a69c8cd7acbd887fdfba870ddd8",
+    "spec/defines/rbenv__definition_spec.rb": "a94134d4a5be5f021ae53489398f74a3",
+    "spec/defines/rbenv__install_spec.rb": "044888bc54fc109eb0c22619bca86ffb",
+    "spec/defines/rbenv__plugin__rbenvvars_spec.rb": "781cdf9a2a0e0f466636d981d19034b0",
+    "spec/defines/rbenv__plugin__rubybuild_spec.rb": "24132e11ad1558227175280ee8fda08f",
+    "spec/defines/rbenv__plugin_spec.rb": "0b172008a61009ceac28625f4788ff4b",
+    "spec/fixtures/manifests/site.pp": "d41d8cd98f00b204e9800998ecf8427e",
+    "spec/spec_helper.rb": "d5f3f46cba1721d2ad62fe96aad002c6",
+    "templates/Gemfile.erb": "c1b501d75ff589a4d2f54c1fc2674283",
+    "templates/dot.rbenvrc.erb": "dc88eda08086172606be9e1b4b87d90e"
+  }
+}

data/lib/templates/puppet/step-0/modules/rbenv/templates/Gemfile.erb

@@ -0,0 +1,5 @@
+source :rubygems
+
+<%- @gems.each do |gem| -%>
+gem '<%= gem %>'
+<% end %>

data/lib/templates/puppet/step-0/modules/rbenv/templates/dot.rbenvrc.erb

@@ -0,0 +1,8 @@
+#
+# This is a shell fragment that initializes rbenv, if it
+# has not been inited yet. Managed by puppet - DO NOT EDIT
+#
+if ! echo $PATH | grep -q rbenv; then
+  export PATH="<%= @root_path %>/bin:$PATH"
+  eval "$(rbenv init -)"
+fi