azd 0.9.0

data/lib/generators/templates/infra/main.bicep

@@ -0,0 +1,243 @@
+targetScope = 'subscription'
+
+// The main bicep module to provision Azure resources.
+// For a more complete walkthrough to understand how this file works with azd,
+// see https://learn.microsoft.com/en-us/azure/developer/azure-developer-cli/make-azd-compatible?pivots=azd-create
+
+@minLength(1)
+@maxLength(64)
+@description('Name of the the environment which is used to generate a short unique hash used in all resources.')
+param environmentName string
+
+@minLength(1)
+@description('Primary location for all resources')
+param location string
+
+@secure()
+@description('PostGreSQL Server administrator password')
+param postgresAdminPassword string
+
+@secure()
+@description('Rails SECRET_KEY_BASE for cryptographic signing')
+param railsSecretKeyBase string
+
+@secure()
+@description('Rails RAILS_MASTER_KEY for secret encryption')
+param railsMasterKey string
+
+// Optional parameters to override the default azd resource naming conventions.
+// Add the following to main.parameters.json to provide values:
+// "resourceGroupName": {
+//      "value": "myGroupName"
+// }
+@description('Resource group name')
+param resourceGroupName string = ''
+
+@description('PostgreSQL database name')
+param postgresDatabaseName string = 'azure_rails_starter_production'
+
+@description('Keyvault resource name')
+param keyVaultName string = ''
+
+@description('Azure Container Apps identity name')
+param identityName string = ''
+
+@description('If true use existing Azure Container Apps instance')
+param acaExists bool = false
+
+var abbrs = loadJsonContent('./abbreviations.json')
+
+var tags = {
+  'azd-env-name': environmentName
+}
+
+// Generate a unique token to be used in naming resources.
+// Remove linter suppression after using.
+#disable-next-line no-unused-vars
+var resourceToken = toLower(uniqueString(subscription().id, environmentName, location))
+
+// Name of the service defined in azure.yaml
+// A tag named azd-service-name with this value should be applied to the service host resource, such as:
+//   Microsoft.Web/sites for appservice, function
+// Example usage:
+//   tags: union(tags, { 'azd-service-name': apiServiceName })
+var appServiceName = 'azure-rails-starter'
+
+// Organize resources in a resource group
+resource resourceGroup 'Microsoft.Resources/resourceGroups@2021-04-01' = {
+  name: !empty(resourceGroupName) ? resourceGroupName : '${abbrs.resourcesResourceGroups}${environmentName}'
+  location: location
+  tags: tags
+}
+
+var prefix = '${environmentName}-${resourceToken}'
+var railsIdentityName = !empty(identityName)
+  ? identityName
+  : '${abbrs.managedIdentityUserAssignedIdentities}rails-${environmentName}'
+var postgresServerName = '${abbrs.dBforPostgreSQLServers}${prefix}'
+var postgresAdminUser = 'admin${uniqueString(resourceGroup.id)}'
+
+// Add resources to be provisioned below.
+// A full example that leverages azd bicep modules can be seen in the todo-python-mongo template:
+// https://github.com/Azure-Samples/todo-python-mongo/tree/main/infra
+
+module railsIdentity 'identity.bicep' = {
+  name: 'identity'
+  scope: resourceGroup
+  params: {
+    name: railsIdentityName
+    location: location
+    tags: tags
+  }
+}
+
+module logAnalyticsWorkspace 'core/monitor/loganalytics.bicep' = {
+  name: 'loganalytics'
+  scope: resourceGroup
+  params: {
+    name: '${prefix}-loganalytics'
+    location: location
+    tags: tags
+  }
+}
+
+module postgresServer 'core/database/postgresql/flexibleserver.bicep' = {
+  name: 'postgresql'
+  scope: resourceGroup
+  params: {
+    name: postgresServerName
+    location: location
+    tags: tags
+    sku: {
+      name: 'Standard_B1ms'
+      tier: 'Burstable'
+    }
+    storage: {
+      storageSizeGB: 32
+    }
+    version: '14'
+    administratorLogin: postgresAdminUser
+    administratorLoginPassword: postgresAdminPassword
+    databaseNames: [postgresDatabaseName]
+    allowAzureIPsFirewall: true
+    azureExtensions: ['PLPGSQL']
+  }
+}
+
+module containerApps 'core/host/container-apps.bicep' = {
+  name: 'container-apps'
+  scope: resourceGroup
+  params: {
+    name: 'app'
+    location: location
+    tags: tags
+    containerAppsEnvironmentName: '${prefix}-containerapps-env'
+    containerRegistryName: '${replace(prefix, '-', '')}registry'
+    logAnalyticsWorkspaceName: logAnalyticsWorkspace.outputs.name
+  }
+}
+
+module keyVault './core/security/keyvault.bicep' = {
+  name: 'keyvault'
+  scope: resourceGroup
+  params: {
+    name: !empty(keyVaultName) ? keyVaultName : '${abbrs.keyVaultVaults}${resourceToken}'
+    location: location
+    tags: tags
+    identityName: railsIdentity.outputs.name
+  }
+}
+
+module keyVaultAccess './core/security/keyvault-access.bicep' = {
+  name: 'keyvault-access'
+  scope: resourceGroup
+  params: {
+    keyVaultName: keyVault.outputs.name
+    principalId: railsIdentity.outputs.principalId
+  }
+}
+
+module keyVaultSecretPostgresAdminPassword './core/security/keyvault-secret.bicep' = {
+  name: 'keyvault-secret-postgres-admin-password'
+  scope: resourceGroup
+  params: {
+    keyVaultName: keyVault.outputs.name
+    name: 'postgres-admin-password'
+    secretValue: postgresAdminPassword
+  }
+}
+
+module keyVaultSecretDatabaseUrl './core/security/keyvault-secret.bicep' = {
+  name: 'keyvault-secret-database-url'
+  scope: resourceGroup
+  params: {
+    keyVaultName: keyVault.outputs.name
+    name: 'database-url'
+    secretValue: 'postgresql://${postgresAdminUser}:${postgresAdminPassword}@${postgresServer.outputs.POSTGRES_DOMAIN_NAME}:5432/${postgresDatabaseName}?connect_timeout=5&sslmode=require'
+  }
+}
+
+module keyVaultSecretSecretKeyBase './core/security/keyvault-secret.bicep' = {
+  name: 'keyvault-secret-secret-key-base'
+  scope: resourceGroup
+  params: {
+    keyVaultName: keyVault.outputs.name
+    name: 'secret-key-base'
+    secretValue: railsSecretKeyBase
+  }
+}
+
+module keyVaultSecretRailsMasterKey './core/security/keyvault-secret.bicep' = {
+  name: 'keyvault-secret-rails-master-key'
+  scope: resourceGroup
+  params: {
+    keyVaultName: keyVault.outputs.name
+    name: 'rails-master-key'
+    secretValue: railsMasterKey
+  }
+}
+
+module rails 'rails.bicep' = {
+  name: 'rails'
+  scope: resourceGroup
+  params: {
+    name: replace('${take(prefix,19)}-ca', '--', '-')
+    location: location
+    tags: tags
+    identityName: railsIdentity.outputs.name
+    containerAppsEnvironmentName: containerApps.outputs.environmentName
+    containerRegistryName: containerApps.outputs.registryName
+    serviceName: appServiceName
+    exists: acaExists
+    keyVaultName: keyVault.outputs.name
+  }
+  dependsOn: [
+    keyVaultSecretDatabaseUrl
+    keyVaultSecretSecretKeyBase
+    keyVaultAccess
+  ]
+}
+
+// Add outputs from the deployment here, if needed.
+//
+// This allows the outputs to be referenced by other bicep deployments in the deployment pipeline,
+// or by the local machine as a way to reference created resources in Azure for local development.
+// Secrets should not be added here.
+//
+// Outputs are automatically saved in the local azd environment .env file.
+// To see these outputs, run `azd env get-values`,  or `azd env get-values --output json` for json output.
+
+output AZURE_LOCATION string = location
+output AZURE_RESOURCE_GROUP_NAME string = resourceGroup.name
+output AZURE_TENANT_ID string = tenant().tenantId
+output AZURE_KEY_VAULT_NAME string = keyVault.outputs.name
+
+output SERVICE_RAILS_IDENTITY_PRINCIPAL_ID string = rails.outputs.SERVICE_RAILS_IDENTITY_PRINCIPAL_ID
+output SERVICE_RAILS_NAME string = rails.outputs.SERVICE_RAILS_NAME
+output SERVICE_RAILS_URI string = rails.outputs.SERVICE_RAILS_URI
+output SERVICE_RAILS_IMAGE_NAME string = rails.outputs.SERVICE_RAILS_IMAGE_NAME
+output SERVICE_RAILS_DATABASE_NAME string = postgresDatabaseName
+
+output AZURE_CONTAINER_ENVIRONMENT_NAME string = containerApps.outputs.environmentName
+output AZURE_CONTAINER_REGISTRY_ENDPOINT string = containerApps.outputs.registryLoginServer
+output AZURE_CONTAINER_REGISTRY_NAME string = containerApps.outputs.registryName

data/lib/generators/templates/infra/main.parameters.json

@@ -0,0 +1,25 @@
+{
+  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
+  "contentVersion": "1.0.0.0",
+  "parameters": {
+    "environmentName": {
+      "value": "${AZURE_ENV_NAME}"
+    },
+    "location": {
+      "value": "${AZURE_LOCATION}"
+    },
+
+    "postgresAdminPassword": {
+      "value": "$(secretOrRandomPassword ${AZURE_KEY_VAULT_NAME} postgres-admin-password)"
+    },
+    "railsSecretKeyBase": {
+      "value": "${SECRET_KEY_BASE}"
+    },
+    "railsMasterKey": {
+      "value": "${RAILS_MASTER_KEY}"
+    },
+    "postgresDatabaseName": {
+      "value": "${SERVICE_RAILS_DATABASE_NAME=azure-rails-starter-production}"
+    }
+  }
+}

data/lib/generators/templates/infra/rails.bicep

@@ -0,0 +1,95 @@
+// 
+// Bicep module with the container app definition for a Rails app.
+//
+@description('Name of the container app')
+param name string
+
+@description('Location of the container app')
+param location string = resourceGroup().location
+
+@description('Tags applied on the container app')
+param tags object = {}
+
+@description('Name of the container apps environment')
+param containerAppsEnvironmentName string
+
+@description('Name of the container registry')
+param containerRegistryName string
+
+@description('Service name (will be added as tag "azd-service-name")')
+param serviceName string = 'rails'
+
+@description('If true re-use existing Azure Container App')
+param exists bool
+
+@description('Name of the key vault to use for secret references')
+param keyVaultName string
+
+@description('Name of the managed identity to use for accessing secrets in the key vault')
+param identityName string
+
+module app 'core/host/container-app-upsert.bicep' = {
+  name: '${serviceName}-container-app-module'
+  params: {
+    name: name
+    containerMinReplicas: 0
+    containerMaxReplicas: 3
+    location: location
+    tags: union(tags, { 'azd-service-name': serviceName })
+    identityName: webIdentity.name
+    exists: exists
+    containerAppsEnvironmentName: containerAppsEnvironmentName
+    containerRegistryName: containerRegistryName
+    env: [
+      {
+        name: 'RAILS_ENV'
+        value: 'production'
+      }
+      {
+        name: 'DATABASE_URL'
+        secretRef: 'database-url'
+      }
+      {
+        name: 'SECRET_KEY_BASE'
+        secretRef: 'secret-key-base'
+      }
+      {
+        name: 'RAILS_MASTER_KEY'
+        secretRef: 'rails-master-key'
+      }
+    ]
+    secrets: [
+      {
+        name: 'database-url'
+        keyVaultUrl: '${keyVault.properties.vaultUri}secrets/database-url'
+        identity: webIdentity.id
+      }
+      {
+        name: 'secret-key-base'
+        keyVaultUrl: '${keyVault.properties.vaultUri}secrets/secret-key-base'
+        identity: webIdentity.id
+      }
+      {
+        name: 'rails-master-key'
+        keyVaultUrl: '${keyVault.properties.vaultUri}secrets/rails-master-key'
+        identity: webIdentity.id
+      }
+    ]
+    targetPort: 3000
+  }
+}
+
+resource keyVault 'Microsoft.KeyVault/vaults@2022-07-01' existing = {
+  name: keyVaultName
+}
+
+resource webIdentity 'Microsoft.ManagedIdentity/userAssignedIdentities@2023-01-31' existing = {
+  name: identityName
+}
+
+output SERVICE_RAILS_IDENTITY_PRINCIPAL_ID string = webIdentity.name
+output SERVICE_RAILS_NAME string = app.outputs.name
+output SERVICE_RAILS_URI string = app.outputs.uri
+output SERVICE_RAILS_IMAGE_NAME string = app.outputs.imageName
+
+

metadata

@@ -0,0 +1,115 @@
+--- !ruby/object:Gem::Specification
+name: azd
+version: !ruby/object:Gem::Version
+  version: 0.9.0
+platform: ruby
+authors:
+- Dominique Broeglin
+autorequire:
+bindir: bin
+cert_chain: []
+date: 2024-04-05 00:00:00.000000000 Z
+dependencies:
+- !ruby/object:Gem::Dependency
+  name: railties
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - ">="
+      - !ruby/object:Gem::Version
+        version: '3'
+    - - "<"
+      - !ruby/object:Gem::Version
+        version: '99'
+  type: :runtime
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - ">="
+      - !ruby/object:Gem::Version
+        version: '3'
+    - - "<"
+      - !ruby/object:Gem::Version
+        version: '99'
+description: Contains generators to make a rails application azd compatible
+email:
+executables: []
+extensions: []
+extra_rdoc_files: []
+files:
+- LICENSE
+- README.md
+- lib/generators/azd/install_generator.rb
+- lib/generators/templates/azure.yaml.tt
+- lib/generators/templates/infra/abbreviations.json
+- lib/generators/templates/infra/core/ai/cognitiveservices.bicep
+- lib/generators/templates/infra/core/config/configstore.bicep
+- lib/generators/templates/infra/core/database/cosmos/cosmos-account.bicep
+- lib/generators/templates/infra/core/database/cosmos/mongo/cosmos-mongo-account.bicep
+- lib/generators/templates/infra/core/database/cosmos/mongo/cosmos-mongo-db.bicep
+- lib/generators/templates/infra/core/database/cosmos/sql/cosmos-sql-account.bicep
+- lib/generators/templates/infra/core/database/cosmos/sql/cosmos-sql-db.bicep
+- lib/generators/templates/infra/core/database/cosmos/sql/cosmos-sql-role-assign.bicep
+- lib/generators/templates/infra/core/database/cosmos/sql/cosmos-sql-role-def.bicep
+- lib/generators/templates/infra/core/database/mysql/flexibleserver.bicep
+- lib/generators/templates/infra/core/database/postgresql/flexibleserver.bicep
+- lib/generators/templates/infra/core/database/sqlserver/sqlserver.bicep
+- lib/generators/templates/infra/core/gateway/apim.bicep
+- lib/generators/templates/infra/core/host/aks-agent-pool.bicep
+- lib/generators/templates/infra/core/host/aks-managed-cluster.bicep
+- lib/generators/templates/infra/core/host/aks.bicep
+- lib/generators/templates/infra/core/host/appservice-appsettings.bicep
+- lib/generators/templates/infra/core/host/appservice.bicep
+- lib/generators/templates/infra/core/host/appserviceplan.bicep
+- lib/generators/templates/infra/core/host/container-app-upsert.bicep
+- lib/generators/templates/infra/core/host/container-app.bicep
+- lib/generators/templates/infra/core/host/container-apps-environment.bicep
+- lib/generators/templates/infra/core/host/container-apps.bicep
+- lib/generators/templates/infra/core/host/container-registry.bicep
+- lib/generators/templates/infra/core/host/functions.bicep
+- lib/generators/templates/infra/core/host/staticwebapp.bicep
+- lib/generators/templates/infra/core/monitor/applicationinsights-dashboard.bicep
+- lib/generators/templates/infra/core/monitor/applicationinsights.bicep
+- lib/generators/templates/infra/core/monitor/loganalytics.bicep
+- lib/generators/templates/infra/core/monitor/monitoring.bicep
+- lib/generators/templates/infra/core/networking/cdn-endpoint.bicep
+- lib/generators/templates/infra/core/networking/cdn-profile.bicep
+- lib/generators/templates/infra/core/networking/cdn.bicep
+- lib/generators/templates/infra/core/search/search-services.bicep
+- lib/generators/templates/infra/core/security/aks-managed-cluster-access.bicep
+- lib/generators/templates/infra/core/security/configstore-access.bicep
+- lib/generators/templates/infra/core/security/keyvault-access.bicep
+- lib/generators/templates/infra/core/security/keyvault-secret.bicep
+- lib/generators/templates/infra/core/security/keyvault.bicep
+- lib/generators/templates/infra/core/security/registry-access.bicep
+- lib/generators/templates/infra/core/security/role.bicep
+- lib/generators/templates/infra/core/storage/storage-account.bicep
+- lib/generators/templates/infra/core/testing/loadtesting.bicep
+- lib/generators/templates/infra/identity.bicep
+- lib/generators/templates/infra/main.bicep
+- lib/generators/templates/infra/main.parameters.json
+- lib/generators/templates/infra/rails.bicep
+homepage: https://github.com/dbroeglin/azure-dev-gem
+licenses:
+- MIT
+metadata:
+  source_code_uri: https://github.com/dbroeglin/azure-dev-gem
+post_install_message:
+rdoc_options: []
+require_paths:
+- lib
+required_ruby_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - ">="
+    - !ruby/object:Gem::Version
+      version: 2.7.0
+required_rubygems_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - ">="
+    - !ruby/object:Gem::Version
+      version: '0'
+requirements: []
+rubygems_version: 3.5.7
+signing_key:
+specification_version: 4
+summary: Azure Developer CLI generators gem
+test_files: []