azure-blob 0.4.1 → 0.5.0

data/main.tf

@@ -0,0 +1,187 @@
+terraform {
+  required_providers {
+    azurerm = {
+      source  = "hashicorp/azurerm"
+      version = "~>3.0"
+    }
+  }
+}
+
+provider "azurerm" {
+  features {}
+}
+
+locals {
+  public_ssh_key = var.ssh_key != "" ? var.ssh_key : file("~/.ssh/id_rsa.pub")
+}
+
+resource "azurerm_resource_group" "main" {
+  name     = var.prefix
+  location = var.location
+  tags = {
+    source = "Terraform"
+  }
+}
+
+resource "azurerm_storage_account" "main" {
+  name                     = var.storage_account_name
+  resource_group_name      = azurerm_resource_group.main.name
+  location                 = azurerm_resource_group.main.location
+  account_tier             = "Standard"
+  account_replication_type = "LRS"
+
+  tags = {
+    source = "Terraform"
+  }
+}
+
+resource "azurerm_storage_container" "private" {
+  name                  = "private"
+  storage_account_name  = azurerm_storage_account.main.name
+  container_access_type = "private"
+}
+
+resource "azurerm_storage_container" "public" {
+  name                  = "public"
+  storage_account_name  = azurerm_storage_account.main.name
+  container_access_type = "blob"
+}
+
+resource "azurerm_virtual_network" "main" {
+  count               = var.create_vm ? 1 : 0
+  name                = "${var.prefix}-network"
+  address_space       = ["10.0.0.0/16"]
+  location            = azurerm_resource_group.main.location
+  resource_group_name = azurerm_resource_group.main.name
+
+  tags = {
+    source = "Terraform"
+  }
+}
+
+resource "azurerm_subnet" "main" {
+  count                = var.create_vm ? 1 : 0
+  name                 = "${var.prefix}-main"
+  resource_group_name  = azurerm_resource_group.main.name
+  virtual_network_name = azurerm_virtual_network.main[0].name
+  address_prefixes     = ["10.0.2.0/24"]
+}
+
+resource "azurerm_network_interface" "main" {
+  count               = var.create_vm ? 1 : 0
+  name                = "${var.prefix}-nic"
+  location            = azurerm_resource_group.main.location
+  resource_group_name = azurerm_resource_group.main.name
+
+  ip_configuration {
+    name                          = "${var.prefix}-ip-config"
+    subnet_id                     = azurerm_subnet.main[0].id
+    private_ip_address_allocation = "Dynamic"
+    public_ip_address_id          = azurerm_public_ip.main[0].id
+  }
+
+  tags = {
+    source = "Terraform"
+  }
+}
+
+resource "azurerm_public_ip" "main" {
+  count               = var.create_vm ? 1 : 0
+  name                = "${var.prefix}-public-ip"
+  resource_group_name = azurerm_resource_group.main.name
+  location            = azurerm_resource_group.main.location
+  allocation_method   = "Static"
+
+  tags = {
+    source = "Terraform"
+  }
+}
+
+resource "azurerm_user_assigned_identity" "vm" {
+  location            = azurerm_resource_group.main.location
+  name                = "${var.prefix}-vm"
+  resource_group_name = azurerm_resource_group.main.name
+}
+
+
+resource "azurerm_role_assignment" "vm" {
+  scope                = azurerm_storage_account.main.id
+  role_definition_name = "Storage Blob Data Contributor"
+  principal_id         = azurerm_user_assigned_identity.vm.principal_id
+}
+
+resource "azurerm_linux_virtual_machine" "main" {
+  count                           = var.create_vm ? 1 : 0
+  name                            = "${var.prefix}-vm"
+  computer_name                   = var.prefix
+  resource_group_name             = azurerm_resource_group.main.name
+  location                        = azurerm_resource_group.main.location
+  size                            = var.vm_size
+  admin_username                  = var.vm_username
+  admin_password                  = var.vm_password
+  disable_password_authentication = true
+  network_interface_ids           = [azurerm_network_interface.main[0].id]
+
+  identity {
+    type         = "UserAssigned"
+    identity_ids = [azurerm_user_assigned_identity.vm.id]
+  }
+
+  admin_ssh_key {
+    username   = var.vm_username
+    public_key = local.public_ssh_key
+  }
+
+  source_image_reference {
+    publisher = "Canonical"
+    offer     = "0001-com-ubuntu-server-jammy"
+    sku       = "22_04-lts"
+    version   = "latest"
+  }
+
+  os_disk {
+    caching              = "ReadWrite"
+    storage_account_type = "Standard_LRS"
+  }
+
+  tags = {
+    source = "Terraform"
+  }
+}
+
+resource "azurerm_service_plan" "main" {
+  count               = var.create_app_service ? 1 : 0
+  name                = "${var.prefix}-appserviceplan"
+  resource_group_name = azurerm_resource_group.main.name
+  location            = azurerm_resource_group.main.location
+  os_type             = "Linux"
+  sku_name            = "B1"
+}
+
+resource "azurerm_linux_web_app" "main" {
+  count               = var.create_app_service ? 1 : 0
+  name                = "${var.prefix}-app"
+  service_plan_id     = azurerm_service_plan.main[0].id
+  resource_group_name = azurerm_resource_group.main.name
+  location            = azurerm_resource_group.main.location
+
+  identity {
+    type         = "UserAssigned"
+    identity_ids = [azurerm_user_assigned_identity.vm.id]
+  }
+
+  site_config {
+    application_stack {
+      node_version = "20-lts"
+    }
+  }
+}
+
+resource "azurerm_app_service_source_control" "main" {
+  count                  = var.create_app_service ? 1 : 0
+  app_id                 = azurerm_linux_web_app.main[0].id
+  repo_url               = "https://github.com/Azure-Samples/nodejs-docs-hello-world"
+  branch                 = "master"
+  use_manual_integration = true
+  use_mercurial          = false
+}

data/output.tf

@@ -0,0 +1,30 @@
+output "devenv_local_nix" {
+  sensitive = true
+  value     = <<EOT
+{pkgs, lib, ...}:{
+  env = {
+    AZURE_ACCOUNT_NAME = "${azurerm_storage_account.main.name}";
+    AZURE_ACCESS_KEY = "${azurerm_storage_account.main.primary_access_key}";
+    AZURE_PRIVATE_CONTAINER = "${azurerm_storage_container.private.name}";
+    AZURE_PUBLIC_CONTAINER = "${azurerm_storage_container.public.name}";
+    AZURE_PRINCIPAL_ID = "${azurerm_user_assigned_identity.vm.principal_id}";
+  };
+}
+EOT
+}
+
+output "vm_ip" {
+  value = var.create_vm ? azurerm_public_ip.main[0].ip_address : ""
+}
+
+output "vm_username" {
+  value = var.vm_username
+}
+
+output "app_service_app_name" {
+  value = var.create_app_service ? azurerm_linux_web_app.main[0].name : ""
+}
+
+output "resource_group" {
+  value = azurerm_resource_group.main.name
+}

metadata

@@ -1,7 +1,7 @@
 --- !ruby/object:Gem::Specification
 name: azure-blob
 version: !ruby/object:Gem::Version
-  version: 0.4.1
+  version: 0.5.0
 platform: ruby
 authors:
 - Joé Dupuis
@@ -34,6 +34,7 @@ files:
 - ".envrc"
 - ".rubocop.yml"
 - ".standard.yml"
+- ".terraform.lock.hcl"
 - CHANGELOG.md
 - LICENSE.txt
 - README.md
@@ -43,6 +44,7 @@ files:
 - devenv.lock
 - devenv.nix
 - devenv.yaml
+- input.tf
 - lib/active_storage/service/azure_blob_service.rb
 - lib/azure_blob.rb
 - lib/azure_blob/blob.rb
@@ -52,18 +54,24 @@ files:
 - lib/azure_blob/canonicalized_resource.rb
 - lib/azure_blob/client.rb
 - lib/azure_blob/const.rb
+- lib/azure_blob/entra_id_signer.rb
 - lib/azure_blob/errors.rb
 - lib/azure_blob/http.rb
+- lib/azure_blob/identity_token.rb
 - lib/azure_blob/metadata.rb
-- lib/azure_blob/signer.rb
+- lib/azure_blob/shared_key_signer.rb
+- lib/azure_blob/user_delegation_key.rb
 - lib/azure_blob/version.rb
-homepage: https://github.com/JoeDupuis/azure-blob
+- main.tf
+- output.tf
+homepage: https://github.com/testdouble/azure-blob
 licenses:
 - MIT
 metadata:
-  homepage_uri: https://github.com/JoeDupuis/azure-blob
-  source_code_uri: https://github.com/JoeDupuis/azure-blob
-  changelog_uri: https://github.com/JoeDupuis/azure-blob/blob/main/CHANGELOG.md
+  rubygems_mfa_required: 'true'
+  homepage_uri: https://github.com/testdouble/azure-blob
+  source_code_uri: https://github.com/testdouble/azure-blob
+  changelog_uri: https://github.com/testdouble/azure-blob/blob/main/CHANGELOG.md
 post_install_message:
 rdoc_options: []
 require_paths: